Для вывода картинок в строки используется процедура в модуле объекта отчета:
Код процедуры для заполнения картинок
Процедура пп_ЗаполнитьКартинки(ДокументРезультат, НастройкиОтчета, ДанныеРасшифровки)
КоличествоСтрок = ДокументРезультат.ВысотаТаблицы;
КоличествоКолонок = ДокументРезультат.ШиринаТаблицы;
ВысотаСтроки = НастройкиОтчета.ПараметрыДанных.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ВысотаКолонкиИзображения")).Значение;
ШиринаКолонки = НастройкиОтчета.ПараметрыДанных.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ШиринаКолонкиИзображения")).Значение;
Для СтрокаДокумента = 1 По КоличествоСтрок Цикл
Для КолонкаДокумента = 1 По КоличествоКолонок Цикл
Область = ДокументРезультат.Область(СтрокаДокумента, КолонкаДокумента);
Расшифровка = Область.Расшифровка;
Если ТипЗнч(Расшифровка) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда
ПоляРасшифровки = ДанныеРасшифровки.Элементы.Получить(Расшифровка).ПолучитьПоля();
//Найденное поле необходимо заменить на нужное вам поле
НайденноеПоле = ПоляРасшифровки.Найти("Номенклатура.ov_ПутьККартинке");
Если НайденноеПоле <> Неопределено Тогда
ПутьККартинке = НайденноеПоле.Значение;
Если ЗначениеЗаполнено(ПутьККартинке) Тогда
Картинка = Новый Картинка(ПутьККартинке);
Изображение = ДокументРезультат.Рисунки.Добавить(ТипРисункаТабличногоДокумента.Картинка);
Изображение.Картинка = Картинка;
Изображение.РазмерКартинки = РазмерКартинки.АвтоРазмер;
Область.АвтоВысотаСтроки = Ложь;
Область.ВысотаСтроки = ВысотаСтроки;
Область.ШиринаКолонки = ШиринаКолонки;
Изображение.Расположить(Область);
КонецЕсли;
КонецЕсли;
КонецЕсли;
КонецЦикла;
КонецЦикла;
КонецПроцедуры
Результат работы отчета:
Высота и ширина колонки изображения для удобства задается пользователем через параметры. Единственный нюанс данного отчета в том, что он разрабатывался для конфигурации, где в справочник "Номенклатура" добавлен реквизит, в котором хранится путь к файлу картинки, хранение файлов внутри базы не используется. Для работы данного отчета в типовой конфигурации необходимо изменить переменную "НайденноеПоле" в процедуре вывода картинок для поиска нужного значения.
Работоспособность данного отчета проверялась на доработанной УТ 11.4.8.92.
Вступайте в нашу телеграмм-группу Инфостарт
