Применение рекурсивных функций при построении отчета с иерархией

////////////////////////////////////////////////////////////////////////////////
// ПоместитьЭлементВДерево(Элемент, Количество, ДеревоЭлементов)
//
// Параметры:
//   Элемент      - СправочникСсылка. Элемент справочника, который необходимо 
//              поместить в дерево "ДеревоЭлементов";
//   Количество      - Число. Количество элемента или итог количества элементов по 
//              группе;
//   ДеревоЭлементов   - ДеревоЗначений. Дерево значений, в которое необходимо 
//              поместить элемент справочника "Элемент". Структура
//              дерева:
//              1. Элемент   - СправочникСсылка;
//              2. Количество   - Число.
//
// Описание:
//   Процедура добавляет элемент справочника "Элемент" и его количество "Количество" в дерево 
//   "ДеревоЭлементов". Элементы   добавляются в дерево с учетом иерархии элементов в справочнике.
//   По группам элементов, формируются итоги по количеству.
Процедура ПоместитьЭлементВДерево(Элемент, Количество, ДеревоЭлементов)

   // Если строка элемента уже есть в дереве, то новую создавать не будем
   ДеревоЭлементовСтрокаЭлемента = ДеревоЭлементов.Строки.Найти(Элемент, "Элемент", Истина);
   
   // Если у элемента есть родитель, то сначала необходимо поместить в дерево родителя
   ЭлементРодитель = Элемент.Родитель;
      
   Если ЗначениеЗаполнено(ЭлементРодитель) = Истина Тогда
      
      ПоместитьЭлементВДерево(ЭлементРодитель, Количество, ДеревоЭлементов);
      
      // Если строки элемента нет в дереве, то добавляем ее
      Если ДеревоЭлементовСтрокаЭлемента = Неопределено Тогда
         
         // Находим строку родителя в дереве и помещаем в нее элемент
         ДеревоЭлементовСтрокаРодителя = ДеревоЭлементов.Строки.Найти(ЭлементРодитель, "Элемент", Истина);
         
         ДеревоЭлементовСтрокаЭлемента = ДеревоЭлементовСтрокаРодителя.Строки.Добавить();
         ДеревоЭлементовСтрокаЭлемента.Элемент = Элемент;
         
      КонецЕсли;
            
   Иначе
      
      // Если строки элемента еще нет в дереве, то добавляем ее
      Если ДеревоЭлементовСтрокаЭлемента = Неопределено Тогда
         
         // У элемента нет родителей, помещаем его в корень дерева
         ДеревоЭлементовСтрокаЭлемента = ДеревоЭлементов.Строки.Добавить();
         ДеревоЭлементовСтрокаЭлемента.Элемент = Элемент;
         
      КонецЕсли;
      
   КонецЕсли; // Конец проверки наличия родителя у элемента
   
   // Плюсуем количество, для формирования итогов по группам
   ТекущееКоличество = ДеревоЭлементовСтрокаЭлемента.Количество;
   
   Если ТекущееКоличество = Неопределено Тогда
      
      ТекущееКоличество = 0;
      
   КонецЕсли;

   ДеревоЭлементовСтрокаЭлемента.Количество = ТекущееКоличество + Количество;
   
КонецПроцедуры // ПоместитьЭлементВДерево(Элемент, Количество, ДеревоЭлементов)

////////////////////////////////////////////////////////////////////////////////
// СформироватьДерево(ТаблицаЭлементов)
//
// Параметры:
//   ТаблицаЭлементов   - ТаблицаЗначений. Таблица, которую необходимо преобразовать 
//                    в дерево значений. Структура таблицы:
//                    1. Элемент   - СправочникСсылка;
//                    2. Количество   - Число.
//
// Описание:
//   Функция предназначена для преобразования таблицы "ТаблицаЭлементов" в дерево
//   значений. Иерархия элементов в дереве соответствует иерархии элементов в справочнике.
//
// Возвращаемое значение:
//   ДеревоЗначений   - дерево иерархии элементов таблицы "ТаблицаЭлементов". Структура
//                 лерева:
//                 1. Элемент   - СправочникСсылка;
//                 2. Количество   - Число.
Функция СформироватьДерево(ТаблицаЭлементов)
   
   ДеревоЭлементов = Новый ДеревоЗначений; 
   ДеревоЭлементов.Колонки.Добавить("Элемент");
   ДеревоЭлементов.Колонки.Добавить("Количество");
   
   Для Каждого ТаблицаЭлементовСтрока Из ТаблицаЭлементов Цикл
      
      Элемент      = ТаблицаЭлементовСтрока.Элемент;
      Количество   = ТаблицаЭлементовСтрока.Количество;
      ПоместитьЭлементВДерево(Элемент, Количество, ДеревоЭлементов);
      
   КонецЦикла; // Конец цикла по элементам таблицы элементов
   
   Возврат ДеревоЭлементов;
   
 КонецФункции // СформироватьДерево(ТаблицаЭлементов)

Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
|   ПартииТоваровНаСкладахОстатки.Номенклатура       КАК Элемент,
|   ПартииТоваровНаСкладахОстатки.КоличествоОстаток КАК Количество
|ИЗ
|   РегистрНакопления.ПартииТоваровНаСкладах.Остатки КАК ПартииТоваровНаСкладахОстатки";

Дерево = СформироватьДерево(Запрос.Выполнить().Выгрузить());