IE 2016

Загрузка из EXCEL в 1С. Чтение файла XLSX средствами 1С. ЧтениеXML

Опубликовал StepByStep в раздел Программирование - Практика программирования

ПРАКТИЧЕСКОЕ ПОСОБИЕ РАЗРАБОТЧИКА: Метод "NativeXLSX" (ЧтениеXML).
Обрабатываются данные EXCEL типов: "Строка", "Число", "Дата" ("Время"), "Булево", "Процент".

В данной статье приведен функционал, с помощью которого в обработке
"Импорт из EXCEL и др.источников (xls,xlsx,ods,sxc,dbf,mxl,csv,sql) в 1С": http://infostart.ru/public/120961/
производится считывание данных из файлов табличного типа *.xlsx средствами 1С (метод "NativeXLSX").

19.09.2014. Уточненная редакция.

Метод позволяет обрабатывать
данные EXCEL типов: "Строка", "Число", "Дата" ("Время"), "Булево", "Процент".


Методы загрузки из внешнего источника:
- Метод "MS ADO" (Чтение файлов xls, xlsx средствами Microsoft ADO): http://infostart.ru/public/163640/
- Метод "MS EXCEL" (Чтение файлов xls, xlsx с картинками средствами Microsoft Office): http://infostart.ru/public/163641/
- Метод "LO CALC" (Чтение файлов xls, xlsx, ods, sxc с картинками средствами LibreOffice): http://infostart.ru/public/163642/
- Метод "NativeXLSX" (Чтение файлов xlsx с картинками средствами 1С. ПостроительDOM): http://infostart.ru/public/300092/
- Метод "NativeXLSX". Предыдущий вариант (Чтение файлов xlsx средствами 1С. ЧтениеXML):
http://infostart.ru/public/225624/
- Метод "Excel1C" (Загрузка на платформе 8.3.6 с картинками. Чтение файлов xls, xlsx, ods): http://infostart.ru/public/341855/
- Список листов файла: http://infostart.ru/public/163724/


Публикаций на тему загрузки из EXCEL - множество, но
"
— Вам билетёр нужен?
— Был нужен, да уже взяли.
— Может и я на что сгожусь?
— Может и сгодишься, если скалиться не будешь ...
"
"НЕУЛОВИМЫЕ МСТИТЕЛИ" (1966).


Публикации других авторов:

"XLSX средствами 1С":
1cmax: Чтение файлов *.xlsx средствами 1С 8.2 (Управляемые формы) в т.ч. Веб-клиент: http://infostart.ru/public/142187
Abadonna: Чтение файлов *.xlsx средствами 1С 8.2: http://infostart.ru/public/139556
Dzenn: Загрузка файлов Excel XLSX через XML: http://infostart.ru/public/205359
webstep: Чтение документа Excel 2007 без офиса, без ВК: http://infostart.ru/public/202023
Душелов: Чтение/Запись документа Excel 2007 без офиса, без ВК. (с примером для 7.7, 8.1 и 8.2 на управляемых формах): http://infostart.ru/public/19139
"Другое: чтение/редактирование XML":
anig99: "Однопальцевое" чтение XML для 8.2: http://infostart.ru/public/84254
Lokiy: Парсинг, преобразование, редактирование XML: http://infostart.ru/public/198131
onec.developer: Редактор XML на управляемых формах 8.2: http://infostart.ru/public/201077
Yashazz: Просмотр xml-файлов: http://infostart.ru/public/203514
Душелов: Создание документа Word 2007: http://infostart.ru/public/16215
"Не 1С, но полезно":
iddqd: akXmlEdit - v1.5.0.7 редактор XML: http://infostart.ru/public/15464


&НаКлиенте
Процедура ПриОткрытии(Отказ)
    ФайлEXCEL= "D:\Товар.xlsx";
    ИмяНомерЛиста = Новый Структура ("ИмяЛиста, НомерЛиста","Alfa1", 1);
    СтрокаЗаголовка = 1;
    НачСтрока = 0;
    КонСтрока = 0;
    КолвоСтрокExcel = 0;
    ЗагрузитьМетодом_NativeXLSX_НаСервере(ФайлEXCEL, ИмяНомерЛиста, СтрокаЗаголовка, НачСтрока, КонСтрока, КолвоСтрокExcel);
КонецПроцедуры

&НаСервере
Процедура ЗагрузитьМетодом_NativeXLSX_НаСервере(ФайлEXCEL, ИмяНомерЛиста, СтрокаЗаголовка, НачСтрока, КонСтрока, КолвоСтрокExcel)
    ТаблицаРезультат = ЗагрузитьМетодом_NativeXLSX(ФайлEXCEL, ИмяНомерЛиста, СтрокаЗаголовка, НачСтрока, КонСтрока, КолвоСтрокExcel);
КонецПроцедуры

// Метод "NativeXLSX" (ЧтениеXML).
// Преобразует текст формата XML (файл типа XLSX) в таблицу значений,
// при этом колонки таблицы формируются на основе описания в XML.
//
// Параметры:
//      ФайлEXCEL - Полное имя файла (путь к файлу с именем файла и расширением)
//      ИмяНомерЛиста - Структура Имя и Номер выбранного листа файла EXCEL.
//      СтрокаЗаголовка (по умолчанию = 1) - Номер строки EXCEL, в которой расположены заголовки колонок.
//          Не используется.
//      В обработке 1-я строка анализируется для сопоставления колонок EXCEL с реквизитами 1С (справочники, докуметны, регистры).
//      НачСтрока (по-умолчанию = 0) - Номер начальной строки, начиная с которой считываются данные из EXCEL.
//      КонСтрока (по-умолчанию = 0) - Номер конечной строки, которой заканчиваются считываемые данные из EXCEL.
//          Если НачСтрока=0 и КонСтрока=0, то считывается вся таблица, находящаяся на листе EXCEL.
//      КолвоСтрокExcel - Количество строк на листе "ИмяЛиста" EXCEL. Возвращается в вызываемую процедуру.
//
// Возвращаемые значения:
//      ТаблицаРезультат - Результат считывания с листа "ИмяНомерЛиста" EXCEL.
//
&НаСервере
Функция ЗагрузитьМетодом_NativeXLSX(Знач ФайлEXCEL, Знач ИмяНомерЛиста, Знач СтрокаЗаголовка = 1, Знач НачСтрока = 0, Знач КонСтрока = 0, КолвоСтрокExcel = 0)
    Перем ZIPКаталог, ФайлИмяЛиста, ФайлНомерЛиста, КолвоКолонокEXCEL, НомерСтроки, НомерКолонки, ИмяКолонки, ИндексКолонки, ШиринаКолонки, ДлинаСтроки;
    Перем МассивИменКолонокXLSX, МассивSharedStrings, МассивNumFmtId, СоответствиеNumFmtIdFormatCode;
    Перем
SheetX,ЗначениеЯчейки, ТипЗначения, ФорматЯчейки, ФорматСтиля;
    Перем ТаблицаРезультат, НоваяСтрока;
   
    ФайлНомерЛиста  = ИмяНомерЛиста.НомерЛиста;
    ФайлНомерЛиста = ?(ФайлНомерЛиста = 0, 1, ФайлНомерЛиста);
   
    ZIPКаталог = КаталогВременныхФайлов() + "XLSX\";
    Если НЕ ПредварительнаяОбработкаФайлаXLSX(ФайлEXCEL, ZIPКаталог) Тогда
        Возврат Новый ТаблицаЗначений;
    КонецЕсли;
   
    СоответствиеNumFmtIdFormatCode = Новый Соответствие;
    МассивNumFmtId = ИзвлечьДанныеИзФайла_StylesXML(ZIPКаталог, СоответствиеNumFmtIdFormatCode);
   
    МассивSharedStrings = ИзвлечьДанныеИзФайла_SharedStringsXML(ZIPКаталог);
   
    SheetX = Новый ЧтениеXML;
    SheetX.ОткрытьФайл(ZIPКаталог + "XL\WorkSheets\Sheet" + ФайлНомерЛиста + ".xml");
   
    МассивИменКолонокXLSX = ПолучитьМассивИменКолонокНаЛистеXLSX(SheetX);
    КолвоКолонокEXCEL = МассивИменКолонокXLSX.Количество();
   
    // Создание результирующей таблицы, в которую будут записываться считанные из EXCEL данные.
    ТаблицаРезультат = Новый ТаблицаЗначений;
    // Формирование колонок результирующей таблицы.
    // "НомерСтроки" - для наглядности и удобства.
    // В зависимости от разрабатываемой обработки.
    // "Сопоставлено" - может быть другим.
    // Здесь же могут быть добавлены другие колонки, не формируемые из содержимого файла EXCEL.
    ТаблицаРезультат.Колонки.Добавить("НомерСтроки", Новый ОписаниеТипов("Число"), "№", 4);
    ТаблицаРезультат.Колонки.Добавить("Сопоставлено", Новый ОписаниеТипов("Булево"), "Сопоставлено", 1)
