Основы компьютерной графики (Часть 2)

03.08.18

Разработка - Математика и алгоритмы

Статья является продолжением публикации "Основы компьютерной графики". Во второй части будут рассмотрены следующие темы: 1. Преобразования в трехмерном пространстве. 2. Ортографическая проекция трехмерного изображения на экран. 3. Определение, какой поверхностью (лицевой/задней) проецируется грань на экран. 4. Перспективная проекция.

Скачать файлы

Наименование Файл Версия Размер
Пример работы с 3Д графикой
.epf 9,58Kb
8
.epf 1.1.2 9,58Kb 8 Скачать

Основы компьютерной графики (часть 2)

Выводы из первой части

Во второй части мы будем использовать весь накопленный опыт первой части. Перечислим итоги первой части статьи:

  1. Выполнять операции преобразования можно с помощью умножения специально заполненных матриц 3х3.
  2. С помощью матриц 3х3 можно накапливать результаты операций преобразований.
  3. Используя несколько матриц, можно организовать вставку преобразования в любое место цепочки преобразований.

Переходим к 3D

На этом моменте многих ждет разочарование. Расчет координат в 3-м мерном пространстве не сильно отличается, от расчета координат в 2-мерном пространстве.
Матрица точки теперь выглядит так (x,y,z,1)
Матрица перемещения

Матрица масштабирования

где  X,Y,Z – коэффициенты масштабирования по соответствующим координатам

С вращением немного сложнее, ключевое слово «немного».  Для начала определим как расположены оси координат. Центр координат расположен в центре экрана (отображаемой области). Ось X – направлена вправо, ось Y – направлена вверх, ось Z – направлена перпендикулярно плоскости монитора в даль, в геометрии обычно обозначают «х» - хвост стрелы.
Надеюсь, многие поняли, что в первой части вы выполняли вращение в плоскости Y0X вокруг оси Z, т.е. у нас уже есть готовая матрица поворота вокруг оси Z.

Матрицы поворота вокруг осей X,Y выводятся подобным образом.
Матрица поворота вокруг оси X

Матрица поворота вокруг оси Y

Программный код для вычисления координат в 3-мерном пространстве не многим отличается от кода для 2-мерного пространства.

Ортографическая проекция

Координаты вычислили, но монитор плоский, маловероятно, но возможно, у кого-то и не плоский, но экран все равно плоский.  Как выводить 3-х мерное изображение на плоский экран?
Мы будем проецировать изображение на (плоскость Y0X). Для начала мы построим ортографическую проекцию – координаты x, y не будут изменятся в зависимости от координаты z. Такие проекции строят, как правило, САПР (системы автоматизированного проектирования), где важно сохранение пропорций и размеров, а не реалистичность.

Теперь у нас уже не квадрат а куб. Точек стало больше, отрезки превратились в ребра, и стало их соответственно тоже больше.

&НаКлиенте
Процедура Инициализация()
	Куб = Новый Структура("Матрицы,Ребра,Точки,Владелец");
	
	Куб.Владелец = Неопределено;
	
	Точки = Новый Массив();
	Точки.Добавить(ПолучитьТочку(-10, -10, -10));
	Точки.Добавить(ПолучитьТочку(-10, 10, -10));
	Точки.Добавить(ПолучитьТочку(10, 10, -10));
	Точки.Добавить(ПолучитьТочку(10, -10, -10));
	
	Точки.Добавить(ПолучитьТочку(-10, -10, 10));
	Точки.Добавить(ПолучитьТочку(-10, 10, 10));
	Точки.Добавить(ПолучитьТочку(10, 10, 10));
	Точки.Добавить(ПолучитьТочку(10, -10, 10));
	
	Куб.Точки = Точки;
	
	Ребра = Новый Массив();
	Ребра.Добавить(ПолучитьРебро(0,1));
	Ребра.Добавить(ПолучитьРебро(1,2));
	Ребра.Добавить(ПолучитьРебро(2,3));
	Ребра.Добавить(ПолучитьРебро(3,0));
	
	Ребра.Добавить(ПолучитьРебро(4,5));
	Ребра.Добавить(ПолучитьРебро(5,6));
	Ребра.Добавить(ПолучитьРебро(6,7));
	Ребра.Добавить(ПолучитьРебро(7,4));
	
	Ребра.Добавить(ПолучитьРебро(0,4));
	Ребра.Добавить(ПолучитьРебро(1,5));
	Ребра.Добавить(ПолучитьРебро(2,6));
	Ребра.Добавить(ПолучитьРебро(3,7));
	
	Куб.Ребра = Ребра;
	
	М = ПолучитьЕдиничнуюМатрицу4х4();
	М[0][0] = 3;
	М[1][1] = 3;
	М[2][2] = 3;
	
	М[3][2] = 20;	
	
	Куб.Матрицы = Новый Массив();
	Куб.Матрицы.Добавить(М);
	
	ВывестиОбъект(Куб);
