Доработка стандартной консоли запросов с ИТС (для 8.2, обычные формы) для возможности получения данных запросом из внешних файлов (.xls, .xlsx, .mxl)

04.04.21

Разработка - Инструментарий разработчика

+2 –

Пример доработки стандартной консоли запросов 8.2, по шагам с описанием и скриншотами + окончательный вариант.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование		По подписке [?]	Купить один файл
Доработка стандартной итс консоли запросов (для 8.2 обычные формы) для возможности получения данных запросом из внешних файлов (.xls, .xlsx, .mxl): .epf 48,48Kb 7	7	Скачать (1 SM)	Купить за 1 850 руб.

Шаги:

1. Сперва откроем основную форму обработки и в командную панель добавим свою команду (кнопку) для открытия нашей формы с настройками подключения (свойства на рисунке справа)

Также создаем действие для нашей команды

Просмотреть код

Процедура КоманднаяПанельФормыВнешниеИсточникиДанных(Кнопка)
	
	Если мФормаВнешнихИсточников.Открыта() Тогда
		мФормаВнешнихИсточников.Закрыть();
	Иначе
		мФормаВнешнихИсточников.Открыть();
	КонецЕсли;
	
КонецПроцедуры

"мФормаВнешнихИсточников" это переменная модуля формы

Из переменной "мФормаПараметров" сделаем экспортную, добавив "Экспорт" в конец.

С модулем основной формы пока что все.

2. Теперь добавим новые необходимые нам формы в обработку

Сразу же для формы "ФормаТаблицаСДаннымиВнешнегоИсточника" добавим реквизит формы с типом "ТаблицаЗначений"

и выведем на форму со стандартной командной панелью,

больше ничего с этой формой не делаем, оставляем в покое.

Переходим в форму "ФормаВнешнихИсточников", так она должна выглядеть в итоге,

добавляем реквизит формы "ПараметрыПодключений" с типом "ТаблицаЗначений"

Можно сразу добавить в модуль формы глобальные переменные, в начало и конец модуля

Добавим на форму командную панель для табличного поля (без автозаполнения, см. рис.), сначала команд не будет совсем, будем поочередно добавлять, так она выглядит в итоге.

Добавляем кнопку добавления на ком. панель (рис.),

с действием "КнопкаДобавитьИсточник",

Посмотреть код

Процедура КнопкаДобавитьИсточник(Кнопка)
	// Открыть диалог выбора файла .xls|.xlsx|.mxl
	Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	Диалог.Заголовок = "Выберите файл";
	Диалог.Фильтр = "Файлы excel (*.xls, *.xlsx)|*.xls;*.xlsx|Табличный документ (*.mxl)|*.mxl";
	
	Если Диалог.Выбрать() Тогда	
		ПутьКФайлу = Диалог.ПолноеИмяФайла;
		
		ТабДокумент = Новый ТабличныйДокумент;
		Попытка
			ТабДокумент.Прочитать(ПутьКФайлу, СпособЧтенияЗначенийТабличногоДокумента.Значение);
		Исключение
			Сообщить(ОписаниеОшибки());
		КонецПопытки;
		
		Если ТабДокумент.Области.Количество() = 0 Тогда 
			Сообщить("Не найдено ни одной области данных для выборки в выбранном документе.");
			Возврат;
		КонецЕсли;
		
		Если ПараметрыПодключений.Найти(ПутьКФайлу, "ПутьКФайлу") <> Неопределено Тогда 
			Предупреждение("Файл с таким расположением пути уже присутствует в списке.
				|Сначала удалите предыдущий.");
			Возврат;
		КонецЕсли;
		
		ПостроительЗапроса = Новый ПостроительЗапроса;
		Попытка
			ПостроительЗапроса.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТабДокумент.Область());
			ПостроительЗапроса.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
			ПостроительЗапроса.ЗаполнитьНастройки();
			ПостроительЗапроса.Выполнить();
			Результат = ПолучитьНормализованнуюТаблицу(ПостроительЗапроса.Результат.Выгрузить());
		Исключение
			Сообщить(ОписаниеОшибки());
			Возврат;
		КонецПопытки;
		
		Массив = Новый Массив;
		Массив.Добавить("Все области данных");  // всегда по умолчанию
		Для Каждого Область Из ТабДокумент.Области Цикл 
			Массив.Добавить(Область.Имя);
		КонецЦикла;
		НовоеИмя = ПодобратьУникальноеИмяПодключения("ИмяПодключения");
		СоответствиеИменИОбластейИсточников.Вставить(НовоеИмя, Массив);
		
		НоваяСтрока = ПараметрыПодключений.Добавить();
		НоваяСтрока.Имя = НовоеИмя;
		НоваяСтрока.ПутьКФайлу = ПутьКФайлу;
		НоваяСтрока.ОбластьВыборки = Массив[0];
		НоваяСтрока.Данные = Результат;
		НоваяСтрока.Просмотр = "Просмотр";
		
		// добавление в форму параметров
		Параметры = ЭтаФорма.ВладелецФормы.мФормаПараметров.Параметры;
		СтрокаПараметров = Параметры.Найти(НовоеИмя,"ИмяПараметра");
		Если  СтрокаПараметров = Неопределено Тогда
			СтрокаПараметров = Параметры.Добавить();
			СтрокаПараметров.ИмяПараметра = НовоеИмя;
			СтрокаПараметров.ЗначениеПараметра = Результат;
		КонецЕсли;
		
		ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока = НоваяСтрока;
		ЭлементыФормы.ПараметрыПодключений.ТекущаяКолонка = ЭлементыФормы.ПараметрыПодключений.Колонки.Имя;
		ЭлементыФормы.ПараметрыПодключений.ИзменитьСтроку();
	КонецЕсли;