;
    ТаблицаРезультат.Колонки.Добавить("УровеньГруппировки", Новый ОписаниеТипов(
"Число"), "Гр", 2); // Группировка строк в файле EXCEL.
    Для ит = 1 ПО КолвоКолонокExcel Цикл
        ИмяКолонки = "N" + ит;
        Колонка = ТаблицаРезультат.Колонки.Добавить(ИмяКолонки);
    КонецЦикла;
   
    SheetX = Новый ЧтениеXML;
    SheetX.ОткрытьФайл(ZIPКаталог + "XL\WorkSheets\Sheet" + ФайлНомерЛиста + ".xml");
   
    ЭтоНачалоДанных = Ложь;
    // Считать очередной узел XML.
    Пока SheetX.Прочитать() Цикл
        Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ЭтоНачалоДанных = Истина;
            Прервать;
        КонецЕсли;
    КонецЦикла;
    Если НЕ ЭтоНачалоДанных Тогда
        Возврат Новый ТаблицаЗначений;
    КонецЕсли;
   
    // Считать очередной узел XML.
    НомерСтроки = 0;
    Пока SheetX.Прочитать() Цикл
        Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
            Прервать;   // Окончание данных.
        КонецЕсли;
        Если ВРег(SheetX.Имя) = "ROW" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            НомерСтроки = НомерСтроки + 1;
            Если НЕ НачСтрока = 0 И НЕ НомерСтроки = 1 И НомерСтроки < НачСтрока Тогда
                Продолжить;
            КонецЕсли;
            НоваяСтрока = ТаблицаРезультат.Добавить();
            НоваяСтрока.НомерСтроки = НомерСтроки
;
            НоваяСтрока.УровеньГруппировки = SheetX.ЗначениеАтрибута("outlineLevel");

            Пока SheetX.Прочитать() Цикл    // Считаем колонки строки EXCEL.
                Если ВРег(SheetX.Имя) = "ROW" Тогда
                    Прервать;
                КонецЕсли;
                Если ВРег(SheetX.Имя) = "SHEETDATA" И SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
                    Прервать;   // Окончание данных.
                КонецЕсли;
                Если ВРег(SheetX.Имя) = "C" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
                    ТипЗначения = SheetX.ЗначениеАтрибута("t");
                    ФорматЯчейки = SheetX.ЗначениеАтрибута("s");
                    ИмяКолонки = SheetX.ЗначениеАтрибута("r");
                    ИмяКолонкиБезЦифр = ЗаменитьОдниСимволыДругими("0123456789", ИмяКолонки, "");
                    ИндексКолонки = МассивИменКолонокXLSX.Найти(ИмяКолонкиБезЦифр)+1;
                    SheetX.Прочитать();
                    Если ВРег(SheetX.Имя) = "V"  ИЛИ ВРег(SheetX.Имя) = "F" Тогда   // "V" - Значение, "F" - Формула.
                        Если ВРег(SheetX.Имя) = "F" Тогда
                            Пока НЕ ВРег(SheetX.Имя) = "V" Цикл
                                SheetX.Прочитать();
                            КонецЦикла;
                        КонецЕсли;
                        SheetX.Прочитать();
                        Если ВРег(SheetX.Имя) = "#TEXT" Тогда
                            ЗначениеЯчейки = SheetX.Значение;
                            ФорматСтиля = "";
                            Если (НЕ ФорматЯчейки = "" И НЕ ФорматЯчейки = Неопределено) Тогда
                                Попытка
                                    ИндексФормата = Число(ФорматЯчейки);
                                    ФорматСтиля = СоответствиеNumFmtIdFormatCode.Получить(МассивNumFmtId[ИндексФормата]);
                                Исключение
                                    ФорматСтиля = "";
                                КонецПопытки;
                            КонецЕсли;
                            Если ЗначениеЗаполнено(ЗначениеЯчейки) Тогда
                                Если ТипЗначения = Неопределено ИЛИ ВРег(ТипЗначения) = "N" ИЛИ ВРег(ТипЗначения) = "B" Тогда
                                    Попытка
                                        Значение1 = Число(ЗначениеЯчейки);
                                    Исключение
                                        Значение1 = ЗначениеЯчейки;
                                    КонецПопытки;
                                    ЗначениеЯчейки = Значение1;
                                    Если (ФорматСтиля = "" ИЛИ ФорматСтиля = Неопределено) Тогда
                                        // ФорматСтиля = Неопределено - Атрибут "s" отсутствует.
                                        // MS Office (2010) может не формировать в xml-файле описание стиля форматирования для ячейки.
                                        // LibreOffice (4.1.5) формирует в xml-файле необходимые описания стиля форматирования ячейки.
                                        // Сообщить("Не определен стиль форматирования для кода " + ФорматЯчейки + " значения " + ЗначениеЯчейки);
                                    КонецЕсли;
                                   
                                    Если ТипЗнч(ЗначениеЯчейки) = Тип("Строка")
                                        И (Найти(ЗначениеЯчейки, "E-") > 0 ИЛИ Найти(ЗначениеЯчейки, "E+") > 0) Тогда
                                        ЗначениеЯчейки = ПолучитьЧислоВСтепениИзСтроковогоЗначения(ЗначениеЯчейки);
                                    КонецЕсли;
                                   
                                    Если ТипЗнч(ЗначениеЯчейки) = Тип("Число") Тогда
                                        // ПРОЦЕНТ.
                                        Если ЭтоПроцентXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = Окр(ЗначениеЯчейки * 100, 3);
                                        // БУЛЕВО.
                                        ИначеЕсли ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = Булево(ЗначениеЯчейки);
                                        // ВРЕМЯ.
                                        ИначеЕсли ЭтоВремяXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = КонвертироватьЧислоXLSXвДатуВремя(ЗначениеЯчейки);
                                        // ДАТА.
                                        ИначеЕсли ЭтоДатаXLSX(ЗначениеЯчейки, ФорматСтиля) Тогда
                                            ЗначениеЯчейки = КонвертироватьЧислоXLSXвДату(ЗначениеЯчейки);
                                        // ЧИСЛО.
                                        ИначеЕсли ТипЗначения = Неопределено
                                            ИЛИ ( ЭтоЧислоXLSX(ЗначениеЯчейки, ФорматСтиля)
                                            И НЕ ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля)
                                            И НЕ ЭтоВремяXLSX(ЗначениеЯчейки, ФорматСтиля)
                                            И НЕ ЭтоДатаXLSX(ЗначениеЯчейки, ФорматСтиля) )
                                            Тогда
                                            // Без преобразования.
                                        Иначе
                                            // Прочие форматы.
                                        КонецЕсли;
                                       
                                    Иначе
                                       
                                        Сообщить("Не удалось преобразовать значение к ""числовому""(процент, время, дата, число) типу.");
                                       
                                    КонецЕсли;
                                   
                                ИначеЕсли ВРег(ТипЗначения) = "S" Тогда
                                   
                                    // МассивSharedStrings может быть пустым.
                                    Попытка
                                        ЗначениеЯчейки = СокрЛП(МассивSharedStrings[Число(SheetX.Значение)]);
                                    Исключение
                                        ЗначениеЯчейки = "";
                                    КонецПопытки;
                                   
                                ИначеЕсли ВРег(ТипЗначения) = "STR" Тогда
                       
                                    Если ТипЗнч(ЗначениеЯчейки) = Тип("Строка") Тогда
                                        ЗначениеЯчейки = СокрЛП(ЗначениеЯчейки);
                                    КонецЕсли;
                       
                                КонецЕсли;
                            КонецЕсли;
                           
                            ИмяКолонки = "N"+ИндексКолонки;
                            НоваяСтрока[ИмяКолонки] = ЗначениеЯчейки;
                            // Используется при формировании таблицы на форме обработки.
                            ШиринаКолонки = ТаблицаРезультат.Колонки[ИмяКолонки].Ширина;
                            ДлинаСтроки = СтрДлина(СокрЛП(ЗначениеЯчейки));
                            ТаблицаРезультат.Колонки[ИмяКолонки].Ширина = ?(ШиринаКолонки < ДлинаСтроки, ДлинаСтроки, ШиринаКолонки);
                           
                        КонецЕсли;
                    КонецЕсли;
                КонецЕсли;
            КонецЦикла;
            Если ((НЕ КонСтрока = 0 И (НомерСтроки + 1) > КонСтрока)
                ИЛИ (НЕ КолвоСтрокExcel = 0  И (НомерСтроки + 1) > КолвоСтрокExcel)) Тогда
                Прервать;   // Окончание диапазона считываемых данных.
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
   
    // Завершение работы.
    // Закрытие Объектов.
    SheetX.Закрыть();
   
    УдалитьКолонкиСНулевойШириной(ТаблицаРезультат);
   
    Возврат ТаблицаРезультат;
   
