Расширенные фильтры на форме отчета СКД

07.05.19

Данная публикация показывает интересную реализацию фильтров на форме отчета, построенного с помощью СКД, которые позволяют выбирать вид сравнения с возможность выбора значений "В списке", "Не в списке", "Заполнено" и тд.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование		По подписке [?]	Купить один файл
Расширенные фильтры на форме отчета СКД: .erf 12,26Kb ver:1 20	20	Скачать (1 SM)	Купить за 1 850 руб.

Представляю Вашему вниманию расширенные фильтры (отборы) на форме отчета, построенного на СКД.

Предыстория

Ни для кого не секрет, что СКД позволяет размещать свои отборы на форме, установив одну лишь галочку в настройках

После чего на форме отчета получить следующее

Свою функцию отбор выполнит, но с видом сравнения "Равно". СКД позволяет настроить поле отбора:

В этом окне можно указать любой доступный вид сравнения.

Но все это выглядит не очень красиво, особенно если этих отборов больше 6. А пользователю нравится когда удобно, все под рукой и фильтры не занимают пол экрана.

Предлагаю Вашему внимаю программное формирования группы отборов на форме, со всеми возможностями СКД.

Выглядеть это будет так:

При желании количество групп с фильтрами можно увеличить. Также программная обработка отборов позволяет использовать свои собственные условия, подмены значений, обработки выбора, скрытые фильтры и тд. Подобный подход также можно использовать для динамического списка.

В пруфах исходный код

Модуль менеджера


#Область СлужебныеПроцедуры

Процедура ИнициализироватьОтборыНаФорме(Форма) Экспорт

	СписокРеквизитов = Новый Структура();
	// создадим реквизиты отборов на форме
	СоздатьРеквизитыОтборовНаФорме(Форма,СписокРеквизитов);
	// расположим элементы на форме	
	РасположитьЭлементыНаФорме(Форма,СписокРеквизитов);
	
КонецПроцедуры

Процедура СоздатьРеквизитыОтборовНаФорме(Форма,СписокРеквизитов) 

	ДобавляемыеРеквизиты = Новый Массив;			
	Для Каждого ДоступноеПолеОтбора Из ЭтотОбъект.КомпоновщикНастроек.Настройки.ДоступныеПоляОтбора.Элементы Цикл	
		ИмяРеквизита = Строка(ДоступноеПолеОтбора.Поле);
		
		// добавим элемент отбора
		ДобавитьЭлементОтбора(ИмяРеквизита);
		// добавим реквизит "Использовать"
		ДобавитьРеквизитНаФорму(ДобавляемыеРеквизиты,"Использовать_"+ИмяРеквизита,Тип("Булево"));
		// добавим реквизит "ВидСравнения"
		ДобавитьРеквизитНаФорму(ДобавляемыеРеквизиты,"ВидСравнения_"+ИмяРеквизита,Тип("Неопределено"));
		// добавим реквизит "Использовать"
		ДобавитьРеквизитНаФорму(ДобавляемыеРеквизиты,"ПравоеЗначение_"+ИмяРеквизита,ДоступноеПолеОтбора.Тип);
		// добавим реквизит "Использовать"
		ДобавитьРеквизитНаФорму(ДобавляемыеРеквизиты,"ПравоеЗначениеСписок_"+ИмяРеквизита,Тип("СписокЗначений"));
		// сохраним данные создаваемго реквизита
		СписокРеквизитов.Вставить(ИмяРеквизита,ИмяРеквизита);
	КонецЦикла;
	
	Форма.ИзменитьРеквизиты(ДобавляемыеРеквизиты);	

КонецПроцедуры

Процедура ДобавитьЭлементОтбора(ИмяРеквизита)
	
	ЭлементОтбора 					= ЭтотОбъект.КомпоновщикНастроек.Настройки.Отбор.Элементы.Добавить(тип("ЭлементОтбораКомпоновкиДанных"));
	ЭлементОтбора.ЛевоеЗначение 	= Новый ПолеКомпоновкиДанных(ИмяРеквизита); 			
	ЭлементОтбора.Использование 	= Ложь;		    
	ЭлементОтбора.РежимОтображения 	= РежимОтображенияЭлементаНастройкиКомпоновкиДанных.БыстрыйДоступ; 	
	ЭлементОтбора.ИдентификаторПользовательскойНастройки = новый УникальныйИдентификатор;			
	ЭлементОтбора.ВидСравнения 		= ВидСравненияКомпоновкиДанных.Равно;				
	