КонецПроцедуры

добавляем следующую командную кнопку "Удалить", выбираем стандартное системное действие удаления, остальные стандартные команды по желанию.

Для табличного поля "ПараметрыПодключений" выставляем свойства и события как на рис.,

Код для события "ПараметрыПодключенийВыбор"

Посмотреть код

Процедура ПараметрыПодключенийВыбор(Элемент, ВыбраннаяСтрока, Колонка, СтандартнаяОбработка)
	Если Колонка.Имя = "Просмотр" Тогда 
		Если мФормаПросмотраДанных.Открыта() Тогда
			мФормаПросмотраДанных.Закрыть();
		Иначе			
			// загрузим данные в таблицу на форме
			мФормаПросмотраДанных.ЭлементыФормы.ТаблицаСДанными.Значение = ВыбраннаяСтрока.Данные;
			мФормаПросмотраДанных.ЭлементыФормы.ТаблицаСДанными.СоздатьКолонки();
			мФормаПросмотраДанных.Открыть();
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры

Код для события "ПараметрыПодключенийПередУдалением"

Посмотреть код

Процедура ПараметрыПодключенийПередУдалением(Элемент, Отказ)
	СоответствиеИменИОбластейИсточников.Удалить(Элемент.ТекущаяСтрока.Имя);
КонецПроцедуры

Код для события "ПараметрыПодключенийПриНачалеРедактирования"

Посмотреть код

Процедура ПараметрыПодключенийПриНачалеРедактирования(Элемент, НоваяСтрока, Копирование)
	Если Элемент.ТекущаяКолонка.Имя = "Имя" Тогда 
		ПредыдущееИмяПодключения = Элемент.ТекущаяСтрока.Имя;
	КонецЕсли;
КонецПроцедуры

далее, добавляем колонки в таблицу:

- Колонка "Имя", тип "Строка", событие - "ОкончаниеВводаТекста"

Код для события "ПараметрыПодключенийИмяОкончаниеВводаТекста"

Посмотреть код

Процедура ПараметрыПодключенийИмяОкончаниеВводаТекста(Элемент, Текст, Значение, СтандартнаяОбработка)
	Если ПредыдущееИмяПодключения <> Текст Тогда
		// Проверить уникальность имени
		Если ПараметрыПодключений.Найти(Текст, "Имя") <> Неопределено Тогда 
			СтандартнаяОбработка = Ложь;
			Предупреждение("Такое имя уже используется.");
			Значение = ПредыдущееИмяПодключения;
			ЭлементыФормы.ПараметрыПодключений.ИзменитьСтроку();
			Возврат;	
		КонецЕсли;
		СоответствиеИменИОбластейИсточников.Вставить(Текст, СоответствиеИменИОбластейИсточников[ПредыдущееИмяПодключения]);
		СоответствиеИменИОбластейИсточников.Удалить(ПредыдущееИмяПодключения);
	КонецЕсли;
