Драйвер Посцентр: Драйвер ККТ с передачей данных в ОФД 4.7 (ФФД 1.2)

15.12.25

Обработка драйвер Посцентр: Драйвер ККТ с передачей данных в ОФД 4.7 (ФФД 1.2) с поддержкой ставки 22% и режима ПИоТ. Предназначена для Управлении торговлей 10.3.

Файлы

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование	Скачано	Купить файл	По подписке PRO
Драйвер Посцентр: Драйвер ККТ с передачей данных в ОФД 4.7 (ФФД 1.2) .zip 3,51Mb 14	14	2 500 руб. Купить	1 SM Скачать

Обработка драйвер Посцентр: Драйвер ККТ с передачей данных в ОФД 4.7 (ФФД 1.2) предназначена для Управлении торговли 10.3. В составе две обработки под х32-битный и х64-битный клиенты платформы 1С.

В конфигурацию самостоятельно добавить новые ставки НДС 22%.

В общих модулях необходимо сделать изменения.

Общий модуль ПодключаемоеОборудованиеУниверсальныйДрайверКлиент:

1. Добавить две функции

Функция ПолучитьПараметрыXML(Параметры, ТипОборудования = Неопределено) Экспорт
	
	Результат = ""; 
	
	Если Параметры <> Неопределено Тогда 
		
		ЗаписьXML = Новый ЗаписьXML; 
		ЗаписьXML.УстановитьСтроку("UTF-8");
		ЗаписьXML.ЗаписатьОбъявлениеXML();
		ЗаписьXML.ЗаписатьНачалоЭлемента("Parameters");    
		
		Если Не ПустаяСтрока(ТипОборудования) Тогда
			ЗаписьXML.ЗаписатьНачалоЭлемента("Parameter");   
			ЗаписьXML.ЗаписатьАтрибут("Name", "EquipmentType");      
			ЗаписьXML.ЗаписатьАтрибут("Value", XMLСтрока(ТипОборудования));
			ЗаписьXML.ЗаписатьКонецЭлемента();
		КонецЕсли;
		
		Для Каждого Параметр ИЗ Параметры Цикл
			Если Лев(Параметр.Ключ, 2) = "P_" Тогда
				ЗаписьXML.ЗаписатьНачалоЭлемента("Parameter");   
				ЗаписьXML.ЗаписатьАтрибут("Name", Сред(Параметр.Ключ, 3));      
				ЗаписьXML.ЗаписатьАтрибут("Value", XMLСтрока(Параметр.Значение));
				ЗаписьXML.ЗаписатьКонецЭлемента();
			КонецЕсли;
		КонецЦикла;
		ЗаписьXML.ЗаписатьКонецЭлемента();
		Результат = ЗаписьXML.Закрыть();   
		
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

// Выполняет тест устройства
// 
// Параметры:
//  ПараметрыПодключения - Структура
//  
// Возвращаемое значение:
//  см. РезультатОперацииНаОборудовании
//
Функция РевизияИнтерфейса(ОбъектДрайвера, ПараметрыПодключения) Экспорт
	
	Попытка                 
		РезультатВызова = ОбъектДрайвера.ПолучитьРевизиюИнтерфейса(); // Структура
		РевизияИнтерфейса = РезультатВызова.Значение;
	Исключение
		// Версия требований 2.5 и ниже
		РевизияИнтерфейса = 4000;
	КонецПопытки;  
	
	ПараметрыПодключения.Вставить("РевизияИнтерфейса", РевизияИнтерфейса);
		
	Возврат РевизияИнтерфейса;
	
КонецФункции

2. Изменить функцию:

