Здравствуйте.
Понадобилось нашей организации быстро просматривать сведения о застрахованных лицах, переданные в ФСС, по каждому человеку.
Вопрос можно было решить различными способами, например, сделав отчет или вывести сообщение пользователю, но все же было принято решение: открывать непосредственно документ и брать данные от туда.
Открыть документ программно не составило никакого труда, но проблема встала в другом, в данном документе около 2 тысяч записей. И мало того, что нужно было открыть документ, но еще и перейти к нужной строке табличной части этого документа:
Поиск в интернете не дал полного и точного ответа. То есть вопросы люди задавали: "А как открыть документ и встать на нужную строку", но в большинстве случаев получали ответ вида:
Форма.Элементы.Товары.ТекущаяСтрока = НайденныеСтроки[0].ПолучитьИдентификатор();
Не знаю почему, но этот код у людей не работал. Например, у меня "ПолучитьИдентификатор()" 1С не понимала... Возможно, данный код работает только на УФ, не проверял. Покажу, как мне удалось решить этот вопрос на обычных формах.
Задание: по нажатию кнопки обработки открыть документ и перейти на строку с сотрудником Баринов Борис Николаевич. Код кнопки получился таким:
Процедура КнопкаВыполнитьНажатие(Кнопка)
//получим сотрудника любым способом,
//у Вас это может быть запрос, или реквизит формы
//я, для примера, получу его поиском из справочника
Сотрудник = Справочники.СотрудникиОрганизаций.НайтиПоНаименованию("Баринов Борис Николаевич", Ложь);
//найдем нужный документ
//Сотрудник может быть в нескольких документах. Нам нужен документ, который был создан последним
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ ПЕРВЫЕ 1
| СведенияОЗастрахованныхЛицахФССРаботникиОрганизации.Ссылка
|ИЗ
| Документ.СведенияОЗастрахованныхЛицахФСС.РаботникиОрганизации КАК СведенияОЗастрахованныхЛицахФССРаботникиОрганизации
|ГДЕ
| СведенияОЗастрахованныхЛицахФССРаботникиОрганизации.Ссылка.Проведен = ИСТИНА
| И СведенияОЗастрахованныхЛицахФССРаботникиОрганизации.Сотрудник = &Сотрудник
|
|УПОРЯДОЧИТЬ ПО
| СведенияОЗастрахованныхЛицахФССРаботникиОрганизации.Ссылка.Дата УБЫВ";
Запрос.УстановитьПараметр("Сотрудник", Сотрудник);
РезультатЗапроса = Запрос.Выполнить().Выгрузить();
//возможно, документ так и не был найден. Проверим это:
Если РезультатЗапроса.Количество() = 1 Тогда
Документ = РезультатЗапроса[0].Ссылка;
//получим программно форму документа
Форма = Документ.ПолучитьФорму("ФормаДокумента");
//найдем все строки в документе по сотруднику
Отбор = Новый Структура();
Отбор.Вставить("Сотрудник", Сотрудник);
СтрокаТаблицы = Форма.ЭтотОбъект.РаботникиОрганизации.НайтиСтроки(Отбор);
//установим текущую позицию в первую из найденных строк,
//на всякий случай проверив перед этим, что есть хотя бы одна
Если СтрокаТаблицы.Количество() > 0 Тогда
Форма.ЭлементыФормы.РаботникиОрганизации.ТекущаяСтрока = СтрокаТаблицы[0];
КонецЕсли;
//откроем форму программно
Форма.Открыть();
КонецЕсли;
КонецПроцедуры
На вид текст получился сложным и объемным. Но большая его часть просто определяет сотрудника и ищет документ с данным сотрудником. Если Документ уже Вами получен и сотрудник известен, то все сведется к:
//получим программно форму документа
Форма = Документ.ПолучитьФорму("ФормаДокумента");
//найдем все строки в документе по сотруднику
Отбор = Новый Структура();
Отбор.Вставить("Сотрудник", Сотрудник);
СтрокаТаблицы = Форма.ЭтотОбъект.РаботникиОрганизации.НайтиСтроки(Отбор);
//установим текущую позицию в первую из найденных строк,
//на всякий случай проверив перед этим, что есть хотя бы одна
Если СтрокаТаблицы.Количество() > 0 Тогда
Форма.ЭлементыФормы.РаботникиОрганизации.ТекущаяСтрока = СтрокаТаблицы[0];
КонецЕсли;
//откроем форму программно
Форма.Открыть();
Здесь мы сначала получаем форму документа и перед открытием этой формы у элемента табличной части устанавливаем текущую позицию. При этом, "ПолучитьИдентификатор()" не требуется.
Вступайте в нашу телеграмм-группу Инфостарт