КонецПроцедуры

- Колонка "ПутьКФайлу", тип "Строка",

- Колонка "ОбластьВыборки", тип "Строка", КнопкаСпискаВыбора "Истина", событие - "ПараметрыПодключенийОбластьВыборкиПриИзменении" и "ПараметрыПодключенийОбластьВыборкиНачалоВыбораИзСписка"

Код для события "ПараметрыПодключенийОбластьВыборкиПриИзменении"

Посмотреть код

Процедура ПараметрыПодключенийОбластьВыборкиПриИзменении(Элемент)	
	ЭлементыФормы.ПараметрыПодключений.ЗакончитьРедактированиеСтроки(Ложь);
	Если мФормаПросмотраДанных.Открыта() Тогда
		мФормаПросмотраДанных.Закрыть();
	КонецЕсли;
	// Заново сформировать данные построителем
	ТабДокумент = Новый ТабличныйДокумент;
	Попытка
		ТабДокумент.Прочитать(ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.ПутьКФайлу, СпособЧтенияЗначенийТабличногоДокумента.Значение);
	Исключение
		Сообщить(ОписаниеОшибки());
	КонецПопытки;
	ОбластьСтрокой = ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.ОбластьВыборки;
	ТекущаяОбласть = Неопределено;
	Если ОбластьСтрокой = "Все области данных" Тогда 
		ТекущаяОбласть = ТабДокумент.Область();
	Иначе 
		ТекущаяОбласть = ТабДокумент.Область(ОбластьСтрокой);
	КонецЕсли;
	
	ПостроительЗапроса = Новый ПостроительЗапроса;
	Попытка
		ПостроительЗапроса.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТекущаяОбласть);
		ПостроительЗапроса.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
		ПостроительЗапроса.ЗаполнитьНастройки();
		ПостроительЗапроса.Выполнить();
		Результат = ПолучитьНормализованнуюТаблицу(ПостроительЗапроса.Результат.Выгрузить());
	Исключение
		Сообщить(ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.Данные = Результат;
КонецПроцедуры

Код для события "ПараметрыПодключенийОбластьВыборкиНачалоВыбораИзСписка"

Посмотреть код

Процедура ПараметрыПодключенийОбластьВыборкиНачалоВыбораИзСписка(Элемент, СтандартнаяОбработка)	
	МассивОбластейИсточника = СоответствиеИменИОбластейИсточников[ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.Имя];
	// Заполнить массив областями из соответствия	
	ЭлементыФормы.ПараметрыПодключений.Колонки.ОбластьВыборки.ЭлементУправления.СписокВыбора.ЗагрузитьЗначения(МассивОбластейИсточника);	
КонецПроцедуры

- Колонка "Просмотр", тип "Строка", Гиперссылка "Истина", РежимРедактирования "Непосредственно".

Полный листинг модуля формы внешних источников

Посмотреть код


Перем СоответствиеИменИОбластейИсточников;
Перем ПредыдущееИмяПодключения;
Перем мФормаПросмотраДанных;

Процедура КнопкаДобавитьИсточник(Кнопка)
	// Открыть диалог выбора файла .xls|.xlsx|.mxl
	Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	Диалог.Заголовок = "Выберите файл";
	Диалог.Фильтр = "Файлы excel (*.xls, *.xlsx)|*.xls;*.xlsx|Табличный документ (*.mxl)|*.mxl";
	
	Если Диалог.Выбрать() Тогда	
		ПутьКФайлу = Диалог.ПолноеИмяФайла;
		
		ТабДокумент = Новый ТабличныйДокумент;
		Попытка
			ТабДокумент.Прочитать(ПутьКФайлу, СпособЧтенияЗначенийТабличногоДокумента.Значение);
		Исключение
			Сообщить(ОписаниеОшибки());
		КонецПопытки;
		
		Если ТабДокумент.Области.Количество() = 0 Тогда 
			Сообщить("Не найдено ни одной области данных для выборки в выбранном документе.");
			Возврат;
		КонецЕсли;
		
		Если ПараметрыПодключений.Найти(ПутьКФайлу, "ПутьКФайлу") <> Неопределено Тогда 
			Предупреждение("Файл с таким расположением пути уже присутствует в списке.
				|Сначала удалите предыдущий.");
			Возврат;
		КонецЕсли;
		
		ПостроительЗапроса = Новый ПостроительЗапроса;
		Попытка
			ПостроительЗапроса.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТабДокумент.Область());
			ПостроительЗапроса.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
			ПостроительЗапроса.ЗаполнитьНастройки();
			ПостроительЗапроса.Выполнить();
			Результат = ПолучитьНормализованнуюТаблицу(ПостроительЗапроса.Результат.Выгрузить());
		Исключение
			Сообщить(ОписаниеОшибки());
			Возврат;
		КонецПопытки;
		
		Массив = Новый Массив;
		Массив.Добавить("Все области данных");  // всегда по умолчанию
		Для Каждого Область Из ТабДокумент.Области Цикл 
			Массив.Добавить(Область.Имя);
		КонецЦикла;
		НовоеИмя = ПодобратьУникальноеИмяПодключения("ИмяПодключения");
		СоответствиеИменИОбластейИсточников.Вставить(НовоеИмя, Массив);
		
		НоваяСтрока = ПараметрыПодключений.Добавить();
		НоваяСтрока.Имя = НовоеИмя;
		НоваяСтрока.ПутьКФайлу = ПутьКФайлу;
		НоваяСтрока.ОбластьВыборки = Массив[0];
		НоваяСтрока.Данные = Результат;
		НоваяСтрока.Просмотр = "Просмотр";
		
		// добавление в форму параметров
		Параметры = ЭтаФорма.ВладелецФормы.мФормаПараметров.Параметры;
		СтрокаПараметров = Параметры.Найти(НовоеИмя,"ИмяПараметра");
		Если  СтрокаПараметров = Неопределено Тогда
			СтрокаПараметров = Параметры.Добавить();
			СтрокаПараметров.ИмяПараметра = НовоеИмя;
			СтрокаПараметров.ЗначениеПараметра = Результат;
		КонецЕсли;
		
		ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока = НоваяСтрока;
		ЭлементыФормы.ПараметрыПодключений.ТекущаяКолонка = ЭлементыФормы.ПараметрыПодключений.Колонки.Имя;
		ЭлементыФормы.ПараметрыПодключений.ИзменитьСтроку();
	КонецЕсли;
КонецПроцедуры

Функция ПолучитьНормализованнуюТаблицу(Источник)	
	// Скопируем вручную исходную таблицу в новую без типов Null
	НормализованнаяКопия = Новый ТаблицаЗначений;
	Для Каждого Колонка Из Источник.Колонки Цикл 
		МассивТипов = Колонка.ТипЗначения.Типы();		
		НоваяКолонка = НормализованнаяКопия.Колонки.Добавить(
			Колонка.Имя, 
			Новый ОписаниеТипов(Колонка.ТипЗначения,, "Null"), 
			Колонка.Заголовок, 
			Колонка.Ширина);
	КонецЦикла;
	Для Каждого Строка Из Источник Цикл 
		ЗаполнитьЗначенияСвойств(НормализованнаяКопия.Добавить(), Строка);
	КонецЦикла;
	Источник.Очистить();
	Возврат НормализованнаяКопия;
КонецФункции

Функция ПодобратьУникальноеИмяПодключения(ШаблонСтрока, Знач НомерПопыткиПоиска = 0)	
	ПопыткаПоиска = НомерПопыткиПоиска;
	ПопыткаПоискаСтрокой = ?(ПопыткаПоиска = 0, "", Строка(ПопыткаПоиска));
	Если ПараметрыПодключений.Найти(ШаблонСтрока + ПопыткаПоискаСтрокой, "Имя") <> Неопределено Тогда 
		ПопыткаПоиска = ПопыткаПоиска + 1;
		ПопыткаПоискаСтрокой = Строка(ПопыткаПоиска);
		Возврат ПодобратьУникальноеИмяПодключения(ШаблонСтрока, ПопыткаПоиска);
	КонецЕсли;
	Возврат ШаблонСтрока + ПопыткаПоискаСтрокой;	
КонецФункции

Процедура ПараметрыПодключенийОбластьВыборкиНачалоВыбораИзСписка(Элемент, СтандартнаяОбработка)	
	МассивОбластейИсточника = СоответствиеИменИОбластейИсточников[ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.Имя];
	// Заполнить массив областями из соответствия	
	ЭлементыФормы.ПараметрыПодключений.Колонки.ОбластьВыборки.ЭлементУправления.СписокВыбора.ЗагрузитьЗначения(МассивОбластейИсточника);	
КонецПроцедуры

Процедура ПараметрыПодключенийОбластьВыборкиПриИзменении(Элемент)	
	ЭлементыФормы.ПараметрыПодключений.ЗакончитьРедактированиеСтроки(Ложь);
	Если мФормаПросмотраДанных.Открыта() Тогда
		мФормаПросмотраДанных.Закрыть();
	КонецЕсли;
	// Заново сформировать данные построителем
	ТабДокумент = Новый ТабличныйДокумент;
	Попытка
		ТабДокумент.Прочитать(ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.ПутьКФайлу, СпособЧтенияЗначенийТабличногоДокумента.Значение);
	Исключение
		Сообщить(ОписаниеОшибки());
	КонецПопытки;
	ОбластьСтрокой = ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.ОбластьВыборки;
	ТекущаяОбласть = Неопределено;
	Если ОбластьСтрокой = "Все области данных" Тогда 
		ТекущаяОбласть = ТабДокумент.Область();
	Иначе 
		ТекущаяОбласть = ТабДокумент.Область(ОбластьСтрокой);
	КонецЕсли;
	
	ПостроительЗапроса = Новый ПостроительЗапроса;
	Попытка
		ПостроительЗапроса.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТекущаяОбласть);
		ПостроительЗапроса.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
		ПостроительЗапроса.ЗаполнитьНастройки();
		ПостроительЗапроса.Выполнить();
		Результат = ПолучитьНормализованнуюТаблицу(ПостроительЗапроса.Результат.Выгрузить());
	Исключение
		Сообщить(ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	ЭлементыФормы.ПараметрыПодключений.ТекущаяСтрока.Данные = Результат;
КонецПроцедуры

Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)	
	Если ПараметрыПодключений.Колонки.Найти("Данные") = Неопределено Тогда 
		ПараметрыПодключений.Колонки.Добавить("Данные", Новый ОписаниеТипов("ТаблицаЗначений")); // для хранения загруженных данных
	КонецЕсли;