Функция ПодключитьУстройство(ОбъектДрайвера, Параметры, ПараметрыПодключения, ВыходныеПараметры) Экспорт
	
	Результат = Истина;
	НовыйСтандарт = Ложь;
	
	ВыходныеПараметры = Новый Массив();
	ПараметрыПодключения.Вставить("ИДУстройства", "");
	
	ТипОборудованияИспользуемый= "";
	
	Если ПараметрыПодключения.Свойство("ТипОборудования") Тогда
		ТипОборудованияИспользуемый = ПараметрыПодключения.ТипОборудования;
		// Предопределенный параметр с указанием типа драйвера.
		Попытка
			ОбъектДрайвера.УстановитьПараметр("EquipmentType", ТипОборудованияИспользуемый) 
		Исключение
			Результат = Ложь;
			ОписаниеОшибки = НСтр("ru='Ошибка обращения к драйверу.'");
			СформироватьОшибку(ВыходныеПараметры, ОписаниеОшибки);
			Возврат Результат;
		КонецПопытки;
	КонецЕсли;
	
	ОписаниеДрайвера          = "";
	
	Попытка
		РевизияИнтерфейса = ОбъектДрайвера.ПолучитьРевизиюИнтерфейса( );
		НовыйСтандарт = Истина;
		// Получаем описание драйвера.
		ОписаниеДрайвера = "";
		
		Попытка
			// Получаем описание драйвера
				ОбъектДрайвера.ПолучитьОписание(ОписаниеДрайвера);
		Исключение
			Результат = Ложь;
			ВыходныеПараметры.Очистить();
			ВыходныеПараметры.Добавить(999);
			ВыходныеПараметры.Добавить(НСтр("ru='Ошибка вызова метода <ОбъектДрайвера.ПолучитьОписание>.'") + Символы.ПС + ОписаниеОшибки());
			Возврат Результат;
		КонецПопытки;
			
	Исключение
		ТипОборудования           = "";
		ИнтеграционныйКомпонент   = Ложь;
		ОсновнойДрайверУстановлен = Ложь;
		РевизияИнтерфейса         = МенеджерОборудованияКлиентПовтИсп.РевизияИнтерфейсаДрайверов();
		URLЗагрузкиДрайвера       = "";
		ПараметрыДрайвера         = "";
		ДополнительныеДействия    = "";
		НаименованиеДрайвера      = "";
	
		Попытка
			// Получаем описание драйвера
				ОбъектДрайвера.ПолучитьОписание(НаименованиеДрайвера, ОписаниеДрайвера, ТипОборудования, РевизияИнтерфейса, ИнтеграционныйКомпонент, ОсновнойДрайверУстановлен, URLЗагрузкиДрайвера);
		Исключение
			Результат = Ложь;                 
			СформироватьОшибкуДрайвера(ВыходныеПараметры, "ПолучитьОписание", ОписаниеОшибки());
			Возврат Результат;
		КонецПопытки;
		
	КонецПопытки;
		
	ПараметрыПодключения.Вставить("РевизияИнтерфейса", РевизияИнтерфейса);
	
	Если ПараметрыПодключения.РевизияИнтерфейса > 4002 Тогда    
		
		ПараметрыПодключения.ПараметрыXML = ПолучитьПараметрыXML(Параметры, ПараметрыПодключения.ТипОборудования);
		
		Попытка
			РезультатВызова = ОбъектДрайвера.ПодключитьОборудование(ПараметрыПодключения.ИДУстройства,  
				ПараметрыПодключения.ТипОборудования, ПараметрыПодключения.ПараметрыXML); // Структура
						
			ПараметрыПодключения.ИДУстройства = РезультатВызова.Параметры[0];
			Ответ = РезультатВызова.Значение;
		Исключение
			Результат = Ложь;
			СформироватьОшибкуДрайвера(ВыходныеПараметры, "Подключить", ОписаниеОшибки());
			Возврат Результат;
		КонецПопытки;
	Иначе
	
		Для Каждого Параметр Из Параметры Цикл
			Если Лев(Параметр.Ключ, 2) = "P_" Тогда
				ЗначениеПараметра = Параметр.Значение;
				ИмяПараметра = Сред(Параметр.Ключ, 3);
				ОбъектДрайвера.УстановитьПараметр(ИмяПараметра, ЗначениеПараметра) 
			КонецЕсли;
		КонецЦикла;
		
		Попытка
			Ответ = ОбъектДрайвера.Подключить(ПараметрыПодключения.ИДУстройства);
		Исключение
			Результат = Ложь;
			СформироватьОшибкуДрайвера(ВыходныеПараметры, "Подключить", ОписаниеОшибки());
			Возврат Результат;
		КонецПопытки;
		
	КонецЕсли;	
	
	Если НЕ Ответ Тогда
		Результат = Ложь;
		ОписаниеОшибки = "";
		ОбъектДрайвера.ПолучитьОшибку(ОписаниеОшибки);
		СформироватьОшибку(ВыходныеПараметры, ОписаниеОшибки);
	Иначе
		
		Если ТипОборудованияИспользуемый = "ПринтерЧеков" 
				Или ТипОборудованияИспользуемый = "ФискальныйРегистратор" 
				Или ТипОборудованияИспользуемый = "ККТ" Тогда
			ВремВыходныеПараметры = Новый Массив();
			Если ПолучитьШиринуСтроки(ОбъектДрайвера, Параметры, ПараметрыПодключения, ВремВыходныеПараметры) Тогда
				ВремШиринаСтроки = ВремВыходныеПараметры[0];
				ШиринаСтроки = ?(ВремШиринаСтроки <> Неопределено И ВремШиринаСтроки > 0, ВремШиринаСтроки, 32);
			КонецЕсли;
			ПараметрыПодключения.Вставить("ШиринаСтроки", ШиринаСтроки);
		ИначеЕсли ТипОборудованияИспользуемый = "ЭквайринговыйТерминал" Тогда
			ПараметрыПодключения.Вставить("КодОригинальнойТранзакции", Неопределено);
			ПараметрыПодключения.Вставить("ТипТранзакции", "");
		ИначеЕсли ТипОборудованияИспользуемый = "СканерШтрихкода" Тогда
			ВыходныеПараметры.Добавить(Строка(ПараметрыПодключения.ИДУстройства));
			ВыходныеПараметры.Добавить(Новый Массив());
			ВыходныеПараметры[1].Добавить("Штрихкод");
			ВыходныеПараметры[1].Добавить("Barcode");
		ИначеЕсли ТипОборудованияИспользуемый = "СчитывательМагнитныхКарт" Тогда
			ВыходныеПараметры.Добавить(Строка(ПараметрыПодключения.ИДУстройства));
			ВыходныеПараметры.Добавить(Новый Массив());
			ВыходныеПараметры[1].Добавить("ДанныеКарты");
			ВыходныеПараметры[1].Добавить("TracksData");
		ИначеЕсли ТипОборудованияИспользуемый = "СчитывательRFID" Тогда
			ВыходныеПараметры.Добавить(Строка(ПараметрыПодключения.ИДУстройства));
			ВыходныеПараметры.Добавить(Новый Массив());
			ВыходныеПараметры[1].Добавить("RFID");
			ВыходныеПараметры[1].Добавить("RFID");
		КонецЕсли;
		
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

Функция ТестУстройства(ОбъектДрайвера, Параметры, ПараметрыПодключения, ВыходныеПараметры)

	Результат            = Истина;
	РезультатТеста       = "";
	АктивированДемоРежим = "";
	
	РевизияИнтерфейса = РевизияИнтерфейса(ОбъектДрайвера, ПараметрыПодключения);
	
	Если РевизияИнтерфейса > 4002 Тогда
		
		ПараметрыПодключения.ПараметрыXML = ПолучитьПараметрыXML(Параметры, ПараметрыПодключения.ТипОборудования);
		
		Попытка
			РезультатВызова = ОбъектДрайвера.ТестированиеОборудования(ПараметрыПодключения.ТипОборудования, 
			ПараметрыПодключения.ПараметрыXML, РезультатТеста, АктивированДемоРежим); // Структура    
		Исключение
			Результат = Ложь;
			СформироватьОшибкуДрайвера(ВыходныеПараметры, "ТестУстройства", ОписаниеОшибки());
		КонецПопытки;
			
		Если ТипЗнч(РезультатВызова.Значение) = Тип("Булево") Тогда
			Результат = РезультатВызова.Значение;       
			РезультатТеста  = РезультатВызова.Параметры[2];      
			АктивированДемоРежим = РезультатВызова.Параметры[3];
			
			Если РезультатВызова.Значение Тогда
				ВыходныеПараметры.Очистить();
				ВыходныеПараметры.Добавить(0);
			Иначе
				ВыходныеПараметры.Очистить();
				ВыходныеПараметры.Добавить(999);
			КонецЕсли;
			
			Если РезультатВызова.Значение <> Истина Тогда
				Результат = Ложь;
				СформироватьОшибкуДрайвера(ВыходныеПараметры, "ТестУстройства", ОписаниеОшибки());
			КонецЕсли;
		КонецЕсли;
		
	Иначе	
	
		Для Каждого Параметр Из Параметры Цикл
			Если Лев(Параметр.Ключ, 2) = "P_" Тогда
				ЗначениеПараметра = Параметр.Значение;
				ИмяПараметра = Сред(Параметр.Ключ, 3);
				Ответ = ОбъектДрайвера.УстановитьПараметр(ИмяПараметра, ЗначениеПараметра) 
			КонецЕсли;
		КонецЦикла;
		
		Попытка
			Ответ = ОбъектДрайвера.ТестУстройства(РезультатТеста, АктивированДемоРежим);
		
			Если Ответ Тогда
				ВыходныеПараметры.Очистить();
				ВыходныеПараметры.Добавить(0);
			Иначе
				Результат = Ложь;
				ВыходныеПараметры.Очистить();
				ВыходныеПараметры.Добавить(999);
			КонецЕсли;
			ВыходныеПараметры.Добавить(РезультатТеста);
			ВыходныеПараметры.Добавить(АктивированДемоРежим);
		
		Исключение
			Результат = Ложь;
			СформироватьОшибкуДрайвера(ВыходныеПараметры, "ТестУстройства", ОписаниеОшибки());
		КонецПопытки;
		
	КонецЕсли;	
	
	Возврат Результат;

