Загрузка из EXCEL в 1С. MS ADODB.Connection

18.04.15

Интеграция - Загрузка и выгрузка в Excel

ПРАКТИЧЕСКОЕ ПОСОБИЕ РАЗРАБОТЧИКА: Метод "MS ADODB" (ADODB.Connection).
Поддерживаемые типы: *.xls,*.xlsx.

 В данной статье приведен функционал, с помощью которого в обработке
"Импорт из EXCEL и др.источников (xls,xlsx,ods,sxc,dbf,mxl,csv,sql) в 1С": //infostart.ru/public/120961
производится считывание данных из файлов табличного типа *xls, *.xlsx.

Методы загрузки из внешнего источника:
- Метод "MS ADO" (Чтение файлов xls, xlsx средствами Microsoft ADO): //infostart.ru/public/163640/
- Метод "MS EXCEL" (Чтение файлов xls, xlsx с картинками средствами Microsoft Office): //infostart.ru/public/163641/
- Метод "LO CALC" (Чтение файлов xls, xlsx, ods, sxc с картинками средствами LibreOffice): //infostart.ru/public/163642/
- Метод "NativeXLSX" (Чтение файлов xlsx с картинками средствами 1С. ПостроительDOM): //infostart.ru/public/300092/
- Метод "NativeXLSX". Предыдущий вариант (Чтение файлов xlsx средствами 1С. ЧтениеXML):
//infostart.ru/public/225624/
- Метод "Excel1C" (Загрузка на платформе 8.3.6 с картинками. Чтение файлов xls, xlsx, ods): //infostart.ru/public/341855/
- Список листов файла: //infostart.ru/public/163724/


Публикаций на тему загрузки из EXCEL - множество, но
"
— Вам билетёр нужен?
— Был нужен, да уже взяли.
— Может и я на что сгожусь?
— Может и сгодишься, если скалиться не будешь ...
"
"НЕУЛОВИМЫЕ МСТИТЕЛИ" (1966).


// Метод "Microsoft ADODB"/
//

// Параметры:
//        ФайлEXCEL - Полное имя файла (путь к файлу с именем файла и расширением).
//        ИмяЛиста - Имя выбранного листа файла EXCEL.
//        СтрокаЗаголовка (по умолчанию = 1) - Номер строки EXCEL, в которой расположены заголовки колонок.
//            Не используется, т.к. в СтрокеСоединения указано HDR=YES, а не HDR=NO.
/ /       В обработке 1-я строка анализируется для сопоставления колонок EXCEL с реквизитами 1С (справочники, докуметны, регистры).
//        НачСтрока (по-умолчанию = 0) - Номер начальной строки, начиная с которой считываются данные из EXCEL.

//        КонСтрока (по-умолчанию = 0) - Номер конечной строки, которой заканчиваются считываемые данные из EXCEL.
//            Если НачСтрока=0 и КонСтрока=0, то считывается вся таблица, находящаяся на листе EXCEL.
//        КолвоСтрокExcel - Количество строк на листе "ИмяЛиста" EXCEL. Возвращается в вызываемую процедуру.
//        ПодключениеADODB - тип драйвера ADODB для подключения к EXCEL.
//
// Возвращаемые значения:
//         ТаблицаРезультат - Результат считывания с листа "ИмяЛиста" EXCEL.
//
Функция ЗагрузитьМетодом_MSADODB(Знач ФайлEXCEL, Знач ИмяЛиста, Знач СтрокаЗаголовка = 1, НачСтрока = 0, КонСтрока = 0, КолвоСтрокExcel,
Знач
ПодключениеADODB = "MicrosoftJetOLEDB40") Экспорт
    Перем СonnectionString, ADODBConnection, ADODBRecordset, ТекстЗапроса;
    Перем КолвоКолонокExcel, Поле, Колонка, ИмяКолонки;
    Перем НоваяСтрока, НомерСтроки;
    Перем ТаблицаРезультат;
    
    // Нумерация MS ADODB начинается с 1.
    
    // Переменная "СтрокаЗаголовка", не используется, т.к. HDR=YES, а не HDR=NO.
    // HDR=YES:
    // 1. Считывание заголовков колонок с 1-ой строки.
    // 2. Считываемые данные со 2-ой и последующих строк типизированы. Для варианта HDR=NO: считываемые данные - строка.
    
    // Строка соединения - определение драйвера, который будет использован для подключения к файлу EXCEL.
    Если ПодключениеADODB = "MicrosoftACEOLEDB12" Тогда
        
        // ACE.OLEDB.12.0 - Для использования данного подключения необходимо дополнительное ПО:
        // Microsoft Access Database Engine 2010 Redistributable 32/64 bit.
        СonnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source= " + СокрЛП(ФайлEXCEL) + ";Extended Properties=""Excel 12.0;HDR=YES;IMEX=1;""";
        
        // Еще один вариант.
        //СтрокаСоединения = "Driver={Microsoft Excel Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)};Dbq=" + СокрЛП(ФайлEXCEL) + ";";
        
    Иначе
        
        // Jet.OLEDB.4.0 - Стандартное подключение, как правило, не требующее установки дополнительного ПО.
        // Рекомендуется установить последний Service Pack Windows.
        СonnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source= "  + СокрЛП(ФайлEXCEL) + ";Extended Properties=""Excel 8.0;HDR=YES;IMEX=1;""";
        
        // Еще один вариант.
        //СтрокаСоединения = "Driver={Microsoft Excel Driver (*.xls)};Dbq=" + СокрЛП(ФайлEXCEL) + ";";
        
    КонецЕсли;
    
    Попытка
        // Инициализация основного объекта ADODB.Connection. Открытие соединения.
        ADODBConnection = Новый COMОбъект("ADODB.Connection");
        ADODBConnection.ConnectionString =  СonnectionString;
        ADODBConnection.Open();
        // Импирически определенный параметр для правильного определения количества строк листа.
        ADODBConnection.CursorLocation = 3;    // По-умолчанию 2.
    Исключение
        Сообщить(НСтр("ru = '"+ОписаниеОшибки()+"'"), СтатусСообщения.Внимание);
        Возврат Новый ТаблицаЗначений;    // В случае ошибки возвращаем пустую таблицу значений.
    КонецПопытки;
    
    ТекстЗапроса = "SELECT * FROM [" + ИмяЛиста + "$]";
    
    // Создание Recordset. Дочерний объект ADODBConnection. Набор записей по запросу.
    Попытка
        ADODBRecordset = Новый COMОбъект("ADODB.Recordset");
        ADODBRecordset.Open(ТекстЗапроса, ADODBConnection);
        
        // Проверка заполненности листа.
        Если (ADODBRecordset.EOF ИЛИ ADODBRecordset.BOF) Тогда
            КолвоСтрокExcel = 0;
            Сообщить(НСтр("ru = '" + ИмяЛиста + ": не содержит данных.'"), СтатусСообщения.Внимание);
            
            // Завершение работы.
            // Закрытие Объектов.
            ADODBRecordset.Close();
            ADODBConnection.Close();
            ADODBRecordset   = Неопределено;
            ADODBConnection = Неопределено;
            
            Возврат Новый ТаблицаЗначений;    // В случае ошибки возвращаем пустую таблицу значений.
        КонецЕсли;
        
        // Импирически определенные параметры для правильного определения количества строк листа.
        ADODBRecordset.AbsolutePage     = 1;
        ADODBRecordset.AbsolutePosition = 1;
    Исключение
        Сообщить(НСтр("ru = '"+ОписаниеОшибки()+"'"), СтатусСообщения.Внимание);
        Возврат Новый ТаблицаЗначений;    // В случае ошибки возвращаем пустую таблицу значений.
    КонецПопытки;
    
    // Параметр, возвращаемый в вызывающую процедуру.
    КолвоСтрокExcel = ADODBRecordset.RecordCount + 1;    // (+1) - учет Строки-Заголовока, которая "съедается".
    КолвоКолонокExcel = ADODBRecordset.Fields.Count;
    
    // Проверка заполненности листа.
     Если КолвоСтрокExcel <= 2