КонецПроцедуры

Все преобразования выполняются схожим образом.

&НаКлиенте
Функция ПолучитьМатрицуПоворотаZ(Угол)
	М = ПолучитьЕдиничнуюМатрицу4х4();
	
	Pi = 3.1415926535897932;
	УголРадианы = Угол / 180 * Pi;
	Косинус = Cos(УголРадианы);
	Синус = Sin(УголРадианы);
	
	М[0][0] = Косинус;
	М[0][1] = -Синус;
	М[1][0] = Синус;
	М[1][1] = Косинус;

	Возврат М;
	
КонецФункции


&НаКлиенте
Процедура КомандаПоворотZ(Команда)
	// Вставить содержимое обработчика.
	М = ПолучитьМатрицуПоворотаZ(УголПоворота);
	
	Если МестоВставки = 0 Тогда
		УмножитьМатрицы4х4(М, Куб.Матрицы[0]);
		Куб.Матрицы[0] = М;		
	Иначе
		УмножитьМатрицы4х4(Куб.Матрицы[0], М);
	КонецЕсли;
	
	ВывестиОбъект(Куб);
	
КонецПроцедуры

Получение координат после всех преобразований:

&НаКлиенте
Функция ПолучитьМатрицуПреобразований(Объект)
	М = ПолучитьЕдиничнуюМатрицу4х4();
	
	Для Каждого Матрица Из Объект.Матрицы Цикл
		УмножитьМатрицы4х4(М, Матрица);		
	КонецЦикла;
	
	Если Объект.Владелец <> Неопределено Тогда
		Для Каждого Матрица Из Объект.Владелец.Матрицы Цикл
			УмножитьМатрицы4х4(М, Матрица);		
		КонецЦикла;		
	КонецЕсли;
	
	Возврат М;
КонецФункции

&НаКлиенте
Функция ПолучитьКоордиантыТочек(Объект, МатрицаПреобразований)
	рТочки = Новый Массив();
	
	Для Каждого Точка Из Объект.Точки Цикл
		рТочка = Новый Массив(4);
		рТочка[0] = Точка[0] * МатрицаПреобразований[0][0] + Точка[1] * МатрицаПреобразований[1][0] + Точка[2] * МатрицаПреобразований[2][0] + Точка[3] * МатрицаПреобразований[3][0];
		рТочка[1] = Точка[0] * МатрицаПреобразований[0][1] + Точка[1] * МатрицаПреобразований[1][1] + Точка[2] * МатрицаПреобразований[2][1] + Точка[3] * МатрицаПреобразований[3][1];
		рТочка[2] = Точка[0] * МатрицаПреобразований[0][2] + Точка[1] * МатрицаПреобразований[1][2] + Точка[2] * МатрицаПреобразований[2][2] + Точка[3] * МатрицаПреобразований[3][2];
		рТочка[3] = Точка[0] * МатрицаПреобразований[0][2] + Точка[1] * МатрицаПреобразований[1][2] + Точка[2] * МатрицаПреобразований[2][2] + Точка[3] * МатрицаПреобразований[3][3];
			
		рТочка[0] = рТочка[0] + 80;
		рТочка[1] = -рТочка[1] + 80;
		
		рТочки.Добавить(рТочка);		
	КонецЦикла;
	
	Возврат рТочки;
	
КонецФункции

&НаКлиенте
Процедура ОбновитьКоординатыРебер(Объект, Точки)
	Для Каждого Ребро Из Объект.Ребра Цикл
		Линия = Ребро[0];
		Точка1 = Точки[Ребро[1]];
		Точка2 = Точки[Ребро[2]];
		
		Линия.Лево = Точка1[0];
		Линия.Верх = Точка1[1];
		Линия.Ширина = Точка2[0] - Точка1[0];
		Линия.Высота = Точка2[1] - Точка1[1];		
	КонецЦикла;