КонецФункции

3. Для поддержки новой функции ПИоТ в общем модуле МенеджерОборудованияВызовСервера изменить процедуры/функции

Функция СформироватьТаблицуПараметровДляОперацииФН(СтруктураПараметров, РевизияИнтерфейса = 0) Экспорт
	
	ЗаписьXML = Новый ЗаписьXML; 
	ЗаписьXML.УстановитьСтроку("UTF-8");
	ЗаписьXML.ЗаписатьОбъявлениеXML();
	
	Если РевизияИнтерфейса >= 3000 Тогда  // Версия стандарта 3.0 (ОФД 1.1)
		
		ЗаписьXML.ЗаписатьНачалоЭлемента("ParametersFiscal");
		ЗаписьXML.ЗаписатьАтрибут("CashierName" , XMLСтрока(?(СтруктураПараметров.Свойство("Кассир")   , XMLСтрока(СтруктураПараметров.Кассир), НСтр("ru='Администратор'"))));
		ЗаписьXML.ЗаписатьАтрибут("CashierINN"  , XMLСтрока(?(СтруктураПараметров.Свойство("КассирИНН"), XMLСтрока(СтруктураПараметров.КассирИНН), "")));
		// Код причины перерегистрации.
		ЗаписьXML.ЗаписатьАтрибут("RegistrationReasonCode", XMLСтрока(СтруктураПараметров.КодПричиныПеререгистрации));
		// Коды причин изменения сведений о ККТ.
		Если Не ПустаяСтрока(СтруктураПараметров.КодыПричинИзмененияСведений) Тогда
			ЗаписьXML.ЗаписатьАтрибут("RegistrationLabelCodes", XMLСтрока(СтруктураПараметров.КодыПричинИзмененияСведений));
		КонецЕсли;
		ЗаписьXML.ЗаписатьАтрибут("KKTNumber"         , XMLСтрока(СтруктураПараметров.РегистрационныйНомерККТ));
		ЗаписьXML.ЗаписатьАтрибут("CompanyName"       , XMLСтрока(СтруктураПараметров.ОрганизацияНазвание));
		ЗаписьXML.ЗаписатьАтрибут("INN"               , XMLСтрока(СтруктураПараметров.ОрганизацияИНН));
		ЗаписьXML.ЗаписатьАтрибут("SaleAddress"       , XMLСтрока(СтруктураПараметров.АдресПроведенияРасчетов));
		ЗаписьXML.ЗаписатьАтрибут("SaleLocation"      , XMLСтрока(СтруктураПараметров.МестоПроведенияРасчетов));
		ЗаписьXML.ЗаписатьАтрибут("TaxationSystems"   , XMLСтрока(СтруктураПараметров.КодыСистемыНалогообложения));
		ЗаписьXML.ЗаписатьАтрибут("IsOffline"         , XMLСтрока(СтруктураПараметров.ПризнакАвтономногоРежима));
		ЗаписьXML.ЗаписатьАтрибут("IsEncrypted"       , XMLСтрока(СтруктураПараметров.ПризнакШифрованиеДанных));
		ЗаписьXML.ЗаписатьАтрибут("IsService"         , XMLСтрока(СтруктураПараметров.ПризнакРасчетовЗаУслуги));
		ЗаписьXML.ЗаписатьАтрибут("IsExcisable"       , XMLСтрока(СтруктураПараметров.ПродажаПодакцизногоТовара));
		ЗаписьXML.ЗаписатьАтрибут("IsGambling"        , XMLСтрока(СтруктураПараметров.ПроведенияАзартныхИгр));
		ЗаписьXML.ЗаписатьАтрибут("IsLottery"         , XMLСтрока(СтруктураПараметров.ПроведенияЛотерей));
		ЗаписьXML.ЗаписатьАтрибут("AgentTypes"        , XMLСтрока(СтруктураПараметров.ПризнакиАгента));
		ЗаписьXML.ЗаписатьАтрибут("BSOSing"           , XMLСтрока(СтруктураПараметров.ПризнакФормированияБСО));
		ЗаписьXML.ЗаписатьАтрибут("IsOnlineOnly"      , XMLСтрока(СтруктураПараметров.ПризнакРасчетовТолькоВИнтернет));
		Если РевизияИнтерфейса >= 3004 Тогда  // Версия стандарта 3.4 (ОФД 1.2)
			ЗаписьXML.ЗаписатьАтрибут("IsOnline"    , XMLСтрока(СтруктураПараметров.ПроведенияРасчетаВИнтернет));
			ЗаписьXML.ЗаписатьАтрибут("IsMarking"   , XMLСтрока(СтруктураПараметров.ПродажаМаркированныхТоваров));
			ЗаписьXML.ЗаписатьАтрибут("IsPawnshop"  , XMLСтрока(СтруктураПараметров.ПризнакПримененияЛомбардами));
			ЗаписьXML.ЗаписатьАтрибут("IsAssurance" , XMLСтрока(СтруктураПараметров.ПризнакДеятельностиПоСтрахованию));
		КонецЕсли;    
		Если РевизияИнтерфейса >= 4000 Тогда  // Версия стандарта 4.0 (ОФД 1.2)
			ЗаписьXML.ЗаписатьАтрибут("IsVendingMachine"  , XMLСтрока(СтруктураПараметров.ПризнакАвтоматическогоТорговогоАвтомата));
			ЗаписьXML.ЗаписатьАтрибут("IsCateringServices", XMLСтрока(СтруктураПараметров.ПризнакОказанииУслугОбщественногоПитания));
			ЗаписьXML.ЗаписатьАтрибут("IsWholesaleTrade"  , XMLСтрока(СтруктураПараметров.ПризнакОптовойТорговлиСОрганизациями));
		КонецЕсли;    
		ЗаписьXML.ЗаписатьАтрибут("IsAutomaticPrinter", XMLСтрока(СтруктураПараметров.УстановкаПринтераВАвтомате));
		ЗаписьXML.ЗаписатьАтрибут("IsAutomatic"       , XMLСтрока(СтруктураПараметров.ПризнакАвтоматическогоРежима));
		ЗаписьXML.ЗаписатьАтрибут("AutomaticNumber"   , XMLСтрока(СтруктураПараметров.НомерАвтоматаДляАвтоматическогоРежима));
		ЗаписьXML.ЗаписатьАтрибут("OFDCompany"        , XMLСтрока(СтруктураПараметров.ОрганизацияОФДНазвание));
		ЗаписьXML.ЗаписатьАтрибут("OFDCompanyINN"     , XMLСтрока(СтруктураПараметров.ОрганизацияОФДИНН));
		Если Не ПустаяСтрока(СтруктураПараметров.ОтправительEmail) Тогда
			ЗаписьXML.ЗаписатьАтрибут("SenderEmail", XMLСтрока(СтруктураПараметров.ОтправительEmail));
		КонецЕсли;
		Если Не ПустаяСтрока(СтруктураПараметров.АдресСайтаФНС) Тогда
			ЗаписьXML.ЗаписатьАтрибут("FNSURL", XMLСтрока(СтруктураПараметров.АдресСайтаФНС));
		КонецЕсли;
		
		Если РевизияИнтерфейса >= 4007 Тогда  // Версия стандарта 4.0 (ОФД 1.2)
			ЗаписьXML.ЗаписатьАтрибут("SupportFNPiot"  , XMLСтрока(СтруктураПараметров.ПоддержкаТСПИоТ));
		КонецЕсли;	
	
	Иначе
		
		ЗаписьXML.ЗаписатьНачалоЭлемента("Parameters");
		ЗаписьXML.ЗаписатьАтрибут("CashierName" , XMLСтрока(?(СтруктураПараметров.Свойство("Кассир")   , XMLСтрока(СтруктураПараметров.Кассир), НСтр("ru='Администратор'"))));
		ЗаписьXML.ЗаписатьАтрибут("CashierVATIN", XMLСтрока(?(СтруктураПараметров.Свойство("КассирИНН"), XMLСтрока(СтруктураПараметров.КассирИНН), "")));
		// ФФД 1.0.0
		ЗаписьXML.ЗаписатьАтрибут("KKTNumber"          , XMLСтрока(СтруктураПараметров.РегистрационныйНомерККТ));
		ЗаписьXML.ЗаписатьАтрибут("OFDVATIN"           , XMLСтрока(СтруктураПараметров.ОрганизацияОФДИНН));
		ЗаписьXML.ЗаписатьАтрибут("OFDOrganizationName", XMLСтрока(СтруктураПараметров.ОрганизацияОФДНазвание));
		ЗаписьXML.ЗаписатьАтрибут("OrganizationName"   , XMLСтрока(СтруктураПараметров.ОрганизацияНазвание));
		ЗаписьXML.ЗаписатьАтрибут("VATIN"              , XMLСтрока(СтруктураПараметров.ОрганизацияИНН));
		ЗаписьXML.ЗаписатьАтрибут("AddressSettle"      , XMLСтрока(СтруктураПараметров.АдресПроведенияРасчетов));
		ЗаписьXML.ЗаписатьАтрибут("TaxVariant"         , XMLСтрока(СтруктураПараметров.КодыСистемыНалогообложения));
		ЗаписьXML.ЗаписатьАтрибут("OfflineMode"        , XMLСтрока(СтруктураПараметров.ПризнакАвтономногоРежима));
		ЗаписьXML.ЗаписатьАтрибут("DataEncryption"     , XMLСтрока(СтруктураПараметров.ПризнакШифрованиеДанных));
		ЗаписьXML.ЗаписатьАтрибут("ServiceSign"        , XMLСтрока(СтруктураПараметров.ПризнакРасчетовЗаУслуги));
		ЗаписьXML.ЗаписатьАтрибут("BSOSing"            , XMLСтрока(СтруктураПараметров.ПризнакФормированияБСО));
		ЗаписьXML.ЗаписатьАтрибут("CalcOnlineSign"     , XMLСтрока(СтруктураПараметров.ПризнакРасчетовТолькоВИнтернет));
		ЗаписьXML.ЗаписатьАтрибут("AutomaticMode"      , XMLСтрока(СтруктураПараметров.ПризнакАвтоматическогоРежима));
		ЗаписьXML.ЗаписатьАтрибут("AutomaticNumber"    , XMLСтрока(СтруктураПараметров.НомерАвтоматаДляАвтоматическогоРежима));
		// ФФД 1.05 & 1.1
		ЗаписьXML.ЗаписатьАтрибут("PlaceSettle"        , XMLСтрока(СтруктураПараметров.МестоПроведенияРасчетов));
		ЗаписьXML.ЗаписатьАтрибут("SaleExcisableGoods" , XMLСтрока(СтруктураПараметров.ПродажаПодакцизногоТовара));
		ЗаписьXML.ЗаписатьАтрибут("SignOfGambling"     , XMLСтрока(СтруктураПараметров.ПроведенияАзартныхИгр));
		ЗаписьXML.ЗаписатьАтрибут("SignOfLottery"      , XMLСтрока(СтруктураПараметров.ПроведенияЛотерей));
		ЗаписьXML.ЗаписатьАтрибут("SignOfAgent"        , XMLСтрока(СтруктураПараметров.ПризнакиАгента));
		ЗаписьXML.ЗаписатьАтрибут("PrinterAutomatic"   , XMLСтрока(СтруктураПараметров.УстановкаПринтераВАвтомате));
		// Изменение параметров регистрации.
		ЗаписьXML.ЗаписатьАтрибут("ReasonCode"         , XMLСтрока(СтруктураПараметров.КодПричиныПеререгистрации));
		Если Не ПустаяСтрока(СтруктураПараметров.КодыПричинИзмененияСведений) Тогда
			ЗаписьXML.ЗаписатьАтрибут("InfoChangesReasonsCodes", XMLСтрока(СтруктураПараметров.КодыПричинИзмененияСведений));
		КонецЕсли;
		Если Не ПустаяСтрока(СтруктураПараметров.ОтправительEmail) Тогда
			ЗаписьXML.ЗаписатьАтрибут("SenderEmail", XMLСтрока(СтруктураПараметров.ОтправительEmail));
		КонецЕсли;
		Если Не ПустаяСтрока(СтруктураПараметров.АдресСайтаФНС) Тогда
			ЗаписьXML.ЗаписатьАтрибут("FNSWebSite", XMLСтрока(СтруктураПараметров.АдресСайтаФНС));
		КонецЕсли;
		
	КонецЕсли;
	
	ЗаписьXML.ЗаписатьКонецЭлемента();
	Возврат ЗаписьXML.Закрыть();
	
