Контекстная подсказка и автозаполнение данных используя DaData.ru

28.05.24

Заполнение контрегнта по ИНН, названию, контекстная подсказка по адресу, данные банка по идентификатору, подсказка по email и по фамилиям.

Файлы

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование	Скачано	Купить файл	По подписке PRO
Контекстная подсказка и автозаполнение данных используя DaData.ru: .cf 82,04Kb 15	15	2 500 руб. Купить	1 SM Скачать

Сервис DaData.ru предоставляет возможность получать данные по контрагентам, банкам и контекстную подсказку для более быстрого и точного заполнения реквизитов. Сервис является бесплатным (до 10 000 запросов в день). Для работы потребуется API ключ, получить его можно на сайте dadata.ru.

В файле содержится конфигурация с обработкой, код которой приведен ниже.

Обработка имеет несколько экспортных функций, которые:

- Находит компанию или ИП по ИНН или ОГРН;

- Ищет компании и индивидуальных предпринимателей по названию (полному и краткому), по ИНН, ОГРН и КПП;

- Ищет адреса по любой части адреса от региона до квартиры («самара авроры 7 12» → «443017, Самарская обл, г Самара, ул Авроры, д 7, кв 12»). Также ищет по почтовому индексу («105568» → «г Москва, ул Магнитогорская»).

- Находит банк по любому из идентификаторов: БИК, SWIFT, ИНН;

- Ищет кредитные организации по названию и другим идентификаторам;

- Подсказывает ФИО одной строкой или отдельно фамилию, имя, отчество;

- Подсказывает при вводе email локальную часть (до «собачки»), подсказывает доменную часть (после «собачки»), исправляет опечатки (yadex.ru → yandex.ru).

Модуль менеджера

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

#Область ПрограммныйИнтерфейс

// Функция - Сведения о юридическом лице по ИНН
//
// Параметры:
//  СтрокаПоиска - Строка - Строка поиска
// 
//  Структура:
//    * ОписаниеОшибки - Строка - содержит текст ошибки, возникшей при получении данных.
//    * suggestions    - Массив - массив структур хранящих найденные сведения. Описание свойств можно найти на https://dadata.ru/api/find-party/
//
Функция СведенияОЮридическомЛицеПоИНН(СтрокаПоиска) Экспорт
	
	СведенияОЮридическомЛице = Новый Структура("ОписаниеОшибки,suggestions");
	
	Если ПустаяСтрока(КлючAPI()) Тогда
		СведенияОЮридическомЛице.ОписаниеОшибки = "Нет действующих настроек для работы с сервисом!";
		Возврат СведенияОЮридическомЛице;
	КонецЕсли;
	
	Результат = ВыполнитьЗапросДанных(СтрокаПоиска, "/suggestions/api/4_1/rs/findById/party");
	
	ПрочитатьРезультатЗапросаДанных(СведенияОЮридическомЛице, Результат); 
	
	УдалитьЮрЛицБезКПП(СведенияОЮридическомЛице);
	ПреобразоватьАдресИСтатусы(СведенияОЮридическомЛице);
	
	Возврат СведенияОЮридическомЛице;
	
КонецФункции

// Функция - Подсказка по организациям
//
// Параметры:
//  СтрокаПоиска - Строка - Строка поиска
// 
//  Структура:
//    * ОписаниеОшибки - Строка - содержит текст ошибки, возникшей при получении данных.
//    * suggestions    - Массив - массив структур хранящих найденные сведения. Описание свойств можно найти на https://dadata.ru/api/suggest/party/
//
Функция ПодсказкаПоОрганизациям(СтрокаПоиска) Экспорт
	
	ПодсказкаПоОрганизациям = Новый Структура("ОписаниеОшибки,suggestions");
	
	Если ПустаяСтрока(КлючAPI()) Тогда
		ПодсказкаПоОрганизациям.ОписаниеОшибки = "Нет действующих настроек для работы с сервисом!";
		Возврат ПодсказкаПоОрганизациям;
	КонецЕсли;
	
	Результат = ВыполнитьЗапросДанных(СтрокаПоиска, "/suggestions/api/4_1/rs/suggest/party");
	
	ПрочитатьРезультатЗапросаДанных(ПодсказкаПоОрганизациям, Результат);
	
	Возврат ПодсказкаПоОрганизациям;
	