Тогда
        КолвоСтрокExcel = 0;
        Сообщить(НСтр("ru = '" + ИмяЛиста + ": не содержит данных.'"), СтатусСообщения.Внимание);
        
        // Завершение работы.
        // Закрытие Объектов.
        ADODBRecordset.Close();
        ADODBConnection.Close();
        ADODBRecordset   = Неопределено;
        ADODBConnection = Неопределено;
        
        Возврат Новый ТаблицаЗначений;    // В случае ошибки возвращаем пустую таблицу значений.
    КонецЕсли;
    
    // Создание результирующей таблицы, в которую будут записываться считанные из EXCEL данные.
    ТаблицаРезультат = Новый ТаблицаЗначений;
    
    // Формирование колонок результирующей таблицы.
    
    // "НомерСтроки" - для наглядности и удобства.
    // В зависимости от разрабатываемой обработки.
    // "Сопоставлено" - может быть другим.
    // Здесь же могут быть добавлены другие колонки, не формируемые из содержимого файла EXCEL.
    ТаблицаРезультат.Колонки.Добавить("НомерСтроки", Новый ОписаниеТипов("Число"), "№", 4);
    ТаблицаРезультат.Колонки.Добавить("Сопоставлено", Новый ОписаниеТипов("Булево"), "Сопоставлено", 1);
    Для ит = 1 ПО КолвоКолонокExcel Цикл
        
        Поле = ADODBRecordset.Fields.Item(ит - 1);
        ИмяКолонки = "К_" + ит;
        Колонка = ТаблицаРезультат.Колонки.Добавить(ИмяКолонки, , СокрЛП(СтрЗаменить(Поле.Name, "#", ".")));
        // Замена "#" на ".", т.к. при считывании ADODB "." в имени колонки заменяется на "#".
        
    КонецЦикла;
    
    // ТаблицаРезультат: 1-я строка - Строка-Заголовок.
    
    // Добавление этой строки обусловлено исключительно из соображений идентичности содержимого файла EXCEL и ТаблицыЗначений,
    // выводимой на форме Обработки, и дальнейшей обработки строки заголовка
    // с целью сопоставления колонок EXCEL и реквизитов 1С: для Справочников, ПВХ, Регистров, Документов.
    
    // Если в Вашей обработке в результирующей таблице в качестве 1-ой строки не нужна Строка-Заголовок, то
    // следует закомментировать следующий цикл:
    НоваяСтрока = ТаблицаРезультат.Добавить();
    НоваяСтрока.НомерСтроки = 1;
    Для ит = 1 ПО КолвоКолонокExcel Цикл
        
        ИмяКолонки = "К_" + ит;
        Колонка = ТаблицаРезультат.Колонки.Найти(ИмяКолонки);
        НоваяСтрока[ИмяКолонки] = Колонка.Заголовок;
        
    КонецЦикла;
    
    // ТаблицаРезультат: Формирование строк по указанному диапазону: НачСтрока - КонСтрока.
    
    НомерСтроки = 1;
    Пока ADODBRecordset.EOF() = 0 Цикл
        
        НомерСтроки = НомерСтроки + 1;
        
        Если НомерСтроки < НачСтрока Тогда    // Номер строки вне диапазона считываемых строк.
            ADODBRecordset.MoveNext();             // Следующая строка.
            Продолжить;
        КонецЕсли;
        
        Если КонСтрока > 0 И НомерСтроки > КонСтрока Тогда    // Номер строки вне диапазона считываемых строк.
            Прервать;
        КонецЕсли;
        
        НоваяСтрока = ТаблицаРезультат.Добавить();
        НоваяСтрока.НомерСтроки = НомерСтроки;
        
        Для ит = 1 ПО КолвоКолонокExcel Цикл
            
            Поле = ADODBRecordset.Fields.Item(ит - 1);
                
            Если Поле.ActualSize = 0 Тогда        // Пустое поле EXCEL.
                Продолжить;
            КонецЕсли;
                
            ЗначениеЯчейки = Поле.Value;        // Учитывая параметр HDR=YES в строке соединения, данные считываются в соответствии с их типом.
            
            ИмяКолонки = "К_" + ит;
            НоваяСтрока[ИмяКолонки] = ЗначениеЯчейки;
            
            // Используется при формировании таблицы на форме обработки.
            ШиринаКолонки = ТаблицаРезультат.Колонки[ИмяКолонки].Ширина;
            ДлинаСтроки      = СтрДлина(СокрЛП(ЗначениеЯчейки));
            ТаблицаРезультат.Колонки[ИмяКолонки].Ширина = ?(ШиринаКолонки < ДлинаСтроки, ДлинаСтроки, ШиринаКолонки);
                
        КонецЦикла;
        
        ADODBRecordset.MoveNext();   // Следующая строка.
        
    КонецЦикла;
    
    //УдалитьКолонкиСНулевойШириной(ТаблицаРезультат);
    
    // Завершение работы.
    // Закрытие Объектов.
    ADODBRecordset.Close();
    ADODBConnection.Close();
    ADODBRecordset   = Неопределено;
    ADODBConnection = Неопределено;
    
    Возврат ТаблицаРезультат;

    
КонецФункции

Преимущества:
1.«В общем случае» метод «Microsoft ADODB» работает и в файловом и в клиент-серверном варианте.
2. Самый быстрый из трех рассматриваемых.
Особенности и Ограничения:
1.Для функционирования метода «Microsoft ADODB» необходимо:

Драйвер подключения Provider=Microsoft.Jet.OLEDB.4.0:
- Установленный Microsoft MDAC, как правило специальная установка не требуется, достаточно последнего Service Pack-а операционной системы..
  Microsoft MDAC 2.8 SP1 10.05.2005: http://www.microsoft.com/download/en/details.aspx?displaylang=en&id=5793