КонецПроцедуры

Результат выглядит так.

Выделение невидимых граней куба

На предыдущем скриншоте у нас получился каркас куба. У проекции куба не все грани должны отображаться. Как определить должна отображаться грань либо нет?
У грани есть две поверхности лицевая и задняя. Если грань повернута в экран лицевой поверхностью, значит её нужно отображать, иначе нет.

Для определения какой поверхностью грань повернута к экрану, воспользуемся следующим свойством:
Векторное произведение двух векторов
 в трехмерном евклидовом пространстве - вектор, перпендикулярный обоим исходным векторам. В нашем случае перпендикулярный грани. Координата Z как раз показывает в экран направлен вектор, либо наоборот.

Произведение векторов находится следующим образом:

Нас интересует только составляющая вектора z, которая у нас получилась равна axbyaybx .

Теперь у нашего куба появились грани, которые состоят из точек и ребер. Для грани важен порядок точек, я указал по порядку, в направлении хода часовой стрелки.

&НаКлиенте
Процедура Инициализация()
	Куб = Новый Структура("Матрицы,Ребра,Точки,Владелец,Грани");
	
	Куб.Грани = Новый Массив();
	Куб.Грани.Добавить(ПолучитьГрань(0,1,2,3,0,1,2,3));
	Куб.Грани.Добавить(ПолучитьГрань(1,5,6,2,9,5,10,1));
	Куб.Грани.Добавить(ПолучитьГрань(3,2,6,7,2,10,6,11));
	Куб.Грани.Добавить(ПолучитьГрань(0,3,7,4,3,11,2,8));
	Куб.Грани.Добавить(ПолучитьГрань(0,4,5,1,8,4,9,0));
	Куб.Грани.Добавить(ПолучитьГрань(4,7,6,5,7,6,5,1));	
	
КонецПроцедуры

&НаКлиенте
Функция ПолучитьГрань(Т0,Т1,Т2,Т3,Р0,Р1,Р2,Р3)
	Грань = Новый Структура("Точки,Ребра");
	Грань.Точки = Новый Массив(4);
	Грань.Точки[0] = Т0;
	Грань.Точки[1] = Т1;
	Грань.Точки[2] = Т2;
	Грань.Точки[3] = Т3;
	
	Грань.Ребра = Новый Массив(4);
	Грань.Ребра[0] = Р0;
	Грань.Ребра[1] = Р1;
	Грань.Ребра[2] = Р2;
	Грань.Ребра[3] = Р3;
	
	Возврат Грань;
КонецФункции

С наименованиями свойств я особо не заморачивался, и уже в таком небольшом коде, можно запутаться, иногда точки - это координаты точек, а иногда индексы точек, тоже самое и с ребрами.

Возможно кому-то кажется, что было бы изящнее вместо куба взять более интересный объект, например, сделать объемную запись 1С. Во-первых на кубе - объяснять проще, а во-вторых - я уже даже на кубе запутался сам с ребрами, где-то в грани указал неправильный индекс ребра.

Изначально я хотел невидимые ребра выводить пунктирной линией, а видимые сплошной, но реализовать это оказалось не просто, т.к. свойство «тип линии», оказалось, доступным только для чтения. Остановился на том что видимые ребра – синие, невидимые – зеленные.

Добавляем определение видимости граней в код.

&НаКлиенте
Процедура ВывестиОбъект(Объект)
	МатрицаПреобразований = ПолучитьМатрицуПреобразований(Объект);
	Точки = ПолучитьКоордиантыТочек(Объект, МатрицаПреобразований);
	ОбновитьКоординатыРебер(Объект, Точки);
	
	ОпределитьВидимостьГраней(Объект, Точки);
	
КонецПроцедуры

Реализация