КонецФункции

Функция ПараметрыИзXMLПакетаККТ(Данные, ИдентификаторУстройства = Неопределено, РевизияИнтерфейса = 0, ИдентификаторТО = "") Экспорт
	
	ЧтениеXML = Новый ЧтениеXML; 
	ЧтениеXML.УстановитьСтроку(Данные);
	ЧтениеXML.ПерейтиКСодержимому();
	
	Параметры = МенеджерОборудованияКлиентСервер.ПараметрыРегистрацииККТ();
	Параметры.Вставить("ТипОборудования", Перечисления.ТипыПодключаемогоОборудования.ККТ);
	Параметры.Вставить("РевизияИнтерфейса", РевизияИнтерфейса);
	
	Если РевизияИнтерфейса >= 3000 Тогда  // Версия стандарта 3.0 (ОФД 1.1)
		
		Если (ЧтениеXML.Имя = "Parameters" Или ЧтениеXML.Имя = "TableParametersKKT") И ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда  
			Параметры.ВерсияФФДФН = "1.1";
			ВерсияФФДФН = ЧтениеXML.ЗначениеАтрибута("FFDVersionFN");
			Если ВерсияФФДФН = "1.0" Тогда
				Параметры.ВерсияФФДФН = "1.0"
			ИначеЕсли ВерсияФФДФН = "1.0.5" Или ВерсияФФДФН = "1.05" Тогда
				Параметры.ВерсияФФДФН = "1.05"
			ИначеЕсли ВерсияФФДФН = "1.2" Тогда
				Параметры.ВерсияФФДФН = "1.2"
			КонецЕсли;
			Параметры.ВерсияФФДККТ = "1.1"; 
			ВерсияФФДККТ = ЧтениеXML.ЗначениеАтрибута("FFDVersionKKT");
			Если ВерсияФФДККТ = "1.0" Тогда
				Параметры.ВерсияФФДККТ = "1.0"
			ИначеЕсли ВерсияФФДККТ = "1.0.5" Или ВерсияФФДККТ = "1.05" Тогда
				Параметры.ВерсияФФДККТ = "1.05"
			ИначеЕсли ВерсияФФДККТ = "1.2" Тогда
				Параметры.ВерсияФФДККТ = "1.2"
			КонецЕсли;
			// ФФД 1.0
			Параметры.РегистрационныйНомерККТ    = СокрЛП(ЧтениеXML.ЗначениеАтрибута("KKTNumber"));
			Параметры.ЗаводскойНомерККТ          = СокрЛП(ЧтениеXML.ЗначениеАтрибута("KKTSerialNumber"));
			Параметры.ЗаводскойНомерФН           = СокрЛП(ЧтениеXML.ЗначениеАтрибута("FNSerialNumber"));
			Параметры.ОрганизацияНазвание        = ЧтениеXML.ЗначениеАтрибута("CompanyName");
			Параметры.ОрганизацияИНН             = СокрЛП(ЧтениеXML.ЗначениеАтрибута("INN"));
			Параметры.АдресПроведенияРасчетов    = ЧтениеXML.ЗначениеАтрибута("SaleAddress");
			Параметры.МестоПроведенияРасчетов    = ЧтениеXML.ЗначениеАтрибута("SaleLocation");
			Параметры.КодыСистемыНалогообложения = ЧтениеXML.ЗначениеАтрибута("TaxationSystems");
			Параметры.ПризнакАвтономногоРежима   = ВРег(ЧтениеXML.ЗначениеАтрибута("IsOffline")) = "TRUE";
			Параметры.ПризнакШифрованиеДанных    = ВРег(ЧтениеXML.ЗначениеАтрибута("IsEncrypted")) = "TRUE";
			Параметры.ПризнакРасчетовЗаУслуги    = ВРег(ЧтениеXML.ЗначениеАтрибута("IsService")) = "TRUE";
			Параметры.ПродажаПодакцизногоТовара  = ВРег(ЧтениеXML.ЗначениеАтрибута("IsExcisable")) = "TRUE";
			Параметры.ПроведенияАзартныхИгр      = ВРег(ЧтениеXML.ЗначениеАтрибута("IsGambling")) = "TRUE";
			Параметры.ПроведенияЛотерей          = ВРег(ЧтениеXML.ЗначениеАтрибута("IsLottery")) = "TRUE";
			Параметры.ПризнакиАгента             = ЧтениеXML.ЗначениеАтрибута("AgentTypes");
			Параметры.ПризнакФормированияБСО         = ВРег(ЧтениеXML.ЗначениеАтрибута("BSOSing")) = "TRUE";
			Параметры.ПризнакРасчетовТолькоВИнтернет = ВРег(ЧтениеXML.ЗначениеАтрибута("IsOnlineOnly")) = "TRUE";
			Параметры.УстановкаПринтераВАвтомате     = ВРег(ЧтениеXML.ЗначениеАтрибута("IsAutomaticPrinter")) = "TRUE";
			Параметры.ПризнакАвтоматическогоРежима   = ВРег(ЧтениеXML.ЗначениеАтрибута("IsAutomatic")) = "TRUE";
			Параметры.НомерАвтоматаДляАвтоматическогоРежима = ЧтениеXML.ЗначениеАтрибута("AutomaticNumber");
			Параметры.ОрганизацияОФДНазвание     = ЧтениеXML.ЗначениеАтрибута("OFDCompany");
			Параметры.ОрганизацияОФДИНН          = СокрЛП(ЧтениеXML.ЗначениеАтрибута("OFDCompanyINN"));
			Параметры.ПризнакФискализации        = ВРег(ЧтениеXML.ЗначениеАтрибута("Fiscal")) = "TRUE";
			Параметры.НомерДокументаФискализации = ЧтениеXML.ЗначениеАтрибута("DocumentNumber");
			Параметры.ДатаВремяФискализации      = ЧтениеXML.ЗначениеАтрибута("DateTime");
			Параметры.ОтправительEmail           = ЧтениеXML.ЗначениеАтрибута("SenderEmail");
			Параметры.АдресСайтаФНС              = ЧтениеXML.ЗначениеАтрибута("FNSURL");
			Если РевизияИнтерфейса >= 3004 Тогда  // Версия стандарта 3.4 (ОФД 1.2)
				Параметры.ПроведенияРасчетаВИнтернет  = ВРег(ЧтениеXML.ЗначениеАтрибута("IsOnline")) = "TRUE";
				Параметры.ПродажаМаркированныхТоваров = ВРег(ЧтениеXML.ЗначениеАтрибута("IsMarking")) = "TRUE"; 
				Параметры.ПризнакПримененияЛомбардами = ВРег(ЧтениеXML.ЗначениеАтрибута("IsPawnshop")) = "TRUE"; 
				Параметры.ПризнакДеятельностиПоСтрахованию = ВРег(ЧтениеXML.ЗначениеАтрибута("IsAssurance")) = "TRUE"; 
			КонецЕсли;     
			Если РевизияИнтерфейса >= 4000 Тогда  // Версия стандарта 4.0 (ОФД 1.2)
				Параметры.ПризнакАвтоматическогоТорговогоАвтомата = ВРег(ЧтениеXML.ЗначениеАтрибута("IsVendingMachine")) = "TRUE";   
				Параметры.ПризнакОказанииУслугОбщественногоПитания = ВРег(ЧтениеXML.ЗначениеАтрибута("IsCateringServices")) = "TRUE";  
				ПризнакОптовойТорговлиСОрганизациями = ЧтениеXML.ЗначениеАтрибута("IsWholesaleTrade"); 
				Если НЕ ПустаяСтрока(ПризнакОптовойТорговлиСОрганизациями) Тогда
					Параметры.ПризнакОптовойТорговлиСОрганизациями = ВРег(ПризнакОптовойТорговлиСОрганизациями) = "TRUE"; 
				КонецЕсли;
			КонецЕсли;    
			Если РевизияИнтерфейса >= 4007 Тогда  // Версия стандарта 4.7
				Параметры.ПоддержкаТСПИоТ = ВРег(ЧтениеXML.ЗначениеАтрибута("SupportFNPiot")) = "TRUE";   
			КонецЕсли;    
		КонецЕсли;
		
	Иначе
		
		Если ЧтениеXML.Имя = "Parameters" И ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда  
			Параметры.ВерсияФФДФН   = ЧтениеXML.ЗначениеАтрибута("FFDVersionFN");
			Если ПустаяСтрока(Параметры.ВерсияФФДФН) Тогда
				Параметры.ВерсияФФДФН = "1.0";
			КонецЕсли;
			Параметры.ВерсияФФДККТ  = ЧтениеXML.ЗначениеАтрибута("FFDVersionKKT");
			Если ПустаяСтрока(Параметры.ВерсияФФДККТ) Тогда
				Параметры.ВерсияФФДККТ = "1.0";
			КонецЕсли;
			// ФФД 1.0
			Параметры.РегистрационныйНомерККТ        = СокрЛП(ЧтениеXML.ЗначениеАтрибута("KKTNumber"));
			Параметры.ОрганизацияНазвание            = ЧтениеXML.ЗначениеАтрибута("OrganizationName");
			Параметры.ОрганизацияИНН                 = СокрЛП(ЧтениеXML.ЗначениеАтрибута("VATIN"));
			Параметры.АдресПроведенияРасчетов        = ЧтениеXML.ЗначениеАтрибута("AddressSettle");
			Параметры.МестоПроведенияРасчетов        = ЧтениеXML.ЗначениеАтрибута("PlaceSettle");
			Параметры.КодыСистемыНалогообложения     = ЧтениеXML.ЗначениеАтрибута("TaxVariant");
			Если ПустаяСтрока(Параметры.КодыСистемыНалогообложения) Тогда
				Параметры.КодыСистемыНалогообложения = ЧтениеXML.ЗначениеАтрибута("TaxVarinat");
			КонецЕсли;
			Параметры.ПризнакАвтономногоРежима       = ВРег(ЧтениеXML.ЗначениеАтрибута("OfflineMode")) = "TRUE";
			Параметры.ПризнакАвтоматическогоРежима   = ВРег(ЧтениеXML.ЗначениеАтрибута("AutomaticMode")) = "TRUE";
			Параметры.НомерАвтоматаДляАвтоматическогоРежима = ЧтениеXML.ЗначениеАтрибута("AutomaticNumber");
			Параметры.ПризнакФормированияБСО   = ВРег(ЧтениеXML.ЗначениеАтрибута("BSOSing")) = "TRUE";
			Параметры.ПризнакРасчетовТолькоВИнтернет = ВРег(ЧтениеXML.ЗначениеАтрибута("CalcOnlineSign")) = "TRUE";
			Параметры.ПризнакШифрованиеДанных        = ВРег(ЧтениеXML.ЗначениеАтрибута("DataEncryption")) = "TRUE";
			Параметры.ОрганизацияОФДИНН          = СокрЛП(ЧтениеXML.ЗначениеАтрибута("OFDVATIN"));
			Параметры.ОрганизацияОФДНазвание     = ЧтениеXML.ЗначениеАтрибута("OFDOrganizationName");
			Параметры.ЗаводскойНомерККТ          = СокрЛП(ЧтениеXML.ЗначениеАтрибута("KKTSerialNumber"));
			Параметры.ПризнакФискализации        = ВРег(ЧтениеXML.ЗначениеАтрибута("Fiscal")) = "TRUE";
			Параметры.ЗаводскойНомерФН           = СокрЛП(ЧтениеXML.ЗначениеАтрибута("FNSerialNumber"));
			Параметры.НомерДокументаФискализации = ЧтениеXML.ЗначениеАтрибута("DocumentNumber");
			Параметры.ДатаВремяФискализации      = ЧтениеXML.ЗначениеАтрибута("DateTime");
			Параметры.ПризнакРасчетовЗаУслуги    = ВРег(ЧтениеXML.ЗначениеАтрибута("ServiceSign")) = "TRUE";
			Параметры.ПродажаПодакцизногоТовара  = ВРег(ЧтениеXML.ЗначениеАтрибута("SaleExcisableGoods")) = "TRUE";
			Параметры.ПроведенияАзартныхИгр      = ВРег(ЧтениеXML.ЗначениеАтрибута("SignOfGambling")) = "TRUE";
			Параметры.ПроведенияЛотерей          = ВРег(ЧтениеXML.ЗначениеАтрибута("SignOfLottery")) = "TRUE";
			Параметры.ПризнакиАгента             = ЧтениеXML.ЗначениеАтрибута("SignOfAgent");
			Параметры.УстановкаПринтераВАвтомате = ВРег(ЧтениеXML.ЗначениеАтрибута("PrinterAutomatic")) = "TRUE";
			Параметры.ОтправительEmail           = ЧтениеXML.ЗначениеАтрибута("SenderEmail");
			Параметры.АдресСайтаФНС              = ЧтениеXML.ЗначениеАтрибута("FNSWebSite");
		КонецЕсли;
		
	КонецЕсли;
	
	СистемыНалогообложения = Новый Массив();
	Если Не ПустаяСтрока(Параметры.КодыСистемыНалогообложения) Тогда
		СистемыНалогообложенияВрем = СтрРазделить(Параметры.КодыСистемыНалогообложения, ",");
		Для Каждого ВремСНО Из СистемыНалогообложенияВрем Цикл
			СНО = МенеджерОборудованияКлиентСервер.СистемаНалогообложенияККТПоКоду(Число(ВремСНО));
			СистемыНалогообложения.Добавить(СНО);
		КонецЦикла;
		Параметры.Вставить("СистемыНалогообложения", СистемыНалогообложения);
	КонецЕсли;
	
	Если НЕ ПустаяСтрока(ИдентификаторТО) Тогда
		СохранитьПараметрыРегистрацииУстройства(ИдентификаторТО, Параметры);
	КонецЕсли;
	
	Возврат Параметры;
	