КонецПроцедуры

Процедура ПараметрыПодключенийИмяОкончаниеВводаТекста(Элемент, Текст, Значение, СтандартнаяОбработка)
	Если ПредыдущееИмяПодключения <> Текст Тогда
		// Проверить уникальность имени
		Если ПараметрыПодключений.Найти(Текст, "Имя") <> Неопределено Тогда 
			СтандартнаяОбработка = Ложь;
			Предупреждение("Такое имя уже используется.");
			Значение = ПредыдущееИмяПодключения;
			ЭлементыФормы.ПараметрыПодключений.ИзменитьСтроку();
			Возврат;	
		КонецЕсли;
		СоответствиеИменИОбластейИсточников.Вставить(Текст, СоответствиеИменИОбластейИсточников[ПредыдущееИмяПодключения]);
		СоответствиеИменИОбластейИсточников.Удалить(ПредыдущееИмяПодключения);
	КонецЕсли;
КонецПроцедуры

Процедура ПараметрыПодключенийПриНачалеРедактирования(Элемент, НоваяСтрока, Копирование)
	Если Элемент.ТекущаяКолонка.Имя = "Имя" Тогда 
		ПредыдущееИмяПодключения = Элемент.ТекущаяСтрока.Имя;
	КонецЕсли;
КонецПроцедуры