&НаКлиенте
Процедура ОпределитьВидимостьГраней(Объект, Точки)
	Для Каждого Ребро Из Объект.Ребра Цикл
		Линия = Ребро[0];
		Линия.ЦветЛинии = Новый Цвет(0,150,0);
	КонецЦикла;
	
	Для Каждого Грань Из Объект.Грани Цикл
		Точка0 = Точки[Грань.Точки[0]];
		Точка1 = Точки[Грань.Точки[1]];
		Точка2 = Точки[Грань.Точки[2]];
		
		Ах = Точка1[0] - Точка0[0];
		Ау = Точка1[1] - Точка0[1];
		
		Вх = Точка2[0] - Точка1[0];
		Ву = Точка2[1] - Точка1[1];
		
		Z = Ах * Ву - Ау * Вх;
		
		//Сообщить(Z);
		
		Если Z < 0 Тогда
			Для Каждого ИндексРебра Из Грань.Ребра Цикл
				Линия = Объект.Ребра[ИндексРебра][0];	
				Линия.ЦветЛинии = Новый Цвет(0,0,150);
			КонецЦикла;			
		КонецЕсли;
		
	КонецЦикла
	
КонецПроцедуры

Результат.

Не сразу понятно, что куб наклонен вниз.

Перспективная проекция

Добавим еще реалистичности нашему изображения. На зрачок человеческого глаза попадает, конечно, не ортографическая проекция, а перспективная. Добиться настоящей реалистичности очень сложно, тут очень много факторов: у человека два глаза, зрачок умеет фокусироваться, изменять чувствительность к яркости, кроме того полученное изображение обрабатывается мозгом. Когда мы смотрим, допустим, на ламинат с близкого расстояния, мы видим параллельные прямые, хотя они, вроде должны быть не параллельными в перспективной проекции. Я позволил себе небольшое отступление, вернемся к перспективной проекции.

Перспективу можно описать следующим образом – чем дальше объект, тем он меньше. Насколько объект удален от нас, зависит от координаты Z. Соответственно при удалении координаты x,y будут смещаться в центр, т.е. уменьшаться.
Вычислять новые координаты будем по следующие формуле:
x’ = x * F / (F + z)
где F – фокусное расстояние.

&НаКлиенте
Функция ПолучитьКоордиантыТочек(Объект, МатрицаПреобразований)
	рТочки = Новый Массив();
	
	Для Каждого Точка Из Объект.Точки Цикл
		рТочка = Новый Массив(4);
		рТочка[0] = Точка[0] * МатрицаПреобразований[0][0] + Точка[1] * МатрицаПреобразований[1][0] + Точка[2] * МатрицаПреобразований[2][0] + Точка[3] * МатрицаПреобразований[3][0];
		рТочка[1] = Точка[0] * МатрицаПреобразований[0][1] + Точка[1] * МатрицаПреобразований[1][1] + Точка[2] * МатрицаПреобразований[2][1] + Точка[3] * МатрицаПреобразований[3][1];
		рТочка[2] = Точка[0] * МатрицаПреобразований[0][2] + Точка[1] * МатрицаПреобразований[1][2] + Точка[2] * МатрицаПреобразований[2][2] + Точка[3] * МатрицаПреобразований[3][2];
		рТочка[3] = Точка[0] * МатрицаПреобразований[0][2] + Точка[1] * МатрицаПреобразований[1][2] + Точка[2] * МатрицаПреобразований[2][2] + Точка[3] * МатрицаПреобразований[3][3];
			
		рТочка[2] = рТочка[2] + 40;		
		
		//УголОбзора = 90;
		//рТочка[0] = рТочка[0] * УголОбзора/рТочка[2] + 80;
		//рТочка[1] = рТочка[1] * УголОбзора/рТочка[2] + 80;
		
		ФокусноеРасстояние = 80;
		рТочка[0] = рТочка[0] * ФокусноеРасстояние / (ФокусноеРасстояние + рТочка[2]) + 80;
		рТочка[1] = рТочка[1] * ФокусноеРасстояние / (ФокусноеРасстояние + рТочка[2]) + 80;
		
				
		рТочки.Добавить(рТочка);		
	КонецЦикла;
	
	Возврат рТочки;
	
КонецФункции

Куб в начальной позиции.

Добавим преобразования поворот вокруг осей

Обработка тестировалась на программных файлах 1С:Предприятие 8.3 (8.3.12.1529), подключение - тонкий клиент.

 

Графика Проекции

См. также

Богатый редактор картинок, хранимых в базе, с возможностью РИСОВАНИЯ. Редактор внешних файлов картинок. Объект, расширяющий возможности работы с картинками из встроенного языка (Три в одном) + Обработка «Стандартизация картинок»