КонецФункции

&НаСервере
Функция ПредварительнаяОбработкаФайлаXLSX(ФайлEXCEL, ZIPКаталог)
    Перем Файл;
   
    Файл = ПолучитьОбъектФайл(ФайлEXCEL);
    Если Файл = Неопределено Тогда
        Сообщить("Невозможно загрузить данные, т.к. невозможно открыть для чтения файл:
        |" + ФайлEXCEL);
        Возврат Ложь;
    КонецЕсли;
   
    Если НЕ ВРег(Файл.Расширение) = ".XLSX" Тогда
        Сообщить("Файл с расширением " + Файл.Расширение +" не поддерживается методом NativeXLSX:
        |" + ФайлEXCEL);
        Возврат Ложь;
    КонецЕсли;
   
    Если НЕ РаспаковатьXLSXвКаталогВременныхФайлов(ФайлEXCEL, ZIPКаталог) Тогда
        Сообщить("Ошибка распаковки файла.
        |Возможно каталог временных файлов занят.
        |" + ФайлEXCEL);
        Возврат Ложь;
    КонецЕсли;
   
    Возврат Истина;
   
КонецФункции

&НаСервере
Функция ПолучитьОбъектФайл(Знач ФайлEXCEL)
    Перем Файл;
   
    Если НЕ ЗначениеЗаполнено(ФайлEXCEL) Тогда
        Возврат Неопределено;
    КонецЕсли;
   
    Файл = Новый Файл(ФайлEXCEL);
    Если НЕ ФайлСуществуетИДоступен(Файл.ПолноеИмя) Тогда
        Сообщить("Файл не существует/не доступен:
        |" + ФайлEXCEL);
        Возврат Неопределено;
    КонецЕсли;
   
    Возврат Файл;
   
КонецФункции

&НаСервере
Функция ФайлСуществуетИДоступен(ПолноеИмяФайла)
    Перем Файл;
   
    Файл = Новый Файл(ПолноеИмяФайла);
    Если НЕ Файл.Существует() Тогда
        Возврат Ложь;
    КонецЕсли;
   
    // Проверка: Занят ли файл другим процессом?
    Если НЕ ВРег(Файл.Расширение) = ".DBF" Тогда
        Попытка
            ПереместитьФайл(Файл.ПолноеИмя,Файл.ПолноеИмя);
        Исключение
            Сообщить("Файл не доступен:
            |" + Файл.ПолноеИмя);
            Возврат Ложь;
        КонецПопытки;
    КонецЕсли;
   
    Возврат Истина;
   
КонецФункции

&НаСервере
Функция РаспаковатьXLSXвКаталогВременныхФайлов(ФайлEXCEL, ZIPКаталог)
    Перем ZIPФайл;
   
    Попытка
        УдалитьФайлы(ZIPКаталог);
       
        ZIPФайл = Новый ЧтениеZipФайла;
        ZIPФайл.Открыть(ФайлEXCEL);
        ZIPФайл.ИзвлечьВсе(ZIPКаталог, РежимВосстановленияПутейФайловZIP.Восстанавливать);
        Возврат Истина;
    Исключение
        Возврат Ложь;
    КонецПопытки;
   
    Возврат Истина;
   
КонецФункции

&НаСервере
Функция ИзвлечьДанныеИзФайла_StylesXML(ZIPКаталог, СоответствиеNumFmtIdFormatCode)
    Перем Файл, Styles;
    Перем МассивNumFmtId, ит;
   
    МассивNumFmtId = Новый Массив;
    СоответствиеNumFmtIdFormatCode = Новый Соответствие;
   
    Файл = Новый Файл(ZIPКаталог + "XL\Styles.xml");
    Если НЕ Файл.Существует() Тогда
        Возврат МассивNumFmtId;
    КонецЕсли;
   
    Styles = Новый ЧтениеXML;
    Styles.ОткрытьФайл(Файл.ПолноеИмя);
   
    Пока Styles.Прочитать() Цикл
        Если ВРег(Styles.Имя) = ВРег("numFmt") И Styles.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            СоответствиеNumFmtIdFormatCode.Вставить(Styles.ЗначениеАтрибута("numFmtId"), ВРег(Styles.ЗначениеАтрибута("formatCode")));
        КонецЕсли;
        Если ВРег(Styles.Имя) = ВРег("cellXfs") Тогда
            Пока Styles.Прочитать() Цикл
                Если ВРег(Styles.Имя) = ВРег("xf") И Styles.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
                    МассивNumFmtId.Добавить(Styles.ЗначениеАтрибута("numFmtId"));
                КонецЕсли;
            КонецЦикла;
        КонецЕсли;
    КонецЦикла;
   
    // Завершение работы.
    // Закрытие Объектов.
    Styles.Закрыть();

    // Проверка сопоставления кодов массива и соответствия.
    // MS Office может не формировать в xml-файле описание стиля форматирования для ячейки.
    // LibreOffice формирует в xml-файле необходимые описания стиля форматирования ячейки.
    Для Каждого ит ИЗ МассивNumFmtId Цикл
        Если СоответствиеNumFmtIdFormatCode.Получить(ит) = Неопределено Тогда
            Если ит = "0" Тогда    // Стандарт для числа (Целое число).
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "GENERAL");
            ИначеЕсли ит = "9" ИЛИ ит = "10" Тогда    // Форматы для % ("0%", "0.00%").
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "0%");
            ИначеЕсли ит = "14" ИЛИ ит = "16" Тогда    // Форматы для даты.
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "DD.MM.YYYY");
            ИначеЕсли ит = "45" ИЛИ ит = "46" ИЛИ ит = "47" Тогда    // Форматы для времени.
                СоответствиеNumFmtIdFormatCode.Вставить(ит, "HH:MM:SS");
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
   
    Возврат МассивNumFmtId;
   
КонецФункции

&НаСервере
Функция ИзвлечьДанныеИзФайла_SharedStringsXML(ZIPКаталог)
    Перем Файл, SharedStrings;
    Перем МассивSharedStrings;
   
    // Если в файле EXCEL не содержится значений, имеющих тип "СТРОКА", то файл "SharedStrings.xml" не формируется.
   
    МассивSharedStrings = Новый Массив;
   
    Файл = Новый Файл(ZIPКаталог + "XL\SharedStrings.xml");
    Если НЕ Файл.Существует() Тогда
        Возврат МассивSharedStrings;
    КонецЕсли;
   
    SharedStrings = Новый ЧтениеXML;
    SharedStrings.ОткрытьФайл(Файл.ПолноеИмя);
   
    Пока SharedStrings.Прочитать() Цикл
        Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
            МассивSharedStrings.Добавить(SharedStrings.Значение);
        КонецЕсли;
    КонецЦикла;
   
    // Завершение работы.
    // Закрытие Объектов.
    SharedStrings.Закрыть();
   
    Возврат МассивSharedStrings;
   
КонецФункции

&НаСервере
Функция ПолучитьМассивИменКолонокНаЛистеXLSX(SheetX)
    Перем ДиапазонДанных, ДиапазонКолонок, ПерваяКолонка, ПоследняяКолонка, НомерПервойК, НомерПоследнейК;
    Перем Подсчет, ИмяКолонки;
    Перем МассивИменКолонокXLSX, КолвоКолонокEXCEL;
    
    МассивИменКолонокXLSX = Новый Массив;
    
    Подсчет = Ложь;
    // Считать очередной узел XML.
    Пока SheetX.Прочитать() Цикл
        // DIMENSION.
        Если ВРег(SheetX.Имя) = "DIMENSION" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ДиапазонДанных     = SheetX.ПолучитьАтрибут("ref");
            ДиапазонКолонок = ЗаменитьОдниСимволыДругими("0123456789", ДиапазонДанных, "");
            ПерваяКолонка     = Лев(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") - 1);
            ПоследняяКолонка= Сред(ДиапазонКолонок, Найти(ДиапазонКолонок ,":") + 1);
            НомерПервойК    = НомерКолонкиДесятичный(ПерваяКолонка);
            НомерПоследнейК    = НомерКолонкиДесятичный(ПоследняяКолонка);
        КонецЕсли;
        // Подсчет по 1-ой строке.
        Если ВРег(SheetX.Имя) = "ROW" Тогда
            Если SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
                // Начало отсчета.
                Подсчет = Истина;
            ИначеЕсли SheetX.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
                // Окончание отсчета.
                Прервать;
            КонецЕсли;
        КонецЕсли;
        Если Подсчет И ВРег(SheetX.Имя) = "C" И SheetX.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ИмяКолонки = SheetX.ПолучитьАтрибут("r");
            ИмяКолонки = ЗаменитьОдниСимволыДругими("0123456789", ИмяКолонки, "");
            МассивИменКолонокXLSX.Добавить(ИмяКолонки);
        КонецЕсли;
    КонецЦикла;
    
    КолвоКолонокEXCEL = МассивИменКолонокXLSX.Количество();
    Если НЕ НомерПоследнейК = Неопределено Тогда
        Если КолвоКолонокEXCEL < НомерПоследнейК Тогда
            Сообщить("Строка заголовков колонок (1-я строка) заполнена не полностью:
            |К-во колонок строки меньше объявленной: " + КолвоКолонокEXCEL + "<" + НомерПоследнейК);
            ДополнитьМассивИменКолонокXLSX(НомерПоследнейК, МассивИменКолонокXLSX);
        ИначеЕсли КолвоКолонокEXCEL > НомерПоследнейК Тогда
            Сообщить("Строка заголовков колонок (1-я строка) содержит больше колонок, чем объявлено:
            |К-во колонок строки больше объявленной:" + КолвоКолонокEXCEL + ">" + НомерПоследнейК);
        КонецЕсли;
    КонецЕсли;
        
    Возврат МассивИменКолонокXLSX;
    
КонецФункции

&НаСервере
Функция НомерКолонкиДесятичный(ИмяКолонкиXLSX)
    Перем Латиница, ДлинаНомера, Поз, ит;
    Перем НомерКолонки;
    
    Латиница = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";    // 26.
    ДлинаНомера = СтрДлина(ИмяКолонкиXLSX);
    НомерКолонки = 0;
    Для ит = 1 ПО ДлинаНомера Цикл
        Поз = Найти(Латиница, Сред(ИмяКолонкиXLSX, (ДлинаНомера + 1 - ит), 1));
        НомерКолонки = НомерКолонки + Поз * Pow(26, ит - 1);
    КонецЦикла;
    
    Возврат НомерКолонки;
    
КонецФункции

&НаСервере
Процедура ДополнитьМассивИменКолонокXLSX(Знач КолвоКолонокExcel, МассивИменКолонокXLSX, Индекс = - 1)
    Перем Алфавит, ит, Буква;
    
    Алфавит = РазложитьСтрокуВМассивПодстрок("A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z", ",");
    
    Если МассивИменКолонокXLSX.Количество() >= КолвоКолонокExcel Тогда
        Возврат;
    КонецЕсли;
    
    Если Индекс > Алфавит.Количество() - 1 Тогда
        Возврат;
    КонецЕсли;
    
    Буква = ?(Индекс = -1, "", Алфавит[Индекс]);
    Для ит = 0 ПО Алфавит.Количество() - 1 Цикл
        Если МассивИменКолонокXLSX.Найти(Буква + Алфавит[ит]) = Неопределено Тогда
            МассивИменКолонокXLSX.Добавить(Буква + Алфавит[ит]);
        КонецЕсли;
        Если МассивИменКолонокXLSX.Количество() >= КолвоКолонокExcel Тогда
            Возврат;
        КонецЕсли;
    КонецЦикла;
    
    Если МассивИменКолонокXLSX.Количество() > КолвоКолонокExcel Тогда
        Возврат;
    Иначе
        Индекс = Индекс + 1;
        ДополнитьМассивИменКолонокXLSX(КолвоКолонокExcel, МассивИменКолонокXLSX, Индекс);
    КонецЕсли;
    
    Возврат;
    
КонецПроцедуры

// Функция "расщепляет" строку на подстроки, используя заданный
//      разделитель. Разделитель может иметь любую длину.
//      Если в качестве разделителя задан пробел, рядом стоящие пробелы
//      считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр
//      игнорируются.
//      Например,
//      РазложитьСтрокуВМассивПодстрок(",один,,,два", ",") возвратит массив значений из пяти элементов,
//      три из которых - пустые строки, а
//      РазложитьСтрокуВМассивПодстрок(" один   два", " ") возвратит массив значений из двух элементов
//
//  Параметры:
//      Стр -           строка, которую необходимо разложить на подстроки.
//                      Параметр передается по значению.
//      Разделитель -   строка-разделитель, по умолчанию - запятая.
//
//  Возвращаемое значение:
//      массив значений, элементы которого - подстроки
//
&НаСервере
Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",")
    
    МассивСтрок = Новый Массив();
    Если Разделитель = " " Тогда
        Стр = СокрЛП(Стр);
        Пока 1 = 1 Цикл
            Поз = Найти(Стр, Разделитель);
            Если Поз = 0 Тогда
                МассивСтрок.Добавить(СокрЛП(Стр));
                Возврат МассивСтрок;
            КонецЕсли;
            МассивСтрок.Добавить(СокрЛП(Лев(Стр, Поз - 1)));
            Стр = СокрЛ(Сред(Стр, Поз));
        КонецЦикла;
    Иначе
        ДлинаРазделителя = СтрДлина(Разделитель);
        Пока 1 = 1 Цикл
            Поз = Найти(Стр, Разделитель);
            Если Поз = 0 Тогда
                Если (СокрЛП(Стр) <> "") Тогда
                    МассивСтрок.Добавить(СокрЛП(Стр));
                КонецЕсли;
                Возврат МассивСтрок;
            КонецЕсли;
            МассивСтрок.Добавить(СокрЛП(Лев(Стр,Поз - 1)));
            Стр = Сред(Стр, Поз + ДлинаРазделителя);
        КонецЦикла;
    КонецЕсли;
   
КонецФункции

&НаСервере
Функция ЭтоЧислоXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ( ВРег(ФорматСтиля) = "GENERAL"
        ИЛИ ВРег(ФорматСтиля) = "STANDARD"
        ИЛИ Найти(ФорматСтиля, "0") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоПроцентXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ( Найти(ФорматСтиля, "%") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоБулевоXLSX(ЗначениеЯчейки, ФорматСтиля)
   
    Если (ЗначениеЯчейки = 0 ИЛИ ЗначениеЯчейки = 1)
        И Найти(ВРег(ФорматСтиля), "ИСТИНА") > 0 ИЛИ Найти(ВРег(ФорматСтиля), "ЛОЖЬ") > 0
        ИЛИ Найти(ВРег(ФорматСтиля), "TRUE") > 0 ИЛИ Найти(ВРег(ФорматСтиля), "FALSE") > 0
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоДатаXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ЗначениеЯчейки = Цел(ЗначениеЯчейки) И
        ( Найти(ФорматСтиля, "DD") > 0
        ИЛИ Найти(ФорматСтиля, "MM") > 0
        ИЛИ Найти(ФорматСтиля, "YY") > 0
        ИЛИ Найти(ФорматСтиля, "QQ") > 0
        ИЛИ Найти(ФорматСтиля, "WW") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция ЭтоВремяXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля)
   
    Если ЗначениеЯчейки < 1 И
        ( Найти(ФорматСтиля, "HH:") > 0
        ИЛИ Найти(ФорматСтиля, "[HH]:") > 0
        ИЛИ Найти(ФорматСтиля, "[H]:") > 0
        ИЛИ Найти(ФорматСтиля, "MM:") > 0
        ИЛИ Найти(ФорматСтиля, ":SS") > 0 )
        Тогда
        Возврат Истина;
    КонецЕсли;
   
    Возврат Ложь;
   
КонецФункции

&НаСервере
Функция КонвертироватьЧислоXLSXвДату(Знач Число)
    Перем Дата1900, Разница, ДатаРезультат;
   
    Дата1900 = Дата("19000101");
   
    Разница = Число - 2;    // EXCEL ошибочно считает 1900-й год високосным.
    Разница = ?(Разница < 0, 0, Разница);
   
    ДатаРезультат = Дата1900 + Разница * 24 * 60 * 60;
   
    Возврат ДатаРезультат;
   
КонецФункции

&НаСервере
Функция КонвертироватьЧислоXLSXвДатуВремя(Знач Число)
    Перем КВоСекунд;
    Перем ВремяРезультат;
   
    // 0,0000115740740740741 = 1 сек.
    // 1                     = 24 часа 00 мин 00 сек.
   
    Если ТипЗнч(Число) = Тип("Число") Тогда
        КВоСекунд = Число * 100000 / 1.15740740740741;
        КВоСекунд = Окр(КВоСекунд);
    Иначе
        Сообщить("Ошибка определения значения типа ""Время"".");
    КонецЕсли;
   
    ВремяРезультат = Дата("19000101000000") + КВоСекунд;
   
    Возврат ВремяРезультат;
   
КонецФункции

&НаСервере
Функция ПолучитьЧислоВСтепениИзСтроковогоЗначения(Знач ЗначениеЯчейки)
    Перем Поз1Е, Степень;
    Перем Значение;
   
    Если Найти(ЗначениеЯчейки, "E-") > 0 Тогда
        Поз1Е = Найти(ЗначениеЯчейки, "E-");
        Степень = Сред(ЗначениеЯчейки, Поз1Е+2);
        Значение = Лев(ЗначениеЯчейки, Поз1Е-1);
        Попытка
            Степень = Число(Степень);
            Значение = Число(Значение) / Pow(10, Степень);
        Исключение
            Значение = ЗначениеЯчейки;
        КонецПопытки;
    ИначеЕсли Найти(ЗначениеЯчейки, "E+") > 0 Тогда
        Поз1Е = Найти(ЗначениеЯчейки, "E+");
        Степень = Сред(ЗначениеЯчейки, Поз1Е+2);
        Значение = Лев(ЗначениеЯчейки, Поз1Е-1);
        Попытка
            Степень = Число(Степень);
            Значение = Число(Значение) * Pow(10, Степень);
        Исключение
            Значение = ЗначениеЯчейки;
        КонецПопытки;
    Иначе
        Значение = ЗначениеЯчейки;
    КонецЕсли;
   
    Возврат Значение;
   
КонецФункции

&НаСервере
Функция ЗаменитьОдниСимволыДругими(ЗаменяемыеСимволы, Строка, СимволыЗамены)
    Результат = Строка;
    Для НомерСимвола = 1 По СтрДлина(ЗаменяемыеСимволы) Цикл
        Результат = СтрЗаменить(Результат, Сред(ЗаменяемыеСимволы, НомерСимвола, 1), Сред(СимволыЗамены, НомерСимвола, 1));
    КонецЦикла;
    Возврат Результат;
КонецФункции

&НаСервере
Процедура УдалитьКолонкиСНулевойШириной(ТаблицаРезультат)
    Перем МассивПустыхКолонок;
    // Найдем пустые колонки.
    МассивПустыхКолонок = Новый Массив;
    Для Каждого Колонка ИЗ ТаблицаРезультат.Колонки Цикл
        Если Колонка.Ширина = 0 Тогда
            МассивПустыхКолонок.Добавить(Колонка.Имя);
        КонецЕсли;
    КонецЦикла;
    // Удалим пустые колонки.
    Для Каждого ПустаяКолонка ИЗ МассивПустыхКолонок Цикл
        ТаблицаРезультат.Колонки.Удалить(ПустаяКолонка);
    КонецЦикла;
КонецПроцедуры

МА! С уважением к сообществу МА!


См. также

Лучшие комментарии

9. CagoBHuK 06.11.2013 14:56
Для тех, кто хочет сделать действительно красивое решение: открываете XML XSLX файла и с помощью XSLT преобразуете в сериализованный табличный документ. А дальше - обычная рассериализация с помощью фабрики XDTO. Никакого геморроя и лишнего текста. Все будет работать штатными средствами.
Ответили: (13) (37)
# Ответить
8. sergnik 06.11.2013 12:33
(5) Eugeneer,
Позволю себе с вами не согласиться.
Сама публикация не то чтобы сильно заинтересовала, но была в топе, и я сюда зашел.
Просмотрел остальные 5 публикаций автора, о которых вы написали

Каждая публикация описывает совсем разные методы обработки информации,
поэтому это не выжимание из воздуха.
Кроме того, весь код выложен прямо в публикации, не нужно качать "кота в мешке" чтобы оценить работу
кода. Уже за одно это автору - ОГРОМНЕЙШИЙ ПЛЮС

Быть может, у Вас личная неприязнь к автору? ))
Ответили: (10)
# Ответить
46. 7OH 05.09.2014 01:53
Ни на что не претендую.
Добавил:
1. чистку временного каталога за собой
2. выбор листа
Переделал:
1. Определение колонок (не по первой строке, а по служебным данным "DIMENSION\ref" )
2. Имена колонок - немного подправил аглоритм - вылетало часто.
3. Сорри - но обычных формах - переделать не сложно.
Ответили: (47) (48) (63)
# Ответить

Комментарии

1. Evgen.Ponomarenko 01.11.2013 18:50
Мега зачетно! В копилку готовых решений на пожизненно! )))
+ 1 [ StepByStep; ]
# Ответить
2. peterxx 01.11.2013 20:59
Очень неплохо, а то внешние компоненты - кот в мешке, ADO - бывает лень возиться и т.п.
+ 1 [ StepByStep; ]
# Ответить
3. Eugeneer 03.11.2013 12:12
Автор маится.
Одну разработку уже не знает как приткнуть. 5 публикаций с кодом одной разработки.

Чо мелочиться? Я считаю на каждую процедуру надо отдельную публикацию делать.
Вместо блога и форума разработки.

ЗЫ пойти чтоли по своим публикациям, из одной десять сделать с расписанием всяких процедурок.
Ответили: (4)
# Ответить
4. TheGrr 03.11.2013 12:23
(3) Eugeneer, а вы в каждой публикации, касающейся загрузки из Excel, будете обсирать автора? :) Уже ведь даже не смешно. Я прекрасно понимаю, что это Ваша вотчина. Но я лично за то, чтобы различных решений одной задачи было много и разных, в т.ч. и бесплатных ;)
Ответили: (5)
+ 2 [ quNas; StepByStep; ]
# Ответить
5. Eugeneer 03.11.2013 12:40
(4) А у вас предвзятое отношение.
Я просто подметил что автор пытается выжать из воздуха все что можно.
Зачем из одной публикации делать шесть для того чтобы в пяти других вставить процедуру из первой ;)
Это называется кризис.
Ну давайте я щаз тоже 50 публикаций сделаю с интересной вырезкой процедуры) Вот весело будет.
Я кстати один раз пытался решение разжевать по полочкам, но модераторы мне написали - что плодить решение нельзя, и описание относящееся к решению должно быть в одной публикации в блоге или форуме ее. Сейчас модераторы вообще все пропускают.

