Функция преобразования СТРОКИ в ДАТУ

 тест 

Функция ПолучитьДатуИзСтроки(Стр, ФорматДаты="")
    Д = Дата("00010101000000");
    Если ПустаяСтрока(Стр) Тогда
        Возврат Д;
	КонецЕсли;
	
	Если Не ПустаяСтрока(ФорматДаты) Тогда
	    Если Найти(ФорматДаты,".")>0 Тогда
	        Если Найти(ФорматДаты,":")>0 И Найти(ФорматДаты," ")>0 Тогда 
	            МассивФормат = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(ФорматДаты," ");
	            Возврат ПолучитьДатуИзСтроки(МассивФормат[0]);
	        КонецЕсли;
	        МассивФормат = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(ФорматДаты,".");
	    ИначеЕсли Найти(ФорматДаты,"/")>0 Тогда
	        МассивФормат = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(ФорматДаты,"/");
	    ИначеЕсли Найти(ФорматДаты,",")>0 Тогда
	        МассивФормат = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(ФорматДаты,",");
	    ИначеЕсли Найти(ФорматДаты,"-")>0 Тогда
	        МассивФормат = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(ФорматДаты,"-");
	    КонецЕсли;
        Если МассивФормат.Количество()<>3 Тогда
			ФорматДаты = "";
        КонецЕсли;
	КонецЕсли;

    Если Найти(Стр,".")>0 Тогда
        Если Найти(Стр,":")>0 И Найти(Стр," ")>0 Тогда 
            МассивДата = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(Стр," ");
            Возврат ПолучитьДатуИзСтроки(МассивДата[0]);
        КонецЕсли;
        МассивДата = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(Стр,".");
    ИначеЕсли Найти(Стр,"/")>0 Тогда
        МассивДата = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(Стр,"/");
    ИначеЕсли Найти(Стр,",")>0 Тогда
        МассивДата = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(Стр,",");
    ИначеЕсли Найти(Стр,"-")>0 Тогда
        МассивДата = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(Стр,"-");
    КонецЕсли;

    Попытка
		Если МассивДата.Количество()=3 Тогда //"01.02.13" или "01.02.2013"
			Если ФорматДаты <> "" Тогда
				Для й = 0 ПО МассивФормат.Количество()-1 Цикл
					ЭлементФормата = МассивФормат[й];
					Если Найти(ЭлементФормата, "д")>0 ИЛИ Найти(ЭлементФормата, "Д")>0 ИЛИ Найти(ЭлементФормата, "D")>0 ИЛИ Найти(ЭлементФормата, "d")>0 Тогда
						День = Число(МассивДата[й]);
					КонецЕсли;
					Если Найти(ЭлементФормата, "м")>0 ИЛИ Найти(ЭлементФормата, "М")>0 ИЛИ Найти(ЭлементФормата, "M")>0 ИЛИ Найти(ЭлементФормата, "m")>0 Тогда
						Месяц = Число(МассивДата[й]);
					КонецЕсли;
					Если Найти(ЭлементФормата, "г")>0 ИЛИ Найти(ЭлементФормата, "Г")>0 ИЛИ Найти(ЭлементФормата, "Y")>0 ИЛИ Найти(ЭлементФормата, "y")>0 Тогда
						Год = МассивДата[й];
						Если СтрДлина(Год)=2 Тогда
							Если Число(Год) > 50 Тогда
								Год = 1900 + Год;
							Иначе	
								Год = 2000 + Год;
							КонецЕсли;
						КонецЕсли;
					КонецЕсли;
				КонецЦикла;
            	Д = Дата(Год, Месяц, День);
			Иначе
				Год = ?(СтрДлина(МассивДата[2])=2,2000+МассивДата[2],МассивДата[2]);
           		Д = Дата(Год, МассивДата[1], МассивДата[0]);
			КонецЕсли;			
        ИначеЕсли МассивДата.Количество()=2 Тогда //"02.13" или "02.2013";
            Год = ?(СтрДлина(МассивДата[1])=2,2000+МассивДата[1],МассивДата[1]);
            Д = Дата(Год,МассивДата[0],1);
        КонецЕсли;
    Исключение
    КонецПопытки;

    Возврат Д;