Работа с интерфейсом Рабочее место Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Обработка предназначена для редактирования картинок в режиме «Предприятие», с возможностью РИСОВАТЬ на них. Поддерживается работа как в обычных формах (толстый клиент) так и на управляемых формах (тонкий клиент). Обработка позволяет редактировать как картинки, хранимые в базе, так и графические файлы с диска на файловой системе. Помимо базовых функций (изменение размеров, преобразование формата, обрезание картинки, повороты и т.п.) – редактор имеет богатый набор инструментов для рисования. Доступна функция вставки изображения из буфера обмена. Также обработка может быть использована из встроенного языка как объект для редактирования картинок. Объект может быть использован: на стороне клиента, на стороне сервера, из внешнего соединения. Данная обработка будет особенно полезна тем, кто вносит картинки в базу (изображения номенклатуры, фотографии физических лиц и т.п.). Функционал реализуется с использованием JavaScript и бесплатного ПО ImageMagick (без использования внешних компонент).

6000 руб.

16.01.2015    61800    43    59    

80

[Расширения] Динамическое управление видимостью и доступностью элементов форм (УФ) (8.3.6+)

Работа с интерфейсом Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Механизм «Динамическое управление доступом к элементам форм объектов 1С8» предназначен для обеспечения возможности оперативного управления видимостью и доступностью элементов форм документов и справочников продуктов фирмы «1С» «1С:Предприятие 8». Решение универсальное, встраивается в любую конфигурацию с минимальными доработками, что позволяет без проблем обновлять типовые решения.

5000 руб.

14.01.2016    54407    16    21    

42

Управление дашбордами

Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Обработка предназначена для создания и управления дашбордами.

2400 руб.

29.06.2020    16700    21    4    

35

Модель состояния для MVC

Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

"MVC плохо применима в 1С" - познакомьтесь с моделью состояния и, возможно, ваше мнение поменяется! Представленное решение является эволюционным развитием идеи реализации MVC для 1С. В новой версии добавлены DSL для описания модели состояния, а также параметризация свойств параметров и элементов формы.

1 стартмани

05.07.2022    3669    kalyaka    2    

27

Табло очереди заказов на экран телевизора

WEB-интеграция Работа с интерфейсом Платформа 1С v8.3 1С:Розница 2 Платные (руб)

Связка из веб-приложения и расширения для 1С: Розница 2.3.

3600 руб.

29.04.2022    12085    1    5    

10

Условное оформление элементов форм в пользовательском режиме 1С (управление видимостью и доступностью элементов форм)

Работа с интерфейсом Платформа 1С v8.3 Платные (руб)

Подсистема условного оформления элементов форм (далее подсистема) предназначена для настройки оформления элементов форм (видимость, доступность, цвет фона, цвет текста и прочее) в пользовательском режиме 1С. Также подсистему возможно использовать для ограничения доступа к реквизитам формы для определенных пользователей (или групп пользователей).

6000 руб.

18.01.2022    8810    1    2    

6
Отзывы
3. Dmitri_1C 186 03.08.18 23:56 Сейчас в теме
Помню, NN-лет назад такое на паскале рисовал.
Ностальгия.
+
Остальные комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. WalterMort 241 03.08.18 15:45 Сейчас в теме
Где матрицы перспективного проецирования? Где шарнирный замок? Где кватернионы?
2. mszsuz 323 03.08.18 23:46 Сейчас в теме
так скоро и "DOOM" получится - первую комнату уже нарисовали.
3. Dmitri_1C 186 03.08.18 23:56 Сейчас в теме
Помню, NN-лет назад такое на паскале рисовал.
Ностальгия.
+
4. HAMMER_59 244 04.08.18 16:26 Сейчас в теме
Как я уже написал в статье, при добавление граней, запутался с ребрами. Изменил код добавления граней, грань теперь добавляется по точкам, ребра добавляются автоматически.
&НаКлиенте
Процедура ДобавитьГрань(Объект,Т0,Т1,Т2,Т3)
	Грань = Новый Структура("Точки,Ребра");
	Грань.Ребра = Новый Массив();
	
	Грань.Точки = Новый Массив(4);
	Грань.Точки[0] = Т0;
	Грань.Точки[1] = Т1;
	Грань.Точки[2] = Т2;
	Грань.Точки[3] = Т3;
	
	ИндексПервойТочки = Т3;
	Для Каждого ИндексТочки Из Грань.Точки Цикл
		ИндексВторойТочки = ИндексТочки;
		Сч = 0;
		Для Каждого Ребро Из Объект.Ребра Цикл
			Если ((Ребро[1] = ИндексПервойТочки) И (Ребро[2] = ИндексВторойТочки))
				ИЛИ ((Ребро[2] = ИндексПервойТочки) И (Ребро[1] = ИндексВторойТочки)) Тогда
					Грань.Ребра.Добавить(Сч);
				Прервать;
			КонецЕсли;
			Сч = Сч + 1;
		КонецЦикла;
		ИндексПервойТочки = ИндексВторойТочки;
	КонецЦикла;
	
	
	Куб.Грани.Добавить(Грань);