А тут мы видим банальное выжимание рейтинга. Ведь те кто первую публикацию скачал будут еще ставить рейтинги в других пяти. Это очевидно)))
Вот и я говорю - автор маится.
Ответили: (6) (8) (10) (14)
# Ответить
6. Yashazz 05.11.2013 12:46
Ну, пущай будет, как оглавление. А то и правда, неохота иной раз лазить да искать.

(5) Кое в чём склонен согласиться.
+ 1 [ StepByStep; ]
# Ответить
7. Pavl0 06.11.2013 10:27
Замечательно! Утащил к себе, проверю на досуге.
Ответили: (12)
+ 1 [ StepByStep; ]
# Ответить
8. sergnik 06.11.2013 12:33
(5) Eugeneer,
Позволю себе с вами не согласиться.
Сама публикация не то чтобы сильно заинтересовала, но была в топе, и я сюда зашел.
Просмотрел остальные 5 публикаций автора, о которых вы написали

Каждая публикация описывает совсем разные методы обработки информации,
поэтому это не выжимание из воздуха.
Кроме того, весь код выложен прямо в публикации, не нужно качать "кота в мешке" чтобы оценить работу
кода. Уже за одно это автору - ОГРОМНЕЙШИЙ ПЛЮС

Быть может, у Вас личная неприязнь к автору? ))
Ответили: (10)
# Ответить
9. CagoBHuK 06.11.2013 14:56
Для тех, кто хочет сделать действительно красивое решение: открываете XML XSLX файла и с помощью XSLT преобразуете в сериализованный табличный документ. А дальше - обычная рассериализация с помощью фабрики XDTO. Никакого геморроя и лишнего текста. Все будет работать штатными средствами.
Ответили: (13) (37)
# Ответить
10. Nick_Godspeed 06.11.2013 15:14
(5) Eugeneer, не ревнуйте :)
Как верно подметил (8) только за открытый код, да плюс за такую всестороннюю проработку вопроса автор заслужил хоть сто постов по одному вопросу.
# Ответить
11. LexSeIch 06.11.2013 16:34
Мир этому дому!
Мне нравиться, когда код публикуется в статье. Автору плюс.
# Ответить
12. StepByStep 06.11.2013 18:36
(7) Pavl0,
Если не затруднит - отпишитесь, пожалуйста, о результатах.
# Ответить
13. StepByStep 06.11.2013 18:47
(9) CagoBHuK,
ПРЕКРАСНО. Существует еще способ.
# Ответить
14. Abadonna 07.11.2013 06:20
(5)
А тут мы видим банальное выжимание рейтинга. Ведь те кто первую публикацию скачал будут еще ставить рейтинги в других пяти. Это очевидно)))

