Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
ПроцедурыПерсонифицированногоУчета.ПоместитьВМенеджерСоответствиеТарифаКатегории(Запрос.МенеджерВременныхТаблиц);
Запрос.УстановитьПараметр("ДатаЗаменыЕСН", ПроведениеРасчетов.ДатаЗаменыЕСНСтраховымиВзносами());
Запрос.УстановитьПараметр("ОтчетныйПериод", ПервыйОтчетныйПериод);
Запрос.УстановитьПараметр("ОтчетныйГод", Год(ПервыйОтчетныйПериод));
Запрос.УстановитьПараметр("КонецОтчетногоПериода", ПроцедурыПерсонифицированногоУчета.ОкончаниеОтчетногоПериодаПерсучета(ПервыйОтчетныйПериод));
Запрос.УстановитьПараметр("ДатаАктуальности", ДатаАктуальности);
Запрос.УстановитьПараметр("КонецПериодаУплаты", Мин(ДатаАктуальности, ПроцедурыПерсонифицированногоУчета.ОкончаниеОтчетногоПериодаПерсучета(ПервыйОтчетныйПериод)));
Запрос.УстановитьПараметр("Организация", Организация);
Запрос.УстановитьПараметр("ГоловнаяОрганизация", ОбщегоНазначения.ГоловнаяОрганизация(Организация));
Запрос.УстановитьПараметр("ДатаНовойРедакцииЗакона212", ПроведениеРасчетов.ДатаРасширенияПеречняЛьготныхТарифовСтраховыхВзносов());
Запрос.Текст =
"ВЫБРАТЬ РАЗЛИЧНЫЕ
| СведенияПринятыеПФР.КомплектДокументов
|ПОМЕСТИТЬ ВТПринятоВПФР
|ИЗ
| РегистрСведений.СведенияПринятыеПФР КАК СведенияПринятыеПФР
|ГДЕ
| СведенияПринятыеПФР.КомплектДокументов <> ЗНАЧЕНИЕ(Документ.ПередачаСЗВ4вПФР.ПустаяСсылка)
| И СведенияПринятыеПФР.Организация = &Организация
| И СведенияПринятыеПФР.ОтчетныйПериодПерсучетаПФР < &ОтчетныйПериод
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| СтраховыеВзносыИсчисленныеОбороты.ФизЛицо КАК ФизЛицо,
| СтраховыеВзносыИсчисленныеОбороты.Период КАК МесяцОтчетногоПериода,
| КОНЕЦПЕРИОДА(СтраховыеВзносыИсчисленныеОбороты.Период, МЕСЯЦ) КАК Период,
| ВЫБОР
| КОГДА СтраховыеВзносыИсчисленныеОбороты.Период < ДАТАВРЕМЯ(2010, 7, 1, 0, 0, 0)
| ТОГДА ДАТАВРЕМЯ(2010, 1, 1, 0, 0, 0)
| КОГДА СтраховыеВзносыИсчисленныеОбороты.Период < ДАТАВРЕМЯ(2011, 1, 1, 0, 0, 0)
| ТОГДА ДАТАВРЕМЯ(2010, 7, 1, 0, 0, 0)
| ИНАЧЕ НАЧАЛОПЕРИОДА(СтраховыеВзносыИсчисленныеОбороты.Период, КВАРТАЛ)
| КОНЕЦ КАК ОтчетныйПериод,
| СтраховыеВзносыИсчисленныеОбороты.ПФРСтраховаяОборот + ВЫБОР
| КОГДА СтраховыеВзносыИсчисленныеОбороты.Период < &ДатаНовойРедакцииЗакона212
| ТОГДА 0
| ИНАЧЕ СтраховыеВзносыИсчисленныеОбороты.ПФРСтраховаяЕНВДОборот
| КОНЕЦ КАК ПФРСтраховаяОборот,
| СтраховыеВзносыИсчисленныеОбороты.ПФРНакопительнаяОборот + ВЫБОР
| КОГДА СтраховыеВзносыИсчисленныеОбороты.Период < &ДатаНовойРедакцииЗакона212
| ТОГДА 0
| ИНАЧЕ СтраховыеВзносыИсчисленныеОбороты.ПФРНакопительнаяЕНВДОборот
| КОНЕЦ КАК ПФРНакопительнаяОборот,
| ВЫБОР
| КОГДА СтраховыеВзносыИсчисленныеОбороты.Период < &ДатаНовойРедакцииЗакона212
| ТОГДА СтраховыеВзносыИсчисленныеОбороты.ПФРСтраховаяЕНВДОборот
| ИНАЧЕ 0
| КОНЕЦ КАК ПФРСтраховаяЕНВДОборот,
| ВЫБОР
| КОГДА СтраховыеВзносыИсчисленныеОбороты.Период < &ДатаНовойРедакцииЗакона212
| ТОГДА СтраховыеВзносыИсчисленныеОбороты.ПФРНакопительнаяЕНВДОборот
| ИНАЧЕ 0
| КОНЕЦ КАК ПФРНакопительнаяЕНВДОборот
|ПОМЕСТИТЬ ВТИсчисленоПоЗЛ
|ИЗ
| РегистрНакопления.СтраховыеВзносыИсчисленные.Обороты(&ОтчетныйПериод, &КонецОтчетногоПериода, Месяц, ОбособленноеПодразделение = &Организация) КАК СтраховыеВзносыИсчисленныеОбороты
|
|ИНДЕКСИРОВАТЬ ПО
| ФизЛицо
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| СрезПоследнихДат.МесяцОтчетногоПериода,
| СрезПоследнихДат.Физлицо КАК Физлицо
|ПОМЕСТИТЬ ВТИнвалиды
|ИЗ
| (ВЫБРАТЬ
| Периоды.МесяцОтчетногоПериода КАК МесяцОтчетногоПериода,
| Периоды.ФизЛицо КАК Физлицо,
| МАКСИМУМ(СведенияОбИнвалидностиФизлиц.Период) КАК Период
| ИЗ
| ВТИсчисленоПоЗЛ КАК Периоды
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.СведенияОбИнвалидностиФизлиц КАК СведенияОбИнвалидностиФизлиц
| ПО Периоды.Период >= СведенияОбИнвалидностиФизлиц.Период
| И Периоды.ФизЛицо = СведенияОбИнвалидностиФизлиц.Физлицо
|
| СГРУППИРОВАТЬ ПО
| Периоды.ФизЛицо,
| Периоды.МесяцОтчетногоПериода) КАК СрезПоследнихДат
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.СведенияОбИнвалидностиФизлиц КАК СведенияОбИнвалидностиФизлиц
| ПО СрезПоследнихДат.Период = СведенияОбИнвалидностиФизлиц.Период
| И СрезПоследнихДат.Физлицо = СведенияОбИнвалидностиФизлиц.Физлицо
|ГДЕ
| СведенияОбИнвалидностиФизлиц.Инвалидность
|
|ИНДЕКСИРОВАТЬ ПО
| Физлицо,
| СрезПоследнихДат.МесяцОтчетногоПериода
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ РАЗЛИЧНЫЕ
| Периоды.МесяцОтчетногоПериода,
| ЕСТЬNULL(УчетнаяПолитикаНалоговыйУчет.ВидТарифаСтраховыхВзносов, ЗНАЧЕНИЕ(Перечисление.ТарифыСтраховыхВзносов.ОбщийНалоговыйРежим)) КАК ВидТарифаСтраховыхВзносов
|ПОМЕСТИТЬ ВТВидыТарифныхСтавокОрганизаций
|ИЗ
| (ВЫБРАТЬ
| Периоды.МесяцОтчетногоПериода КАК МесяцОтчетногоПериода,
| УчетнаяПолитикаНалоговыйУчет.Организация КАК Организация,
| МАКСИМУМ(УчетнаяПолитикаНалоговыйУчет.Период) КАК ПериодРегистра
| ИЗ
| ВТИсчисленоПоЗЛ КАК Периоды
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.УчетнаяПолитикаНалоговыйУчет КАК УчетнаяПолитикаНалоговыйУчет
| ПО Периоды.Период >= УчетнаяПолитикаНалоговыйУчет.Период
| И (УчетнаяПолитикаНалоговыйУчет.Организация = &ГоловнаяОрганизация)
|
| СГРУППИРОВАТЬ ПО
| Периоды.МесяцОтчетногоПериода,
| УчетнаяПолитикаНалоговыйУчет.Организация) КАК Периоды
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.УчетнаяПолитикаНалоговыйУчет КАК УчетнаяПолитикаНалоговыйУчет
| ПО Периоды.ПериодРегистра = УчетнаяПолитикаНалоговыйУчет.Период
| И Периоды.Организация = УчетнаяПолитикаНалоговыйУчет.Организация
|
|ИНДЕКСИРОВАТЬ ПО
| Периоды.МесяцОтчетногоПериода
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ИсчисленоПоЗЛ.ФизЛицо КАК ФизЛицо,
| ИсчисленоПоЗЛ.ПФРНакопительнаяОборот КАК ПФРНакопительнаяОборот,
| ИсчисленоПоЗЛ.ПФРСтраховаяОборот КАК ПФРСтраховаяОборот,
| ИсчисленоПоЗЛ.ОтчетныйПериод КАК ОтчетныйПериод,
| НАЧАЛОПЕРИОДА(ИсчисленоПоЗЛ.ОтчетныйПериод, ГОД) КАК ГодОтчетногоПериода,
| ВЫБОР
| КОГДА Инвалиды.Физлицо ЕСТЬ НЕ NULL
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ТарифыСтраховыхВзносов.ОрганизацияИнвалидов)
| ИНАЧЕ ВидыТарифныхСтавокОрганизаций.ВидТарифаСтраховыхВзносов
| КОНЕЦ КАК ВидТарифаСтраховыхВзносов
|ПОМЕСТИТЬ ВТИсчисленоПоЗЛпоВидамТарифа
|ИЗ
| ВТИсчисленоПоЗЛ КАК ИсчисленоПоЗЛ
| ЛЕВОЕ СОЕДИНЕНИЕ ВТИнвалиды КАК Инвалиды
| ПО ИсчисленоПоЗЛ.ФизЛицо = Инвалиды.Физлицо
| И ИсчисленоПоЗЛ.МесяцОтчетногоПериода = Инвалиды.МесяцОтчетногоПериода
| ЛЕВОЕ СОЕДИНЕНИЕ ВТВидыТарифныхСтавокОрганизаций КАК ВидыТарифныхСтавокОрганизаций
| ПО ИсчисленоПоЗЛ.МесяцОтчетногоПериода = ВидыТарифныхСтавокОрганизаций.МесяцОтчетногоПериода
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ИсчисленоПоЗЛ.ФизЛицо,
| ИсчисленоПоЗЛ.ПФРНакопительнаяЕНВДОборот,
| ИсчисленоПоЗЛ.ПФРСтраховаяЕНВДОборот,
| ИсчисленоПоЗЛ.ОтчетныйПериод,
| НАЧАЛОПЕРИОДА(ИсчисленоПоЗЛ.ОтчетныйПериод, ГОД),
| ВЫБОР
| КОГДА Инвалиды.Физлицо ЕСТЬ НЕ NULL
| ТОГДА ЗНАЧЕНИЕ(Перечисление.ТарифыСтраховыхВзносов.ОрганизацияИнвалидов)
| ИНАЧЕ ЗНАЧЕНИЕ(Перечисление.ТарифыСтраховыхВзносов.ЕНВД)
| КОНЕЦ
|ИЗ
| ВТИсчисленоПоЗЛ КАК ИсчисленоПоЗЛ
| ЛЕВОЕ СОЕДИНЕНИЕ ВТИнвалиды КАК Инвалиды
| ПО ИсчисленоПоЗЛ.ФизЛицо = Инвалиды.Физлицо
| И ИсчисленоПоЗЛ.МесяцОтчетногоПериода = Инвалиды.МесяцОтчетногоПериода
|
|ИНДЕКСИРОВАТЬ ПО
| ФизЛицо
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ИсчисленоПоЗЛ.ФизЛицо,
| СоответствиеТарифаКатегории.КатегорияЗастрахованныхЛиц,
| СУММА(ИсчисленоПоЗЛ.ПФРСтраховаяОборот) КАК ПФРСтраховая,
| СУММА(ИсчисленоПоЗЛ.ПФРНакопительнаяОборот) КАК ПФРНакопительная
|ПОМЕСТИТЬ ВТНачисленоЗаОтчетныйПериодФормирования
|ИЗ
| ВТИсчисленоПоЗЛпоВидамТарифа КАК ИсчисленоПоЗЛ
| ЛЕВОЕ СОЕДИНЕНИЕ ВТСоответствиеТарифаКатегории КАК СоответствиеТарифаКатегории
| ПО (&ОтчетныйГод МЕЖДУ СоответствиеТарифаКатегории.ГодС И СоответствиеТарифаКатегории.ГодПо)
| И ИсчисленоПоЗЛ.ВидТарифаСтраховыхВзносов = СоответствиеТарифаКатегории.ВидТарифаСтраховыхВзносов
|
|СГРУППИРОВАТЬ ПО
| СоответствиеТарифаКатегории.КатегорияЗастрахованныхЛиц,
| ИсчисленоПоЗЛ.ФизЛицо
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| РасчетыПоСтраховымВзносамОбороты.ПФРСтраховаяПриход КАК ПФРСтраховаяПриход,
| РасчетыПоСтраховымВзносамОбороты.ПФРНакопительнаяПриход КАК ПФРНакопительнаяПриход
|ПОМЕСТИТЬ ВТВсегоНачислено
|ИЗ
| РегистрНакопления.РасчетыПоСтраховымВзносам.Обороты(
| ,
| &ДатаАктуальности,
| ,
| ВидПлатежа = ЗНАЧЕНИЕ(Перечисление.ВидыПлатежейВГосБюджет.Налог)
| И Организация = &Организация
| И ОтчетныйПериодПерсучетаПФР = &ОтчетныйПериод) КАК РасчетыПоСтраховымВзносамОбороты
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| РасчетыПоСтраховымВзносамОбороты.ПФРСтраховаяРасход КАК ПФРСтраховаяРасход,
| РасчетыПоСтраховымВзносамОбороты.ПФРНакопительнаяРасход КАК ПФРНакопительнаяРасход,
| ""Уплата"" КАК ВидСтроки
|ПОМЕСТИТЬ ВТВсегоУплачено
|ИЗ
| РегистрНакопления.РасчетыПоСтраховымВзносам.Обороты(
| &ОтчетныйПериод,
| &КонецПериодаУплаты,
| Месяц,
| ВидПлатежа = ЗНАЧЕНИЕ(Перечисление.ВидыПлатежейВГосБюджет.Налог)
| И ОтчетныйПериодПерсучетаПФР >= &ДатаЗаменыЕСН
| И Организация = &Организация) КАК РасчетыПоСтраховымВзносамОбороты
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ВЫБОР
| КОГДА РасчетыПоСтраховымВзносамОстатки.ПФРСтраховаяОстаток > 0
| ТОГДА 0
| ИНАЧЕ -РасчетыПоСтраховымВзносамОстатки.ПФРСтраховаяОстаток
| КОНЕЦ,
| ВЫБОР
| КОГДА РасчетыПоСтраховымВзносамОстатки.ПФРНакопительнаяОстаток > 0
| ТОГДА 0
| ИНАЧЕ -РасчетыПоСтраховымВзносамОстатки.ПФРНакопительнаяОстаток
| КОНЕЦ,
| ""Переплата""
|ИЗ
| РегистрНакопления.РасчетыПоСтраховымВзносам.Остатки(
| &ОтчетныйПериод,
| ВидПлатежа = ЗНАЧЕНИЕ(Перечисление.ВидыПлатежейВГосБюджет.Налог)
| И ОтчетныйПериодПерсучетаПФР >= &ДатаЗаменыЕСН
| И Организация = &Организация) КАК РасчетыПоСтраховымВзносамОстатки
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.ФизЛицо,
| ВЫБОР
| КОГДА &ОтчетныйГод = ГОД(СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ОтчетныйПериод)
| ТОГДА СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.КатегорияЗастрахованныхЛиц
| КОГДА СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.КатегорияЗастрахованныхЛиц = ЗНАЧЕНИЕ(Перечисление.КатегорииЗастрахованныхЛицПФР.УСЕН)
| ТОГДА СоответствиеТарифаКатегории.КатегорияЗастрахованныхЛиц
| КОГДА СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.КатегорияЗастрахованныхЛиц = ЗНАЧЕНИЕ(Перечисление.КатегорииЗастрахованныхЛицПФР.ОЗОИ)
| ТОГДА ЗНАЧЕНИЕ(Перечисление.КатегорииЗастрахованныхЛицПФР.ООИ)
| ИНАЧЕ СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.КатегорияЗастрахованныхЛиц
| КОНЕЦ КАК КатегорияЗастрахованныхЛиц,
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.НачисленоНакопительная,
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.НачисленоСтраховая,
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.УплаченоНакопительная,
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.УплаченоСтраховая,
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ОтчетныйПериод
|ПОМЕСТИТЬ ВТПринятоУплаты
|ИЗ
| ВТПринятоВПФР КАК ПринятоВПФР
| ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПередачаСЗВ4вПФР.ПачкиДокументов КАК ПередачаСЗВ4вПФРПачкиДокументов
| ЛЕВОЕ СОЕДИНЕНИЕ Документ.СведенияОТрудовомСтажеИЗаработкеСЗВ4.РаботникиОрганизации КАК СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации
| ПО ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка
| ПО ПринятоВПФР.КомплектДокументов = ПередачаСЗВ4вПФРПачкиДокументов.Ссылка
| ЛЕВОЕ СОЕДИНЕНИЕ ВТВидыТарифныхСтавокОрганизаций КАК ТарифыСтавокОрганизации
| ЛЕВОЕ СОЕДИНЕНИЕ ВТСоответствиеТарифаКатегории КАК СоответствиеТарифаКатегории
| ПО (ГОД(ТарифыСтавокОрганизации.МесяцОтчетногоПериода) МЕЖДУ СоответствиеТарифаКатегории.ГодС И СоответствиеТарифаКатегории.ГодПо)
| И ТарифыСтавокОрганизации.ВидТарифаСтраховыхВзносов = СоответствиеТарифаКатегории.ВидТарифаСтраховыхВзносов
| ПО (&ОтчетныйПериод = ТарифыСтавокОрганизации.МесяцОтчетногоПериода)
|ГДЕ
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ТипСведенийСЗВ = ЗНАЧЕНИЕ(Перечисление.ТипыСведенийСЗВ.ИСХОДНАЯ)
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ РАЗЛИЧНЫЕ
| ПринятоУплаты.ОтчетныйПериод КАК ОтчетныйПериод,
| ВЫБОР
| КОГДА &ОтчетныйГод = ГОД(ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка.КорректируемыйПериод)
| ТОГДА ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка.КатегорияЗастрахованныхЛиц
| КОГДА ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка.КатегорияЗастрахованныхЛиц = ЗНАЧЕНИЕ(Перечисление.КатегорииЗастрахованныхЛицПФР.УСЕН)
| ТОГДА СоответствиеТарифаКатегории.КатегорияЗастрахованныхЛиц
| КОГДА ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка.КатегорияЗастрахованныхЛиц = ЗНАЧЕНИЕ(Перечисление.КатегорииЗастрахованныхЛицПФР.ОЗОИ)
| ТОГДА ЗНАЧЕНИЕ(Перечисление.КатегорииЗастрахованныхЛицПФР.ООИ)
| ИНАЧЕ ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка.КатегорияЗастрахованныхЛиц
| КОНЕЦ КАК КатегорияЗастрахованныхЛиц,
| ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка
|ПОМЕСТИТЬ ВТДокументыКорректировки
|ИЗ
| ВТПринятоУплаты КАК ПринятоУплаты
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СведенияПринятыеПФР КАК Корректировки
| ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПередачаСЗВ4вПФР.ПачкиДокументов КАК ПередачаСЗВ4вПФРПачкиДокументов
| ПО Корректировки.КомплектДокументов = ПередачаСЗВ4вПФРПачкиДокументов.Ссылка
| ПО ПринятоУплаты.ОтчетныйПериод < Корректировки.ОтчетныйПериодПерсучетаПФР
| И (&ОтчетныйПериод > Корректировки.ОтчетныйПериодПерсучетаПФР)
| И (Корректировки.Организация = &Организация)
| ЛЕВОЕ СОЕДИНЕНИЕ ВТВидыТарифныхСтавокОрганизаций КАК ТарифыСтавокОрганизации
| ЛЕВОЕ СОЕДИНЕНИЕ ВТСоответствиеТарифаКатегории КАК СоответствиеТарифаКатегории
| ПО (ГОД(ТарифыСтавокОрганизации.МесяцОтчетногоПериода) МЕЖДУ СоответствиеТарифаКатегории.ГодС И СоответствиеТарифаКатегории.ГодПо)
| И ТарифыСтавокОрганизации.ВидТарифаСтраховыхВзносов = СоответствиеТарифаКатегории.ВидТарифаСтраховыхВзносов
| ПО (&ОтчетныйПериод = ТарифыСтавокОрганизации.МесяцОтчетногоПериода)
|ГДЕ
| ПередачаСЗВ4вПФРПачкиДокументов.ДокументПачка.ТипСведенийСЗВ В (ЗНАЧЕНИЕ(Перечисление.ТипыСведенийСЗВ.ОТМЕНЯЮЩАЯ), ЗНАЧЕНИЕ(Перечисление.ТипыСведенийСЗВ.КОРРЕКТИРУЮЩАЯ))
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ОписаниеДокумента.ОтчетныйПериод,
| ОписаниеДокумента.ФизЛицо,
| ОписаниеДокумента.КатегорияЗастрахованныхЛиц,
| ВЫБОР
| КОГДА СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ТипСведенийСЗВ = ЗНАЧЕНИЕ(Перечисление.ТипыСведенийСЗВ.ОТМЕНЯЮЩАЯ)
| ТОГДА 0
| ИНАЧЕ СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.УплаченоСтраховая
| КОНЕЦ КАК УплаченоСтраховая,
| ВЫБОР
| КОГДА СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ТипСведенийСЗВ = ЗНАЧЕНИЕ(Перечисление.ТипыСведенийСЗВ.ОТМЕНЯЮЩАЯ)
| ТОГДА 0
| ИНАЧЕ СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.УплаченоНакопительная
| КОНЕЦ КАК УплаченоНакопительная,
| ВЫБОР
| КОГДА СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ТипСведенийСЗВ = ЗНАЧЕНИЕ(Перечисление.ТипыСведенийСЗВ.ОТМЕНЯЮЩАЯ)
| ТОГДА 0
| ИНАЧЕ СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.НачисленоСтраховая
| КОНЕЦ КАК НачисленоСтраховая,
| ВЫБОР
| КОГДА СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ТипСведенийСЗВ = ЗНАЧЕНИЕ(Перечисление.ТипыСведенийСЗВ.ОТМЕНЯЮЩАЯ)
| ТОГДА 0
| ИНАЧЕ СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.НачисленоНакопительная
| КОНЕЦ КАК НачисленоНакопительная
|ПОМЕСТИТЬ ВТКорректировкиПринятыеПФР
|ИЗ
| (ВЫБРАТЬ
| ПринятоУплаты.ОтчетныйПериод КАК ОтчетныйПериод,
| ПринятоУплаты.ФизЛицо КАК ФизЛицо,
| МАКСИМУМ(СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ОтчетныйПериод) КАК ОтчетныйПериодКорректировки,
| ПринятоУплаты.КатегорияЗастрахованныхЛиц КАК КатегорияЗастрахованныхЛиц
| ИЗ
| ВТПринятоУплаты КАК ПринятоУплаты
| ЛЕВОЕ СОЕДИНЕНИЕ ВТДокументыКорректировки КАК Корректировки
| ПО ПринятоУплаты.ОтчетныйПериод = Корректировки.ОтчетныйПериод
| И ПринятоУплаты.КатегорияЗастрахованныхЛиц = Корректировки.КатегорияЗастрахованныхЛиц
| ЛЕВОЕ СОЕДИНЕНИЕ Документ.СведенияОТрудовомСтажеИЗаработкеСЗВ4.РаботникиОрганизации КАК СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации
| ПО ПринятоУплаты.ОтчетныйПериод = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.КорректируемыйПериод
| И ПринятоУплаты.ФизЛицо = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.ФизЛицо
| И (Корректировки.ДокументПачка = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка)
| ГДЕ
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.ФизЛицо ЕСТЬ НЕ NULL
|
| СГРУППИРОВАТЬ ПО
| ПринятоУплаты.ОтчетныйПериод,
| ПринятоУплаты.ФизЛицо,
| ПринятоУплаты.КатегорияЗастрахованныхЛиц) КАК ОписаниеДокумента
| ЛЕВОЕ СОЕДИНЕНИЕ ВТДокументыКорректировки КАК Корректировки
| ПО ОписаниеДокумента.ОтчетныйПериод = Корректировки.ОтчетныйПериод
| И ОписаниеДокумента.КатегорияЗастрахованныхЛиц = Корректировки.КатегорияЗастрахованныхЛиц
| ЛЕВОЕ СОЕДИНЕНИЕ Документ.СведенияОТрудовомСтажеИЗаработкеСЗВ4.РаботникиОрганизации КАК СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации
| ПО ОписаниеДокумента.ОтчетныйПериод = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.КорректируемыйПериод
| И ОписаниеДокумента.ФизЛицо = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.ФизЛицо
| И ОписаниеДокумента.ОтчетныйПериодКорректировки = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка.ОтчетныйПериод
| И (Корректировки.ДокументПачка = СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.Ссылка)
|ГДЕ
| СведенияОТрудовомСтажеИЗаработкеСЗВ4РаботникиОрганизации.ФизЛицо ЕСТЬ НЕ NULL
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ПринятоУплаты.ФизЛицо,
| ПринятоУплаты.КатегорияЗастрахованныхЛиц,
| СУММА(ЕСТЬNULL(КорректировкиПринятыеПФР.УплаченоНакопительная, ПринятоУплаты.УплаченоНакопительная)) КАК УплаченоНакопительная,
| СУММА(ЕСТЬNULL(КорректировкиПринятыеПФР.УплаченоСтраховая, ПринятоУплаты.УплаченоСтраховая)) КАК УплаченоСтраховая,
| СУММА(ЕСТЬNULL(КорректировкиПринятыеПФР.НачисленоНакопительная, ПринятоУплаты.НачисленоНакопительная)) КАК НачисленоНакопительная,
| СУММА(ЕСТЬNULL(КорректировкиПринятыеПФР.НачисленоСтраховая, ПринятоУплаты.НачисленоСтраховая)) КАК НачисленоСтраховая
|ПОМЕСТИТЬ ВТУплатыПринятыеПФР
|ИЗ
| ВТПринятоУплаты КАК ПринятоУплаты
| ЛЕВОЕ СОЕДИНЕНИЕ ВТКорректировкиПринятыеПФР КАК КорректировкиПринятыеПФР
| ПО ПринятоУплаты.ФизЛицо = КорректировкиПринятыеПФР.ФизЛицо
| И ПринятоУплаты.ОтчетныйПериод = КорректировкиПринятыеПФР.ОтчетныйПериод
| И ПринятоУплаты.КатегорияЗастрахованныхЛиц = КорректировкиПринятыеПФР.КатегорияЗастрахованныхЛиц
|
|СГРУППИРОВАТЬ ПО
| ПринятоУплаты.ФизЛицо,
| ПринятоУплаты.КатегорияЗастрахованныхЛиц
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| УплатыПринятыеПФР.ФизЛицо
|ПОМЕСТИТЬ ВТФизлицаСПереплатой
|ИЗ
| ВТУплатыПринятыеПФР КАК УплатыПринятыеПФР
|
|СГРУППИРОВАТЬ ПО
| УплатыПринятыеПФР.ФизЛицо
|
|ИМЕЮЩИЕ
| (СУММА(УплатыПринятыеПФР.НачисленоНакопительная) < СУММА(УплатыПринятыеПФР.УплаченоНакопительная)
| ИЛИ СУММА(УплатыПринятыеПФР.НачисленоСтраховая) < СУММА(УплатыПринятыеПФР.УплаченоСтраховая))
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| УплатыПринятыеПФР.ФизЛицо,
| УплатыПринятыеПФР.КатегорияЗастрахованныхЛиц,
| УплатыПринятыеПФР.НачисленоНакопительная - УплатыПринятыеПФР.УплаченоНакопительная КАК Накопительная,
| УплатыПринятыеПФР.НачисленоСтраховая - УплатыПринятыеПФР.УплаченоСтраховая КАК Страховая
|ПОМЕСТИТЬ ВТНедоуплаченоЗаПрошлыеПериоды
|ИЗ
| ВТУплатыПринятыеПФР КАК УплатыПринятыеПФР
|ГДЕ
| (НЕ УплатыПринятыеПФР.ФизЛицо В
| (ВЫБРАТЬ
| ФизЛица.ФизЛицо
| ИЗ
| ВТФизлицаСПереплатой КАК ФизЛица))
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) КАК Накопительная,
| ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) КАК Страховая,
| ЕСТЬNULL(ВсегоНачислено.ПФРСтраховаяПриход, 0) КАК ПФРСтраховаяПриход,
| ЕСТЬNULL(ВсегоНачислено.ПФРНакопительнаяПриход, 0) КАК ПФРНакопительнаяПриход,
| ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0) КАК ПФРСтраховаяРасход,
| ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0) КАК ПФРНакопительнаяРасход,
| ВЫБОР
| КОГДА ЕСТЬNULL(ВсегоНачислено.ПФРСтраховаяПриход, 0) = 0
| ТОГДА 0
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) > ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0)
| ТОГДА 0
| КОГДА ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0) - ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) > ЕСТЬNULL(ВсегоНачислено.ПФРСтраховаяПриход, 0)
| ТОГДА 100000
| ИНАЧЕ ВЫРАЗИТЬ((ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0) - ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0)) * 100000 / (ВЫРАЗИТЬ(ЕСТЬNULL(ВсегоНачислено.ПФРСтраховаяПриход, 0) КАК ЧИСЛО(25, 6))) КАК ЧИСЛО(20, 6))
| КОНЕЦ КАК КоэффициентТекущегоПериодаСтраховая,
| ВЫБОР
| КОГДА ЕСТЬNULL(ВсегоНачислено.ПФРНакопительнаяПриход, 0) = 0
| ТОГДА 0
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) > ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0)
| ТОГДА 0
| КОГДА ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0) - ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) > ЕСТЬNULL(ВсегоНачислено.ПФРНакопительнаяПриход, 0)
| ТОГДА 100000
| ИНАЧЕ ВЫРАЗИТЬ((ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0) - ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0)) * 100000 / (ВЫРАЗИТЬ(ЕСТЬNULL(ВсегоНачислено.ПФРНакопительнаяПриход, 0) КАК ЧИСЛО(25, 6))) КАК ЧИСЛО(20, 6))
| КОНЕЦ КАК КоэффициентТекущегоПериодаНакопительная,
| ВЫБОР
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) = 0
| ТОГДА 0
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) < ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0)
| ТОГДА 100000
| ИНАЧЕ ВЫРАЗИТЬ(ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0) * 100000 / (ВЫРАЗИТЬ(ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) КАК ЧИСЛО(25, 6))) КАК ЧИСЛО(20, 6))
| КОНЕЦ КАК КоэффициентПрошлыхПериодовСтраховая,
| ВЫБОР
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) = 0
| ТОГДА 0
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) < ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0)
| ТОГДА 100000
| ИНАЧЕ ВЫРАЗИТЬ(ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0) * 100000 / (ВЫРАЗИТЬ(ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) КАК ЧИСЛО(25, 6))) КАК ЧИСЛО(20, 6))
| КОНЕЦ КАК КоэффициентПрошлыхПериодовНакопительная,
| ВЫБОР
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) + ЕСТЬNULL(ВсегоНачислено.ПФРСтраховаяПриход, 0) > ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0)
| ТОГДА ЕСТЬNULL(ВсегоУплачено.ПФРСтраховаяРасход, 0)
| ИНАЧЕ ЕСТЬNULL(ПрошлыеПериоды.Страховая, 0) + ЕСТЬNULL(ВсегоНачислено.ПФРСтраховаяПриход, 0)
| КОНЕЦ КАК УчтеноУплатыСтраховая,
| ВЫБОР
| КОГДА ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) + ЕСТЬNULL(ВсегоНачислено.ПФРНакопительнаяПриход, 0) > ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0)
| ТОГДА ЕСТЬNULL(ВсегоУплачено.ПФРНакопительнаяРасход, 0)
| ИНАЧЕ ЕСТЬNULL(ПрошлыеПериоды.Накопительная, 0) + ЕСТЬNULL(ВсегоНачислено.ПФРНакопительнаяПриход, 0)
| КОНЕЦ КАК УчтеноУплатыНакопительная
|ПОМЕСТИТЬ ВТКоэффициентыУплаты
|ИЗ
| (ВЫБРАТЬ
| 1 КАК Поле) КАК СтрокаЗапроса
| ЛЕВОЕ СОЕДИНЕНИЕ ВТВсегоНачислено КАК ВсегоНачислено
| ПО (ИСТИНА)
| ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
| СУММА(ВсегоУплачено.ПФРСтраховаяРасход) КАК ПФРСтраховаяРасход,
| СУММА(ВсегоУплачено.ПФРНакопительнаяРасход) КАК ПФРНакопительнаяРасход
| ИЗ
| ВТВсегоУплачено КАК ВсегоУплачено) КАК ВсегоУплачено
| ПО (ИСТИНА)
| ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
| СУММА(НедоуплаченоЗаПрошлыеПериоды.Накопительная) КАК Накопительная,
| СУММА(НедоуплаченоЗаПрошлыеПериоды.Страховая) КАК Страховая
| ИЗ
| ВТНедоуплаченоЗаПрошлыеПериоды КАК НедоуплаченоЗаПрошлыеПериоды) КАК ПрошлыеПериоды
| ПО (ИСТИНА)
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| НедоуплаченоЗаПрошлыеПериоды.ФизЛицо КАК ФизЛицо,
| НедоуплаченоЗаПрошлыеПериоды.КатегорияЗастрахованныхЛиц КАК КатегорияЗастрахованныхЛиц,
| НедоуплаченоЗаПрошлыеПериоды.Накопительная * КоэффициентыУплаты.КоэффициентПрошлыхПериодовНакопительная / 100000 КАК УплаченоНакопительная,
| НедоуплаченоЗаПрошлыеПериоды.Страховая * КоэффициентыУплаты.КоэффициентПрошлыхПериодовСтраховая / 100000 КАК УплаченоСтраховая,
| 0 КАК НачисленоСтраховая,
| 0 КАК НачисленоНакопительная,
| ""Прошлые периоды"" КАК ВидСтроки
|ПОМЕСТИТЬ ВТРасчетСумм
|ИЗ
| ВТНедоуплаченоЗаПрошлыеПериоды КАК НедоуплаченоЗаПрошлыеПериоды
| ЛЕВОЕ СОЕДИНЕНИЕ ВТКоэффициентыУплаты КАК КоэффициентыУплаты
| ПО (ИСТИНА)
|ГДЕ
| (НедоуплаченоЗаПрошлыеПериоды.Накопительная <> 0
| ИЛИ НедоуплаченоЗаПрошлыеПериоды.Страховая <> 0)
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| НачисленоПоЗЛ.ФизЛицо,
| НачисленоПоЗЛ.КатегорияЗастрахованныхЛиц,
| НачисленоПоЗЛ.ПФРНакопительная * КоэффициентыУплаты.КоэффициентТекущегоПериодаНакопительная / 100000,
| НачисленоПоЗЛ.ПФРСтраховая * КоэффициентыУплаты.КоэффициентТекущегоПериодаСтраховая / 100000,
| НачисленоПоЗЛ.ПФРСтраховая,
| НачисленоПоЗЛ.ПФРНакопительная,
| ""Текущий период""
|ИЗ
| ВТНачисленоЗаОтчетныйПериодФормирования КАК НачисленоПоЗЛ
| ЛЕВОЕ СОЕДИНЕНИЕ ВТКоэффициентыУплаты КАК КоэффициентыУплаты
| ПО (ИСТИНА)
|ГДЕ
| (НачисленоПоЗЛ.ПФРНакопительная <> 0
| ИЛИ НачисленоПоЗЛ.ПФРСтраховая <> 0)
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| Уплачено.УчтеноУплатыСтраховая КАК Страховая,
| Уплачено.УчтеноУплатыНакопительная КАК Накопительная
|ИЗ
| ВТКоэффициентыУплаты КАК Уплачено
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ЕСТЬNULL(СУММА(ВЫРАЗИТЬ(РасчетныеДанные.УплаченоСтраховая КАК ЧИСЛО(15, 2))),0) КАК Страховая,
| ЕСТЬNULL(СУММА(ВЫРАЗИТЬ(РасчетныеДанные.УплаченоНакопительная КАК ЧИСЛО(15, 2))),0) КАК Накопительная
|ИЗ
| ВТРасчетСумм КАК РасчетныеДанные
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| РасчетныеДанные.ФизЛицо КАК ФизЛицо,
| РасчетныеДанные.КатегорияЗастрахованныхЛиц КАК КатегорияЗастрахованныхЛиц,
| СУММА(РасчетныеДанные.УплаченоНакопительная) КАК УплаченоНакопительная,
| СУММА(РасчетныеДанные.УплаченоСтраховая) КАК УплаченоСтраховая,
| СУММА(РасчетныеДанные.НачисленоСтраховая) КАК НачисленоСтраховая,
| СУММА(РасчетныеДанные.НачисленоНакопительная) КАК НачисленоНакопительная
|ИЗ
| ВТРасчетСумм КАК РасчетныеДанные
|
|СГРУППИРОВАТЬ ПО
| РасчетныеДанные.ФизЛицо,
| РасчетныеДанные.КатегорияЗастрахованныхЛиц
|
|ИМЕЮЩИЕ
| (СУММА(РасчетныеДанные.УплаченоНакопительная) <> 0
| ИЛИ СУММА(РасчетныеДанные.УплаченоСтраховая) <> 0
| ИЛИ СУММА(РасчетныеДанные.НачисленоСтраховая) <> 0
| ИЛИ СУММА(РасчетныеДанные.НачисленоНакопительная) <> 0)
|
|УПОРЯДОЧИТЬ ПО
| ФизЛицо,
| КатегорияЗастрахованныхЛиц";
Запрос.Текст = СтрЗаменить(Запрос.Текст,"РегистрСведений.УчетнаяПолитикаНалоговыйУчет", ЗаполнениеРегламентированнойОтчетностиПереопределяемый.ИмяУчетнойПолитики());
