Ранее на Инфостарте уже публиковались внешние компоненты для построения графов на основе библиотеки GraphViz. Предлагаемая реализация выгодно отличается от них тем, что исходный код внешней компоненты доступен и поддерживается 64х битная версия клиента 1С.
Вот пример описания графа в формате dot.
digraph {
node[shape=none label=""]
edge[penwidth=2 color="darkgreen"]
Команда[image="img/team.png"]
Заказчик[image="img/businessman.png"]
Программист[image="img/programmer.png"]
Фрилансер[image="img/freelance.png"]
Секретарь[image="img/secretary.png"]
Техник[image="img/technician.png"]
Механик[image="img/mechanic.png"]
Сервер[image="img/server.png"]
Заказчик -> Команда -> Программист
Команда -> Секретарь
Команда -> Фрилансер
Механик -> Сервер
Техник -> Сервер
}
Внешняя компонента допускает использование картинок для визуализации вершин графа и поддерживает метки в формате HTML. Рекомендуется использовать для экспорта формат картинок SVG, также доступны графические форматы BPM, GIF, PNG, JPEG, TIFF и другие. Полный список поддерживаемых форматов можно получить вызвав соответствующий метод компоненты.
Ниже пример программного кода для асинхронного подключения компоненты. Вас может смутить, что что для подключения компоненты используется уникальный идентификатор. Этот лайфхак полезен при разработке и тестировании, потому что позволяет избежать конфликта при подключении различных версий одной компоненты.
&НаКлиенте
Перем ИдентификаторКомпоненты, ВнешняяКомпонента;
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ОбработкаОбъект = РеквизитФормыВЗначение("Объект");
МакетКомпоненты = ОбработкаОбъект.ПолучитьМакет("GraphViz1C");
АдресКомпоненты = ПоместитьВоВременноеХранилище(МакетКомпоненты, УникальныйИдентификатор);
КонецПроцедуры
&НаКлиенте
Процедура ПриОткрытии(Отказ)
ИдентификаторКомпоненты = "_" + СтрЗаменить(Новый УникальныйИдентификатор, "-", "");
ВыполнитьПодключениеВнешнейКомпоненты(Истина);
КонецПроцедуры
&НаКлиенте
Процедура ВыполнитьПодключениеВнешнейКомпоненты(ДопПараметры) Экспорт
НачатьПодключениеВнешнейКомпоненты(
Новый ОписаниеОповещения("ПодключенаВнешняяКомпонента", ЭтаФорма, ДопПараметры),
АдресКомпоненты, ИдентификаторКомпоненты, ТипВнешнейКомпоненты.Native);
КонецПроцедуры
&НаКлиенте
Процедура ПодключенаВнешняяКомпонента(Подключение, ДополнительныеПараметры) Экспорт
Если Подключение Тогда
ВнешняяКомпонента = Новый("AddIn." + ИдентификаторКомпоненты + ".GraphViz1C");
ИначеЕсли ДополнительныеПараметры = Истина Тогда
НачатьУстановкуВнешнейКомпоненты(
Новый ОписаниеОповещения("ВыполнитьПодключениеВнешнейКомпоненты", ЭтаФорма, Ложь),
АдресКомпоненты);
КонецЕсли;
КонецПроцедуры
Для генерации картинки графа используется метод Сформировать, который принимает на вход двоичные данные, либо строку с описанием графа. Метод возвращает картинку в виде двоичных данных или строку с текстом ошибки.
&НаКлиенте
Процедура СформироватьКартинку(Команда)
ДвоичныеДанные = Новый ДвоичныеДанные(ИмяФайла);
ОписаниеОповещения = Новый ОписаниеОповещения("ПолученаКартинка", ЭтаФорма);
ВнешняяКомпонента.НачатьВызовСформировать(ОписаниеОповещения, ДвоичныеДанные, "svg", "dot");
КонецПроцедуры
&НаКлиенте
Процедура ПолученаКартинка(РезультатВызова, ПараметрыВызова, ДополнительныеПараметры) Экспорт
Если ТипЗнч(РезультатВызова) = Тип("ДвоичныеДанные") Тогда
АдресКартинки = ПоместитьВоВременноеХранилище(РезультатВызова, УникальныйИдентификатор);
ИначеЕсли ТипЗнч(РезультатВызова) = Тип("Строка") Тогда
Сообщить("ОШИБКА: " + РезультатВызова);
КонецЕсли;
КонецПроцедуры
К сожалению, библиотека GraphViz больше не поддерживает экспорт в формат Microsoft Visio. Прилагаемая внешняя обработка дополнительно содержит пример экспорта простого графа в приложение Microsoft Visio через вызов методов COM-объекта Visio.Application. Возможно вам придется доработать его самостоятельно. Можете взять его за основу.
Чтобы получить статическую сборку библиотеки GraphViz пришлось скорректировать её исходный код, преимущественно исправить файлы CMakeLists.txt. Также потребовалось статическая сборка библиотеки Expat для поддержки меток в формате HTML. Полностью вся сборка внешней компоненты, примера обработки и публикация релиза осуществляется автоматизированно посредством облачного сервиса AppVeyor. Вы можете посмотреть как это делается во всех подробностях.
Исходный код внешней компоненты выложен на GitHub: https://github.com/lintest/GraphViz1C
Вступайте в нашу телеграмм-группу Инфостарт