КонецПроцедуры

Процедура ДобавитьРеквизитНаФорму(ДобавляемыеРеквизиты,ИмяРеквизита,Тип)
	
	МассивТипов = новый Массив;
	МассивТипов.Добавить(Тип);
	ОписаниеТипов = Новый ОписаниеТипов(МассивТипов);
	Если ТипЗнч(Тип) = ТИП("ОписаниеТипов") Тогда
		ОписаниеТипов = Тип;			
	КонецЕсли;	
	Реквизит = Новый РеквизитФормы("Отбор_" + ИмяРеквизита, ОписаниеТипов,,, Ложь);
	ДобавляемыеРеквизиты.Добавить(Реквизит);	
	
КонецПроцедуры

Процедура РасположитьЭлементыНаФорме(Форма,СписокРеквизитов)

	ГруппаФильтра = Форма.Элементы.Добавить("ГруппаФильтр", Тип("ГруппаФормы"));
	ГруппаФильтра.Вид = ВидГруппыФормы.ОбычнаяГруппа;
	ГруппаФильтра.Группировка = ГруппировкаПодчиненныхЭлементовФормы.Горизонтальная;	
	ГруппаФильтра.ОтображатьЗаголовок = Ложь;
	ГруппаФильтра.Видимость = Ложь;
	
	ГруппаФильтраЛевая = Форма.Элементы.Добавить("ГруппаФильтрыЛево", Тип("ГруппаФормы"),ГруппаФильтра);
	ГруппаФильтраЛевая.Вид = ВидГруппыФормы.ОбычнаяГруппа;
	ГруппаФильтраЛевая.Группировка = ГруппировкаПодчиненныхЭлементовФормы.Вертикальная;	
	ГруппаФильтраЛевая.ОтображатьЗаголовок = Ложь;
	
	ГруппаФильтраПравая = Форма.Элементы.Добавить("ГруппаФильтрыПраво", Тип("ГруппаФормы"),ГруппаФильтра);
	ГруппаФильтраПравая.Вид = ВидГруппыФормы.ОбычнаяГруппа;
	ГруппаФильтраПравая.Группировка = ГруппировкаПодчиненныхЭлементовФормы.Вертикальная;	
	ГруппаФильтраПравая.ОтображатьЗаголовок = Ложь;
	
	Форма.Элементы.Переместить(ГруппаФильтра,Форма,Форма.Элементы.Результат);
	
	ЛеваяГруппа = Истина;
	Для Каждого Реквизит Из СписокРеквизитов Цикл
		ПолеОтбора = ЭтотОбъект.КомпоновщикНастроек.Настройки.ДоступныеПоляОтбора.Элементы.Найти(Реквизит.Значение);
		
		Если ПолеОтбора = Неопределено Тогда
			Продолжить;
		КонецЕсли;
		
		// Предустановим тип списка значений
		Форма["Отбор_ПравоеЗначениеСписок_" + Реквизит.Значение].ТипЗначения = ПолеОтбора.Тип;				
		
		Если ЛеваяГруппа Тогда
			ЭлементФормыГруппаФильтра = Форма.Элементы.Добавить("Отбор_ГруппаФильтра_" + Реквизит.Значение, Тип("ГруппаФормы"), Форма.Элементы.ГруппаФильтрыЛево);
		Иначе
			ЭлементФормыГруппаФильтра = Форма.Элементы.Добавить("Отбор_ГруппаФильтра_" + Реквизит.Значение, Тип("ГруппаФормы"), Форма.Элементы.ГруппаФильтрыПраво);
		КонецЕсли;
		
		ЛеваяГруппа = НЕ ЛеваяГруппа;
		
		// ГРУППА РАСПОЛОЖЕНИЯ ОТБОРА
		ЭлементФормыГруппаФильтра.Вид 						= ВидГруппыФормы.ОбычнаяГруппа;
		ЭлементФормыГруппаФильтра.ОтображатьЗаголовок 		= Ложь;
		ЭлементФормыГруппаФильтра.Группировка 				= ГруппировкаПодчиненныхЭлементовФормы.Горизонтальная;	
		ЭлементФормыГруппаФильтра.Отображение 				= ОтображениеОбычнойГруппы.Нет;
		ЭлементФормыГруппаФильтра.РастягиватьПоГоризонтали 	= Истина;
		ЭлементФормыГруппаФильтра.Объединенная 				= Ложь; 
		
		// ЭЛЕМЕНТ "Использовать"
		ЭлементФормы = Форма.Элементы.Добавить("Отбор_Использовать_" + Реквизит.Значение, Тип("ПолеФормы"), ЭлементФормыГруппаФильтра);
		ЭлементФормы.ПутьКДанным 					= "Отбор_Использовать_" + Реквизит.Значение; 
		ЭлементФормы.Вид 							= ВидПоляФормы.ПолеФлажка;
		ЭлементФормы.ПоложениеЗаголовка 			= ПоложениеЗаголовкаЭлементаФормы.Право;
		ЭлементФормы.ТолькоПросмотр 				= Ложь;
		ЭлементФормы.ВертикальноеПоложениеВГруппе 	= ВертикальноеПоложениеЭлемента.Центр;
		ЭлементФормы.Заголовок 						= " ";
		ЭлементФормы.УстановитьДействие("ПриИзменении","ОтборПриИзменении");
		
		// НАДПИСЬ С НАИМЕНОВАНИЕМ ОТБОРА
		НадписьРеквизита = Форма.Элементы.Добавить("Отбор_Наименование_" + Реквизит.Значение, Тип("ДекорацияФормы"), ЭлементФормыГруппаФильтра);
		НадписьРеквизита.Заголовок 						= ПолеОтбора.Заголовок;
		НадписьРеквизита.ВертикальноеПоложениеВГруппе 	= ВертикальноеПоложениеЭлемента.Центр;
		НадписьРеквизита.РастягиватьПоГоризонтали 		= Ложь;
		
		// ЭЛЕМЕНТ "Вид сравнения"
		ЭлементФормы = Форма.Элементы.Добавить("Отбор_ВидСравнения_" + Реквизит.Значение, Тип("ПолеФормы"), ЭлементФормыГруппаФильтра);
		ЭлементФормы.ПутьКДанным 			= "Отбор_ВидСравнения_" + Реквизит.Значение; 
		ЭлементФормы.Вид 					= ВидПоляФормы.ПолеВвода;
		ЭлементФормы.ПоложениеЗаголовка 	= ПоложениеЗаголовкаЭлементаФормы.Нет;
		ЭлементФормы.ТолькоПросмотр 		= Ложь;
		ЭлементФормы.РежимВыбораИзСписка 	= Истина;
		ЭлементФормы.РедактированиеТекста 	= Ложь; 
		ЭлементФормы.Ширина 				= 10;
		ЭлементФормы.Высота 				= 1;
		ЭлементФормы.РастягиватьПоГоризонтали = Ложь;
		ЭлементФормы.КнопкаВыбора 			= Ложь;
		ЭлементФормы.УстановитьДействие("ПриИзменении","ОтборПриИзменении");
		
		// заполним доступные виды сравнения
		Если ПолеОтбора.ТипЗначения.СодержитТип(ТИП("Число")) Тогда
			ЭлементФормы.СписокВыбора.Добавить(ВидСравненияКомпоновкиДанных.Больше);
			ЭлементФормы.СписокВыбора.Добавить(ВидСравненияКомпоновкиДанных.Меньше);
			ЭлементФормы.СписокВыбора.Добавить(ВидСравненияКомпоновкиДанных.Равно);
		Иначе
			Для Каждого СтрВидаСравнения Из ПолеОтбора.ДоступныеВидыСравнения Цикл
				ЭлементФормы.СписокВыбора.Добавить(СтрВидаСравнения.Значение);
			КонецЦикла;
		КонецЕсли;	
		// по умолчанию значение "Равно"
		Форма["Отбор_ВидСравнения_" + Реквизит.Значение] = ВидСравненияКомпоновкиДанных.Равно;
		
		// Группа "Правое значение"
		ЭлементФормыПраваяГруппа = Форма.Элементы.Добавить("Отбор_ГруппаПравоеЗначение_" + Реквизит.Значение, Тип("ГруппаФормы"), ЭлементФормыГруппаФильтра);
		ЭлементФормыПраваяГруппа.Вид 						= ВидГруппыФормы.ОбычнаяГруппа;
		ЭлементФормыПраваяГруппа.ОтображатьЗаголовок 		= Ложь;
		ЭлементФормыПраваяГруппа.Группировка 				= ГруппировкаПодчиненныхЭлементовФормы.Горизонтальная;	
		ЭлементФормыПраваяГруппа.Отображение 				= ОтображениеОбычнойГруппы.Нет;
		ЭлементФормыПраваяГруппа.РастягиватьПоГоризонтали 	= Истина;
		
		// ЭЛЕМЕНТ "Правое значение"
		ЭлементФормы = Форма.Элементы.Добавить("Отбор_ПравоеЗначение_" + Реквизит.Значение, Тип("ПолеФормы"), ЭлементФормыПраваяГруппа);
		ЭлементФормы.ПутьКДанным 					= "Отбор_ПравоеЗначение_" + Реквизит.Значение; 
		ЭлементФормы.Вид 							= ВидПоляФормы.ПолеВвода;
		ЭлементФормы.ПоложениеЗаголовка 			= ПоложениеЗаголовкаЭлементаФормы.Нет;
		ЭлементФормы.ТолькоПросмотр 				= Ложь;
		ЭлементФормы.РежимРедактирования 			= РежимРедактированияКолонки.Непосредственно; 
		ЭлементФормы.КнопкаОткрытия 				= Ложь;
		ЭлементФормы.АвтоМаксимальнаяШирина 		= Ложь;
		ЭлементФормы.РастягиватьПоГоризонтали 		= Истина;
		ЭлементФормы.Ширина 						= 15;
		ЭлементФормы.АвтоВыборНезаполненного 		= Ложь;
		ЭлементФормы.ОбновлениеТекстаРедактирования = ОбновлениеТекстаРедактирования.ПриИзмененииЗначения;
		ЭлементФормы.УстановитьДействие("ПриИзменении","ОтборПриИзменении");
		ЭлементФормы.УстановитьДействие("НачалоВыбора","ОтборНачалоВыбора");
		
		// ЭЛЕМЕНТ "Правое значение список"
		ЭлементФормы = Форма.Элементы.Добавить("Отбор_ПравоеЗначениеСписок_" + Реквизит.Значение, Тип("ПолеФормы"), ЭлементФормыПраваяГруппа);
		ЭлементФормы.ПутьКДанным 				= "Отбор_ПравоеЗначениеСписок_" + Реквизит.Значение; 
		ЭлементФормы.Вид 						= ВидПоляФормы.ПолеВвода;
		ЭлементФормы.ПоложениеЗаголовка 		= ПоложениеЗаголовкаЭлементаФормы.Нет;
		ЭлементФормы.ТолькоПросмотр 			= Ложь;
		ЭлементФормы.РежимРедактирования 		= РежимРедактированияКолонки.Непосредственно; 
		ЭлементФормы.КнопкаОткрытия 			= Ложь;
		ЭлементФормы.Видимость 					= Ложь;
		ЭлементФормы.АвтоМаксимальнаяШирина 	= Ложь;
		ЭлементФормы.РастягиватьПоГоризонтали 	= Истина;
		ЭлементФормы.Ширина 					= 15;
		ЭлементФормы.УстановитьДействие("ПриИзменении","ОтборПриИзменении");
		
	КонецЦикла;