Процедура ПараметрыПодключенийВыбор(Элемент, ВыбраннаяСтрока, Колонка, СтандартнаяОбработка)
	Если Колонка.Имя = "Просмотр" Тогда 
		Если мФормаПросмотраДанных.Открыта() Тогда
			мФормаПросмотраДанных.Закрыть();
		Иначе			
			// загрузим данные в таблицу на форме
			мФормаПросмотраДанных.ЭлементыФормы.ТаблицаСДанными.Значение = ВыбраннаяСтрока.Данные;
			мФормаПросмотраДанных.ЭлементыФормы.ТаблицаСДанными.СоздатьКолонки();
			мФормаПросмотраДанных.Открыть();
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры

Процедура ПараметрыПодключенийПередУдалением(Элемент, Отказ)
	СоответствиеИменИОбластейИсточников.Удалить(Элемент.ТекущаяСтрока.Имя);
КонецПроцедуры

// Ключ - имя подключения, Значение - массив с областями источника подключения
СоответствиеИменИОбластейИсточников = Новый Соответствие;
ПредыдущееИмяПодключения            = "";
мФормаПросмотраДанных	            = ОбработкаОбъект.ПолучитьФорму("ФормаТаблицаСданнымиВнешнегоИсточника", ЭтаФорма);