Драйвер подключения Provider=Microsoft.ACE.OLEDB.12.0:
- Установленный Microsoft Access Database Engine 2010 Redistributable (16/12/2010) 32 и 64 - разрядные версии:
  Microsoft ADE 2010 16/12/2010:  http://www.microsoft.com/en-us/download/details.aspx?id=13255

2. 1-я строка файла EXCEL - строка, содержащая заголовки колонок. Можно изменить, изменив HDR=YES на HDR=NO + некоторые изменения в функции.

МА! С уважением к сообществу МА!

1C Предприятие Импорт Загрузка Чтение Microsoft MS Excel LibreOffice OpenOffice dbf dBase xml mxl ActiveX ADO ADODB Windows

См. также

Загрузка номенклатуры из Excel в УТ11, КА 2, ERP 2, Розница 2. Дополнительные реквизиты и сведения, характеристики, картинки, цены, остатки

Загрузка и выгрузка в Excel Розничная торговля Логистика, склад и ТМЦ Ценообразование, анализ цен Прайсы Платформа 1С v8.3 1С:Комплексная автоматизация 1.х 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Управленческий учет Платные (руб)

Загрузка из файлов xls, xlsx, ods, csv, mxl в УТ11, КА 2, ERP 2, Розница 2. Задействованы все возможности конфигурации - заполнение реквизитов номенклатуры, дополнительных реквизитов и сведений, характеристики, доп.реквизиты и сведения характеристик. Дополнительные обработки для расширения возможностей.

10560 руб.

29.10.2014    209835    620    524    

438

Загрузка номенклатуры c картинками (несколько потоков одновременно) и сопутствующими данными в базу и любые документы из yml, xls, xlsx, xlsm, ods, ots, csv для УТ 10.3, УТ 11 (все), БП 3, КА 2, ERP 2, УНФ 1.6/3.0, Розница 2

Загрузка и выгрузка в Excel Логистика, склад и ТМЦ Ценообразование, анализ цен Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Платные (руб)

Эволюция не стоит на месте - новая удобная версия функциональной обработки для Вашего бизнеса! Что же Вы получаете? Удобный и интуитивно понятный интерфейс с 3-мя этапами работы. 2 режима - автоматический и ручной. Чтение XLSX, XLSM, CSV, XML/YML форматов без офиса, на любом сервере! Визуальное связывание колонок файла и реквизитов простым перетаскиванием колонок. Создание или обновление номенклатуры с иерархией, характеристик, доп. реквизитов, упаковок, загрузка практически неограниченного количества картинок на одну номенклатуру (с возможностью загрузки в несколько потоков одновременно), с хранением в томах или в базе. Загрузка номенклатуры поставщиков или поиск по их данным номенклатуры. Загрузка доп. реквизитов в характеристики. Загрузка штрихкодов с генерацией новых. Создание элементов справочников и ПВХ "на лету" для выбранных реквизитов. (Обновление от 11.12.2023, версия 9.5 - 9.9)

13200 руб.

20.11.2015    150391    365    375    

499

Распознавание и загрузка сканов в 1С "одним нажатием": УПД, ТОРГ-12, накладные, счета, номенклатура, заказы и т.д.

Загрузка и выгрузка в Excel Документооборот и делопроизводство (СЭД) Учет документов Распознавание документов и образов Управляемые формы 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Розница 2 1С:Управление производственным предприятием 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Управление холдингом 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Бухгалтерский учет Управленческий учет Платные (руб)

Универсальная программа для распознавания ЛЮБЫХ СКАНОВ ИЛИ ФОТО ТОВАРНЫХ ДОКУМЕНТОВ в 1С. Не требует указания параметров и предварительной настройки. Просто выбираете файл (PDF, JPG, DOC, XLS, HTML и т.д.) выбираете документ 1С и нажимаете кнопку "Распознать и загрузить".

5400 руб.

04.06.2019    101141    296    173    

312

Загрузка данных отчета о реализации товаров из Excel файла СберМегаМаркет

Загрузка и выгрузка в Excel Маркетплейсы Платформа 1С v8.3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Управление нашей фирмой 3.0 Бухгалтерский учет Управленческий учет Платные (руб)

Загрузка данных отчета о реализации товаров из сервиса СберМегаМаркет для конфигурации: Бухгалтерия предприятия, редакция 3.0; Управление торговлей, редакция 11 и Управление нашей фирмой, редакция 3.0 в документ "Отчет комиссионера (агента) о продажах".

3600 руб.

07.06.2022    14956    78    0    

59

Загрузка документов и номенклатуры из Excel в 1С "одним нажатием": УПД, ТОРГ-12, отчеты маркетплейсов, заказы, счета, прайсы

Загрузка и выгрузка в Excel Оптовая торговля Платформа 1С v8.3 Управляемые формы Платформа 1C v8.2 Конфигурации 1cv8 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Розница 2 1С:Управление производственным предприятием 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Бухгалтерский учет Управленческий учет Платные (руб)

Универсальная обработка для загрузки документов из Excel в 1С. Не требует указания параметров (номера колонок, номер первой строки таблицы и т.д.) и предварительной настройки. Просто выбираете файл Excel, документ 1С и нажимаете кнопку "Загрузить". Обработка сама находит таблицу в файле Excel, необходимые для загрузки данные в ней (номенклатура, количество, НДС, цена, сумма) и загружает ее в 1С. Вместе с номенклатурой может найти контрагента, номер и дату документа, штрих-коды, серии ГТД, страну и т.д. Распознает документы ЛЮБОЙ ФОРМЫ (УПД, ТОРГ-12, заказ, отчет комиссионера и т.д.). Не требует MS Office. Для поиска таблиц используются методы эвристического поиска. Загружает только то, что нужно, т.е. пропускает повторы шапки таблицы, заголовки, промежуточные итоги, подписи и т.д. Содержит модуль работы с электронной почтой и api-загрузчик отчетов о продажах маркетплейсов.

5000 руб.

09.11.2016    214619    921    886    

938

Универсальная загрузка остатков и цен поставщиков в 1С (УТ 11, КА 2, ERP 2.0) из файлов Excel, CSV, XML (YML и CML)

Прайсы Оптовая торговля Розничная торговля Ценообразование, анализ цен Файловый обмен (TXT, XML, DBF), FTP Загрузка и выгрузка в Excel Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Управленческий учет Платные (руб)

Обработка позволяет легко настроить загрузку прайс-листов и остатков поставщиков. Форматы файлов задаются для каждого поставщика отдельно. В настройках предусмотрена возможность гибкой обработки входящих данных (убрать лишние символы, пересчитать цены в другую валюту, сделать произвольную наценку и т.д.).

12000 руб.

23.01.2017    58798    59    48    