КонецПроцедуры
	
#КонецОбласти

Форма отчета


#Область ОбработчикиФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	ОтчетОбъект = РеквизитФормыВЗначение("Отчет");
	ОтчетОбъект.ИнициализироватьОтборыНаФорме(ЭтаФорма);
КонецПроцедуры

#КонецОбласти

#Область ПодключаемыеОбработчикиОтборов

&НаКлиенте
Процедура ПоказатьНастройки(Команда)
	
	Если Элементы.ГруппаФильтр.Видимость Тогда
		Элементы.ФормаПоказатьНастройки.Заголовок = "Показать фильтры";
	Иначе
		Элементы.ФормаПоказатьНастройки.Заголовок = "Скрыть фильтры";
	КонецЕсли;
	Элементы.ГруппаФильтр.Видимость = Не Элементы.ГруппаФильтр.Видимость;
	
КонецПроцедуры

&НаКлиенте
Процедура ОтборПриИзменении(Элемент)
	
	ОтборПриИзмененииНаСервере(Строка(Элемент.Имя));		
	
КонецПроцедуры

&НаСервере
Процедура ОтборПриИзмененииНаСервере(Имя)
	
	Если НЕ Найти(Имя,"Отбор") = 0 Тогда
		Имя = Сред(Имя,7);
		ПоложениеПробела = СтрНайти(Имя,"_");
		Если ПоложениеПробела = 0 Тогда
			Сообщение = Новый СообщениеПользователю;
			Сообщение.Текст = "Ошибка применения фильтра";
			Сообщение.Сообщить();
			Возврат;
		КонецЕсли;	
		ИмяПоля = Сред(Имя,1,ПоложениеПробела-1);
		ИмяРеквизита = Сред(Имя,ПоложениеПробела+1);
		
		Если ИмяПоля = "ВидСравнения" Тогда
			ТекущееЗначение = ЭтаФорма["Отбор_ВидСравнения_" + ИмяРеквизита];
			Если Найти(ВРег(ТекущееЗначение), "СПИС") = 0 Тогда
				Элементы["Отбор_ПравоеЗначение_" + ИмяРеквизита].Видимость = Истина;
				Элементы["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита].Видимость = Ложь;
				Если Не ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита].Количество() = 0 Тогда
					ЭтаФорма["Отбор_ПравоеЗначение_" + ИмяРеквизита] = ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита][0].Значение;
					ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита].Очистить();
				КонецЕсли;
			Иначе
				Элементы["Отбор_ПравоеЗначение_" + ИмяРеквизита].Видимость = Ложь;
				Элементы["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита].Видимость = Истина;					
				Если ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита].Количество() = 0 И ЗначениеЗаполнено(ЭтаФорма["Отбор_ПравоеЗначение_" + ИмяРеквизита]) Тогда
					ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита].Добавить(ЭтаФорма["Отбор_ПравоеЗначение_" + ИмяРеквизита]);
					ЭтаФорма["Отбор_ПравоеЗначение_" + ИмяРеквизита] = Неопределено;
				КонецЕсли;
			КонецЕсли;
		КонецЕсли;
		
		ТекущийОтбор = Неопределено;
		//Найдем отбор
		Для Каждого СтрОтбор Из Отчет.КомпоновщикНастроек.Настройки.Отбор.Элементы Цикл
			Если Строка(СтрОтбор.ЛевоеЗначение) = ИмяРеквизита	Тогда
				ТекущийОтбор = СтрОтбор;
			КонецЕсли;
		КонецЦикла;
		Если Не ТекущийОтбор = Неопределено Тогда
			Если Не (ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита] = Ложь И ТекущийОтбор.Использование = Ложь) Тогда
				Если Не ЭтаФорма["Отбор_ВидСравнения_" + ИмяРеквизита] = Неопределено Тогда
					Попытка
							ТекущийОтбор.ВидСравнения = ЭтаФорма["Отбор_ВидСравнения_" + ИмяРеквизита];	
							ТекЗначениеВидаСравнения = ЭтаФорма["Отбор_ВидСравнения_" + ИмяРеквизита];
							Если Найти(ВРег(ТекЗначениеВидаСравнения), "СПИС") = 0 Тогда
								ТекущийОтбор.ПравоеЗначение = ЭтаФорма["Отбор_ПравоеЗначение_" + ИмяРеквизита];
							Иначе
								ТекущийОтбор.ПравоеЗначение = ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита];
							КонецЕсли;
							ТекущийОтбор.Использование = ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита];
					Исключение
						ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита] = Ложь;
					КонецПопытки;
				Иначе
					ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита] = Ложь;
				КонецЕсли;
			Иначе
				ТекЗначениеВидаСравнения = ЭтаФорма["Отбор_ВидСравнения_" + ИмяРеквизита];
				Если Найти(ВРег(ТекЗначениеВидаСравнения), "СПИС") = 0 Тогда						
					Если ЗначениеЗаполнено(ЭтаФорма["Отбор_ПравоеЗначение_" + ИмяРеквизита]) И ЗначениеЗаполнено(ЭтаФорма["Отбор_ВидСравнения_" + ИмяРеквизита]) Тогда
						Если ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита] = Ложь Тогда
							ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита] = Истина;
							ТекущийОтбор.ВидСравнения = ТекЗначениеВидаСравнения;
							ТекущийОтбор.ПравоеЗначение = ЭтаФорма["Отбор_ПравоеЗначение_" + ИмяРеквизита];
							ТекущийОтбор.Использование = Истина;
						КонецЕсли;
					КонецЕсли;
				Иначе
					Если ЗначениеЗаполнено(ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита]) 
						И ЗначениеЗаполнено(ЭтаФорма["Отбор_ВидСравнения_" + ИмяРеквизита]) Тогда 
						Если ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита] = Ложь Тогда
							ЭтаФорма["Отбор_Использовать_" + ИмяРеквизита] = Истина;
							ТекущийОтбор.ВидСравнения = ТекЗначениеВидаСравнения;
							ТекущийОтбор.ПравоеЗначение = ЭтаФорма["Отбор_ПравоеЗначениеСписок_" + ИмяРеквизита];
							ТекущийОтбор.Использование = Истина;
						КонецЕсли;
					КонецЕсли;
				КонецЕсли;
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