КонецФункции

Дата("03.06.2014 0:15:55"); =>  03.06.2014 0:15:55	//Тип("Дата")

Дата("3.6.2014 0:15:55"); =>  03.06.2014 0:15:55	//Тип("Дата")

ДатаСтрокой = "2015-08-22";
ДатаДатой = Дата(СтрЗаменить(ДатаСтрокой, "-", "")); // 22.08.2015 0:00:00

Функция ПолучитьДату(тДата)
	
		ТаблицаМесяцев = Новый ТаблицаЗначений;
		ТаблицаМесяцев.Колонки.Добавить("Номер");
		ТаблицаМесяцев.Колонки.Добавить("Написание");
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "01";
		Нстр.Написание = "ЯНВРАРЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "02";
		Нстр.Написание = "ФЕВРАЛЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "03";
		Нстр.Написание = "МАРТА";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "04";
		Нстр.Написание = "АПРЕЛЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "05";
		Нстр.Написание = "МАЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "06";
		Нстр.Написание = "ИЮНЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "07";
		Нстр.Написание = "ИЮЛЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "08";
		Нстр.Написание = "АВГУСТА";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "09";
		Нстр.Написание = "СЕНТЯБРЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "10";
		Нстр.Написание = "ОКТЯБРЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "11";
		Нстр.Написание = "НОЯБРЯ";
		нстр = ТаблицаМесяцев.Добавить();
		Нстр.Номер = "12";
		Нстр.Написание = "ДЕКАБРЯ";
        	
	
		тДата 		= СокрЛП(СтрЗаменить(тДата,"г."," "));
		ДоПробела  	= Найти(тДата," ");
		тЧисло 		= СокрЛП(Лев(тДата,ДоПробела));
		тГод 		= СокрЛП(Прав(тДата,4));
		ДлинаСтроки = СтрДлина(тДата);
		МесяцСтрока = Лев(тДата,ДлинаСтроки-4);
		ДлинаМесяца = СтрДлина(МесяцСтрока);
		МесяцСтрока = СокрЛП(Прав(МесяцСтрока,ДлинаМесяца-2));
		СтрТабл = ТаблицаМесяцев.Найти(ВРег(МесяцСтрока),"Написание");
		тМесяц = СтрТабл.Номер;
		Дат = Дата(тГод+тМесяц+тЧисло);

		
		Возврат Дат;
	
КонецФункции	

Функция ДатаИзСтроки(СтрокаДата)
	
	Возврат Дата(
					Сред(СтрокаДата,7,4) 
					+ Сред(СтрокаДата,4,2) 
					+ Лев(СтрокаДата,2) 
					+ Сред(СтрокаДата,12,2) 
					+ Сред(СтрокаДата,15,2) 
					+ Сред(СтрокаДата,18,2)
				);
				
КонецФункции