67
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. coch 27 30.11.12 09:57 Сейчас в теме
Есть ещё нюанс. Если в первых 8-ми строках числа, 0 например, хотя дальше пойдут строки, "1,5 EUR" например, то автоопределение типа данных в ячейке возмет число для всей колонки, и все значения с типом строка будут 0, соответственно.
Параметр строки подключения MAXSCANROW лично мне никак не помог решить эту проблему. Свойства ячеек на автоопределение типа тоже не влияют.
З.Ы. Это для Microsoft.Jet.OLEDB.4.0
с Microsoft.ACE.OLEDB.12.0 не работал.
Kinestetik; ditiatko; Gremlin; StepByStep; +4 Ответить
2. StepByStep 3666 30.11.12 10:29 Сейчас в теме
(1) coch,
Спасибо. Надо будет обязательно это посмотреть.
72. ditiatko 39 02.11.16 10:23 Сейчас в теме
(1) coch, в 12.0 та же беда. если 8 пустых, то остальные не читает. Есть идеи как с этим бороться?
3. Ёпрст 1063 04.12.12 12:20 Сейчас в теме
Просто можно писать запрос не селект *, а к конкретной колонке и её уже кастовать к нужному типу данных.
JohnyDeath; +1 Ответить
5. coch 27 04.12.12 13:30 Сейчас в теме
(3) Ёпрст, естественно select не *, а конкретные поля. Чтобы использовать Cast надо через MSSQL (например) делать запрос к таблице (в 7.7 лет 5 назад так и было)
(4) djd.sf, пробовал, не взлетело. Была таблица для сверки остатков из 7.7 значение колонки с остатками выглядело как "5.000 EUR 15", если в первых 8 строках "", то значения всех строк приводились к типу число.
7. djd.sf 04.12.12 13:38 Сейчас в теме
(5) IMEX отключите и взлетит. только, что проверил.(а вообще покажите строку подключения).
8. coch 27 04.12.12 14:45 Сейчас в теме
(7) djd.sf, уже не могу показать строку подключения, т.к. эта проблема была на предыдущем месте работы.
IMEX надо бы запомнить. при оказии попробовать.
4. djd.sf 04.12.12 12:59 Сейчас в теме
типизировать можно прямо в самом запросе, только не CAST(это T-Sql), а функциями http://msdn.microsoft.com/en-us/library/s2dy91zy.aspx . Наример: SELECT CDbl(F11) FROM ['Прайс-лист$']
ded00786; StepByStep; romansun; +3 Ответить
9. romansun 193 04.12.12 16:12 Сейчас в теме
(4)
+1

вполне можно поюзать функционал вот того скуля, да

я для себя в итоге завел всю эту тему в консоль запросов - получилось достаточно удобно. Ставим галку "запрос к эксель", пишем свой запрос sql, жмем кнопку "создать временную таблицу" - вуаля, теперь можно писать полноценные 1С-ные запросы к получившейся таблице.

Единственное, так и не вычислил как в этом скуле ремарить строки - перепробовал кучи вариантов - не взлетает :). Может кто знает?
10. djd.sf 04.12.12 16:32 Сейчас в теме
(9) я себе также в консоль сделал. собственно и проверяю в ней. и временные запросы также)))
а что это такое
ремарить строки
, я не понял?
75. Alex26071991 18.10.17 07:04 Сейчас в теме
Нужна помощь.... 1с ругается на Внешнюю обработку, точнее доступ к базе...

{ВнешняяОбработка.СопоставлениеИЗагрузкаНоменклатуры.МодульОбъекта(10)}: Ошибка при вызове метода контекста (Open)
НаборДанных.Open("select * from [Test$]", Соединение);
по причине:
Произошла исключительная ситуация (Microsoft Office Access Database Engine): 'Test$' is not a valid name. Make sure that it does not include invalid characters or punctuation and that it is not too long.
{ВнешняяОбработка.СопоставлениеИЗагрузкаНоменклатуры.МодульОбъекта(10)}: Ошибка при вызове метода контекста (Open)
НаборДанных.Open("select * from [Test$]", Соединение);
по причине:
Произошла исключительная ситуация (Microsoft Office Access Database Engine): 'Test$' is not a valid name. Make sure that it does not include invalid characters or punctuation and that it is not too long.

База Скульная.
11. StepByStep 3666 05.12.12 05:18 Сейчас в теме
(4) djd.sf,
Спасибо, возьму на заметку.

Предложенное возможно, если заранее известно в какой колонке какого типа данные.
В обработке Импорт из EXCEL тремя методами это, заранее неизвестно. Именно по считыванию и определяется тип.
6. AlexO 135 04.12.12 13:36 Сейчас в теме
МА, "забыли" упомянуть самый главный плюс загрузки через ADODB - на сервере не нужна установка Excel :)
12. vamleshka 15.12.12 20:44 Сейчас в теме
Спасибо. Очень поможет, а то админ засранец не хочет покупать эксель на сервак, вот и приходилось все время мучать при загрузках экселей, т.к работал удалено на серваке.
13. GreenFox 31.01.13 01:41 Сейчас в теме
Попробовал - летает, однозначно в разы быстрее чтения через сам Ексель. Единственное но, которое мне не понравилось - надо указывать имя листа. При доступе из МС Ексель можно использовать activeworkbook и activesheet.
14. DoctorRoza 11.03.13 21:21 Сейчас в теме
Не могу понять. Есть файл екселя, настроил выгрузку в 1с, так после второго или третьего прогона выгрузки постоянно выпадает ошибка: Ошибка при вызове метода контекста (Open): Произошла исключительная ситуация (Microsoft JET Database Engine): Внешняя таблица не имеет предполагаемый формат.
У меня стоит офис 2010, крякнутый. Файл с расширением *.xlsx. Что я делаю не так?
17. StepByStep 3666 14.04.13 01:08 Сейчас в теме
(14) DoctorRoza,

Попробуйте установить Microsoft Access Database Engine 2010 Redistributable
Ссылка 32х и 64х: http://www.microsoft.com/en-us/download/details.aspx?id=13255

В настройке обработки выберите "Тип подключения ADODB" = "Excel 12.0".
И с такой настройкой осуществляйте загрузку.

Если нетрудно, отпишите, пожалуйста, о результатах.

Удачи.
76. AlexandraSerg 7 21.01.18 20:48 Сейчас в теме
(17) Здравствуйте!
у меня та же проблема.
скачала, установила Microsoft Access Database Engine 2010 Redistributable
по ссылке: http://www.microsoft.com/en-us/download/details.aspx?id=13255