Пример использования программных отборов отчета на СКД тестировался на платформе 8.3.13.1644.

Режим совместимости 8.3.10

Отчет СКД Отборы Фильтры Параметры расширенный

+16 –

См. также

[Расширения] Динамическое управление видимостью и доступностью элементов форм (УФ) (8.3.6+)

Работа с интерфейсом Системный администратор Программист Платформа 1С v8.3 Управляемые формы 1C:Бухгалтерия Платные (руб)

Механизм «Динамическое управление доступом к элементам форм объектов 1С8» предназначен для обеспечения возможности оперативного управления видимостью и доступностью элементов форм документов и справочников продуктов фирмы «1С» «1С:Предприятие 8». Решение универсальное, встраивается в любую конфигурацию с минимальными доработками, что позволяет без проблем обновлять типовые решения.

5000 руб.

14.01.2016 55616 17 23

Универсальный редактор картинок 1С, хранимых в базе, с возможностью рисования

Работа с интерфейсом Рабочее место Платформа 1С v8.3 Управляемые формы 1C:Бухгалтерия Платные (руб)

Универсальный редактор картинок 1С предназначен для обработки изображений в режиме «Предприятие», с возможностью рисовать на них. Поддерживается работа как в обычных формах (толстый клиент) так и на управляемых формах (тонкий клиент). Обработка позволяет редактировать как картинки, хранимые в базе, так и графические файлы с диска на файловой системе. Помимо базовых функций (изменение размеров, преобразование формата, обрезание картинки, повороты и т.п.) – редактор имеет богатый набор инструментов для рисования. Доступна функция вставки изображения из буфера обмена. Объект может быть использован: на стороне клиента, на стороне сервера, из внешнего соединения. Обработка будет особенно полезна тем, кто вносит картинки в базу (изображения номенклатуры, фотографии физических лиц и т.п.). Функционал реализуется с использованием JavaScript и бесплатного ПО ImageMagick (без использования внешних компонент).