Функция СтрокаВДату(Знач ДатаСтрока)  
	
	ОписаниеТипа = Новый ОписаниеТипов("Дата");
	Результат    = ОписаниеТипа.ПривестиЗначение(ДатаСтрока);
	
	Если ЗначениеЗаполнено(Результат) Тогда
		Возврат Результат;                                 	
	КонецЕсли;
	
	ПозицияПробела = СтрНайти(ДатаСтрока, " ", НаправлениеПоиска.СНачала);
	Если ПозицияПробела > 0 Тогда
		ДатаСтрока = Лев(ДатаСтрока, ПозицияПробела - 1);
	КонецЕсли;
		
	ДатаСтрока = СокрЛП(СтрЗаменить(ДатаСтрока, ".", ""));
	ДатаСтрока = СокрЛП(СтрЗаменить(ДатаСтрока, ",", ""));
	ДатаСтрока = СокрЛП(СтрЗаменить(ДатаСтрока, ":", ""));
	ДатаСтрока = СокрЛП(СтрЗаменить(ДатаСтрока, "/", ""));
	ДатаСтрока = СокрЛП(СтрЗаменить(ДатаСтрока, "-", ""));

	ДатаСтрока = Сред(ДатаСтрока, 5) + Сред(ДатаСтрока, 3, 2) + Лев(ДатаСтрока, 2);
	Если СтрДлина(ДатаСтрока) = 6 Тогда
		ДатаСтрока = "20" + ДатаСтрока;
	КонецЕсли;
	
	//ОписаниеТипа = Новый ОписаниеТипов("Дата");
	Результат    = ОписаниеТипа.ПривестиЗначение(ДатаСтрока);
	
	Возврат Результат;
	
КонецФункции

Попытка
	   СтрокаТЧ.Реквизит9 = Дата(ДатаСтрокой  + " 00:00:00");
	Исключение
	    СтрокаТЧ.Реквизит9 = ДатаТТН;
КонецПопытки;

//	    СтрокаТЧ.Реквизит9 реквизит ТЧ