установила "Тип подключения ADODB" = "Excel 12.0".
Ошибка все равно выходит: Ошибка при вызове метода контекста (Open): Произошла исключительная ситуация (Microsoft JET Database Engine): Внешняя таблица не имеет предполагаемый формат.
15. vers139 53 09.04.13 16:08 Сейчас в теме
У меня такая проблема: у поставщиков есть товар с кодом 0001. При сохранении в Excel в ячейку пишется значение 1, формат 0000. Пользователю показывается правильно: 0001. Однако при считывании данных из Excel получаю значение 1, а надо именно 0001. Можно ли это как-то "активизировать" каким-нибудь параметром?
18. StepByStep 3666 14.04.13 01:35 Сейчас в теме
(15) vers139,
Самое простое - считывать ячейку как строку.
НоваяСтрока[ИмяКолонки] = Строка(ЗначениеЯчейки);
16. пользователь 12.04.13 00:52
Сообщение было скрыто модератором.
...
19. vers139 53 16.04.13 16:35 Сейчас в теме
ЗначениеЯчейки

это ЛистЭксель.Cells(СтрокаЭксель, НомерКолонкиКод).Value?
20. StepByStep 3666 17.04.13 21:27 Сейчас в теме
21. Pawlick 10 17.05.13 09:51 Сейчас в теме
Братцы, а мне нужно в цикле перебирать строки и получить доступ к свойствам строки.
Никак не воткнусь как это сделать?

т.е в случае подключения через
Excel = Новый COMОбъект("Excel.Application");
Excel.WorkBooks.Open(ИмяФайла);
ExcelЛист = Excel.Sheets(НомерЛистаExcel);

есть возможность сдалать так:
ExcelЛист.Rows(НомерСТроки).___

А вашем случае взлетит?
22. unoDosTres 28.05.13 10:25 Сейчас в теме
вообще какойто весьма неудобный способ считывания (воспользовался только изза отсутствия экселя на машине)... много лишнего кода писать приходится, да и методы и функции длл не везде найдешь, писал обработку ЗТЧ на этой приблуде, видимо изза недостатка знаний пришлось такой кривокод нагородить что ппц, мало того что из цикла хрен пойми когда выходит, после считывания файла Экселя, уже по всем строкам пробежал а EOF никак достичь не могу, пришлось писать принудительный выход, да и потом наперед ведь не знаешь длину файла, а метода этой длл для его определения я и не знаю.. короче разочаровался..
23. echo77 1868 01.10.13 14:10 Сейчас в теме
зашифрованные листы не читает
24. StepByStep 3666 03.10.13 21:46 Сейчас в теме
(23) echo77,
Если Вы имеете в виду запароленную книгу - то да - не читает, как впрочем и другие.
28. Shade 2 13.03.14 01:28 Сейчас в теме
(24) уважаемый МА :) скажите пожалуйста, можно ли переделать имеющийся код загрузки Эксель методом на ADODB? Вот сам код:
Процедура ЗагрузитьФайл(Объект,ИмяТабличнойЧасти)
Екс = Новый COMОбъект("Excel.Application");

Попытка
ВыбрФайл = Екс.WorkBooks.Open(ПолноеИмяФайла); //Открываем файл
ОК = Истина;
Исключение
Предупреждение("Неудалось открыть файл");
КонецПопытки;

Если ОК = Истина Тогда
Sheet = Екс.Sheets(1); //Номер листа

Если Объект[ИмяТабличнойЧасти].Количество() > 0 Тогда

ТекстВопроса = "Перед заполнением табличная часть будет очищена. Заполнить?";
Ответ = Вопрос(ТекстВопроса, РежимДиалогаВопрос.ДаНет, , КодВозвратаДиалога.Да, Объект.Метаданные().Имя);
Если Ответ <> КодВозвратаДиалога.Да Тогда
Возврат;
КонецЕсли;

Объект[ИмяТабличнойЧасти].Очистить();
КонецЕсли;

// обработка файла
Стр = НомПервойСтроки;
Пока Стр <= НомПоследнейСтроки Цикл
Строка = Объект[ИмяТабличнойЧасти].Добавить();

Строка.Представление = СокрЛП(Sheet.Cells(Стр, ПредставлениеДок).Value);

Попытка
Строка.Дебет = Число(Sheet.Cells(Стр, КолДеб).Value);
Исключение
Строка.Дебет = 0;
КонецПопытки;

Попытка
Строка.Кредит = Число(Sheet.Cells(Стр, КолКред).Value);
Исключение
Строка.Кредит = 0;
КонецПопытки;

Попытка
Строка.Дата = Дата(Sheet.Cells(Стр, КолДата).Value);
Исключение
Строка.Дата = "";
КонецПопытки;

Стр = Стр + 1;
КонецЦикла;
КонецЕсли;

Екс.WorkBooks.Close();
КонецПроцедуры

Заранее спасибо за ответ
32. StepByStep 3666 13.03.14 10:12 Сейчас в теме
(28) Shade,
Предложенная Вами загрузка относится к другому методу, описанному мною в статье:
Загрузка из EXCEL в 1С /3+1 метод/. MS EXCEL.Application: http://infostart.ru/public/163641/
+ Дебет/Кредит и др. - это уже по необходимости.
25. spaminfostart 15 05.03.14 14:44 Сейчас в теме
Не подходит для файла с числом столбцов более 255.
1Cnick.sk; +1 Ответить
29. StepByStep 3666 13.03.14 09:12 Сейчас в теме
(25) spaminfostart,
СПАСИБО.
"Не подходит для файла с числом столбцов более 255."
Откровенно говоря, на таком большом количестве колонок не тестировал.
Надо посмотреть.
55. AlexO 135 26.04.15 21:31 Сейчас в теме
(29)
Откровенно говоря, на таком большом количестве колонок не тестировал.
Это при подключении ADODB и старом Excel. В новом Эксель ограничение убрали...
80. 1Cnick.sk 22.01.19 10:21 Сейчас в теме
(29)
(55) Что значит в старом или новом? У меня 2010 - ограничение есть.
81. GreenDragon 22.01.19 15:49 Сейчас в теме
(80) 2010 - это не актуальная версия. Это 8 с лишним лет назад
26. Shade 2 11.03.14 18:55 Сейчас в теме
Огромное спасибо!!! Со старой версией майкрософтовского движка и правда иногда возникала проблема тип Число у колонки, от чего не типовые значения слетали, с новым все тип топ, только пришлось установить обе компоненты http://www.microsoft.com/download/en/details.aspx?id=23734 и http://www.microsoft.com/en-us/download/details.aspx?id=13255 с одной той что в шапке не взлетело.
Спасибо!
30. StepByStep 3666 13.03.14 10:04 Сейчас в теме
(26), (27) Shade,
Мне на Win7/8 x64 достаточно было http://www.microsoft.com/en-us/download/details.aspx?id=13255

http://www.microsoft.com/en-us/download/details.aspx?id=23734:
Version: Date Published:
2 10/3/2008
File name: File size:
AccessDatabaseEngine.exe 25.3 MB