КонецФункции

Проверено на следующих конфигурациях и релизах:

Управление торговлей, редакция 10.3, релизы 10.3.88.3, 10.3.88.2, 10.3.88.1, 10.3.87.3

Вступайте в нашу телеграмм-группу Инфостарт

Посцентр Драйвер ККТ УТ 10 ОФД 4.7

+1 –

См. также

ККТ-ОНЛАЙН 54-ФЗ: Обработка для работы онлайн касс

ККМ Кассовые операции Розничная торговля НДС 22% Системный администратор Программист 1С:Предприятие 8 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Розница 2 1С:Управление производственным предприятием 1С:Бухгалтерия государственного учреждения 1С:Бухгалтерия 1.6 1С:Бухгалтерия автономного учреждения Россия Платные (руб)

Универсальная обработка для обслуживания любых фискальных регистраторов (ККТ), в том числе Веб сервер АТОЛ. Работает в соответствии с 54-ФЗ. (ФФД 1.0, ФФД 1.05, ФФД 1.1, ФФД 1.2). Подключайте любую онлайн кассу к практически любой конфигурации на обычных формах. Нет необходимости обновлять 1С. Можно бесплатно скачать и протестировать. Может работать одновременно с несколькими онлайн-кассами, либо одной с разных рабочих мест. (через RDP, TCP\IP или веб-сервер) Позволяет разделить один чек сразу на несколько ККТ или на несколько систем налогообложения. Поддерживает разрешительный режим и маркировку. Поддерживает локальный модуль честного знака для офлайн проверки. Можно настроить собственный шаблонов чека. Можно использовать эквайринг там, где он не поддерживается. Работает на LINUX и Windows Адаптировано к ставке НДС 22% и ТС ПИоТ.