КонецФункции

// Функция - Банк по идентификатору
//
// Параметры:
//  СтрокаПоиска - Строка - Строка поиска
// 
//  Структура:
//    * ОписаниеОшибки - Строка - содержит текст ошибки, возникшей при получении данных.
//    * suggestions    - Массив - массив структур хранящих найденные сведения. Описание свойств можно найти на https://dadata.ru/api/find-bank/
//
Функция БанкПоИдентификатору(СтрокаПоиска) Экспорт
	
	БанкПоИдентификатору = Новый Структура("ОписаниеОшибки,suggestions");
	
	Если ПустаяСтрока(КлючAPI()) Тогда
		БанкПоИдентификатору.ОписаниеОшибки = "Нет действующих настроек для работы с сервисом!";
		Возврат БанкПоИдентификатору;
	КонецЕсли;
	
	Результат = ВыполнитьЗапросДанных(СтрокаПоиска, "/suggestions/api/4_1/rs/findById/bank");
	
	ПрочитатьРезультатЗапросаДанных(БанкПоИдентификатору, Результат);
	
	Возврат БанкПоИдентификатору;
	
КонецФункции

// Функция - Подсказка по банкам
//
// Параметры:
//  СтрокаПоиска - Строка - Строка поиска
// 
//  Структура:
//    * ОписаниеОшибки - Строка - содержит текст ошибки, возникшей при получении данных.
//    * suggestions    - Массив - массив структур хранящих найденные сведения. Описание свойств можно найти на https://dadata.ru/api/suggest/bank/
//
Функция ПодсказкаПоБанкам(СтрокаПоиска) Экспорт
	
	ПодсказкаПоБанкам = Новый Структура("ОписаниеОшибки,suggestions");
	
	Если ПустаяСтрока(КлючAPI()) Тогда
		ПодсказкаПоБанкам.ОписаниеОшибки = "Нет действующих настроек для работы с сервисом!";
		Возврат ПодсказкаПоБанкам;
	КонецЕсли;
	
	Результат = ВыполнитьЗапросДанных(СтрокаПоиска, "/suggestions/api/4_1/rs/suggest/bank");
	
	ПрочитатьРезультатЗапросаДанных(ПодсказкаПоБанкам, Результат);
	
	Возврат ПодсказкаПоБанкам;
	
КонецФункции

// Функция - Подсказка по ФИО
//
// Параметры:
//  СтрокаПоиска - Строка - Строка поиска
// 
//  Структура:
//    * ОписаниеОшибки - Строка - содержит текст ошибки, возникшей при получении данных.
//    * suggestions    - Массив - массив структур хранящих найденные сведения. Описание свойств можно найти на https://dadata.ru/api/suggest/name/
//
Функция ПодсказкаПоФИО(СтрокаПоиска) Экспорт
	
	ПодсказкаПоФИО = Новый Структура("ОписаниеОшибки,suggestions");
	
	Если ПустаяСтрока(КлючAPI()) Тогда
		ПодсказкаПоФИО.ОписаниеОшибки = "Нет действующих настроек для работы с сервисом!";
		Возврат ПодсказкаПоФИО;
	КонецЕсли;
	
	Результат = ВыполнитьЗапросДанных(СтрокаПоиска, "/suggestions/api/4_1/rs/suggest/fio");
	
	ПрочитатьРезультатЗапросаДанных(ПодсказкаПоФИО, Результат);
	
	Возврат ПодсказкаПоФИО;
	
КонецФункции

