Заполнение формул в файлах Excel (кроссплатформенное решение)

#Область ПрограммныйИнтерфейс

Процедура ЗаполнитьФормулыВФайлеExcel(ИмяМакета, ПутьФайла) Экспорт
	
	Если ИмяМакета = "НазваниеМакетаВашейПечатнойФормы" Тогда
		ЗаполнитьФормулыВФайлеНазваниеВашейПечатнойФормы(ПутьФайла);
	КонецЕсли;
	
КонецПроцедуры

// Процедура - Извлечь архив
// Извлекает переданный архив в нужную папку
// Параметры:
//  ПутьФайла		- Строка - путь до архива к распаковке
//  ПутьКаталога	- Строка - путь для распаковки архива
//
Процедура ИзвлечьАрхив(ПутьФайла, ПутьКаталога) Экспорт
	
	ДДФайла = Новый ДвоичныеДанные(ПутьФайла);
	
	Поток = Новый ПотокВПамяти(ПолучитьБуферДвоичныхДанныхИзДвоичныхДанных(ДДФайла));
	
	Архив = Новый ЧтениеZipФайла(Поток);
	Архив.ИзвлечьВсе(ПутьКаталога, РежимВосстановленияПутейФайловZIP.Восстанавливать);
	Архив.Закрыть();
	
	Поток.Закрыть();
	
КонецПроцедуры

// Процедура - Собрать архив
// Упаковывает файлы из указанного каталога в архив
// Параметры:
//  ПутьКаталога	- Строка - Путь до каталога с файлами к архивации
//  ПутьФайла		- Строка - Путь размещения создаваемого архива
//
Процедура СобратьАрхив(ПутьКаталога, ПутьФайла) Экспорт
	
	Архив = Новый ЗаписьZipФайла(ПутьФайла);
	Архив.Добавить(	ПутьКаталога + "\*.*",
					РежимСохраненияПутейZIP.СохранятьОтносительныеПути,
					РежимОбработкиПодкаталоговZIP.ОбрабатыватьРекурсивно);
	Архив.Записать();
	
КонецПроцедуры

// Функция - Получить DOMДокумент из XMLФайла
// Возвращает указанный xml файл в виде дом модели
// Параметры:
//  ПутьXMLФайла  - Строка - путь xml файла, который нужно получить как дом документ
// 
// Возвращаемое значение:
// ДокументDOM  - полученный ДокументDOM
//
Функция ПолучитьDOMДокументИзXMLФайла(ПутьXMLФайла) Экспорт
	
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.ОткрытьФайл(ПутьXMLФайла);
	
	ПостроительDOM = Новый ПостроительDOM;
	ДокументDOM = ПостроительDOM.Прочитать(ЧтениеXML);
	
	ЧтениеXML.Закрыть();
	
	Возврат ДокументDOM;
	
КонецФункции

// Процедура - Сохранить DOMДокумент КАКXMLФайл
// Сохраняет переданный дом документа, в указанный файл
// Параметры:
//  ДокументDOM		 - ДокументDOM - Документ, который нужно сохранить
//  ПутьXMLФайла	 - Строка - путь до файла xml в который нужно сохранить
//
Процедура СохранитьDOMДокументКАКXMLФайл(ДокументDOM, ПутьXMLФайла) Экспорт
	
	ЗаписьXML = Новый ЗаписьXML();
	ЗаписьXML.ОткрытьФайл(ПутьXMLФайла);
	
	ЗаписьDOM = Новый ЗаписьDOM();
	ЗаписьDOM.Записать(ДокументDOM, ЗаписьXML);
	
	ЗаписьXML.Закрыть();
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

Процедура ЗаполнитьФормулыВФайлеНазваниеВашейПечатнойФормы(ПутьДоФайла)
	
	ВременныйКаталог = КаталогВременныхФайлов() + "\excel_temp\";
	
	СоздатьКаталог(ВременныйКаталог);
	
	ИзвлечьАрхив(ПутьДоФайла, ВременныйКаталог);
	
	ПутьДоXMLФайлаЛист1 = ВременныйКаталог + "xl\worksheets\sheet1.xml";

	// Чтение распакованного xml-файла листа 1 в ДокументDOM
	ДокументDOM = ПолучитьDOMДокументИзXMLФайла(ПутьДоXMLФайлаЛист1);
	
	ВсеЯчейки = ДокументDOM.ПолучитьЭлементыПоИмени("c");
	ВсеСтроки = ДокументDOM.ПолучитьЭлементыПоИмени("row");
	ВсегоСтрок = ВсеСтроки.Количество();

	// Обход ячеек и определение формул по произвольному алгоритму
	Для Каждого Ячейка Из ВсеЯчейки Цикл
		Формула = Неопределено;
		
		ИмяЯчейки = Ячейка.ПолучитьАтрибут("r");
		Если ИмяЯчейки = Неопределено Тогда
			Продолжить;
		КонецЕсли;
		
		ИмяСтолбца = Сред(ИмяЯчейки, 1, 1);
		ИмяСтроки = Сред(ИмяЯчейки, 2);
		
		НомерСтроки = Число(ИмяСтроки);
	
		// Сборка формулы по условиям для ячейки в формате "=A1+B2"
		// Тут необходимо прописать логику по определению формулы
		Формула = "=A1+B2";
		
		Если Формула = Неопределено Тогда
			Продолжить;
		КонецЕсли;
		
		Пока Ячейка.ЕстьДочерниеУзлы() Цикл
			Ячейка.УдалитьДочерний(Ячейка.ПервыйДочерний);
		КонецЦикла;
		
		// Заполнение формулы
		ЭлФормула = ДокументDOM.СоздатьЭлемент("f");
		ЭлФормула.ТекстовоеСодержимое = Формула;
	
		Ячейка.ДобавитьДочерний(ЭлФормула);
	
	КонецЦикла;
	
	// Запись модифицированного объекта ДокументDOM в xml-файл листа 1
	СохранитьDOMДокументКАКXMLФайл(ДокументDOM, ПутьДоXMLФайлаЛист1);
	
	УдалитьФайлы(ПутьДоФайла);
	
	СобратьАрхив(ВременныйКаталог, ПутьДоФайла);
	
	УдалитьФайлы(ВременныйКаталог);
	
КонецПроцедуры

#КонецОбласти