6100 руб.

27.02.2017 880088 6093 10302

3203

Обновление для 1С:УТ 10.3, КА 1.1 и УПП 1.3 на новую ставку НДС 22%

НДС 22% Учетные задачи ККМ Файловый обмен (TXT, XML, DBF), FTP 1С 8.3 1С:Комплексная автоматизация 1.х 1С:Управление торговлей 10 1С:Управление производственным предприятием Бухгалтерский учет Налоговый учет НДС Платные (руб)

Готовое обновление для конфигурации 1С:Управление торговлей 10.3, 1С:Комплексная автоматизация 1.1 , 1С:Управление производственным предприятием 1.3 обеспечивающее полную поддержку новой ставки НДС 22%. Для 1С:УТ 10.3 реализована поддержка печати чеков ККМ, а также Правила обмена с 1С:БП 3.0. Решение встраивает необходимые изменения в перечисления и документы, включая торговые операции и печатные формы.

12200 руб.

16.12.2025 6054 76 0

Работа с ККТ по 54-ФЗ и разрешительным режимом

ККМ Кассовые операции Розничная торговля НДС 22% Системный администратор Программист 1С:Предприятие 8 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Розница 2 1С:Управление производственным предприятием 1С:Бухгалтерия государственного учреждения 1С:Бухгалтерия автономного учреждения Россия Платные (руб)