// Функция - Подсказка по email
//
// Параметры:
//  СтрокаПоиска - Строка - Строка поиска
// 
//  Структура:
//    * ОписаниеОшибки - Строка - содержит текст ошибки, возникшей при получении данных.
//    * suggestions    - Массив - массив структур хранящих найденные сведения. Описание свойств можно найти на https://dadata.ru/api/suggest/email/
//
Функция ПодсказкаПоEmail(СтрокаПоиска) Экспорт
	
	ПодсказкаПоEmail = Новый Структура("ОписаниеОшибки,suggestions");
	
	Если ПустаяСтрока(КлючAPI()) Тогда
		ПодсказкаПоEmail.ОписаниеОшибки = "Нет действующих настроек для работы с сервисом!";
		Возврат ПодсказкаПоEmail;
	КонецЕсли;
	
	Результат = ВыполнитьЗапросДанных(СтрокаПоиска, "/suggestions/api/4_1/rs/suggest/email");
	
	ПрочитатьРезультатЗапросаДанных(ПодсказкаПоEmail, Результат);
	
	Возврат ПодсказкаПоEmail;
	
КонецФункции

// Функция - Подсказка по адресам
//
// Параметры:
//  СтрокаПоиска - Строка - Строка поиска
// 
//  Структура:
//    * ОписаниеОшибки - Строка - содержит текст ошибки, возникшей при получении данных.
//    * suggestions    - Массив - массив структур хранящих найденные сведения. Описание свойств можно найти на https://dadata.ru/api/suggest/address/
//
Функция ПодсказкаПоАдресам(СтрокаПоиска) Экспорт
	
	ПодсказкаПоАдресам = Новый Структура("ОписаниеОшибки,suggestions");
	
	Если ПустаяСтрока(КлючAPI()) Тогда
		ПодсказкаПоАдресам.ОписаниеОшибки = "Нет действующих настроек для работы с сервисом!";
		Возврат ПодсказкаПоАдресам;
	КонецЕсли;
	
	Результат = ВыполнитьЗапросДанных(СтрокаПоиска, "/suggestions/api/4_1/rs/suggest/address");
	
	ПрочитатьРезультатЗапросаДанных(ПодсказкаПоАдресам, Результат);
	
	Возврат ПодсказкаПоАдресам;
	
КонецФункции

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

Функция ВыполнитьЗапросДанных(СтрокаПоиска, Метод)
	
	ЗаписьJSON = Новый ЗаписьJSON;
	ЗаписьJSON.УстановитьСтроку();
	ЗаписатьJSON(ЗаписьJSON, Новый Структура("query", СтрокаПоиска));
	
	Тело = ЗаписьJSON.Закрыть();
	Сервер = "suggestions.dadata.ru";
	Порт = 443;
	Таймаут = 30;
	ЗащищенноеСоединение = Новый ЗащищенноеСоединениеOpenSSL;
	
	Возврат ВыполнитьPOSTЗапрос(Сервер, Порт, Метод, Таймаут, Тело, ЗащищенноеСоединение);
	
КонецФункции

Функция ВыполнитьPOSTЗапрос(Сервер, Порт, Адрес, Таймаут, Тело, ЗащищенноеСоединение)
	
	Соединение = Новый HTTPСоединение(Сервер,Порт,,,,Таймаут, ЗащищенноеСоединение);
	
	Заголовки = Новый Соответствие;
	Заголовки.Вставить("Content-type",  "application/json");
	Заголовки.Вставить("Accept",        "application/json");
	Заголовки.Вставить("Authorization", "Token " + КлючAPI());
	
	Запрос = Новый HTTPЗапрос(Адрес, Заголовки);
	Запрос.УстановитьТелоИзСтроки(Тело);
	
	СтруктураДанных = Новый Структура("КодСостояния,Тело");
	Попытка
		Ответ = Соединение.ОтправитьДляОбработки(Запрос);
		СтруктураДанных.КодСостояния = Ответ.КодСостояния;
		СтруктураДанных.Тело = Ответ.ПолучитьТелоКакСтроку();
		Возврат СтруктураДанных;
	Исключение
		//ToDo: Заменить на другой код, более точный для таких исключений
		СтруктураДанных.КодСостояния = 500;
		Возврат СтруктураДанных;
	КонецПопытки;
		
КонецФункции	

