На инфостарте уже есть несколько статей о языке запросов, после прочтения наиболее популярных них, например:
//infostart.ru/public/80366/
//infostart.ru/public/158617/
//infostart.ru/public/165456/
, решил внести свою лепту и описать те особенности языка, которые не были рассмотрены в приведенных выше статьях. Статья ориентирована на начинающих разработчиков.
1. Конструкция "ИЗ".
Для того, чтобы получить данные из базы совсем необязательно использовать конструкцию "ИЗ".
Пример: Нам необходимо выбрать все сведения о банках из справочника банки.
Запрос :
ВЫБРАТЬ Справочник.Банки.*
Выбирает все поля из справочника Банки. И является аналогичным запросу:
ВЫБРАТЬ
Банки.*
ИЗ
Справочник.Банки КАК Банки
2. Упорядочивание данных по ссылочному полю
Когда нам необходимо упорядочить данные запроса по примитивным типам: "Строка", "Число", "Дата" и т.д., то все решается использованием конструкции "УПОРЯДОЧИТЬ ПО", если вам необходимо упорядочить данные по ссылочному полю? Ссылочное поле представляет из себя ссылку, уникальный идентификатор, т.е. грубо говоря некий произвольный набор символов и обычное упорядочивание может выдать не совсем ожидаемый результат. Для упорядочивания ссылочным полей используется конструкция "АВТОУПОРЯДОЧИВАНИЕ". Для этого необходимо сначала упорядочить данные непосредственно по ссылочному типу конструкцией "УПОРЯДОЧИТЬ ПО", а затем конструкция "АВТОУПОРЯДОЧИВАНИЕ".
ВЫБРАТЬ
Партия.Ссылка КАК Ссылка,
Партия.Организация,
Партия.Контрагент
ИЗ
Документ.Партия КАК Партия
УПОРЯДОЧИТЬ ПО Ссылка
АВТОУПОРЯДОЧИВАНИЕ
В этом случае для документов упорядочивание будет происходить в порядке "Дата->Номер" , для справочников по "Основному представлению". Если упорядочивание происходит не по ссылочным полям, то использовать конструкцию "АВТОУПОРЯДОЧИВАНИЕ" не рекомендуется.
В некоторых случаях конструкция "АВТОУПОРЯДОЧИВАНИЕ" может замедлять процесс выборки. Аналогичным образом можно переписать без автоупорядочивания для документов:
ВЫБРАТЬ
Партия.Ссылка КАК Ссылка,
Партия.Организация,
Партия.Контрагент
ИЗ
Документ.Партия КАК Партия
УПОРЯДОЧИТЬ ПО
Партия.Дата,
Партия.Номер
3.Получение текстового представления ссылочного типа. Конструкция "ПРЕДСТАВЛЕНИЕ".
Когда вам необходимо вывести для показа поле ссылочного типа, например поле "Банк", которое является ссылкой на элемент справочника "Банки", то необходимо понимать, что при выводе этого поля автоматически выполнится подзапрос к справочнику "Банки", чтобы получить представление справочника. Это будет замедлять вывод данных. Для Того, чтобы этого избежать необходимо использовать конструкцию "ПРЕДСТАВЛЕНИЕ" в запросе, чтобы сразу получить представление объекта и уже его выводить для просмотра.
ВЫБРАТЬ
Партия.Ссылка КАК Ссылка,
ПРЕДСТАВЛЕНИЕ(Партия.Организация) КАК Организация,
ПРЕДСТАВЛЕНИЕ(Партия.Контрагент) КАК Контрагент
ИЗ
Документ.Партия КАК Партия
В система компоновки данных этот механизм используется по умолчанию, а вот при формировании макетов в ячейках следует указывать представление ссылочного поля, а например в расшифровку помещать саму ссылку.
4. Условие на выборку данных по шаблону.
Например, вам необходимо получить мобильные телефоны сотрудников вида (8 -123- 456-78-912). Для этого необходимо поставить такое условие в запросе:
ВЫБРАТЬ
Сорудник.Наименование,
Сорудник.Телефон КАК Телефон
ИЗ
Справочник.Сотрудники КАК Сотрудники
ГДЕ
Телефон ПОДОБНО "_-___-___-__-__"
Символ "_" является служебным и заменяет любой символ.
5. Одновременное использование итогов и группировок.
Итоги часто используются совместно с группировками, в таком случае агрегатные функции в итогах можно не указывать.
ВЫБРАТЬ
ОказаниеУслуг.Организация КАК Организация,
ОказаниеУслуг.Номенклатура КАК Номенклатура,
СУММА(ОказаниеУслуг.СуммаДокумента) КАК СуммаДокумента
ИЗ
Документ.ОказаниеУслуг КАК ОказаниеУслуг
СГРУППИРОВАТЬ ПО
ОказаниеУслуг.Организация,
ОказаниеУслуг.Номенклатура
ИТОГИ ПО
ОБЩИЕ,
Организация,
Номенклатура
В этом случае запрос вернет практически тоже самое что и такой запрос:
ВЫБРАТЬ
ОказаниеУслуг.Организация КАК Организация,
ОказаниеУслуг.Номенклатура КАК Номенклатура,
ОказаниеУслуг.СуммаДокумента КАК СуммаДокумента
ИЗ
Документ.ОказаниеУслуг КАК ОказаниеУслуг
ИТОГИ
СУММА(СуммаДокумента)
ПО
ОБЩИЕ,
Организация,
Номенклатура
Только первый запрос свернет записи с одинаковой номенклатурой.
6. Разыменование полей.
Обращение к полям через точку называется операцией разыменования ссылочного поля. Например Оплата.Организация.АдминистративнаяЕдиница. В этом случае в ссылочном поле "Организация" документа "Оплата", ссылается на другую таблицу "Организации", в которой будет получено значение реквизита "АдминистративнаяЕдиница". Важно понимать, что при обращении к полям через точку платформа неявно создает подзапрос и соединяет эти таблицы.
Запрос:
ВЫБРАТЬ
Оплата.Ссылка,
Оплата.Организация,
Оплата.Организация.АдминистративнаяЕдиница
ИЗ
Документ.Оплата КАК Оплата
Можно представить в виде:
ВЫБРАТЬ
Оплата.Ссылка,
Оплата.Организация,
Оплата.Организация,
Организации. АдминистративнаяЕдиница
ИЗ
Документ.Оплата КАК Оплата
ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Организации КАК Организации
ПО Оплата.Организация = Организации.Ссылка
При разыменовании ссылочных полей составного типа платформа пытается создать неявные соединения со всеми таблицами, которые входят в тип этого поля. В этом случае запрос будет неоптимален.Если четко известно, какого типа поле, необходимо ограничивать такие поля по типу конструкцией ВЫРАЗИТЬ().
Например имеется регистр накопления "Нераспределенные оплаты", где регистратором могут выступать несколько документов. В этом случае неверно получать значения реквизитов регистратора таким образом:
ВЫБРАТЬ
НераспределенныеОплаты.Регистратор.Дата,
.....
ИЗ
РегистрНакопления.НераспределеныеОплаты КАК НераспределенныеОплаты
следует ограничить тип составного поля регистратор:
ВЫБРАТЬ
ВЫРАЗИТЬ(НераспределенныеОплаты.Регистратор КАК Документ.Оплата).Дата,
.....
ИЗ
РегистрНакопления.НераспределеныеОплаты КАК НераспределенныеОплаты
7. Конструкция "ГДЕ"
При левом соединении двух таблиц, когда вы накладываете условие "ГДЕ" на правую таблицу то мы получим результат аналогичный результату при внутреннем соединении таблиц.
Пример. Необходимо выбрать всех Клиентов из Справочника клиенты и для тех клиентов, у которых имеется документ оплата со значением реквизита "Организация" = &Организация вывести документ "Оплата", для тех у кого нет, не выводить.
Запрос:
ВЫБРАТЬ
Клиенты.Ссылка КАК Клиент,
Оплата.Ссылка КАК Оплата
ИЗ
Справочник.Клиенты КАК Клиенты
ЛЕВОЕ СОЕДИНЕНИЕ Документ.Оплата КАК Оплата
ПО Клиенты.Ссылка = Оплата.Клиент
ГДЕ
Оплата.Организация = &Организация
Результат запроса вернет записи только для тех клиентов, у которых была оплата по организации в параметре, а других клиентов отсеет. Поэтому необходимо сначала получить все оплаты по "такой-то" организации во временной таблице, а потом уже соединять со справочником "Клиенты" левым соединением.
ВЫБРАТЬ
Оплата.Ссылка КАК Оплата,
Оплата.Пайщик КАК Клиент
ПОМЕСТИТЬ тОплаты
ИЗ
Документ.Оплата КАК Оплата
ГДЕ
Оплата.Отделение = &Отделение
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
Клиенты.Ссылка КАК Клиент,
ЕСТЬNULL(тОплаты.Оплата, "") КАК Оплата
ИЗ
Справочник.Клиенты КАК Клиенты
ЛЕВОЕ СОЕДИНЕНИЕ тОплаты КАК тОплаты
ПО Клиенты.Ссылка = тОплаты.Клиент
Можно обойти это условие и другим способом. необходимо наложить условие "ГДЕ" непосредственно в связи двух таблиц. Пример:
ВЫБРАТЬ
Клиенты.Ссылка,
Оплата.Ссылка
ИЗ
Справочник.УС_Абоненты КАК УС_Абоненты
ЛЕВОЕ СОЕДИНЕНИЕ Документ.Оплата КАК Оплата
ПО (Клиенты.Ссылка = Оплата.Клиент
И Оплата.Клиент.Наименование ПОДОБНО "Сахарный Пакет")
СГРУППИРОВАТЬ ПО
Клиенты.Ссылка,
Оплата.Ссылка
8. Соединения с Вложенными и Виртуальными таблицами
Вложенные запросы зачастую необходимы для выборки данных по какому-либо условию. Если же потом использовать их в соединении с другими таблицами то это может критически замедлить выполнение запроса.
Для примера нам необходимо для некоторых клиентов получить Сумму остатка на текущую дату.
ВЫБРАТЬ
НераспределенныеОплатыОстатки.Клиент,
НераспределенныеОплатыОстатки.СуммаОстаток
ИЗ
(ВЫБРАТЬ
Клиенты.Ссылка КАК Ссылка
ИЗ
Справочник.Клиенты КАК Клиенты
ГДЕ
Клиенты.Ссылка В(&Клиенты)) КАК ВложенныйЗапрос
ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.НераспределенныеОплаты.Остатки КАК НераспределенныеОплаты
ПО ВложенныйЗапрос.Ссылка = НераспределенныеОплатыОстатки.Клиент
При выполнении такого запроса , вероятны ошибки оптимизатора СУБД при выборе плана, что приведет к неоптимальному выполнению запроса. При соединении двух таблиц оптимизатор СУБД выбирает алгоритм соединения таблиц исходя из количества записей в обеих таблицах. В случае наличия вложенного запроса, определить количество записей, которое вернет вложенный запрос крайне сложно. Поэтому вместо вложенных запросов всегда стоит использовать временные таблицы. Поэтому перепишем запрос.
ВЫБРАТЬ
Клиенты.Ссылка КАК Ссылка
ПОМЕСТИТЬ тКлиенты
ИЗ
Справочник.Клиенты КАК Клиенты
ГДЕ
Клиенты.Ссылка В (&Клиенты)
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
тКлиенты.Ссылка,
НераспределенныеОплатыОстатки.СуммаОстаток,
ИЗ
тКлиенты КАК тКлиенты
ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.НераспределенныеОплаты.Остатки(
,
Клиент В
(ВЫБРАТЬ
тКлиенты.Ссылка
ИЗ
тКлиенты)) КАК НераспределенныеОплатыОстатки
ПО тКлиенты.Ссылка = НераспределенныеОплатыОстатки.Клиенты
В данном случае оптимизатор сможет определить, какое количество записей использует временная таблица тКлиенты и сможет подобрать оптимальный алгоритм соединения таблиц.
Виртуальные таблицы , позволяют получить практически готовые данные для большинства прикладных задач.(СрезПервых,СрезПоследних,Остатки,Обороты,ОстаткиИОбороты) Ключевое слово здесь виртуальные. Эти таблицы не являются физическими, а компонуются системой налету, т.е. при получении данных из виртуальных таблиц система собирает данные из итоговых таблиц регистров, компонует, группирует и выдает пользователю.
Т.е. при соединении с виртуальной таблицей происходит соединение с подзапросом. В этом случае оптимизатор СУБД может также выбрать неоптимальный план соединения. Если запрос формируется недостаточно быстро и в запросе испольуются соединения в виртуальными таблицами, то реклмендуется вынести обращение к виртуальным таблицам во временную таблицу, а затем в произвести соедининие между двумя временными таблицами. Перепишем предыдущий запрос.
ВЫБРАТЬ
Клиенты.Ссылка КАК Ссылка
ПОМЕСТИТЬ тКлиенты
ИЗ
Справочник.Клиенты КАК Клиенты
ИНДЕКСИРОВАТЬ ПО
Ссылка
ГДЕ
Клиенты.Ссылка В (&Клиенты)
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
НераспределенныеОплаты.СуммаОстаток,
НераспределенныеОплаты.Клиент КАК Клиент
ПОМЕСТИТЬ тОстатки
ИЗ
РегистрНакопления.НераспределенныеОплаты.Остатки( ,
Клиент В
(ВЫБРАТЬ
тКлиенты.Ссылка
ИЗ
тКлиенты)) КАК НераспределенныеОплатыОстатки
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
тКлиенты.Ссылка,
тОстатки.СуммаОстаток КАК СуммаОстаток
ИЗ
тКлиенты КАК тКлиенты
ЛЕВОЕ СОЕДИНЕНИЕ тОстатки КАК тОстатки
ПО тКлиенты.Ссылка = тОстатки.Клиент
9.Проверка результата выполнения запроса.
Результат выполнения запроса может быть пустым, для проверки на пустые значения следует использовать конструкцию:
резЗапроса = Запрос.Выполнить();
Если резЗапроса.Пустой() Тогда
Возврат;
КонецЕсли;
Метод Пустой() следует использовать до методов Выбрать() или Выгрузить(), так как на получение коллекции тратится время.
10. Запросы в цикле.
Ни для кого не является открытием то, что запросы в цикле использовать крайне нежелательно. Это может критически сказаться на времени работы той или иной функции. Очень желательно получать все данные в запросе и уже потом обрабатывать данные в цикле. Но иногда бывают случаи, когда вынести запрос за пределы цикла становится невозможным. В этом случае для оптимизации можно вынести создание запроса за пределы цикла, а в цикле подставлять необходимые параметры и выполнять запрос.
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| Клиенты.Ссылка,
| Клиенты.ДатаРождения
|ИЗ
| Справочник.Клиенты КАК Клиенты
|ГДЕ
| Клиенты.Ссылка = &Клиент";
Для Каждого Строка ИЗ ТаблицаКлиенты Цикл
Запрос.УстановитьПараметр("Клиент", Клиент);
РезультатЗапроса = Запрос.Выполнить().Выбрать();
КонецЦикла;
Это избавит систему от синтаксической проверки запроса в цикле.
11. Конструкция "ИМЕЮЩИЕ".
Конструкция, довольно редко встречающаяся в запросах. Позволяет накладывать условия на значения агрегатные функций (СУММА, МИНИМУМ, СРЕДНЕЕ и т.д.). Например, вам необходимо выбрать только тех клиентов, у которых сумма оплат в сентябре была больше 13 000 рублей. Если использовать условие "ГДЕ", то придется сначала создавать временную таблицу или вложенный запрос, там группировать записи по сумме оплаты и потом накладывать условие. Конструкция "ИМЕЮЩИЕ" поможет этого избежать.
ВЫБРАТЬ
Оплата.Клиент,
СУММА(Оплата.Сумма) КАК Сумма
ИЗ
Документ.Оплата КАК Оплата
ГДЕ
МЕСЯЦ(Оплата.Дата) = 9
СГРУППИРОВАТЬ ПО
Оплата.Клиент
ИМЕЮЩИЕ
СУММА(Оплата.Сумма) > 13000
В конструкторе для этого достаточно перейти на вкладку "Условия", добавить новое условие и поставить галочку на "Произвольное". Далее просто написать Сумма(Оплата.Сумма) > 13000
12. Значение NULL
Я не буду описывать здесь принципы трехзначной логики в БД, есть множество статей на эту тему. Просто вкратце о том как NULL может повлиять на результат запроса. Значение NULL на самом деле не значение, а факт того, что значение не определено, неизвестно. Поэтому любые операции с NULL возвращают NULL, будь то сложение, вычитание, деление или сравнение. Значение NULL не может быть сравнимо со значением NULL, потому как мы не знаем, что именно сравнивать. Т.е. оба этих сравнения: NULL = NULL, NULL<>NULL - это не Истина или не Ложь, это неизвестно.
Давайте рассмотрим пример.
Нам необходимо для тех клиентов, у которых нет оплат, вывести поле "Признак" со значением "Нет оплат". Причем мы точно знаем, что такие клиенты у нас есть. И для того, чтобы отразить суть того, что писал выше сделаем это так.
ВЫБРАТЬ
"Нет оплат" КАК Признак,
NULL КАК Документ
ПОМЕСТИТЬ тОплаты
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
Клиенты.Ссылка КАК Клиент,
Оплата.Ссылка КАК Оплата
ПОМЕСТИТЬ тКлиентОплата
ИЗ
Справочник.Клиенты КАК Клиенты
ЛЕВОЕ СОЕДИНЕНИЕ Документ.Оплата КАК Оплата
ПО Клиенты.Ссылка = Оплата.Пайщик
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
тКлиентОплата.Клиент
ИЗ
тКлиентОплата КАК тКлиентОплата
ВНУТРЕННЕЕ СОЕДИНЕНИЕ тОплаты КАК тОплаты
ПО тКлиентОплата.Оплата = тОплаты.Документ
Обратите внимание на вторую временную таблицу тКлиентОплата. Левым соединением я выбираю всех клиентов и все оплаты по этим клиентам. Для тех же клиентов у которых нет оплат в поле "Оплата" будет NULL . Следуя логике, в первой временной таблице "тОплаты" я обозначил 2 поля, одно из них NULL, второе строка "Не имеет оплат". В третьей таблице я соединяю внутренним соединением таблицы "тКлиентОплата" и "тОплаты" по полям "Оплата" и "Документ". Мы знаем, что в первой таблице поле "Документ" это NULL, и во второй таблице у тех, у кого нет оплат в поле "Оплата" тоже NULL. Что же вернет нам такое соединение? А ничего не вернет. Потому как сравнение NULL = NULL не принимает значение Истина.
Для того, чтобы запрос вернул нам ожидаемый результат, перепишем его:
ВЫБРАТЬ
"Нет оплат" КАК Признак,
ЗНАЧЕНИЕ(Документ.Оплата.ПустаяСсылка) КАК Документ
ПОМЕСТИТЬ тОплаты
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
Клиенты.Ссылка КАК Клиент,
ЕСТЬNULL(Оплата.Ссылка, ЗНАЧЕНИЕ(Документ.Оплата.ПустаяСсылка)) КАК Оплата
ПОМЕСТИТЬ тКлиентОплата
ИЗ
Справочник.Клиенты КАК Клиенты
ЛЕВОЕ СОЕДИНЕНИЕ Документ.Оплата КАК Оплата
ПО Клиенты.Ссылка = Оплата.Пайщик
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
тКлиентОплата.Клиент
ИЗ
тКлиентОплата КАК тКлиентОплата
ВНУТРЕННЕЕ СОЕДИНЕНИЕ тОплаты КАК тОплаты
ПО тКлиентОплата.Оплата = тОплаты.Документ
Теперь, во второй временной таблице, мы указали, что в случае, если поле "Оплата" есть NULL, тогда это поле = пустая ссылка на документ оплата. В Первой таблице мы также заменили NULL на пустую ссылку. Теперь в соединении участвуют не NULL поля и запрос вернет нам ожидаемый результат.
Все запросы, которые содержатся в статье, отражают ситуации, которые я бы хотел рассмотреть и ничего больше. Они могут быть бредовые или не оптимальные, главное, чтобы отражали суть примера.
13. Недокументированная особенность конструкции "ВЫБОР КОГДА...ТОГДА....КОНЕЦ".
В том случае, когда необходимо описывать в запросе контрукцию "Условия", то мы используем стандартный синтаксис:
ВЫБРАТЬ
ВЫБОР
КОГДА Пользователи.Наименование = "Вася Пупкин"
ТОГДА "Наш любимый сотрудник"
ИНАЧЕ "Не знаем такого"
КОНЕЦ КАК Поле1
ИЗ
Справочник.Пользователи КАК Пользователи
А что делать, если, к примеру, нам надо получить название месяца в запросе? Писать огромную конструкцию в запросе некрасиво и долго, поэтому нас может выручить такая форма записи выше:
ВЫБОР МЕСЯЦ(УС_РасчетПотребления_ГрафикОбороты.ПериодРасчета)
КОГДА 1
ТОГДА "Январь"
КОГДА 2
ТОГДА "Февраль"
КОГДА 3
ТОГДА "Март"
КОГДА 4
ТОГДА "Апрель"
КОГДА 5
ТОГДА "Май"
КОГДА 6
ТОГДА "Июнь"
КОГДА 7
ТОГДА "Июль"
КОГДА 8
ТОГДА "Август"
КОГДА 9
ТОГДА "Сентябрь"
КОГДА 10
ТОГДА "Октябрь"
КОГДА 11
ТОГДА "Ноябрь"
КОГДА 12
ТОГДА "Декабрь"
КОНЕЦ КАК Месяц
Теперь конструкция выглядит не такой громоздкой и легко воспринимается.
14. Пакетное выполнение запроса.
Для того, чтобы не плодить запросы, можно создать один большой запрос, разбить его на пакеты и работать уже с ним.
Например, мне нужно получить из справочника "Пользователи" поля: "ДатаРождения" и доступные роли для каждого пользователя. в выгрузить это в разные табличные части на форме. Конечно можно сделать это в одном запросе, тогда придется перебирать записи или сворачивать, а можно так:
ВЫБРАТЬ
Пользователи.Ссылка КАК ФИО,
Пользователи.ДатаРождения,
Пользователи.Роль
ПОМЕСТИТЬ втПользователи
ИЗ
Справочник.Пользователи КАК Пользователи
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
втПользователи.ФИО,
втПользователи.ДатаРождения
ИЗ
втПользователи КАК втПользователи
СГРУППИРОВАТЬ ПО
втПользователи.ФИО,
втПользователи.ДатаРождения
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
втПользователи.ФИО,
втПользователи.Роль
ИЗ
втПользователи КАК втПользователи
СГРУППИРОВАТЬ ПО
втПользователи.ФИО,
втПользователи.ДатаРождения
тПакет = Запрос.ВыполнитьПакет();
ТП_ДатыРождения = тПакет[1].Выгрузить();
ТП_Роли = тПакет[2].Выгрузить();
Как мы видим, запрос можно выполнить в пакете и работать с результатом как с массивом. В некоторых случаях очень удобно.
15. Условия в пакетном запросе
Например, у нас есть пакетный запрос, где сначало мы получаем поля: "Наименование, ДатаРождения, Код" из справочника "Пользователи" и хотим из справочника "ФизЛица" получить записи с условием по этим полям.
ВЫБРАТЬ
Пользователи.ФизЛицо.Наименование КАК Наименование,
Пользователи.ФизЛицо.ДатаРождения КАК ДатаРождения,
Пользователи.ФизЛицо.Код КАК Код
ПОМЕСТИТЬ втПользователи
ИЗ
Справочник.Пользователи КАК Пользователи
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ФизическиеЛица.Ссылка КАК ФизЛицо
ИЗ
Справочник.ФизическиеЛица КАК ФизическиеЛица
Можно накложить условия таким образом:
ГДЕ
ФизическиеЛица.Код В
(ВЫБРАТЬ
втПользователи.Код
ИЗ
втПользователи)
И ФизическиеЛица.Наименование В
(ВЫБРАТЬ
втПользователи.Код
ИЗ
втПользователи)
И ФизическиеЛица.ДатаРождения В
(ВЫБРАТЬ
втПользователи.ДатаРождения
ИЗ
втПользователи)
А Можно и так:
ГДЕ
(ФизическиеЛица.Код, ФизическиеЛица.Наименование, ФизическиеЛица.ДатаРождения) В
(ВЫБРАТЬ
втПользователи.Код,
втПользователи.Наименование,
втПользователи.ДатаРождения
ИЗ
втПользователи)
Причем обязателено соблюдать порядок.
16. Вызов конструктора запросов для "условия" в пакетном запросе
Когда необходимо наложить условие, как в примере выше, можно забыть как то или иное поле называется в виртуальной таблице.
Например надо наложить условие на поле "ДатаРождения", а в виртуальной таблице это поле называется "ДатаРожденияДебитора", и если вы забыли название, то придется выходить из редактирования условия без сохранения и смотреть название поля. Для того, чтобы избежать этого можно воспользоватьтся следующим приемом.
Необходимо после Конструкции "В" поставить скобки и между скобками оставить пустое место(пробел), выделить это место и вызвать контруктор запросов. Контруктору будут доступны все таблицы пакетного запроса. Прием работает как на виртуальных таблицах регистров, так и для вкладки "Условия". В последнем случае необходимо поставить галочку "П(произволное условие)" и войти в режим редактирования "F4".
Запросов зачастую выдумывал на ходу и они служат просто для отображения "приемов", которые я рассматривал.
Хотел рассмотреть использование индексов в запросах, но больно обширная тема. Вынесу в отдельную статью, либо позже добавлю здесь.
upd1. Пункты 11,12
upd2. Пункты 13,14,15,16
Используемая литература:
Язык запросов "1С:Предприятия 8" - Е.Ю. Хрусталева
Профессиональная разработка в системе 1С:Предприятие 8".