Обработка осуществляет обслуживание ККТ АТОЛ, Штрих, Вики Принт и Меркурий для конфигураций "УТ 10.3", "КА 1.1", "УПП 1.3", "Розница 1.0", "БП 2.0" и других отраслевых решений, построенных на основе указанных выше конфигурациях. Поддерживает возможность параллельно пробития чеков на одной ККМ несколькими пользователями. Поддерживает Веб-сервер Атол. Соответствует требованиям 54-ФЗ. Поддерживает ФФД 1.0, 1.05, 1.1 и 1.2. Разделяет чеки по нескольким СНО. Поддерживает механизмы подключения ККТ по TCP/IP, для работы через RDP или интернет. Поддержка маркировки и разрешительного режима. Поддержка пробития чеков с новыми ставками НДС 5%, НДС 7% и НДС 22%.

7900 руб.

25.05.2015 367890 1653 3231

1154

Рабочее место для ЭДО

ЭДО и ОФД Обмен с ГосИС Программист Бухгалтер Пользователь 1С 8.3 1С:Управление торговлей 10 1С:Розница 2 1С:Управление производственным предприятием 1С:Управление нашей фирмой 1.6 1С:Документооборот 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Управление холдингом 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Бухгалтерский учет Управленческий учет Платные (руб)

Рабочее место для работы с ЭДО из 1С. Загрузка и отправка УПД, УКД, ТОРГ12, Акта в 1С (сохранение в файл и последующая загрузка через личный кабинет не требуется). Также поддерживается: отправка печатных форм, произвольных файлов, подписание, отклонение, аннулирование документов. Поддержка МЧД. Решение реализовано в виде расширения на управляемых формах. Для обычных форм - внешняя обработка. Поддержка Linux.

4600 руб.

16.12.2020 47100 279 201

101

Интеграция 1С с приложением "Госключ" Электронная подпись