Функция ДесериализоватьСтруктуруОтвета(Тело)
	
	ЧтениеJSON = Новый ЧтениеJSON;
	ЧтениеJSON.УстановитьСтроку(Тело);
	Возврат ПрочитатьJSON(ЧтениеJSON, Ложь).suggestions;
	
КонецФункции // ДесериализоватьСтруктуруОтвета()

Функция КлючAPI()
	
	КлючОбъекта  = "DaData.ru";
	КлючНастроек = "DaDataAPI";
	ОписаниеНастроек = "API ключ для сервиса DaData.ru";
	Пользователь = "Общие";
	
	СтруктураНастроек = Неопределено;
	СтруктураНастроек = ХранилищеОбщихНастроек.Загрузить(КлючОбъекта, КлючНастроек, ОписаниеНастроек, Пользователь);
	
	Если ЗначениеЗаполнено(СтруктураНастроек) Тогда
		Возврат СтруктураНастроек.КлючAPI;
	Иначе
		Возврат "";
	КонецЕсли;
	
КонецФункции

Процедура ПреобразоватьАдресИСтатусы(СтруктураОтвет)
	
	Для каждого suggestion Из СтруктураОтвет.suggestions Цикл
		
		Сведения = suggestion.data;
		
		Статусы = Новый Соответствие;
		Статусы.Вставить("LIQUIDATING",  "в стадии ликвидации");
		Статусы.Вставить("LIQUIDATED",   "ЛИКВИДИРОВАН");
		Статусы.Вставить("BANKRUPT",     "БАНКРОТ");
		Статусы.Вставить("REORGANIZING", "В СТАДИИ РЕОРГАНИЗАЦИИ");
		Статусы.Вставить("ACTIVE",       "действующий");
		
		Сведения.state.status = Статусы[Сведения.state.status];

		Если Сведения.type = "LEGAL" Тогда
			Сведения.name.full = ПреобразоватьНаименование(Сведения.name.full);
			Сведения.name.short_with_opf = ПреобразоватьНаименование(Сведения.name.short_with_opf);
			Сведения.name.full_with_opf = ПреобразоватьНаименование(Сведения.name.full_with_opf);
		КонецЕсли;
			
	КонецЦикла;
	
КонецПроцедуры

Функция ПреобразоватьНаименование(Наименованиекомпании)
	
	ОПФ = "ПАОЗАООООНКООПАОИП";
	
	СокращенияГородов = СокращенияГородов();
	
	Слова = СтрРазделить(Наименованиекомпании, " ", Ложь);
	
	Результат = Новый Массив;
		
	Для Каждого Слово Из Слова Цикл
		Если СтрНайти(ОПФ, Слово) > 0 Тогда
			Результат.Добавить(Слово);
			Продолжить;
		КонецЕсли;
		Если СтрСравнить(Слово, "филиал") = 0 ИЛИ СтрСравнить(Слово, "фил") > 0 Тогда
			Результат.Добавить(НРег(Слово));
			Продолжить;
		КонецЕсли;
		
		Если НЕ СокращенияГородов.Найти(ВРег(Слово)) = Неопределено Тогда
			Результат.Добавить(ВРег(Слово));
			Продолжить;
		КонецЕсли;
		
		Результат.Добавить(ТРег(Слово));
		
	КонецЦикла;
	
	Возврат СтрСоединить(Результат, " ");
	
КонецФункции

