[Замер] Кто самый быстрый в конфигураторе?

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ЧислоПотоков = 1;
	КоличествоЗаписей = 1;
	ТипЗамера = Элементы.ТипЗамера.СписокВыбора[0].Значение; 
	ТекущийРазмерТела = 0;
	
КонецПроцедуры

&НаКлиенте
Процедура ТелоСообщенияПриИзменении(Элемент)
	ТекущийРазмерТела = ТелоСообщенияПриИзмененииНаСервере(ТелоСообщения);
КонецПроцедуры       

&НаСервереБезКонтекста
Функция ТелоСообщенияПриИзмененииНаСервере(ТелоСообщения)
	
	Буфер = ПолучитьБуферДвоичныхДанныхИзСтроки(ТелоСообщения); 
	//Получает размер двоичных данных в байтах.
	Возврат Буфер.Размер;

КонецФункции

&НаКлиенте
Процедура НачатьЗамер(Команда)
	НачатьЗамерНаСервере();
КонецПроцедуры

&НаСервере
Процедура НачатьЗамерНаСервере()
	
	Если ЧислоПотоков < 1 Тогда 
		ЧислоПотоков = 1;
	КонецЕсли;
	
	Если КоличествоЗаписей < 1 Тогда 
		КоличествоЗаписей = 1;
	КонецЕсли;
		
	СтруктураВходныхПараметров = Новый Структура;
	СтруктураВходныхПараметров.Вставить("ДатаУстаревания", 	ТекущаяДатаСеанса() + 60 * 86400);  
	СтруктураВходныхПараметров.Вставить("КодОтправителя", 	"ЗамерРегистровСведенийИСервисовИнтеграции"); 
	СтруктураВходныхПараметров.Вставить("ТелоСообщения", 	ТелоСообщения);
	СтруктураВходныхПараметров.Вставить("РазмерСообщения", 	ТекущийРазмерТела);
	СтруктураВходныхПараметров.Вставить("ТипСообщения", 	ТипЗамера);
	
	
	// объем порции данных для обработки каждым потоком
	РазмерПорции = Цел(КоличествоЗаписей / ЧислоПотоков);
	
	Для НомерПотока = 1 По ЧислоПотоков Цикл
		
		СтруктураВходныхПараметров.Вставить("КодПолучателя", ТипЗамера+"_Поток"+НомерПотока); 
				
		Если НомерПотока = ЧислоПотоков Тогда
			// если это последний поток, то посылаем все оставшиеся данные
			РазмерПорции = КоличествоЗаписей - (ЧислоПотоков * РазмерПорции) + РазмерПорции;
		КонецЕсли; 
		
		СтруктураВходныхПараметров.Вставить("КоличествоЗаписей", РазмерПорции);

		// определяем массив параметров для процедуры
		НаборПараметров = Новый Массив;
		НаборПараметров.Добавить(СтруктураВходныхПараметров);
		
		ФоновыеЗадания.Выполнить("ФоновоеВыполнение.ЗаписатьСообщения"+ТипЗамера, НаборПараметров);

	КонецЦикла;
	

КонецПроцедуры

Примечание:

           У нас будет три типа замера.

           1 Сервис интеграции – запись в канал сервиса интеграции

2 РС набор записей – запись в регистр сведений при помощи набора данных.

3 РС менеджер записи – запись в регистр сведений при помощи менеджера записи.