6000 руб.

16.01.2015 63938 45 60

Управление дашбордами

Работа с интерфейсом Программист Платформа 1С v8.3 1C:Бухгалтерия 1С:ERP Управление предприятием 2 Платные (руб)

Обработка предназначена для создания и управления дашбордами.

2400 руб.

29.06.2020 19931 28 6

Дизайн Гайд для создания форм на 1С. Когда и как использовать различные элементы, примеры и антипримеры по использованию

Работа с интерфейсом Программист Стажер Платформа 1С v8.3 Бесплатно (free)

Это инструкция по дизайну форм в среде 1С. Гайд охватывает рекомендации и стандарты для оптимизации пользовательского интерфейса. В гайде содержатся указания по использованию элементов интерфейса, включая как основные, так и продвинутые аспекты. Предоставляются также примеры и антипримеры для наглядного понимания принципов дизайна

20.08.2024 23419 mrXoxot 44

130

Прогресс-бар в поле динамического списка

Работа с интерфейсом Программист Платформа 1С v8.3 Бесплатно (free)

Пример простого и симпатичного прогресс-бара в динамическом списке, без картинок, используя редактирование запроса.

27.05.2024 11963 smielka 37

105

Новогоднее оформление для 1С

Работа с интерфейсом Платформа 1С v8.3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 Бесплатно (free)