Бюджетный учет ЭДО и ОФД Бухгалтер Пользователь 1С:Предприятие 8 1С:Бухгалтерия государственного учреждения 1С:Документооборот 1С:ERP Управление предприятием 2 1С:Зарплата и кадры государственного учреждения 3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Россия Бухгалтерский учет Бюджетный учет Платные (руб)

Расширение для автоматизации процесса подписания электронных документов в мобильном приложении "Госключ" с видом подписи УКЭП/УНЭП, которое подходит для электронного подписания бухгалтерских документов, список которых утвержден в приказе Минфина №61н «Об утверждении унифицированных форм электронных документов бухгалтерского учета…»

325000 руб.

06.11.2024 18300 4 0

Выгрузка УПД в формате XML для ЭДО

Файловый обмен (TXT, XML, DBF), FTP ЭДО и ОФД Программист Бухгалтер 1С:Предприятие 8 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Бухгалтерский учет Платные (руб)

Данные обработки позволяют выгружать документ УПД в формате xml. (В ФАЙЛ) для ЭДО в 1С: УТ, БП, КА версии ПРОФ и БАЗОВЫЕ. Формат выгрузки 5.03

4270 руб.

25.09.2019 104676 1303 608

628

Печать кассовых чеков на одну ККМ с нескольких рабочих мест для 1С:УТ11.5, Розница 2.3/3.0, УНФ 3.0

ККМ Кассовые операции Розничная торговля Программист Бухгалтер Пользователь 1С:Предприятие 8 1С:Розница 2 1С:Управление торговлей 11 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Платные (руб)

Расширение для типовых конфигураций для Управляемых форм позволяет выполнять печать кассовых чеков на одну ККМ 54-ФЗ с нескольких рабочих мест. НИКАКИХ НАСТРОЕК В РАЗРАБОТКЕ - ПОДКЛЮЧИЛ И ПЕЧАТАЙ. Если у вас несколько отделов и одна ККМ - печатайте на одной ККМ! Если у вас две ККМ и одна поломалась - печатайте на одной ККМ, пока ремонтируете другую!

9500 руб.

27.08.2018 132757 743 603

931

Сервер ККМ: Сетевая печать чеков, 54-ФЗ, Требования от 1 сентября 2025г, НДС 5%,7% и 22%, разрешительный режим, бесплатный эмулятор ККМ, очередь печати с нескольких ПК, быстрая печать чеков из терминального сеанса.

ККМ Кассовые операции Розничная торговля НДС 22% Системный администратор Программист Пользователь 1С:Предприятие 8 1C:Бухгалтерия 1С:Бухгалтерия 3.0 1С:Торговля и склад 7.7 1С:ERP Управление предприятием 2 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 1С:Управление торговлей 10 1С:Управление торговлей 11 1С:Розница 3.0 Розничная и сетевая торговля (FMCG) Оптовая торговля, дистрибуция, логистика Рестораны, кафе и фаст-фуд Россия Платные (руб)

«Сервер ККМ» позволяет приложениям работать с фискальными регистраторами по локальной сети или интернет, организовать печать на одном ККМ с нескольких рабочих мест с поддержкой очереди печати. Поддержка НДС 22% для Атол, Штрих, Ритейл и всех 1С-совместимых ККМ с драйвером ревизии 4.7 и 5.0. Поддерживаются ВСЕ ревизии требований фирмы 1С к разработке драйверов ККТ от 2.2 до 4.7. Возможность печати чеков с НДС 22% без изменения конфигурации 1С. Поддержка драйвера от "Торгового баланса М" с возможностью работы с ТСПиОТ. Поддерживаются требования к ККМ, действующие с 1 сентября 2025г.

9000 руб.

02.09.2016 149923 198 201

225

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. Torin 934 15.12.25 11:09 Сейчас в теме

(0)

Функция ТестУстройства(ОбъектДрайвера, Параметры, ПараметрыПодключения, ВыходныеПараметры)

	Результат            = Истина;
	РезультатТеста       = "";
	АктивированДемоРежим = "";

//Вставка
      Если  Не ПараметрыПодключения.Свойство("РевизияИнтерфейса") Тогда
       ПараметрыПодключения.Вставить("РевизияИнтерфейса", 2005);
       КонецЕсли;
// Конец вставки
	

	РевизияИнтерфейса = РевизияИнтерфейса(ОбъектДрайвера, ПараметрыПодключения);


..............
КонецФункции

Показать

2. Scorpanatoly 15 24.12.25 09:23 Сейчас в теме

Добрый день!
На 8.3.18.1208 взлетит?

3. andrew.ab 234 24.12.25 12:42 Сейчас в теме

(2) думаю нет, проще платформу поднять до 8.3.23 минимум.

4. akR00b 25 25.12.25 10:08 Сейчас в теме

Добрый день, На УПП 1.3 взлетит? касса штрих-м, я правильно понял что это обработка обслуживания? сейчас на старой обработке после обновления прошивки при печати чека выдает,
FFFFFFF8h, No XML attribute AdvancePayment , может вручную можно указать этот параметр? Версия ФФД ККТ 1.2

5. ikmercury 03.01.26 23:08 Сейчас в теме

обновленная обработка обслуживания выложена на оф.сайте 1С - в разделе Обработки обслуживания торгового оборудования

6. madonov 268 15.01.26 10:11 Сейчас в теме

Подскажите где скачать?
https://downloads.v8.1c.ru/tmplts/ITS/TradeWare/ShtrihMkkt.zip - по этой ссылке УПП ищет новую версию, но там 404.

7. madonov 268 15.01.26 10:22 Сейчас в теме

https://releases.1c.ru/additional_file?nick=TradeWareEpf82&path=TradeWare%5cExtrafiles%5cShtrihMkkt.epf

Для отправки сообщения требуется регистрация/авторизация

Автор:

Андрей Пономарев (andrew.ab)

Рейтинг: 234

Для получения уведомлений о новых публикациях автора подключите телеграм бот: Инфостарт бот

Публикация:

№ 2553254

Создание 15.12.25 10:30

Обновление 15.12.25 10:30

Статистика:

Просмотры 1224

Загрузки 14

Рейтинг 1

Комментарии 7

Характеристики:

Код открыт Да

Рубрики ККМ ЭДО и ОФД

Кому Программист

Тип файла Архив с данными

Платформа 1С 8.3

Конфигурация 1С:Управление торговлей 10

Операционная система Не имеет значения

Страна Не имеет значения

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Не имеет значения

Доступ к файлу Абонемент ($m)