Процедура ПрочитатьРезультатЗапросаДанных(СтруктураОтвета, РезультатЗапроса)
	
	Если РезультатЗапроса.КодСостояния = 200 Тогда
		
		СтруктураОтвета.suggestions = ДесериализоватьСтруктуруОтвета(РезультатЗапроса.Тело);
		
	Иначе
		СтруктураОтвета.ОписаниеОшибки = СтрШаблон("Не удалось получить ответ от сервиса DaData
												   |Код состояния: %1
												   |Ответ сервера: %2", РезультатЗапроса.КодСостояния, РезультатЗапроса.Тело);
	КонецЕсли;
	
КонецПроцедуры // ПрочитатьРезультатЗапросаДанных()

Функция СокращенияГородов()
	
	МассивГородов = Новый Массив;
	МассивГородов.Добавить("МАЙ");
	МассивГородов.Добавить("ГОА");
	МассивГородов.Добавить("УФА");
	МассивГородов.Добавить("УДЭ");
	МассивГородов.Добавить("МАХ");
	МассивГородов.Добавить("НЗР");
	МассивГородов.Добавить("НАЛ");
	МассивГородов.Добавить("ЭЛИ");
	МассивГородов.Добавить("ЧЕР");
	МассивГородов.Добавить("ПТЗ");
	МассивГородов.Добавить("СЫК");
	МассивГородов.Добавить("ЙШК");
	МассивГородов.Добавить("СРН");
	МассивГородов.Добавить("ЯКУ");
	МассивГородов.Добавить("ВЛК");
	МассивГородов.Добавить("ТАТ");
	МассивГородов.Добавить("КЗЛ");
	МассивГородов.Добавить("ИЖВ");
	МассивГородов.Добавить("АБН");
	МассивГородов.Добавить("ГРЗ");
	МассивГородов.Добавить("ЧЕБ");
	МассивГородов.Добавить("БАР");
	МассивГородов.Добавить("ЧИТ");
	МассивГородов.Добавить("ПТР");
	МассивГородов.Добавить("КРД");
	МассивГородов.Добавить("КРР");
	МассивГородов.Добавить("ПЕМ");
	МассивГородов.Добавить("ВЛВ");
	МассивГородов.Добавить("СТВ");
	МассивГородов.Добавить("ХАБ");
	МассивГородов.Добавить("БЛГ");
	МассивГородов.Добавить("АРХ");
	МассивГородов.Добавить("ACT");
	МассивГородов.Добавить("БЕЛ");
	МассивГородов.Добавить("БРН");
	МассивГородов.Добавить("ВЛМ");
	МассивГородов.Добавить("ВЛГ");
	МассивГородов.Добавить("ВОЛ");
	МассивГородов.Добавить("ВРЖ");
	МассивГородов.Добавить("ИВА");
	МассивГородов.Добавить("ИРК");
	МассивГородов.Добавить("КЛГ");
	МассивГородов.Добавить("КЛЖ");
	МассивГородов.Добавить("КЕМ");
	МассивГородов.Добавить("КИР");
	МассивГородов.Добавить("КОС");
	МассивГородов.Добавить("КУГ");
	МассивГородов.Добавить("КРС");
	МассивГородов.Добавить("ЛОД");
	МассивГородов.Добавить("ЛПЦ");
	МассивГородов.Добавить("МАГ");
	МассивГородов.Добавить("МСК");
	МассивГородов.Добавить("МУР");
	МассивГородов.Добавить("НЖГ");
	МассивГородов.Добавить("НВГ");
	МассивГородов.Добавить("НОВ");
	МассивГородов.Добавить("ОМС");
	МассивГородов.Добавить("ОРБ");
	МассивГородов.Добавить("ОРЛ");
	МассивГородов.Добавить("ПНЗ");
	МассивГородов.Добавить("ПСК");
	МассивГородов.Добавить("РСТ");
	МассивГородов.Добавить("РЯЗ");
	МассивГородов.Добавить("СМР");
	МассивГородов.Добавить("СРТ");
	МассивГородов.Добавить("ЮСХ");
	МассивГородов.Добавить("CBE");
	МассивГородов.Добавить("СМО");
	МассивГородов.Добавить("ТМБ");
	МассивГородов.Добавить("ТВЕ");
	МассивГородов.Добавить("ТОМ");
	МассивГородов.Добавить("ТУЛ");
	МассивГородов.Добавить("ТЮМ");
	МассивГородов.Добавить("УЛН");
	МассивГородов.Добавить("ЧЕЛ");
	МассивГородов.Добавить("ЯРЛ");
	МассивГородов.Добавить("БИР");
	МассивГородов.Добавить("ЧИТ");
	МассивГородов.Добавить("НРМ");
	МассивГородов.Добавить("УОР");
	МассивГородов.Добавить("ХМН");
	МассивГородов.Добавить("АНД");
	МассивГородов.Добавить("СЛХ");
	МассивГородов.Добавить("МОС");
	МассивГородов.Добавить("СПБ");
	МассивГородов.Добавить("ШАЗ");
	МассивГородов.Добавить("ШБТ");
	МассивГородов.Добавить("ШБМ");
	МассивГородов.Добавить("ШБЛ");
	МассивГородов.Добавить("ШБР");
	МассивГородов.Добавить("ШВС");
	МассивГородов.Добавить("ШКМ");
	МассивГородов.Добавить("ШКС");
	МассивГородов.Добавить("ШМЛ");
	МассивГородов.Добавить("ШОМ");
	МассивГородов.Добавить("ШПМ");
	МассивГородов.Добавить("ШЧМ");
	МассивГородов.Добавить("ШЧУ");
	МассивГородов.Добавить("ШЯМ");
	
	Возврат МассивГородов;
		
КонецФункции

Процедура УдалитьЮрЛицБезКПП(СтруктураОтвет)

	НовыйМассив = Новый Массив;
	
	Для Каждого suggestion Из СтруктураОтвет.suggestions Цикл
		
		Если suggestion.data.type = "INDIVIDUAL"
		ИЛИ (suggestion.data.type = "LEGAL" И НЕ ПустаяСтрока(suggestion.data.kpp)) Тогда
		
		НовыйМассив.Добавить(suggestion);
		КонецЕсли;
		
	КонецЦикла;
	
	СтруктураОтвет.suggestions = НовыйМассив;

КонецПроцедуры // УдалитьКонтрагентовБезКПП()

#КонецОбласти

#КонецЕсли

Модуль формы

#Область ОбработчикиСобытийЭлементовШапкиФормы

&НаКлиенте
Процедура КлючAPIПриИзменении(Элемент)
    ЭтаФорма.Модифицированность = Истина;
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
    
    КлючОбъекта  = "DaData.ru";
    КлючНастроек = "DaDataAPI";
    ОписаниеНастроек = "API ключ для сервиса DaData.ru";
    Пользователь = "Общие";
    
    СтруктураНастроек = Неопределено;
    СтруктураНастроек = ХранилищеОбщихНастроек.Загрузить(КлючОбъекта, КлючНастроек, ОписаниеНастроек, Пользователь);
    
    Если ЗначениеЗаполнено(СтруктураНастроек) Тогда
        Объект.КлючAPI = СтруктураНастроек.КлючAPI; 
    КонецЕсли;

КонецПроцедуры

&НаКлиенте
Процедура ПередЗакрытием(Отказ, СтандартнаяОбработка)
    
    Если Модифицированность Тогда
        
        Отказ = Истина;
        
        Оповещение = Новый ОписаниеОповещения("ПослеОтветаНаВопрос", ЭтотОбъект);
        ПоказатьВопрос(Оповещение, "Данные были изменены, сохранить ключ API?", РежимДиалогаВопрос.ДаНетОтмена);
        
    КонецЕсли;
    
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиКомандФормы

&НаКлиенте
Процедура ПерейтиНаГлавнуюСтраницуDaData(Команда)
    ЗапуститьПриложение("https://dadata.ru/");
КонецПроцедуры

&НаКлиенте
Процедура ПерейтиНаСтраницуAPI(Команда)
    ЗапуститьПриложение("https://dadata.ru/api");
КонецПроцедуры

&НаКлиенте
Процедура Сохранить(Команда)
    СохранитьКлючAPI();
    Модифицированность = Ложь;
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

Процедура СохранитьКлючAPI()
    
    УстановитьПривилегированныйРежим(Истина);
    КлючОбъекта  = "DaData.ru";
    КлючНастроек = "DaDataAPI";
    ОписаниеНастроек = "API ключ для сервиса DaData.ru";
    Пользователь = "Общие";
    Настройки    = Новый Структура("КлючAPI", Объект.КлючAPI);
    ХранилищеОбщихНастроек.Сохранить(КлючОбъекта,  КлючНастроек, Настройки, ОписаниеНастроек, Пользователь);
    
КонецПроцедуры

&НаКлиенте
Процедура ПослеОтветаНаВопрос(РезультатВопроса, ДополнительныеПараметры) Экспорт
    
    Если РезультатВопроса = КодВозвратаДиалога.Нет Тогда
        Модифицированность = Ложь;
        Закрыть();
    ИначеЕсли РезультатВопроса = КодВозвратаДиалога.Да Тогда
        СохранитьКлючAPI();
        Модифицированность = Ложь;
        Закрыть();
    КонецЕсли;
    
КонецПроцедуры

#КонецОбласти

Тестировалось на платформе 8.3.13, 8.3.20, 8.3.22.

Проверено на следующих конфигурациях и релизах:

Управление торговлей, редакция 10.3, релизы 10.3.88.3

Вступайте в нашу телеграмм-группу Инфостарт

контекстная подсказка контрагенты автозаполнение егрюл dadata dadata.ru

+12 –

См. также

Интеграция Альфа Авто 5 и 6 и AUTOCRM + LOGICSTARS

Сайты и интернет-магазины WEB-интеграция Системный администратор Программист Пользователь 1С:Предприятие 8 1C:Бухгалтерия 1С:Управление торговлей 11 Автомобили, автосервисы Россия Управленческий учет Платные (руб)

Интеграционный модуль обмена между конфигурацией Альфа Авто 5 и Альфа Авто 6 и порталом AUTOCRM / LOGICSTARS. Данный модуль универсален. Позволяет работать с несколькими обменами AUTOCRM / LOGICSTAR разных брендов в одной информационной базе в ручном и автоматическом режиме.

42700 руб.

03.08.2020 23137 33 24

Интеграция 1С с OpenCart 2.x, 3x модуль обмена данными

WEB-интеграция Оптовая торговля Розничная торговля Программист 1С:Предприятие 8 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 Розничная и сетевая торговля (FMCG) Оптовая торговля, дистрибуция, логистика Управленческий учет Платные (руб)

Модуль интеграции 1С с OpenCart 2.x, 3x позволяет обмениваться данными между OpenCart (самая популярная бесплатная cms для интернет-магазинов) и 1С:Предприятие 8.

6914 руб.

17.11.2015 130301 451 143

248

Экспортер — автоматизация выгрузки данных из 1С в Spot2D

WEB-интеграция Программист Бизнес-аналитик 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Оптовая торговля, дистрибуция, логистика ИТ-компания Платные (руб)

Модуль "Экспортер" — это расширение для 1С, предназначенное для автоматизации процессов выгрузки данных. Оно позволяет эффективно извлекать, преобразовывать и передавать данные из систем 1С в интеграционную платформу Spot2D. Подсистема упрощает настройку, снижает количество ручных операций и обеспечивает удобный контроль данных.

17568 руб.

20.12.2024 5201 22 4

Интеграция 1С с API СДЭК, Деловые Линии, ПЭК, Boxberry, Почта России и др. Управление доставками в 1С 8.3

WEB-интеграция Рабочее место Оптовая торговля Розничная торговля Логистика, склад и ТМЦ Пользователь 1С:Предприятие 8 1С:Бухгалтерия 2.0 1С:Бухгалтерия 3.0 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 1С:Управление торговлей 10 1С:Управление торговлей 11 1С:Розница 2 1С:Розница 3.0 Оптовая торговля, дистрибуция, логистика Россия Управленческий учет Платные (руб)

Программный продукт "Управление доставками в 1С" позволяет обмениваться с личным кабинетом СДЭК, Деловые Линии, ПЭК, DPD, Почта России и другими транспортных компаниями. Упрощает создание заявок и резервирование заказов прямо в интерфейсе 1С

18300 руб.

10.03.2016 69991 314 98

Amocrm: интеграция с 1С

WEB-интеграция Анализ продаж Системный администратор Программист Пользователь 1С:Предприятие 8 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Управленческий учет Платные (руб)

Модуль "Подсистема интеграции AmoCRM с 1С" позволяет обеспечить единое информационное пространство, в котором пользователи могут эффективно управлять клиентской базой, следить за статусами сделок и поддерживать актуальность данных как в AmoCRM, так и в 1С.

60000 руб.

07.05.2019 41082 75 45

Интеграция Vetmanager с 1С: автоматизация учета для ветеринарных клиник. Синхронизация документов, справочников и оплат через API

WEB-интеграция Программист 1С:Предприятие 8 1С:Бухгалтерия 3.0 Бытовые услуги, сервис Платные (руб)

Расширение для автоматизации передачи данных между сервисом Vetmanager с 1С: Бухгалтерия 3.0. Решение позволяет загружать документы и справочники из Ветменеджер в 1С:Бухгалтерию, сокращая время на ручной ввод данных и минимизируя ошибки.

24000 руб.

02.02.2021 21741 62 52

Заполнение контрагента по ИНН или наименованию реквизитов по данным сайта ФНС в 1С: 8.3

Обмен с ГосИС WEB-интеграция Бухгалтер Пользователь 1С:Предприятие 8 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Управление производственным предприятием 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия государственного учреждения 1С:Документооборот 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Платные (руб)

Обработка является альтернативой механизму, разработанному фирмой 1С и заполняющему реквизиты контрагента по ИНН или наименованию. Не требуется действующей подписки ИТС. Вызывается как внешняя дополнительная обработка, т.е. используется, непосредственно, из карточки контрагента. Заполнение по ИНН или наименованию реквизитов контрагента по данным сайта ФНС (egrul.nalog.ru) для БП 2.0, БП 3.0, БГУ 1.0, БГУ 2.0, УТ 10.3, УТ 11.x, КА 1.1, КА 2.x, УПП 1.x, ERP 2.x, УНФ 1.5, УНФ 1.6, УНФ 3.0, ДО 2.1

5283 руб.

28.04.2016 99854 116 219

364

Выгрузка товаров в VK маркет из 1С

WEB-интеграция Загрузка и выгрузка в Excel Программист Пользователь 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Розничная и сетевая торговля (FMCG) Россия Платные (руб)

Расширение освободит вас от необходимости вручную обновлять товары в группах ВКонтакте. Достаточно задать правила один раз, и система автоматически синхронизирует ваш каталог. Вы сможете легко выбирать, какие товары публиковать, создавая гибкие критерии отбора. Например, можно добавить важные для покупателей параметры: цвет, размер или другие характеристики.

12200 руб.

29.08.2025 1530 2 0

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. Гость 31.07.24 11:57

Забавно, но в приложенном к публикации файле конфа, в которой только одна обработка. И в которой только форма открытия сервиса dadata.ru для сохранения ключа API. Общих модулей нет. Модуль обработки пустой.

UPD: слона не заметил. Всё на месте.

2. simuljakr 207 14.08.24 16:11 Сейчас в теме

А где найти ключ API ?
(кроме сайта dadata)

3. simuljakr 207 14.08.24 18:08 Сейчас в теме

(2) Отвечу сам себе ))
До 10 тысяч запросов в месяц он бесплатный, скачивается на их сайте.

4. simuljakr 207 14.08.24 18:09 Сейчас в теме

(0) Скажите, а на обычных формах работать будет ?

Для отправки сообщения требуется регистрация/авторизация

Автор:

Олег Криворучко (Krivoruchko_O)

Рейтинг: 33

Для получения уведомлений о новых публикациях автора подключите телеграм бот: Инфостарт бот

Публикация:

№ 1875171

Создание 05.06.23 11:00

Обновление 28.05.24 17:28

Статистика:

Просмотры 2931

Загрузки 15

Рейтинг 12

Комментарии 4

Характеристики:

Код открыт Да

Рубрики WEB-интеграция

Кому Пользователь

Тип файла Конфигурация (md, cf)

Платформа 1С:Предприятие 8

Конфигурация 1C:Бухгалтерия ,
1С:Управление торговлей 10

Операционная система Не имеет значения

Страна Не имеет значения

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Не имеет значения

Доступ к файлу Абонемент ($m)