Здравствуйте!
В нескольких статьях я расскажу о возможностях протестировать с помощью SoapUI, как работают веб-сервисы 1С. Также приведу примеры возврата из 1С документов в формате PDF и сложных xml-файлов. Некоторые вещи сходны с вот с этой статьей, однако я рассмотрю более сложные примеры работы с веб-сервисами. Но для начала я по шагам рассмотрю процесс запуска веб-сервисов и работы с SoapUI, чтобы легче было разобраться в их функционировании с нуля.
1. Простой веб-сервис
Для начала возьмем каркасную конфигурацию без веб-сервисов и пройдем по шагам процесс их создания.
Добавим новый веб-сервис с именем test1 и создадим в нем операцию hello с возвращаемым типом string. Имена веб-сервисов и операций лучше всегда задавать на латинице.
Также нужно задать URI пространства имен и имя файла публикации:
При нажатии на лупу в поле "Имя процедуры" будет открыт модуль веб-сервиса и можно будет реализовать функцию hello.
Функция hello()
возврат "строка из веб-сервиса 1с";
КонецФункции
2. Публикация веб-сервиса.
Теперь, чтобы получившаяся функция была доступна по http, нужно опубликовать наш сервис на веб-сервере. Для этого подойдет Apache 2.2. Я почитал статьи о том, как можно настроить работу с IIS и мне это показалось гораздо сложнее. После установки и запуска Apache 2.2 нужно зайти в меню Администрирование - Публикация на веб-сервере. Поле "каталог" должно быть заполнено и содержать каталог установки Apache. Запомните поля "имя" и "адрес" веб-сервиса, они нам пригодятся на следующем шаге.
3. Тестирование с помощью SoapUI
Для тестирования создадим отдельного пользователя WsUser, с простым паролем и дадим ему полные права.
После этого устанавливаем и запускаем SoapUI. Эта программа очень удобна для тестирования веб-сервисов, она может получать их описание и делать post-запросы к сервисам.
Заходим в меню File - New SOAP project, задаем имя проекта hellotest а в поле Initial WSDL пропишем вот такую ссылку:
http://localhost/test_ws/ws/test1.1cws?wsdl
В ней часть "test_ws" была задана на прошлом этапе в поле "имя" а test1.1cws в поле "адрес".
Нажимаем ОК и на этом этапе нужно будет авторизоваться, войдя под тестовым пользователем WsUser. Будет создан проект и два элемента binding.
Soap12Binding отличается тем, что работает по новой версии стандарта SOAP 1.2. Откроем в test1Soap12Binding элемент Request1 и увидим вот что:
SoapUI показывает, какой xml будет передано в нашу функцию. Перед запуском теста есть еще один нюанс, по умолчанию SoapUI будет требовать авторизацию для каждого отдельного элемента Request. Поэтому, чтобы не задавать ее каждый раз, нужно кликнуть правой кнопкой мышки на testSoap12Binding, выбрать Show interface view и в открывшемся окне на вкладке "Service Endpoint" задать имя и пароль пользователя веб-сервисов:
Если этого не сделать, то для каждого Request нужно будет задавать авторизацию, в нижней панели по кнопке Auth.
Теперь можно наконец-то выполнить запрос к функции hello и посмотреть ответ:
Отлично, все заработало!
4. Передача простых параметров в функцию.
Теперь сделаем новую функцию с параметрами, например проверим работу с датами, сделаем функцию getSaleDocNumbersByDate, которая будет принимать дату документа (расходной накладной) и возвращать номера документов за эту дату строкой. Добавим к операции параметр date с типом dateTime:
код такой:
Функция getSaleDocNumbersByDate(date)
//
датаНачала = началоДня(date);
датаКонца = конецДня(date);
выборкаДокументов = документы.Расходная.Выбрать(датаНачала, датаКонца);
номера="";
пока выборкаДокументов.Следующий() цикл
номера = номера+" №"+выборкаДокументов.Номер+";";
конеццикла;
возврат номера;
КонецФункции
Теперь в SoapUI правой кнопкой мыши нужно кликнуть на элемент testSoap12Binding и выбрать пункт Update Definition. После этого в проекте появится функция getSaleDocNumbersByDate и готовый Request к ней. Для заполнения даты нужно использовать формат "YYYY-MM-DDThh:mm:ss" (можно посмотреть на w3schools и ОЧЕНЬ рекомендую пользоваться этим сайтом для понимания работы с xml)
Тогда получатся вот такие запрос и ответ:
5. Пакеты XDTO
Если необходимо передавать в функции более сложные параметры (например, xml с несколькими полями), или получать в ответ сложные по структуре xml, то нам не обойтись без пакетов XDTO.
Очень подробно работа с XDTO рассмотрена в цикле статей XDTO это просто. По сути, пакет определяет структуру и тип полей используемых xml-файлов.
Я рассмотрю пример передачи и получение xml-файла, тип которого определен в пакете
А также в следующих статьях я рассмотрю примеры:
- передача в 1с xml-файла, не описанного в пакете, в формате base64
- получение из 1с документа pdf в формате base64 и его декодирование
- получение из 1с xml-файла со вложенной структурой элементов и определение их количества
6. Передача в 1с в параметре xml-файла, тип которого определен в пакете.
Задача будет такая: найти документ расходной накладной по заданным во входящем xml номеру и дате и вернуть найденный документ. Возвращать нужно также в виде xml с номером, датой, контрагентом и его кодом и табличной частью товаров.
Создадим пакет packet1 с пространством имен packet1_ns. Для входящего xml-файла определим тип объекта InDocSaleQuery с полем number типа string и полем date типа dateTime. Для выходного файла определим сначала тип для одной строки табличной части товаров: SaleItem с полями name типа string, price sum, quantity типа decimal. А сам документ SaleDoc будет у нас составного типа: поля number, date, partnerName и поле SaleItems у которого будет тип SaleItem и максимальное количество -1. Именно такое поле обозначает, что в нем может присутствовать массив из нескольких элементов. Вот так всё это выглядит в конфигураторе:
Далее в свойствах веб-сервиса нужно задать использование пакета XDTO packet1_ns. getSaleDoc с типом возвращаемого значения SaleDoc и входным параметром incomingXML типа InDocSaleQuery.
Сначала продемонстрирую код функции, а уже затем объясню что происходит
Код:
Функция getSaleDoc(incomingXML)
НомерДок = incomingXML.number;
ДатаДок = incomingXML.date;
запрос = новый запрос;
запрос.Текст = "ВЫБРАТЬ
| РасходнаяТовары.Номенклатура.Наименование как name,
| РасходнаяТовары.Цена как price,
| РасходнаяТовары.Количество как quantity,
| РасходнаяТовары.Сумма как sum,
| РасходнаяТовары.Ссылка
|ИЗ
| Документ.Расходная.Товары КАК РасходнаяТовары
|ГДЕ
| РасходнаяТовары.Ссылка.Номер = &Номер
| И РасходнаяТовары.Ссылка.Дата = &ДатаДок";
запрос.УстановитьПараметр("Номер",номерДок);
запрос.УстановитьПараметр("ДатаДок",ДатаДок);
выборка = запрос.Выполнить().Выбрать();
если выборка.Количество()=0 тогда
//вернем ошибку
ТипДокумента = ФабрикаXDTO.Тип("packet1_ns", "SaleDoc");
ПакетДокумента = ФабрикаXDTO.Создать(ТипДокумента);
ПакетДокумента.number = "Документов Не найдено!";
Возврат ПакетДокумента;
иначе
//создаем типы
ТипДокумента = ФабрикаXDTO.Тип("packet1_ns", "SaleDoc");
ТипТабличнойЧасти = ФабрикаXDTO.Тип("packet1_ns", "SaleItem");
ПакетДокумента = ФабрикаXDTO.Создать(ТипДокумента);
//выбираем из табличной части
сч=0;
пока выборка.Следующий() цикл
если сч=0 тогда
//заполним реквизиты документа
док = выборка.ссылка;
ПакетДокумента.number = док.Номер;
ПакетДокумента.date = док.Дата;
ПакетДокумента.partnerName = строка(док.Контрагент);
конецесли;
//заполняем табличную часть
ПакетТабличнойЧасти = ФабрикаXDTO.Создать(ТипТабличнойЧасти);
ЗаполнитьЗначенияСвойств(ПакетТабличнойЧасти,выборка);
//добавляем ее в документ
ПакетДокумента.SaleItems.Добавить(ПакетТабличнойЧасти);
сч=сч+1;
конеццикла;
Возврат ПакетДокумента;
конецесли;
КонецФункции
Здесь два основных нюанса. Первый: так как был задан тип входящего параметра incomingXML и он был описан этот тип в пакете, то сразу возможно обращаться к полям этого входящего xml. Второй: работа с фабрикой XDTO. Из нее был получен тип для результирующих выходных параметров и создано ЗначениеXDTO этого типа, у которого были заполнены необходимые поля. Также стоит заметить, что в типе SaleDoc следует ввести отдельное поле для ошибки, но для тестовых целей ошибки будут записаны в поле number.
Вот как выглядит результат этого запроса в SoapUI:
Как видно, все работает, но еще есть что улучшить - например, хотелось бы знать какое количество элементов SaleItems у нас в документе.
Об этом и о более сложных примерах я расскажу уже в следующей статье.
В приложенном архиве - выгрузка информационной базы и проект SoapUI.