3. Финальная часть, возвращаемся в основную форму обработки, добавляем оставшийся код в процедуру "ВыполнитьЗапрос()",

весь код процедуры "ВыполнитьЗапрос()":

Посмотреть код

Процедура ВыполнитьЗапрос()

	вСохранитьЗапросТекущейСтроки();

	ОбъектЗапрос = Новый Запрос;

	Для каждого СтрокаПараметров Из мФормаПараметров.Параметры Цикл
		Если СтрокаПараметров.ЭтоВыражение Тогда
			ОбъектЗапрос.УстановитьПараметр(СтрокаПараметров.ИмяПараметра, Вычислить(СтрокаПараметров.ЗначениеПараметра));
		Иначе
			ОбъектЗапрос.УстановитьПараметр(СтрокаПараметров.ИмяПараметра, СтрокаПараметров.ЗначениеПараметра);
			// mairon меанир
			// найти имя параметра в форме внешних источников, проверить тип на "ТаблицаЗначений" и установить данные параметра
			Если мФормаВнешнихИсточников.ПараметрыПодключений.Найти(СтрокаПараметров.ИмяПараметра, "Имя") <> Неопределено 
					И СтрокаПараметров.ЗначениеПараметра = "ТаблицаЗначений" Тогда
				ОбъектЗапрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;	
				ОбъектЗапрос.УстановитьПараметр(СтрокаПараметров.ИмяПараметра, 
					мФормаВнешнихИсточников.ПараметрыПодключений.Найти(СтрокаПараметров.ИмяПараметра, "Имя").Данные);					
			КонецЕсли;
		КонецЕсли;
	КонецЦикла;

	ОбъектЗапрос.Текст = СтрЗаменить(вПолучитьТекстЗапроса(Истина), "|", "");

	Если ПустаяСтрока(ОбъектЗапрос.Текст) Тогда
		Предупреждение("Не заполнен текст запроса!", 30);
		Возврат;
	КонецЕсли;

	ДатаНачала = ТекущаяДата();
	
	Попытка
		мРезЗапроса = ОбъектЗапрос.Выполнить();
		ДатаКонцаВыполнения = ТекущаяДата();

		мТаблицаЗагружена = Ложь;
		мСводнаяТаблицаЗагружена = Ложь;

		вЗагрузитьРезультат();
		
		ДатаКонца = ТекущаяДата();

	Исключение
		Предупреждение(Сред(ОписаниеОшибки(),69));
	КонецПопытки;

КонецПроцедуры // ВыполнитьЗапрос()

Описание работы и нюансы:

для файлов .mxl необходимо иметь имя области, хотя бы одно (имя области можно назначить прямо в режиме предприятия)

для файлов excel области - это листы,

первой строчкой всегда определяются названия колонок, потом данные.

При добавлении подключения формируется уникальное Имя подключения, - это название параметра запроса, которое необходимо использовать в кач-ве параметра таблицы значений, т.е имя подключения должно совпадать с именем параметра в форме параметров запроса.

по гиперссылке в колонке "просмотр" можно смотреть какие данные были загружены и править их при необходимости (вручную прямо в таблице, отсюда они попадут в запрос).

Далее, необходимо сформировать шаблон текста запроса для вытягивания данных из параметра таблицы значений:

ВЫБРАТЬ
	*
ПОМЕСТИТЬ ВТ
ИЗ
	&ИмяПодключения КАК ИмяПодключения

Доработка и тестирование производилось на платформе версии 8.3.18.