КонецПроцедуры
Показать
5. Неопределено 90 04.08.18 17:16 Сейчас в теме
Хочется посмотреть на анимированный пример вращения в режиме реального времени.
6. Неопределено 90 06.08.18 07:26 Сейчас в теме
Не сразу понятно, что куб наклонен вниз.
Да, не сразу. А после этого так вообще. Что вы сделали с кубом? Зачем так растянули и исказили его? Я имею в виду, очевидно что спереди находятся зелёные грани Это явно не куб, а что-то трапецевидное.
7. HAMMER_59 244 06.08.18 09:08 Сейчас в теме
(6)
то вы сделали с кубом? Зачем так растянули и исказили его?


Бывают люди адекватные, а бывают неадекватные. Нормальная реакция адекватного человека - подвергать все критическому мышлению. Т.е. ознакомился с материалом, затем проверил. Как проверить? Посмотреть в других источниках информации. В конце концов запустить в программе подобной 3Д макс, построить куб, построить перспективную проекцию - и убедиться, что куб действительно получается именно таким. Потом сами же пишите, что кто-то Вас идиотом выставляют. Может дело в Вас, может Вы так себе ведете?


(6)
очевидно что спереди находятся зелёные грани

Опять же достаточно внимательно прочитать статью, где написано, что мы не пытаемся получить 100% реалистичность (как-то забавно в рамках 1С говорить о реалистичной модели), мы строим приближенную модель. В данном случае не грани, а ребра отмечены разными цветами, даже не для реалистичности, а чтобы показать, что мы правильно определили какой поверхностью грань проецируется на экран.

Фраза сравнима с мышлением школьника, естественно не лучшего: "Так формулы из школьного курса по физике не точные, например, не учтено что масса изменяется от скорости". А если еще добавить, когда мы отмерили линеечкой 127 мм, так это ведь не точно 127 мм там ведь тоже погрешность, а расстояние там и того хуже порой метрами меряем. Как дальше жить?

Какое говорите образование? Не программист, а инженер? Странно, похоже, зря только время потратили на институт, знания мимо Вас прошли. В институте крайне доходчиво и не раз объясняют, что максимальная точность - крайне редко эффективна.
8. Неопределено 90 06.08.18 09:22 Сейчас в теме
(7)
Может дело в Вас

Я просто решил поддержать вашу традицию писать как это не похоже на куб.

мы строим приближенную модель

Да, мы тоже строили приближённую, но вам это не помешало написать что у нас не 3D и не куб.

В институте крайне доходчиво и не раз объясняют, что максимальная точность - крайне редко эффективна.

Может быть у вас и объясняют. Меня научили тому, что малейшее отклонение и волновод уже работает на пропуск другой частоты, а антенна перестаёт ловить сигнал в заданном диапазоне, а если дорожку специальными ухищрениями LГLГLГLГLГ не удлинить в нужном месте, байты будут добегать с разной скоростью и сумматор не заработает как положено.
9. HAMMER_59 244 06.08.18 10:27 Сейчас в теме
(8)
Да, мы тоже строили приближённую, но вам это не помешало написать что у нас не 3D и не куб.


Это Вы сами себе додумали, я так не писал. Опять же если прочитать повнимательнее статью в ней написано, что математическая модель той части, которую Вы использовали для отображения в 3Д, ничем не отличается от 2Д.


(8)
Может быть у вас и объясняют. Меня научили тому, что малейшее отклонение и волновод уже работает на пропуск другой частоты