// Функция преобразует строку в дату
//
// Параметры:
//  ДатаСтрокой - строка - дата в любом формате даты https://yandex.ru/support/partnermarket/export/date-format.html
//  АмериканскийФормат - булево - нужно указывать если известно, что дата в таком формате ММ/ДД/ГГГГ
//
// Возвращаемое значение:
//  Значение типа "Дата"
//
Функция ПолучитьДатуИзСтроки(Знач ДатаСтрокой,АмериканскийФормат=Ложь)
	Если ПустаяСтрока(ДатаСтрокой) Тогда
		Возврат Дата("00010101000000");
	КонецЕсли;
	ДатаСтрокой=СокрЛП(СтрЗаменить(ДатаСтрокой,"  "," "));
	
	Если Найти(нРег(ДатаСтрокой),"янв")>0 или
		 Найти(нРег(ДатаСтрокой),"фев")>0 или
		 Найти(нРег(ДатаСтрокой),"мар")>0 или
		 Найти(нРег(ДатаСтрокой),"апр")>0 или
		 Найти(нРег(ДатаСтрокой),"май")>0 или
		 Найти(нРег(ДатаСтрокой),"мая")>0 или
		 Найти(нРег(ДатаСтрокой),"июн")>0 или
		 Найти(нРег(ДатаСтрокой),"июл")>0 или
		 Найти(нРег(ДатаСтрокой),"авг")>0 или
		 Найти(нРег(ДатаСтрокой),"сен")>0 или
		 Найти(нРег(ДатаСтрокой),"окт")>0 или
		 Найти(нРег(ДатаСтрокой),"ноя")>0 или
		 Найти(нРег(ДатаСтрокой),"дек")>0 Тогда // месяц прописью
		// 31 декабря 2013 г.
		// 31 дек 13
		// 31-дек-13
		// декабрь 2013
		// 2013, декабрь
		// 2013, 31 декабря
		ДатаСтрокой=СтрЗаменить(ДатаСтрокой,"г.",""); // 31 декабря 2013 г. -> 31 декабря 2013
		ДатаСтрокой=СтрЗаменить(ДатаСтрокой,"г","");  // 31 декабря 2013 г -> 31 декабря 2013
		ДатаСтрокой=СокрЛП(ДатаСтрокой);
		Если Найти(ДатаСтрокой,",")>0 Тогда // 2013, 31 декабря
			_ЧастиДаты=СтрРазделить(ДатаСтрокой,",");
			ДатаСтрокой=_ЧастиДаты[1]+" "+_ЧастиДаты[0]; // 31 декабря 2013
			ДатаСтрокой=СокрЛП(ДатаСтрокой);
		КонецЕсли;
		ДатаСтрокой=СтрЗаменить(ДатаСтрокой,"-"," "); // 31-дек-13 -> 31 дек 13
		_ЧастиДаты=СтрРазделить(ДатаСтрокой," ");
		Если _ЧастиДаты.Количество()=2 Тогда // декабрь 2013
			_ЧастиДаты.Вставить(0,"01"); // 01 декабрь 2013
		КонецЕсли;
		
		Если нРег(Лев(_ЧастиДаты[1],3))="янв" Тогда
			_ЧастиДаты[1]="01";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="фев" Тогда
			_ЧастиДаты[1]="02";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="мар" Тогда
			_ЧастиДаты[1]="03";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="апр" Тогда
			_ЧастиДаты[1]="04";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="мая" или нРег(Лев(_ЧастиДаты[1],3))="май"Тогда
			_ЧастиДаты[1]="05";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="июн" Тогда
			_ЧастиДаты[1]="06";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="июл" Тогда
			_ЧастиДаты[1]="07";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="авг" Тогда
			_ЧастиДаты[1]="08";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="сен" Тогда
			_ЧастиДаты[1]="09";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="окт" Тогда
			_ЧастиДаты[1]="10";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="ноя" Тогда
			_ЧастиДаты[1]="11";
		ИначеЕсли нРег(Лев(_ЧастиДаты[1],3))="дек" Тогда
			_ЧастиДаты[1]="12";
		КонецЕсли;
		_Дата=_ЧастиДаты[0]+"."+_ЧастиДаты[1]+"."+_ЧастиДаты[2]; // 31.12.2013
		_Время="00:00:00";
	ИначеЕсли Найти(ДатаСтрокой,"T")>0 Тогда // 31.12.2013T23:59:59.999Z
		_ЧастиДаты=СтрРазделить(ДатаСтрокой,"T");
		_Дата =_ЧастиДаты[0];
		_Время=_ЧастиДаты[1];
		Если Найти(_Время,"+")>0 Тогда // 20130225T182510+03
			_Время=СокрЛП(Лев(_Время,Найти(_Время,"+")-1));
		КонецЕсли;
		Если Найти(_Время,":")=0 Тогда // 20130225T182510
			_Время=Лев(_Время+"000000",6);
			_Время=Сред(_Время,1,2)+":"+Сред(_Время,3,2)+":"+Сред(_Время,5,2);
		ИначеЕсли СтрЧислоВхождений(_Время,":")=1 Тогда // 2013-12-31T23:59
			_Время=_Время+":00";
		КонецЕсли;
	ИначеЕсли Найти(ДатаСтрокой," ")>0 Тогда // 31.12.2013 23:59:59
		_ЧастиДаты=СтрРазделить(ДатаСтрокой," ");
		_Дата =_ЧастиДаты[0];
		_Время=_ЧастиДаты[1];
		Если Найти(_Время,"+")>0 Тогда // 2013/02/25 18:25:10 +03:00
			_Время=СокрЛП(Лев(_Время,Найти(_Время,"+")-1));
		КонецЕсли;
		Если Найти(_Время,":")=0 Тогда // 20130225 182510
			_Время=Лев(_Время+"000000",6);
			_Время=Сред(_Время,1,2)+":"+Сред(_Время,3,2)+":"+Сред(_Время,5,2);
		ИначеЕсли СтрЧислоВхождений(_Время,":")=1 Тогда // 2013-12-31 23:59
			_Время=_Время+":00";
		КонецЕсли;
	Иначе
		_Дата =ДатаСтрокой;
		_Время="00:00:00";
	КонецЕсли;
		
	Если Найти(_Дата,".")=0 и Найти(_Дата,"/")=0 и СтрДлина(_Дата)=8 Тогда // 20131231 YYYYMMDD
		_Дата=Сред(_Дата,1,4)+"-"+Сред(_Дата,5,2)+"-"+Сред(_Дата,7,2); // 2013-12-31
	КонецЕсли;
	Если Найти(_Дата,"/")>0 Тогда
		_ЧастиДаты=СтрРазделить(_Дата,"/");
		Если СтрДлина(_ЧастиДаты[0])=4 Тогда // YYYY/MM/DD
			_Дата=СтрЗаменить(_Дата,"/","-"); // 2013-12-31
		Иначе
			Если АмериканскийФормат Тогда // ММ/ДД/ГГГГ
				_Дата=_ЧастиДаты[1]+"."+_ЧастиДаты[0]+"."+_ЧастиДаты[2]; // 31.12.2013
			Иначе
				_Дата=СтрЗаменить(_Дата,"/","."); // 31.12.2013
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;
	Если Найти(_Дата,"-")>0 Тогда // 2013-12-31
		_ЧастиДаты=СтрРазделить(_Дата,"-"); // ГГГГ|ММ|ДД
		Если СтрДлина(_ЧастиДаты[2])=4 Тогда // ДД|ММ|ГГГГ -> 31-12-2013
			_Дата=_ЧастиДаты[0]+"."+_ЧастиДаты[1]+"."+_ЧастиДаты[2]; // 31.12.2013
		Иначе
			_Дата=_ЧастиДаты[2]+"."+_ЧастиДаты[1]+"."+_ЧастиДаты[0]; // 31.12.2013
		КонецЕсли;
	КонецЕсли;
	Если Найти(_Дата,".")=0 Тогда // Какая-то хрень
		Возврат Дата("00010101000000");
	КонецЕсли;
	// Основная обработка
	_ЧастиДаты=СтрРазделить(_Дата,"."); // ДД|ММ|ГГГГ
	Если _ЧастиДаты.Количество()=2 Тогда //"12.13" или "12.2013";
		_ЧастиДаты.Вставить(0,"01"); // 01.12.2013
	КонецЕсли;
	Для iii=0 По _ЧастиДаты.Количество()-1 Цикл
		Если СтрДлина(_ЧастиДаты.Получить(iii))<2 Тогда // 1.6.2013
			_ЧастиДаты.Установить(iii,Прав("00"+_ЧастиДаты.Получить(iii),2)); // 01.06.2013
		КонецЕсли;
	КонецЦикла;
	// год в формате ГГ
	Если СтрДлина(_ЧастиДаты[2])=2 Тогда // 31.12.13
		Если _ЧастиДаты[2]<"50" Тогда // 31.12.13
			_ЧастиДаты[2]="20"+_ЧастиДаты[2]; // 31.12.2013
		Иначе
			_ЧастиДаты[2]="19"+_ЧастиДаты[2]; // 31.12.1970
		КонецЕсли;
	КонецЕсли;
	_ЧастиВремени=СтрРазделить(_Время,":");
	Для iii=0 По _ЧастиВремени.Количество()-1 Цикл
		Если СтрДлина(_ЧастиВремени.Получить(iii))<2 Тогда // 0|0|0
			_ЧастиВремени.Установить(iii,Прав("00"+_ЧастиВремени.Получить(iii),2)); // 00|00|00
		КонецЕсли;
		Если СтрДлина(_ЧастиВремени.Получить(iii))>2 Тогда // 23|59|59.999Z
			_ЧастиВремени.Установить(iii,Лев(_ЧастиВремени.Получить(iii),2)); // 00|00|00
		КонецЕсли;
	КонецЦикла;
	
	Попытка
		Возврат Дата(_ЧастиДаты[2]+_ЧастиДаты[1]+_ЧастиДаты[0]+_ЧастиВремени[0]+_ЧастиВремени[1]+_ЧастиВремени[2]) // 20131231235959
	Исключение
		Сообщить("Ошибка преобразования даты "+ДатаСтрокой);
		Возврат Дата("00010101000000");
	КонецПопытки; 
КонецФункции // ПолучитьДатуИзСтроки