http://www.microsoft.com/en-us/download/details.aspx?id=13255:
Version: Date Published:
SP2 7/22/2013
File name: File size:
AccessDatabaseEngine.exe 25.3 MB
AccessDatabaseEngine_x64.exe 27.3 MB
31. Shade 2 13.03.14 10:11 Сейчас в теме
(30) я написал, вдруг у кого не запустится, как у меня, решение нашел на мисте, у человека тоже не заработало, он установил второй пакет все завелось, мне тоже помогло :) он говорил про 7. у меня не завелось на foundation 2012 server :)
33. StepByStep 3666 13.03.14 10:14 Сейчас в теме
(31) Shade,
ХОРОШО. Кому-то может пригодиться.
34. Karlitos 17.04.14 15:47 Сейчас в теме
(33) огромное спасибо! Статья очень помогла реализовать загрузку цен из прайс-листов в формате .XLS. Раньше все было завязано на Excel, теперь всем OpenOffice накатили)
57. Flares 21.12.15 18:01 Сейчас в теме
(30) подскажите с чем может быть связана такая проблема, ADODBRecordset.Fields.Count работает максимум до 52 колонки, как только этот лимит превышается (53 колонки в файле) все равно выдает 52 и попытка прочитать содержимое в 53 колонке выдает ошибку. Кто-то писал про предел в 255 - но тут и близко нет!!! У меня стоит Microsoft Access Database Engine 2010 32x тип подключения соотв "Excel 12.0" На другом сервере грузится, НО на нем никогда не устанавливался Офис. похоже дело в офисе или его кривой версии.
59. StepByStep 3666 24.12.15 17:24 Сейчас в теме
(57) Flares,
Нет ли в файле множества скрытых колонок, или объединенных ячеек, состоящих из множества ячеек. Такое бывает.
Можно попытаться пересохранить файл в MS Office.
60. Flares 01.02.16 15:46 Сейчас в теме
(59) Нет ни скрытых ни объединенных. Ни Пересохранение файла, ни переустановка Microsoft Access Database Engine 2010 не помогает :( Оч. странно.
64. StepByStep 3666 20.07.16 13:01 Сейчас в теме
(60) Flares,
Попробуйте "поиграть" с разными строками соединения:

// Основные.
1. ("Jet_OLEDB_4_0_EXCEL_8_0" , "Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(ФайлEXCEL) + ";Extended Properties=""EXCEL 8.0;HDR=YES;IMEX=1;""")
2. ("EXCEL_Driver_XLS", "Driver={Microsoft EXCEL Driver (*.xls)};Dbq= " + СокрЛП(ФайлEXCEL) + ";ReadOnly=1;")
3. ("ACE_OLEDB_12_0_EXCEL_12_0_XML", "Provider=Microsoft.ACE.OLEDB.12.0;Data Source= " + СокрЛП(ФайлEXCEL) + ";Extended Properties=""EXCEL 12.0 XML;HDR=YES;IMEX=1;""")
4. ("EXCEL_Driver_XLSX", "Driver={Microsoft EXCEL Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)};Dbq=" + СокрЛП(ФайлEXCEL) + ";ReadOnly=1;")
// Дополнительные.
5. ("Jet_OLEDB_4_0_EXCEL_9_0" , "Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(ФайлEXCEL) + ";Extended Properties=""EXCEL 9.0;HDR=YES;IMEX=1;""")
6. ("ACE_OLEDB_12_0_EXCEL_8_0", "Provider=Microsoft.ACE.OLEDB.12.0;Data Source= " + СокрЛП(ФайлEXCEL) + ";Extended Properties=""EXCEL 8.0;HDR=YES;IMEX=1;""")
7. ("ACE_OLEDB_12_0_EXCEL_12_0", "Provider=Microsoft.ACE.OLEDB.12.0;Data Source= " + СокрЛП(ФайлEXCEL) + ";Extended Properties=""EXCEL 12.0;HDR=YES;IMEX=1;""")
87. chemezov 47 13.09.19 03:35 Сейчас в теме
27. Shade 2 11.03.14 18:56 Сейчас в теме
от операционки зависит если вин 7 или сервер фаундейшн 2012 64 бит то нужно обе
35. Mraque 16.10.14 16:54 Сейчас в теме
StepByStep, спасибо большое за развернутую статью.
36. mihast 68 21.10.14 08:21 Сейчас в теме
Жаль, что картинки так не загрузить...
Или просто ЗДЕСЬ не описано ?
37. Bukaska 140 21.10.14 16:22 Сейчас в теме
(36) mihast, Почему не загрузить?
Обратите внимание на мигающую голубую ссылку внизу сообщения: Прикрепить файл
Ниже неё есть только галка: Подписаться на ответы этой темы.
далее внизу уже только кнопки: Ответить и Просмотр
Не можем искать сверху вниз, ищите согласно моего комментария снизу вверх)
38. Mraque 21.10.14 16:46 Сейчас в теме
Подскажите пожалуйста
:
На клиенте все работает замечательно.
Перенес код в фоновое задание, выполняющееся на сервере.
Появилась ошибка:

Ошибка при установке значения атрибута контекста (ActiveConnection)
Catalog.ActiveConnection = СтрокаПодключения;
по причине:
Произошла исключительная ситуация (ADOX.Catalog): Provider cannot be found. It may not be properly installed.


СтрокаПодключения = "
|Provider=Microsoft.Jet.OLEDB.4.0;
|Data Source="+ИмяФайла1+";
|Extended Properties=""Excel 8.0;HDR=Yes;"";";

Сервер 1С Предприятия это отдельный сервер. Везде 64-битная операционная система.
На клиенте и на нем была установлена http://www.microsoft.com/en-us/download/details.aspx?id=23734. Но не помогло.

В чем может быть проблема ?
39. StepByStep 3666 25.11.14 23:43 Сейчас в теме
(38) Mraque,
Возможно у пользователя, от имени которого выполняется задание, не хватает прав.
91. user656915_sibilev.reg 06.09.22 20:58 Сейчас в теме
(39) Подскажите, пожалуйста, каких может не хватать.
Вроде все перепробовал из советов выше, все равно ошибка вылезает:
Произошла исключительная ситуация (ADODB.Connection): Операция не допускается, если объект закрыт.
40. ssa 26.11.14 18:29 Сейчас в теме
Загружаю указанным методом файл. Значения, находящиеся в одной колонке файла переносятся в результирующую таблицу как-то странно:
ЗначенияВФайле |  ЗначенияВТаблице
14,24          | 14,24
49,30          | 49,3
98,60          | 98,59999999999999
147,89         | 147,89
71,18          | 71,18000000000001