У Вас один предмет был в институте? Несмотря на то, что учился я на специальности "Автоматизация систем управления", при этом на электротехнической кафедре, поэтому пришлось немного окунуться и в электричество и в электронику. Был у нас такой предмет "Основы теории автоматизации управления". Прекрасный предмет, где просто очень много теории. Предмет, конечно, не только про электронику, но в основном как раз речь шла про электронику, и как раз решались проблемы, что в электронике далеко все от идеала, обычный усилитель - это уже целая история, т.к. показатели какому-нибудь транзистора не линейны.

Малейшее отклонение - вещь крайне растяжимая. Крайне странные вещи вы пишите, крайне странные. Вся электроника - это диапазоны и отклонения, вы точно в институте учились, а не кружок радиолюбителя посещали?
10. Неопределено 90 06.08.18 10:45 Сейчас в теме
У Вас один предмет был в институте?

Предложение, начинающееся с "Меня научили тому", включает в себя описание четырёх предметов.
пришлось немного окунуться
в основы теории
Вся электроника - это...

Вопросов больше нет.

Если абстрагироваться от нашей игры в снежки, на уровне кода и механики всё предельно понятно. Есть координаты точек в трёхмерном пространстве, с которыми мы взаимодействуем на уровне кода. Если построить их в голове, виден объёмный объект -- обычный куб. Как в вашем, так и в моём посте. Но вам не понравилась моя визуализация. Вы посчитали её не информативной. А затем повторно не закрасили синие рёбра куба и тем самым визуально вывели зелёные на передний план и дали мне возможность показать как некрасиво вы повели себя в моём посте. А так, мой пост зачётный. Шучу, этот на самом деле круче, но на анимацию вращения всё равно хочется посмотреть.
11. HAMMER_59 244 06.08.18 12:10 Сейчас в теме
(10)
Но вам не понравилась моя визуализация


Еще раз повторю, что мне не понравилась математическая модель, не знаю почему Вы так упорно настаиваете на визуализации.


(10)
Вы посчитали её не информативной

Уже устал повторять, что не в визуализации дело. Точно такую же математическую модель можно было построить в 2Д.

(10)
А затем повторно не закрасили синие рёбра куба

Участок кода из статьи - определение видимости граней.
&НаКлиенте
Процедура ОпределитьВидимостьГраней(Объект, Точки)
	Для Каждого Ребро Из Объект.Ребра Цикл
		Линия = Ребро[0];
		Линия.ЦветЛинии = Новый Цвет(0,150,0);
	КонецЦикла;
	
	Для Каждого Грань Из Объект.Грани Цикл
		Точка0 = Точки[Грань.Точки[0]];
		Точка1 = Точки[Грань.Точки[1]];
		Точка2 = Точки[Грань.Точки[2]];
		
		Ах = Точка1[0] - Точка0[0];
		Ау = Точка1[1] - Точка0[1];
		
		Вх = Точка2[0] - Точка1[0];
		Ву = Точка2[1] - Точка1[1];
		
		Z = Ах * Ву - Ау * Вх;
		
		//Сообщить(Z);
		
		Если Z < 0 Тогда
			Для Каждого ИндексРебра Из Грань.Ребра Цикл
				Линия = Объект.Ребра[ИндексРебра][0];	
				Линия.ЦветЛинии = Новый Цвет(0,0,150);
			КонецЦикла;			
		КонецЕсли;
		
	КонецЦикла
	
КонецПроцедуры
Показать


Вроде всё должно быть понятно. Сначала ко всем ребрам применяется зеленый цвет, а затем ребрам видимых граней цвет изменяется на синий.
Линии заново каждый раз не создаются, и скорее всего отображаются в том порядке, в котором изначально были созданы, но не факт.



(10)
но на анимацию вращения всё равно хочется посмотреть

Хотите проверить как я умею записывать видео с экрана, затем делать из них гифку? Я никогда этим не занимался.
12. Неопределено 90 07.08.18 03:10 Сейчас в теме
(11)
Я никогда этим не занимался.

Я тоже, но потом начал делать публикации и загуглил подходящую программу за пару минут. Сейчас можно писать с экрана сразу в gif.
13. yarsort 140 06.05.19 10:53 Сейчас в теме
Сколько же у людей свободного времени бывает... :)
Оставьте свое сообщение