Нет, Евген, тут ты как раз не прав! Плюсуют/качают только то, что на виду. Не будут еще ставить рейтинги в других пяти, за редчайшими исключениями. По личному опыту;)..
P.S. Давным-давно, хохмы ради, я опубликовал свою же обработку под другим ником. Как попёрли плюсы! А самое интересное: продолжали плюсовать даже после того, как я написал, что это шутка и указал первоисточник. Продолжали!
+ 1 [ StepByStep; ]
# Ответить
15. Abadonna 07.11.2013 07:09
(0) 13.06.2012 Чтение файлов *.xlsx средствами 1С 8.2
в упор ссылки не вижу.
Ответили: (16)
# Ответить
16. StepByStep 07.11.2013 10:45
(15) Abadonna,
Упоминание об этой работе встречал. Страница была недоступна. Причина - неизвестна.
А вообще, хорошая мысль, сделать подборку ссылок по вопросу "Загрузки из EXCEL ..." от разных авторов в разных "ракурсах".
Соберу - выложу.
# Ответить
17. StepByStep 07.11.2013 13:30
07.11.2013.
Добавлены ссылки на публикации других авторов.
Если что-то не увидел, не обессудьте.
# Ответить
18. soap 07.11.2013 15:45
Интересно. Оч хор что код прямо в статье.
Автору плюс
# Ответить
19. Abadonna 07.11.2013 16:55
(0) В тексте поправь
Импирически:
-Эмпирически ;)
Ответили: (20)
# Ответить
20. StepByStep 07.11.2013 20:35
(19) Abadonna,
СПАСИБО. "Велик и Могуч Русский язык".
# Ответить
21. RainyAugust22 08.11.2013 06:37
Плюсую. Взял на заметку.
# Ответить
22. zspr 15.11.2013 15:01
Автору большое спасибо