Т.е. непонятно, почему так с разрядностью некоторых чисел происходит.
В файле для всей колонки установлен числовой тип с точностью 2.
Почему так может быть?
41. StepByStep 3666 27.11.14 13:41 Сейчас в теме
(40) ssa,
Такое наблюдал. Это некритично, т.к. в дальнейшем приводя к значению определенного реквизита 1С произойдет правильное округление.
В реальности в файле может находиться значение 98,59999999999999 (внутреннее содержание ячейки), которое средствами форматирования excel-ячейки приводится к виду 98,60.
42. ssa 27.11.14 14:49 Сейчас в теме
(41)
В том то и дело, что в файле значение 98,6 - сам вбивал )
43. StepByStep 3666 27.11.14 21:09 Сейчас в теме
(42) ssa,
Что ж, оставим это на совести мелкософта.
44. ssa 28.11.14 01:00 Сейчас в теме
(43) StepByStep
Да, придется принять как данное. Буду работать со строковыми значениями.
83. vodorosl 71 10.04.19 23:40 Сейчас в теме
Windows Server 2012R2 (так же на Win7 Pro) выдает одинааковую ошибку:

ВнешняяОбработка.ВнешняяОбработка1.Форма.Форма.Форма(40)}: Ошибка при вызове метода контекста (Open)
ADODBRecordset.Open(ТекстЗапроса, ADODBConnection);
по причине:
Произошла исключительная ситуация (ADODB.Recordset): Невозможно использование подключения для выполнения операции. Оно закрыто или не допускается в данном контексте.
45. mvgfirst 6 07.01.15 18:05 Сейчас в теме
Вопрос знатокам:
Как с помощью ADO получить информацию о сгруппированных строках на листе Excel?

Некоторые из поставщиков не дублируют группирующее поле в колонке листа.
(особенно те которые формируют прайс-листы из 1С)... и если группировка одноуровневая то это еще по божески. Можно как-то при загрузке отличить группу от товара.

А как быть когда групп много и они вложены друг в друга?
46. kuza_87 28 06.02.15 09:07 Сейчас в теме
На получается считать данные. Пробую "MicrosoftJetOLEDB40" - внешняя таблица не имеет предполагаемый формат
"MicrosoftACEOLEDB12" - Не удается найти указанный поставщик. возможно, он установлен неправильно.

То что вы писали установить - я установил

Опериционка - Server 2008 R2
47. kuza_87 28 06.02.15 09:11 Сейчас в теме
48. kuza_87 28 06.02.15 09:24 Сейчас в теме
Проблема решилась после перезагрузки сервера. Извините за беспокойство, и спасибо за программу
49. cmd_vasec 34 25.03.15 11:59 Сейчас в теме
У меня в файловом варианте все работает, а в клиент-серверном выдает ошибку: {Форма.Форма.Форма(266)}: Ошибка при вызове метода контекста (Open): Произошла исключительная ситуация (ADODB.Connection): Не удается найти указанный поставщик. Вероятно, он установлен неправильно.

все делал на сервере, права админа.
68. Shurik1C 01.08.16 11:37 Сейчас в теме
(49) cmd_vasec,

тоже такая хрень была
ничего из выше описанного не помогло

в итоге вылечил вот этим

https://www.microsoft.com/en-us/download/details.aspx?id=23734
69. GreenDragon 02.09.16 02:11 Сейчас в теме
(68) Shurik1C, не забываем, что клиент 1С - 32-х битный. Могу предположить, что Сервер 1С в вашей ситуации был 64-битный. Соответственно, если компонента стоит 32-битная, то сервер не сможет с ней работать, тогда как клиент - легко. Ну, и обратная ситуация. Решил аналогичную проблему (у меня Сервер читал, а Клиент - нет) просто передачей файла на сервер через ВременноеХранилище. Кстати, нюанс битности в контексте 1С при работе с ADO, мало кто затрагивает.
50. cmd_vasec 34 25.03.15 12:22 Сейчас в теме
Винда 2012, а 1с - 64 битный
51. fzt 25.03.15 12:28 Сейчас в теме
(50) cmd_vasec, сделай обертку СОМ объекта как тут
http://infostart.ru/public/197627/
53. bacila 03.04.15 19:49 Сейчас в теме
(50) cmd_vasec, надо добавить такие ключи, и прописать в них значения и Microsoft Access Database Engine 2010 надо 64 битный

ОС: 64bit офис: 64bit) или (ОС: 32bit офис: 32bit)

Ключ: HKCR \ CLSID \ {3BE786A0-0366-9434-4F5C-25CF162E475E} \ InprocServer32 \

Параметр: (По умолчанию)

Данные значения: C: \ Program Files \ Common Files \ Microsoft Shared \ Office14 \ ACEOLEDB.DLL


(ОС: 64bit офис: 32bit)

Ключ: HKCR \ Wow6432Node \ CLSID \ {3BE786A0-0366-9434-4F5C-25CF162E475E} \ InprocServer32 \

Параметр: (По умолчанию)

Данные значения: C: \ Program Files (x86) \ Common Files \ Microsoft Shared \ Office14 \ ACEOLEDB.DLL
52. cmd_vasec 34 25.03.15 12:36 Сейчас в теме
проблему решил установкой Microsoft Access Database Engine 2010 Redistributable (16/12/2010) 64 - разрядной версии.
54. StepByStep 3666 04.04.15 17:06 Сейчас в теме
(52) cmd_vasec,
Хорошо. Это описано здесь http://infostart.ru/public/120961/
Надо было конечно это и здесь описать.
56. XelOla 17 18.10.15 08:44 Сейчас в теме
(54)
Здравствуйте! Попыталась воспользоваться вашей обработкой.
Вызов - ЗагрузитьМетодом_MSADODB(Файл, "Работники",,,,1);
Ваша функция Функция ЗагрузитьМетодом_MSADODB(Знач ФайлEXCEL, Знач ИмяЛиста, Знач СтрокаЗаголовка = 1, НачСтрока = 0, КонСтрока = 0, КолвоСтрокExcel,
Знач ПодключениеADODB = "MicrosoftJetOLEDB40") Экспорт - полная копия.
Файл - строк штук 15, столбцов 8. Некое подобие табеля.
При определении падает в
Сon nectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(ФайлEXCEL) + ";Extended Properties=""Excel 8.0;HDR=YES;IMEX=1;""";
Потом ошибка
{Форма.Форма.Форма(87)}: Ошибка при вызове метода контекста (Open): Произошла исключительная ситуация (Microsoft JET Database Engine): Определено слишком много полей.
Хм... а другой файл прочел. Я пока не нашла в чем причина...
58. StepByStep 3666 24.12.15 17:21 Сейчас в теме
(56) XelOla,
Существует ограничение на 255 колонок для файла типа xlsx.
1Cnick.sk; +1 Ответить
61. lev6975 15.04.16 18:56 Сейчас в теме
У меня с датами траблы - в экселе стоит тип ячейки"дата". В 1С летит номер дня с 01.01.1900 года... селектил с типом CDate,некоторые берет, но, тогда, не все даты берет, почему - то. А, некоторые, попросту не считывает и возвращает пустое поле... В режиме CSTR грузит числами дня с 1900 года...Например, дата 16.04.2016 это 42476
день с 01.01.1900...Хорошо бы, просто, строкой дату показывал...В 1С ее можно самому привести
62. fzt 20.04.16 12:19 Сейчас в теме
(61) lev6975, в соседней ветке отписался. Не помогло?
65. StepByStep 3666 20.07.16 13:04 Сейчас в теме
(61) lev6975,
Попробуйте вместо HDR=YES использовать HDR=NO.
63. prelest' 18.07.16 12:45 Сейчас в теме
Есть проблема с чтением некоторых ячеек, возвращает пустое поле. В таблице в ячейке стоит текст, а в 1С NULL. Скажите в чем может быть косяк?
66. StepByStep 3666 20.07.16 13:06 Сейчас в теме
67. prelest' 26.07.16 13:00 Сейчас в теме
(66)
Спасибо.