Добавьте новогоднего настроения! Расширение создает декорацию в виде гирлянды на некоторых формах объектов.

27.12.2023 18341 1228 elcoan 53

125

Конструктор HTML, CSS и javascript

Инструментарий разработчика Работа с интерфейсом Программист Платформа 1С v8.3 1C:Бухгалтерия Абонемент ($m)

Подходит для создания web-страниц для замены управляемых форм 1С, красивых отчетов, интерфейса мобильного приложения на платформе 1С и для простых страниц веб-сайтов.

3 стартмани

10.04.2023 12879 167 acces969 31

126

Модель состояния для MVC

Работа с интерфейсом Программист Платформа 1С v8.3 1C:Бухгалтерия Абонемент ($m)

"MVC плохо применима в 1С" - познакомьтесь с моделью состояния и, возможно, ваше мнение поменяется! Представленное решение является эволюционным развитием идеи реализации MVC для 1С. В новой версии добавлены DSL для описания модели состояния, а также параметризация свойств параметров и элементов формы.

1 стартмани

05.07.2022 7954 kalyaka 6

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. noprogrammer 239 07.05.19 15:32 Сейчас в теме

Свою функцию отбор выполнит, но с видом сравнения "Равно"

Возможно (скорее всего) я чего не понял, но откуда такая информация, что в СКД форму можно вывести сравнение только на равенство? Вообще-то на форму можно точно так же вывести любое сравнение.