Прикрепленные файлы:

zhs33n.jpg
# Ответить
24. mvgfirst 20.01.2014 13:28
Кто нибудь тестировал это на практических данных?
Значения ячеек с формулами полностью игнорируются при использовании этого метода.
Вернее не метода а если скопировать приведенный исходный код.

Без допиливания руками - никак не обойтись.
Ответили: (25) (26)
+ 1 [ dimontit; ]
# Ответить
25. StepByStep 30.01.2014 13:02
(24) mvgfirst,
СПАСИБО.
Действительно так. Надо "допилить".
# Ответить
26. StepByStep 01.02.2014 14:18
(24) mvgfirst,
01.02.2014.
Изменена функция ЗагрузитьМетодом_1CXML().
Дополнена считыванием значений из ячеек, содержащих формулы.
# Ответить
27. Al-X 05.02.2014 10:48
+ Актуально-то как !!! Жлобы, не хотят офис покупать !! ))))
# Ответить
28. smilebringer 26.02.2014 12:05
Эмпирическая догадка не верна, любое целое, дробное число, процент, время, и другие числовые форматы будут интерпретироваться как дата. Строковые значения будут верно обрабатываться.
Ответили: (30) (32)
# Ответить
29. igyo 27.02.2014 10:08
Косяк если в колонке будет пустая ячейка, смещаются колонки тогда... :(
Ответили: (31) (32)
# Ответить
30. StepByStep 27.02.2014 16:56
(28) smilebringer,
СПАСИБО.
Строки, числа, даты читаются.
Процент, время - посмотрю, подправлю.
# Ответить
31. StepByStep 27.02.2014 16:58
(29) igyo,
Это проверялось.
В смысле одна или несколько пустых ячеек в колонке или вся колонка пустая?
Если можно - файл выложите, пожалуйста.
# Ответить
32. StepByStep 01.03.2014 23:16
01.03.2014 г. Обновление.
(28) smilebringer, (29) igyo,
СПАСИБО за указанные неточности.
Доработал.
Если обнаружите неточности - напишите, пожалуйста.
# Ответить
33. spaminfostart 05.03.2014 16:47
и тут спрошу про 255 столбцов... таки не обрабатывает такие файлы?
# Ответить
34. smilebringer 11.03.2014 13:43
Тебе бы еще такие вещи вынести на git или другую систему контроля версий, тебе тогда и сообщество укажет, где что поправить, может и свой вариант кто-то предложит. А так изменение читать тяжело и поэтому лениво :)
# Ответить
35. Glk 15.04.2014 14:36
// ЧИСЛО.
                                        Если Прав(ЗначениеЯчейки, 5) = "E-003" Тогда
                                            УдалитьПоследнийСимволВСтроке(ЗначениеЯчейки, 5);
                                            Попытка
                                                ЗначениеЯчейки = Число(ЗначениеЯчейки);
                                            Исключение
                                            КонецПопытки;
                                            // ЧИСЛО.
                                        ИначеЕсли Прав(ЗначениеЯчейки, 3) = "E-3" Тогда
                                            УдалитьПоследнийСимволВСтроке(ЗначениеЯчейки, 3);
                                            Попытка
                                                ЗначениеЯчейки = Число(ЗначениеЯчейки);
                                            Исключение
                                            КонецПопытки;