// Процедура - Записать сообщения в регистр сведений при помощи Менеджера записи
//
// Параметры:
//  СтруктураВходныхПараметров	 - Структура - Содержится вся необходимая для замера информация 
//
Процедура ЗаписатьСообщенияРСМенеджерЗаписи(СтруктураВходныхПараметров) Экспорт
	
	ВремяНачала = ТекущаяУниверсальнаяДатаВМиллисекундах();

	КоличествоЗаписей = СтруктураВходныхПараметров.КоличествоЗаписей;	
	Для счетчик = 1 По КоличествоЗаписей Цикл
		
		// Так же как и в сообщениях сервисов интеграции считаем УИ уникальным
		ТекИдентификатор = Новый УникальныйИдентификатор;	
		МенеджерЗаписи  = РегистрыСведений.СообщенияДляЗамера.СоздатьМенеджерЗаписи();			
		
		// Записываем тело сообщения
		МенеджерЗаписи.ТелоСообщения = Новый ХранилищеЗначения(СтруктураВходныхПараметров.ТелоСообщения);  
		
		// Изображаем структуру на подобии Сообщения сервисов интеграции
		МенеджерЗаписи.Идентификатор	= ТекИдентификатор;     		
		МенеджерЗаписи.ДатаУстаревания	= СтруктураВходныхПараметров.ДатаУстаревания; 
		МенеджерЗаписи.Позиция		= счетчик;
		
		// Заполняем свойства сообщения
		ШапкаСообщения = Новый Структура; 
		ШапкаСообщения.Вставить("ДатаОтправки", 	ТекущаяДатаСеанса());  
		ШапкаСообщения.Вставить("ДатаУстаревания", 	СтруктураВходныхПараметров.ДатаУстаревания);
		ШапкаСообщения.Вставить("Идентификатор", 	ТекИдентификатор); 
		ШапкаСообщения.Вставить("КодОтправителя", 	СтруктураВходныхПараметров.КодОтправителя);
		ШапкаСообщения.Вставить("КодПолучателя", 	СтруктураВходныхПараметров.КодПолучателя); 
		
		// Заполняем свойство Параметры сообщения
		Параметры = Новый Структура("ТипСообщения", СтруктураВходныхПараметров.ТипСообщения);
		Параметры.Вставить("РазмерСообщения", 		СтруктураВходныхПараметров.РазмерСообщения);
		ШапкаСообщения.Вставить("Параметры", Параметры);  
		
		// Помещаем структуру свойств
		МенеджерЗаписи.ШапкаСообщения = Новый ХранилищеЗначения(ШапкаСообщения);	
		
		// Сохраняем сообщение в регистре
		МенеджерЗаписи.Записать(); 
	
	КонецЦикла;
	
	Длительность = ТекущаяУниверсальнаяДатаВМиллисекундах() - ВремяНачала; 
	СоздатьСообщениеОЗамере(СтруктураВходныхПараметров, Длительность);
	
КонецПроцедуры

// Процедура - Записать сообщения в регистр сведений при помощи Набора записи
//
// Параметры:
//  СтруктураВходныхПараметров	 - Структура - Содержится вся необходимая для замера информация 
//
Процедура ЗаписатьСообщенияРСНаборЗаписей(СтруктураВходныхПараметров) Экспорт
	
	ВремяНачала = ТекущаяУниверсальнаяДатаВМиллисекундах();
	
	КоличествоЗаписей = СтруктураВходныхПараметров.КоличествоЗаписей;	
	Для счетчик = 1 По КоличествоЗаписей Цикл
		
		// Так же как и в сообщениях сервисов интеграции считаем УИ уникальным
		ТекИдентификатор = Новый УникальныйИдентификатор;
		НаборЗаписей = РегистрыСведений.СообщенияДляЗамера.СоздатьНаборЗаписей();  
		НаборЗаписей.Отбор.Идентификатор.Установить(ТекИдентификатор);
		
		НоваяЗапись  = НаборЗаписей.Добавить();	   
		// Записываем тело сообщения
		НоваяЗапись.ТелоСообщения = Новый ХранилищеЗначения(СтруктураВходныхПараметров.ТелоСообщения);
		
		// Изображаем структуру на подобии Сообщения сервисов интеграции
		НоваяЗапись.Идентификатор	= ТекИдентификатор;
		НоваяЗапись.ДатаУстаревания	= СтруктураВходныхПараметров.ДатаУстаревания; 
		НоваяЗапись.Позиция		= счетчик;   
		
		// Заполняем свойства сообщения
		ШапкаСообщения = Новый Структура; 
		ШапкаСообщения.Вставить("ДатаОтправки", 	ТекущаяДатаСеанса());  
		ШапкаСообщения.Вставить("ДатаУстаревания", 	СтруктураВходныхПараметров.ДатаУстаревания);
		ШапкаСообщения.Вставить("Идентификатор", 	ТекИдентификатор); 
		ШапкаСообщения.Вставить("КодОтправителя", 	СтруктураВходныхПараметров.КодОтправителя);
		ШапкаСообщения.Вставить("КодПолучателя", 	СтруктураВходныхПараметров.КодПолучателя); 
		
		// Заполняем свойство Параметры сообщения
		Параметры = Новый Структура("ТипСообщения", СтруктураВходныхПараметров.ТипСообщения);
		Параметры.Вставить("РазмерСообщения", 		СтруктураВходныхПараметров.РазмерСообщения);	
		ШапкаСообщения.Вставить("Параметры", Параметры);  
		
		// Помещаем структуру свойств
		НоваяЗапись.ШапкаСообщения = Новый ХранилищеЗначения(ШапкаСообщения);	
		
		// Сохраняем сообщение в регистре
		НаборЗаписей.Записать();   
		
	КонецЦикла;
	
	Длительность = ТекущаяУниверсальнаяДатаВМиллисекундах() - ВремяНачала; 
	СоздатьСообщениеОЗамере(СтруктураВходныхПараметров, Длительность);
	