На одном из форумов нашла:
"Смешанные данные в колонках (подводный камень способный попортить не мало крови) Из-за настроек по умолчанию Excel ваша программа нормально считывающая данные из полностью заполненных таблиц, может сбиться на тех таблицах, в первых N (>8) записях которых пустые значения.
В результате, когда доходит до записей с не пустыми полям их значения возвращаются как NULL независимо от реального содержимого в XLS.
Для предотвращения подобной ситуации следует использовать аттрибут IMEX=1 в Extended Properties. "
70. mikeA 1 19.10.16 10:27 Сейчас в теме
// Нумерация MS ADODB начинается с 1
Нумерация с нуля вроде.
71. mikeA 1 19.10.16 11:35 Сейчас в теме
(70) mikeA,
Хотя нет, это нумерация колонок в экселе с 0
73. ditiatko 39 02.11.16 10:26 Сейчас в теме
Extended Properties = Excel 12.0;HDR=NO;IMEX=1 - при первых восьми пустых строках не читает, удаляю строки - читает
74. Bozau 03.05.17 09:52 Сейчас в теме
из неприятностей, с которыми приходилось сталкиваться с загрузкой через ADODB (и которые не получилось тогда решить) было неправильное определение типа колонки (вместо строки - число) и приведение длинных цепочек цифр к экспоненциальной форме записи. Очень неприятно получать в качестве штрихкода товара запись типа "4,67Е13", или вместо ИНН что-нибудь типа "6,67Е11"
92. BarsukM 10.11.22 13:25 Сейчас в теме
(74) это из-за IMEX=1. В этом режиме берется не само значение, а его строковое представление.
IMEX=0 может помочь.
77. pyrkin_vanya 487 05.11.18 20:25 Сейчас в теме
Добрый день. Подскажите пожалуйста, каким образом производить загрузку из файла в клиент-серверном варианте?
78. GreenDragon 05.11.18 22:16 Сейчас в теме
(77) Я реализовал через временное хранилище. На стороне клиента при отправке пакую файл и отправляю в процедуру на сервере АдресВременногоХранилища. На стороне сервера делаю примерно это:

	Если АдресВременногоХранилища <> Неопределено Тогда
		ДвоичныеДанные = ПолучитьИзВременногоХранилища(АдресВременногоХранилища);
		ИмяВременногоФайла = ПолучитьИмяВременногоФайла(Расширение);
		ДвоичныеДанные.Записать(ИмяВременногоФайла);
		ФайлEXCEL = ИмяВременногоФайла;
	КонецЕсли;
pyrkin_vanya; +1 Ответить
79. pyrkin_vanya 487 12.11.18 12:45 Сейчас в теме
(78)Строка соединения не проходит.

 СonnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source= "  + СокрЛП(ФайлEXCEL) + ";Extended Properties=""Excel 8.0;HDR=YES;IMEX=1;""";


Проходит это

СтрокаСоединения = "Driver={Microsoft Excel Driver (*.xls)};Dbq=" + СокрЛП(ФайлEXCEL) + ";";


Но, не читает некоторые значения в ячейках. Просто типа их нет.

Может кто сталкивался?
82. superlexa2008 25.02.19 16:07 Сейчас в теме
я так читаю


ТабДок = Новый ТабличныйДокумент;
ТабДок.Прочитать(ПутьКфайлу);

ТЗ = ОбщегоНазначения.ТабличныйДокументВТаблицуЗначений(ТабДок);



Функция ТабличныйДокументВТаблицуЗначений(ТабДок) Экспорт

ПЗ = Новый ПостроительЗапроса;
ПЗ.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТабДок.Область());//передаем ТЗ
ПЗ.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
ПЗ.ЗаполнитьНастройки();
ПЗ.Выполнить();
ТЗ = ПЗ.Результат.Выгрузить();

Возврат ТЗ;

КонецФункции
Antoska; olezhe; +2 Ответить
85. olezhe 21 26.04.19 18:24 Сейчас в теме
(82) Хахахахаха! Гениально. Интересно сравнить производительность. Но таблицу в 4500 строк этот метод втягивает мгновенно.
86. GreenDragon 26.04.19 19:22 Сейчас в теме
Попробуйте скормить своему методу таблицу, в которой присутствуют объединённые ячейки.
84. olezhe 21 26.04.19 18:10 Сейчас в теме
У многих в Windows 10 возникает проблема с Microsoft.jet.oledb.4.0

Microsoft.jet.oledb.4.0 не будет работать в 64bit операционной системе (он для 32bit), вместо него следует использовать Microsoft.ACE.OLEDB.12.0
atroxa; nayd; +2 Ответить
88. loki03 07.11.19 06:43 Сейчас в теме
Ошибка при установке значения атрибута контекста (AbsolutePage): Произошла исключительная ситуация (ADODB.Recordset): Текущий объект Recordset не поддерживает закладки. Это связано с ограничением поставщика или с выбранным типом курсора.

ADODBRecordset = Новый COMОбъект("ADODB.Recordset");
ADODBRecordset.Open(ТекстЗапроса, ADODBConnection);

нужно добавить

ADODBRecordset = Новый COMОбъект("ADODB.Recordset");
ADODBRecordset.CursorType=1:
ADODBRecordset.Open(ТекстЗапроса, ADODBConnection);
89. loki03 07.11.19 12:44 Сейчас в теме
И еще такая проблема. Теряется первая строка.
В файле 17222 строки, смотрю в отладчике 17221.
в чем может быть проблема, подскажите.
90. user742690 29.12.19 23:31 Сейчас в теме
Если листов в книге нет как это указать при чтении?
НаборДанных.Open("activeworkbook",Соединение);
Как правильно прописать?Подскажите,пожалуйста.
93. user645801_yyyuuu123q 28.12.22 08:37 Сейчас в теме
А можно ли через адо установить фильтры подобно:
 Область = Excel.ActiveSheet.Range(Excel.ActiveSheet.Cells(1,1), Excel.ActiveSheet.Cells(1,ВсегоКолонок));
        Область.AutoFilter();
Оставьте свое сообщение