...Показать Скрыть

Обрезать обрезали, а поделить на 1000 забыли.
Ответили: (36)
+ 1 [ StepByStep; ]
# Ответить
36. StepByStep 20.08.2014 15:46
(35) Glk,
СПАСИБО.
Ответили: (38)
# Ответить
37. nSpirit2 20.08.2014 15:07
Меня очень нервирует способ объявление переменных взятый явно из Делфи. Ну а так полностью согласен с (9) CagoBHuK все намного проще :)
# Ответить
38. Glk 23.08.2014 01:13
(36) StepByStep, Кстати, пришлось еще добавить аналогичную конструкцию для
Прав(ЗначениеЯчейки, 3) = "E-2"
, регулярно попадалось в присылаемых нам файликах.
Ответили: (39) (40)
# Ответить
39. StepByStep 27.08.2014 21:02
(38) Glk,
Скоро будет новая редакция. В ней будет и Е-..., Е+... и др.
# Ответить
40. StepByStep 03.09.2014 13:57
(38) Glk,
03.09.2014. Новая редакция.
+ 1 [ Glk; ]
# Ответить
41. Glk 03.09.2014 16:39
ИндексКолонки = ?(ИндексКолонки = Неопределено, КоличествоСлужебныхКолонок-1, ИндексКолонки+КоличествоСлужебныхКолонок-1);

Непонятно, зачем тут КоличествоСлужебныхКолонок-1, если имя колонки никак от количества служебных не зависит.
У меня добавляется еще одна служебная колонка с уровнем группировки для загрузки иерархических справочников номенклатуры от поставщиков, возможно стоит ее добавить и в вашу обработку для универсальности.
НоваяСтрока.УровеньГруппировки=SheetX.ЗначениеАтрибута("outlineLevel");
Ответили: (42)
+ 1 [ StepByStep; ]
# Ответить
42. StepByStep 03.09.2014 22:43
(41) Glk,
ИндексКолонки = ?(ИндексКолонки = Неопределено, КоличествоСлужебныхКолонок-1, ИндексКолонки+КоличествоСлужебныхКолонок-1);
СПАСИБО.

Атрибут "outlineLevel" может отсутствовать, например, если файл создан в MS EXCEL.
При сохранении в LibreOffice - он есть.
Ответили: (43)
# Ответить
43. Glk 04.09.2014 12:47
(42) StepByStep,
Он отсутствует, если нет собственно группировки в текущей строке, но это не мешает загружать его для остальных. А если определить колонку как
ТаблицаРезультат.Колонки.Добавить("УровеньГруппировки", Новый ОписаниеТипов("Число"), "Гр", 4);

то даже проверку на Неопределено делать не приходится - само в 0 преобразуется.
Ответили: (44) (45)
+ 1 [ StepByStep; ]
# Ответить
44. StepByStep 04.09.2014 15:22
(43) Glk,
Хорошо. Посмотрю.
# Ответить
45. StepByStep 04.09.2014 15:32
(43) Glk,
ОТЛИЧНО. СПАСИБО.
# Ответить
46. 7OH 05.09.2014 01:53
Ни на что не претендую.
Добавил:
1. чистку временного каталога за собой
2. выбор листа
Переделал:
1. Определение колонок (не по первой строке, а по служебным данным "DIMENSION\ref" )
2. Имена колонок - немного подправил аглоритм - вылетало часто.
3. Сорри - но обычных формах - переделать не сложно.
Ответили: (47) (48) (63)

Прикрепленные файлы:

ЗагрузкаXLSX.erf
# Ответить
47. StepByStep 05.09.2014 13:44
(46) 7OH,
Определение колонок (не по первой строке, а по служебным данным "DIMENSION\ref"

Сталкнулся с несоответствием служебных данных и реальных колонок - поэтому по 1-ой строке "по факту".
Имена колонок - немного подправил аглоритм - вылетало часто

Если не сложно опишите пример.
СПАСИБО.
Ответили: (49)
# Ответить
48. StepByStep 05.09.2014 17:14
(46) 7OH,
Не заполненная/не полностью заполненная 1-я строка ?
# Ответить
49. 7OH 06.09.2014 15:30
(47) StepByStep,
в первой строке шапка документа в виде
Склад : техника
ответственный: Пупкин
и тут пошла шапка колонок
итого он определяет всего 2 колонки и при попытке считывания на шапке вываливается с ошибкой
а так в DIMENSION вроде красиво лежит весь диапазон - спеациально ставил спрва снизу подальше одну букву - подхватывало
Ответили: (50)
# Ответить
50. StepByStep 10.09.2014 13:53
(49) 7OH,
СПАСИБО.
# Ответить
51. Drizer2000 24.09.2014 15:57
Эх описал бы кто преимущество, того или иного метода, я не читал все статьи автора, может где и есть. Например, мне нужно загружать в базу из экселя прайсы поставщиков. Прайсы могут содержать до 10 тыс строк, вот и думаю какой бы метод использовать. Сейчас сделано классичеси через ОЛЕ,но относительно медленно идет загрузка.
# Ответить
52. kostyaomsk 24.09.2014 16:19
Ставлю "плюс" за подборку решений. Все равно для разных задач приходится свое писать. В одной из нехороших обработок по загрузке основных средств лучшего решения чем вручную указание пользователем номеров колонок не было.
# Ответить
53. Drizer2000 24.09.2014 20:54
А кто знает какой используется метод для обработки указанной вот по этой ссылке:
http://infostart.ru/public/21810/
# Ответить
54. SinglCOOLer 26.09.2014 14:08
все бы вроде не плохо, но часть данных колонок почему то берется с нужно листа, а часть с другого
Ответили: (57)
# Ответить
55. SinglCOOLer 26.09.2014 14:34
Если делаешь лист 1 и единственным, то перестает путать и грузит корректно
Ответили: (57)
# Ответить
56. MishaHD 05.11.2014 07:32
Update :) Написал хвалебный комментарий, а потом нашел косяк. В представленных выше процедурах когда мы формируем МассивSharedStrings из файла SharedStrings.xml не учитывается то, что может встречаться значение "пустая строка". То есть условие
Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
не будет отрабатывать. Соответственно если в файле SharedStrings.xml встретилась пустая строка, то начинаю "плыть" индексы массива МассивSharedStrings, а за ними "плывет" результирующая таблица.

Написал следующий костыль, может кому полезно будет:

Вот это:
Пока SharedStrings.Прочитать() Цикл
        Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
            МассивSharedStrings.Добавить(SharedStrings.Значение);
        КонецЕсли;
    КонецЦикла;
...Показать Скрыть


Меняем на это:
ФлагСтрокаЗаписана = Ложь;
    
	Пока SharedStrings.Прочитать() Цикл
		Если ВРег(SharedStrings.Имя) = "SI" и SharedStrings.ТипУзла = ТипУзлаXML.НачалоЭлемента тогда
			ФлагСтрокаЗаписана = Ложь;
		КонецЕсли;
		
        Если ВРег(SharedStrings.Имя) = "#TEXT" Тогда
            МассивSharedStrings.Добавить(SharedStrings.Значение);
			ФлагСтрокаЗаписана = Истина;
		КонецЕсли;
		
		Если ВРег(SharedStrings.Имя) = "SI" и SharedStrings.ТипУзла = ТипУзлаXML.КонецЭлемента и не ФлагСтрокаЗаписана тогда
			//встретили пустую строку!
			 МассивSharedStrings.Добавить("");
		КонецЕсли;
		
    КонецЦикла;
...Показать Скрыть