КонецПроцедуры

// Процедура - Записать сообщения в регистр сведений при помощи Сообщения сервисов интеграции
//
// Параметры:
//  СтруктураВходныхПараметров	 - Структура - Содержится вся необходимая для замера информация 
//
Процедура ЗаписатьСообщенияСервисИнтеграции(СтруктураВходныхПараметров) Экспорт
	
	ВремяНачала = ТекущаяУниверсальнаяДатаВМиллисекундах(); 
	
	КоличествоЗаписей = СтруктураВходныхПараметров.КоличествоЗаписей;  	
	Для счетчик = 1 По КоличествоЗаписей Цикл 
		НовоеСообщение = СервисыИнтеграции.ДляЗамера.СоздатьСообщение(СтруктураВходныхПараметров.ДатаУстаревания);
		
		// Записываем тело сообщения
		Буфер = ПолучитьБуферДвоичныхДанныхИзСтроки(СтруктураВходныхПараметров.ТелоСообщения);   
		Тело = НовоеСообщение.ПолучитьТелоКакПоток();
		Тело.Записать(Буфер, 0, Буфер.Размер);
		Тело.Закрыть();
		
		// Заполняем свойства сообщения
		НовоеСообщение.КодОтправителя = СтруктураВходныхПараметров.КодОтправителя;
		НовоеСообщение.КодПолучателя = СтруктураВходныхПараметров.КодПолучателя;
		
		// Заполняем свойство Параметры сообщения
		НовоеСообщение.Параметры.Вставить("ТипСообщения", СтруктураВходныхПараметров.ТипСообщения);
		НовоеСообщение.Параметры.Вставить("РазмерСообщения", Буфер.Размер); 	
		
		// Сохраняем сообщение в канале
		СервисыИнтеграции.ДляЗамера.СообщенияДляЗамера.ОтправитьСообщение(НовоеСообщение);
		
	КонецЦикла;
	
	Длительность = ТекущаяУниверсальнаяДатаВМиллисекундах() - ВремяНачала; 
	СоздатьСообщениеОЗамере(СтруктураВходныхПараметров, Длительность);
	
КонецПроцедуры	         

// Процедура - Создать сообщение о замере
//
// Параметры:
//  СтруктураВходныхПараметров	 - Структура - Содержится вся необходимая для замера информация
//  Длительность				 - Число	 - Результат замера в миллисекундах
//
Процедура СоздатьСообщениеОЗамере(СтруктураВходныхПараметров, Длительность) 
	
	НовоеСообщение = СервисыИнтеграции.СлужебноеХранилище.СоздатьСообщение(СтруктураВходныхПараметров.ДатаУстаревания);	
	
	Буфер = ПолучитьБуферДвоичныхДанныхИзСтроки(СтруктураВходныхПараметров.ТелоСообщения);   
	Тело = НовоеСообщение.ПолучитьТелоКакПоток();
	Тело.Записать(Буфер, 0, Буфер.Размер);
	Тело.Закрыть();
	
	НовоеСообщение.КодОтправителя = СтруктураВходныхПараметров.КодОтправителя;
	НовоеСообщение.КодПолучателя = СтруктураВходныхПараметров.КодПолучателя;

	НовоеСообщение.Параметры.Вставить("ТипСообщения", 	СтруктураВходныхПараметров.ТипСообщения);
 	НовоеСообщение.Параметры.Вставить("Длительность", 	Длительность);	
	НовоеСообщение.Параметры.Вставить("РазмерСообщения",Буфер.Размер);
	
	СервисыИнтеграции.СлужебноеХранилище.РезультатыЗамеров.ОтправитьСообщение(НовоеСообщение);

КонецПроцедуры