2. Isonic 243 07.05.19 15:38 Сейчас в теме

(1)

Вообще-то на форму можно точно так же вывести любое сравнение

Можно, и я об этом сказал (3-ий скриншот)

3. noprogrammer 239 07.05.19 15:42 Сейчас в теме

(2) Третий скриншот этот https://infostart.ru/upload/iblock/629/6293719cd5ce9620cd007ee5027767ca.jpg ?
Я просто не совсем понял, для чего самому формировать отборы если они формируются автоматически

4. Isonic 243 07.05.19 15:46 Сейчас в теме

(3)

Я просто не совсем понял, для чего самому формировать отборы если они формируются автоматически

Наберусь терпения и скопирую строчку под скриншотом
"Но все это выглядит не очень красиво, особенно если этих отборов больше 6. А пользователю нравится когда удобно, все под рукой и фильтры не занимают пол экрана."

Дочитайте пожалуйста до конца!

5. noprogrammer 239 07.05.19 15:50 Сейчас в теме

(4) Разумеется я все прочитал. Стандартными средствами отборы рисуются точно так же как Вы нарисовали программно.
т.е. вот так https://infostart.ru/upload/iblock/021/021dddfd26cbe92da04ce2ef2acf4f9d.jpg

7. Isonic 243 07.05.19 15:54 Сейчас в теме

(5) Не совсем так, выбор вида сравнения появляется только когда оно не равно стандартному значению вида сравнения

6. noprogrammer 239 07.05.19 15:52 Сейчас в теме

Все, я понял, что Вас не устроило в стандартном формирование (то, что при равенстве оно не отображается на форме, на форме отображаются только другие виды сравнения)

8. Isonic 243 07.05.19 15:56 Сейчас в теме

(6) Именно. Также плюс программного формирования - это контроль того что выбирает пользователь. На практике это бывает очень важным

9. script 128 08.05.19 23:05 Сейчас в теме

Код не работает в конфигурациях в режиме совместимости ниже 8.3.10

10. Isonic 243 13.05.19 08:39 Сейчас в теме

(9) Прошу прощения. Добавил в описание информацию о режиме совместимости.

В общем можно опустить до 8.2.13 например, но тогда потребуются дополнительные манипуляции с элементами форм (нужно будет добавить кнопку выбора с картинкой, добавить настройку группы элементов по размерам,некоторые события не так работают и тд и тп.).
Я исходил из того, что сейчас уже большинство разработчиков перешло на платформу 8.3.10 и более

11. Tekkonkinkreet 02.08.20 16:54 Сейчас в теме

Подскажите пожалуйста, в отчете предполагается отбор, где вид сравнения в группе. Когда автоматически добавляются отборы программа дает выбирать группы, когда добавляю отбор из примера отчета, не дает выбирать группу. Как можно поправить?