Спасибо за процедуры, приятно что все нормально отлажено и работает (как выяснилось кроме некоторых косяков))). Небольшое пожелание, бы бы удобно если бы колонки именовались из заголовочных данных (например если указываем что заголовок - это строка №1).
Ответили: (58) (67)
+ 2 [ [4EPHbIYY_KOT]; Glk; ]
# Ответить
57. StepByStep 25.11.2014 23:20
(54), (55) SinglCOOLer,
В ранних версиях обработки "Импорт (загрузка) из внешнего источника (Excel,LibreOffice,SQL,DBF,MXL) в 1С 8.2/8.3: Розница,УТ,БП,КА. /РОССИЯ,УКРАИНА,БЕЛАРУСЬ/" http://infostart.ru/public/120961/ описанный метод использовался и корректно брал данные с необходимого листа.
# Ответить
58. StepByStep 25.11.2014 23:21
(56) MishaHD,
Рекомендую обратить внимание на "Загрузка из EXCEL в 1С. Чтение файла XLSX средствами 1С. ПостроительDOM" http://infostart.ru/public/300092/
Ответили: (59)
# Ответить
59. MishaHD 21.12.2014 08:33
(58) StepByStep, спасибо за совет. В принципе допилил то, что в этом посте выложено под свои нужды, все работает без косяков
# Ответить
60. kostyaomsk 28.01.2015 13:41
Вопрос граждане по отказоустойчивости при чтении из Excel. Тут есть сервер 1С (вроде 64 битный без установленного на нем офисного пакета. Соответственно на нем нет зарегистрированного объекта COMОбъект "Excel.Application". Как раз смотрели недавнюю статью Настройка DCOM компоненты "Excel.Application" на 64-битном сервере приложений 1С
Суть вопроса в чем. Мне прислали такое техническое мнение корпорации Майкрософт:
Корпорация Microsoft на сегодняшний день не рекомендует производить и не поддерживает автоматизацию программ из пакета Microsoft Office с помощью автоматических, неинтерактивных клиентских приложений или компонентов (включая ASP, DCOM и службы NT), поскольку при запуске в этом окружении программы пакета Office могут работать нестабильно или зависать.

Насчет при запуске в этом окружении программы пакета Office могут работать нестабильно или зависать частично согласен. Методы закрытия работают плохо и висят на сервере о чем писали.
Что народ скажед по поводу данного мнения? Не хотелось бы вступать в админские споры. Если загрузка хотя бы периодическая под контролем оператора? Насколько это критично. В чем получается преимущество ADO? В том что не надо пакет офисный ставить (я про уклон в лицензионную политику)? Или еще есть преимущества (про скорость и прочие радости излишне).
Ответили: (64)
# Ответить
61. kostyaomsk 28.01.2015 14:17
Насчет "универсального ADO" как-то начал обработку чтения xls в тонком клиенте для БП 3.0 с анализом ошибок. Предполагалось сделать универсальной с ведением протокола ошибок на сервере с передачей на клиент.
Сразу предупреждаю, данную обработку запускать осторожно чтоб не повредить данные. Тут выкладываю только с целью сравнения и отладки технологии по чтению из екселя с помощью ADO.
По крайней мере лист начинает читать без всяких настроек ADO и локального Екслея (на компе только Libre office).
Код чтения (главное, метод ADODBConnection.Open(); срабатывает:
// Инициализация основного объекта ADODB.Connection. Открытие соединения.
		ADODBConnection = Новый COMОбъект("ADODB.Connection");		
		ADODBConnection.ConnectionString =  СonnectionString;
		
		ADODBConnection.Provider = "Microsoft.Jet.OLEDB.4.0"; //????? ставился САМ MSSQL -		
		ADODBConnection.Open();
		// Импирически определенный параметр для правильного определения количества строк листа.
		ADODBConnection.CursorLocation = 3;    // По-умолчанию 2.
		
	ТекстЗапроса = "SELECT * FROM [" + ИмяЛиста + "$]";
	
	// Создание Recordset. Дочерний объект ADODBConnection. Набор записей по запросу.
	
		ADODBRecordset = Новый COMОбъект("ADODB.Recordset");
		ADODBRecordset.Open(ТекстЗапроса, ADODBConnection);
		
		// Проверка заполненности листа.
		Если (ADODBRecordset.EOF ИЛИ ADODBRecordset.BOF) Тогда
			КолвоСтрокExcel = 0;
			ДобавитьВЛогНаСервере("Лист екселя " + ИмяЛиста + ": не содержит данных (вообще)!");
			
			// Завершение работы.
			// Закрытие Объектов.
			ADODBRecordset.Close();
			ADODBConnection.Close();
			ADODBRecordset   = Неопределено;
			ADODBConnection = Неопределено;
			
			Возврат;
		КонецЕсли;
		
		// Импирически определенные параметры для правильного определения количества строк листа.
		ADODBRecordset.AbsolutePage     = 1;
		ADODBRecordset.AbsolutePosition = 1;
		
	// Параметр, возвращаемый в вызывающую процедуру.
	КолвоСтрокExcel = ADODBRecordset.RecordCount + 1;    // (+1) - учет Строки-Заголовока, которая "съедается".
	КолвоКолонокExcel = ADODBRecordset.Fields.Count;
	
	// Проверка заполненности листа.
	Если КолвоСтрокExcel <= 2 Тогда
		КолвоСтрокExcel = 0;
		 ДобавитьВЛогНаСервере("Лист екселя " + ИмяЛиста + ": не содержит данных (строк)!");
		
		// Завершение работы.
		// Закрытие Объектов.
		ADODBRecordset.Close();
		ADODBConnection.Close();
		ADODBRecordset   = Неопределено;
		ADODBConnection = Неопределено;
		
		Возврат;
	КонецЕсли;
...Показать Скрыть

обработка прилагается
Ответили: (64)

Прикрепленные файлы:

ЗагрузкаВБухгалтерию3.epf
Скриншот обработки чтения из xls методами ADO без установки Excel на ПК база БП 3.0.35.28 тонкий клиент.jpg
# Ответить
62. Petrony 20.08.2015 16:53
Также не распознаются ячейки с Дата+Время.
Поскольку Дата+Время - это не целое число, которое больше 1, то оно не распознается ни процедурой ЭтоДатаXLSX() ни процедурой ЭтоВремяXLSX
В принципе, можно из функции ЭтоДатаXLSX(Знач ЗначениеЯчейки, Знач ФорматСтиля) убрать проверку на то, что значение ячейки - целое число. Или отдельно создать функцию.
Ответили: (65)
# Ответить
63. XelOla 18.10.2015 00:39
(46) 7OH, будет ли это работать в обычном приложении?
Что еще можно использовать для работы с Эксель без установленного Офиса?
Ответили: (66)
# Ответить
64. StepByStep 15.11.2015 19:31
(60) kostyaomsk, (61) kostyaomsk,
См. Загрузка из EXCEL в 1С. MS ADODB.Connection : http://infostart.ru/public/163640/
# Ответить
65. StepByStep 15.11.2015 19:32
(62) Petrony,
СПАСИБО.
# Ответить
66. StepByStep 15.11.2015 19:36
(63) XelOla,
будет ли это работать в обычном приложении?
Что еще можно использовать для работы с Эксель без установленного Офиса?

Да, будет.
См. также
Методы загрузки из внешнего источника:
- Метод "MS ADO" (Чтение файлов xls, xlsx средствами Microsoft ADO): http://infostart.ru/public/163640/
- Метод "NativeXLSX" (Чтение файлов xlsx с картинками средствами 1С. ПостроительDOM): http://infostart.ru/public/300092/
- Метод "Excel1C" (Загрузка на платформе 8.3.6 с картинками. Чтение файлов xls, xlsx, ods): http://infostart.ru/public/341855/

При установленном бесплатном LibreOffice:
- Метод "LO CALC" (Чтение файлов xls, xlsx, ods, sxc с картинками средствами LibreOffice): http://infostart.ru/public/163642/
# Ответить
67. [4EPHbIYY_KOT] 09.02.2016 10:31
(56) MishaHD, ещё бы автор это подправил - вообще был бы зачёт. А то без разбора кода пооткрывали файлики, плывёт всё жестко. Даже с соседних листов данные берёт :)
# Ответить
Внимание! За постинг в данном форуме $m не начисляются.
Внимание! Для написания сообщения необходимо авторизоваться
Текст сообщения*
Прикрепить файл