консоль запросы внешний excel

+2 –

См. также

Infostart Toolkit — Инструменты разработчика 1С 8.3

Инструментарий разработчика Роли и права Запросы СКД Программист Руководитель проекта Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Платные (руб)

Инструменты для разработчиков 1С 8.3: Infostart Toolkit. Автоматизация и ускорение разработки на управляемых формах. Легкость работы с 1С.

15500 руб.

02.09.2020 174552 973 403

930

Database Compression Tool: Инструмент для свертки и сжатия баз данных 1С

Инструментарий разработчика Чистка данных Свертка базы Инструменты администратора БД Системный администратор Программист Руководитель проекта Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Россия Платные (руб)

Инструмент представляет собой обработку для проведения свёртки или обрезки баз данных. Работает на ЛЮБЫХ конфигурациях (УТ, БП, ERP, УНФ, КА и т.д.). Поддерживаются серверные и файловые базы, управляемые и обычные формы. Может выполнять свертку сразу нескольких баз данных и выполнять их автоматически без непосредственного участия пользователя. Решение в Реестре отечественного ПО

8400 руб.

20.08.2024 16256 113 51

115

Infostart PrintWizard (конструктор печатных форм)

Пакетная печать Печатные формы Инструментарий разработчика Программист Платформа 1С v8.3 Запросы 1С:Зарплата и кадры бюджетного учреждения 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Платные (руб)

Инструмент, позволяющий абсолютно по-новому взглянуть на процесс разработки печатных форм. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и "прозрачность" разработки, а также навести порядок в многообразии корпоративных печатных форм.

22200 руб.

06.10.2023 17948 49 16

OneDebugger - инструмент для отладки кода в 1С без использования конфигуратора

Инструментарий разработчика Программист Платформа 1С v8.3 Платные (руб)

Инструмент для написания и отладки кода в режиме «1С:Предприятие». Представляет собой консоль кода с возможностью пошаговой отладки, просмотра значений переменных любых типов, использования процедур и функций, просмотра стека вызовов, вычисления произвольных выражений на встроенном языке в контексте точки останова, синтаксического контроля и остановки по ошибке. В консоли используется удобный редактор кода с подсветкой, контекстной подсказкой, возможностью вызова конструкторов запроса и форматной строки.

9360 руб.

17.05.2024 28125 98 48

141

Infostart DataFormWizard: Управление данными и формами 1С 8.3

Инструменты администратора БД Инструментарий разработчика Роли и права Программист Платформа 1С v8.3 1C:Бухгалтерия Россия Платные (руб)

Расширение позволяет без изменения кода конфигурации выполнять проверки при вводе данных, скрывать от пользователя недоступные ему данные, выполнять код в обработчиках. Не изменяет данные конфигурации, легко устанавливается практически на любую конфигурацию на управляемых формах.

15000 руб.

10.11.2023 12330 49 33

SALE! %

PowerTools: Инструменты администратора 1С 8.3

Инструментарий разработчика Инструменты администратора БД Системный администратор Программист Платформа 1С v8.3 Управляемые формы 1C:ERP 1С:УТ 1С:ДО 1С:Бухгалтерия 3.0 1С:ERP. Управление холдингом 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 1С:Управление торговлей 11 Россия Платные (руб)

Универсальный инструмент программиста для администрирования конфигураций. Сборник наиболее часто используемых обработок под единым интерфейсом.

~~4800~~ 3840 руб.

14.01.2013 192125 1153 0

920

Бустер Конвертации данных 3 (Infostart Toolkit)

Инструментарий разработчика Программист 8.3.14 Россия Платные (руб)

Расширение для конфигурации “Конвертация данных 3”. Добавляет подсветку синтаксиса, детальную контекстную подсказку, глобальный поиск по коду.

20000 руб.

07.10.2021 18337 7 32

Конструктор АРМ

Инструментарий разработчика Платформа 1С v8.3 1C:Бухгалтерия 1С:ERP Управление предприятием 2 Платные (руб)

Разработка Конструктор автоматизированных рабочих мест "Конструктор АРМ" реализована в виде расширения и является универсальным инструментом для создания АРМ любой сложности в пользовательском режиме.

3600 руб.

27.12.2024 1427 2 0