gifts2017

Методика оперативного проведения и управляемые блокировки

Опубликовал Павел Чистов (GROOVY) в раздел Программирование - Практика программирования

Несмотря на то, что у меня уже есть статья посвященная механизму оперативного проведения, очень часто, нет не так, очень-очень-очень часто спрашивают, что это такое.
Я подумал и решил написать ну очень-очень-очень подробную статью про методику оперативного проведения и управляемые блокировки. А без управляемых блокировок, собственно, методику использовать бессмысленно.

Введение.

Несмотря на то, что у меня уже есть статья посвященная механизму оперативного проведения, очень часто, нет не так, очень-очень-очень часто спрашивают, что это такое.
Я подумал и решил написать ну очень-очень-очень подробную статью про методику оперативного проведения и управляемые блокировки. А без управляемых блокировок, собственно, методику использовать бессмысленно.
 
При написании статьи, демопример я вводил на платформе 8.3.3.641. Всю задачу создавал на пустой базе.

Постановка задачи.

Необходимо автоматизировать 2 операции: покупка, продажа товаров. При продаже товаров необходимо контролировать наличие товаров в остатках предприятия и рассчитывать себестоимость списания товаров по методу FIFO.

Начнем...

Структура метаданных:
Справочник: Товары
Документы: Приходная и Расходная с табличными частями "Список товаров" (товар, количество, сумма).
Регистры: ОстаткиТоваров, в регистре одно измерение: Товар, и один ресурс: Количество.
Назначение регистра - быстрое принятие решения, можно ли проводить документ.
СтоимостьТоваров, в регистре два измерения: Товар, Партия, и два ресурса: Количество, Стоимость. Назначение регистра: хранение информации о стоимости остатков товаров в разрезе партий.
 
Описывать проведение документа "Приходная" не буду, там все очевидно, все можно конструктором сделать.
 
В расходной опишем проведение по регистру ОстаткиТоваров...

Методика оперативного проведения.

Под термином "Методика оперативного проведения" я понимаю следующее: при проведении документа, вместо того, чтобы, сформировать запрос и понять хватает ли товаров или нет, мы сначала сформируем движения, а затем уже проверим, не ушли ли мы в минус? Подробнее с плюсами и минусами этой технологии можно познакомиться в моей прошлой статье.
 
Опишем формирование движений в документе "Расходная":
 
Процедура ОбработкаПроведения(Отказ, Режим)

 //1
 Движения.ОстаткиТоваров.Записывать = Истина;
 
 //2
 Движения.ОстаткиТоваров.Очистить();
 
 Для каждого Стр Из СписокТоваров Цикл
  Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
  Движение.Период = Дата;
  Движение.Товар = Стр.Товар;
  Движение.Количество = Стр.Количество;
 КонецЦикла; 
 
 //3
КонецПроцедуры
 
Прокомментируем текст модуля:
1. Устанавливаем маркер необходимости записи движений. Это необходимо делать в том случае, если у документа установлено свойство "Записывать выбранные".
 
 
Что дает нам это свойство?
Интересную фишку, раньше мы могли принудительно записать движения документа (наборы данных), но при окончании транзакции проведения наборы данных записывались еще раз. Теперь мы вольны в выборе, что и когда нужно записывать. Маркер записи автоматически снимается при записи набора, тем самым, при окончании транзакции проведения, набор записей еще раз записываться не будет. К чему это приведет? Правильно, к уменьшению блокировок таблиц и к сокращению времени транзакций при проведении.
 
2. Очищаем движения. Зачем? Все дело в еще одном новом свойстве документов "Удалять движения". 
При установленном свойстве "Удалять автоматически" в самом начале транзакции проведения система автоматически записывает пустые наборы записей в регистры, тем самым очищая старые движения. Это физически происходит, запись, со всеми вытекающими транзакциями и блокировками. 
Для облегчения нагрузки на таблицы баз данных теперь есть возможность не очищать автоматом старые движения... 
И тут обычно я слышу: "Так и всегда можно было "Не очищать автоматически"! Ага, можно было, но в каждом документе приходилось описывать очистку каждого набора записей при отмене проведения... Удобно...
Короче, 1С пошла на поводу у здравого смысла и сделала новое свойство "Удалять автоматически при отмене проведения", Это гарантирует нам, что все движения документа будут очищены в том случае если у документа отработает событие "ОтменаПроведения".
Теперь вопрос, а зачем мы в модуле написали "Очистить()", тут все дело в том, что теперь у нас движения автоматом не очищаются... НО! При работе с управляемыми формами копия объекта БД может не загрузить старые движения, к примеру, зависит это и от свойства данных формы "Использовать всегда".
К примеру, в зависимости от этого свойства, движения документа будут прочитаны (если галка стоит) при открытии формы или нет. А если даже галка не установлена, и в форме отображаются движения, то движения будут прочитаны при открытии формы.
В обычных формах движения будут однозначно прочитаны при открытии формы.
А если движения прочитаны, то наборы записей в свойстве документа "Движения" не пустые, и добавление при проведении новых движений, как правило приводит к дублям движений.
Так вот, чтобы не зависеть от обстоятельств, мы на всякий случай удаляем то, что возможно может находиться в коллекции движений по регистру ОстаткиТоваров. Обращаю внимание, что запись данных в базу тут не производится, просто в памяти очищается набор записей.
Кстати, если свойство конфигурации "Основной режим запуска" будет установлено в значение "Обычное приложение", то такую строку "Движения.ИмяРегистра.Очистить()" будет писать и сам конструктор формирования движений.
3. Итак, движения сформировали, самое время их записать. Тут есть два варианта. либо Движения.Записать();  либо Движения.ОстаткиТоваров.Записать(); В чем разница и что выбрать?
Начнем с последнего: Движения.ОстаткиТоваров.Записать()Этот способ безусловно запишет данные в регистр накопления. Но при этом флаг "Записывать" у набора записей снят не будет. Но это ерунда, главное тут то, что при большом количестве наборов записей у документа нам придется самостоятельно контролировать что в каком порядке в базу пишется, это может (да что там "может", точно скажется) негативно сказаться на проблеме взаимных блокировок (DeadLock), когда одна транзакция заблокирует таблицу А и будет ждать освобождения таблицы Б, а другая транзакция будет вести себя строго наоборот. 
теперь посмотрим как работает метод Движения.Записать()Метод записывает только те движения документа у которых установлен флаг "Записывать", при этом флаг в итоге снимается, что не приводит к повторной записи движений по окончании транзакции проведения. И главное, Движения.Записать()всегда записывают движения в том порядке в котором таблицы указаны в дереве метаданных, что на порядок уменьшает шансы взаимных блокировок, ведь все транзакции в одинаковом порядке блокируют таблицы.
Теперь надеюсь очевидно, выбираем метод Движения.Записать();
 
Запишем движения и проверим остатки в регистре.
 
//3
 Движения.Записать();

 Запрос = Новый Запрос;
//4
Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
Запрос.Текст = "ВЫБРАТЬ
 | Док.Товар КАК Товар,
 | СУММА(Док.Количество) КАК Количество
 |ПОМЕСТИТЬ ДокТЧ
 |ИЗ
 | Документ.Расходная.СписокТоваров КАК Док
 |ГДЕ
 | Док.Ссылка = &Ссылка
 |
 |СГРУППИРОВАТЬ ПО
 | Док.Товар
 |
 |ИНДЕКСИРОВАТЬ ПО
 | Товар
 |;
 |
 |////////////////////////////////////////////////////////////////////////////////
 |ВЫБРАТЬ
 | Остатки.Товар.Представление КАК ТоварПредставление,
 | Остатки.КоличествоОстаток
 |ИЗ
 | РегистрНакопления.ОстаткиТоваров.Остатки(
 | &ТочкаИтогов,
 | Товар В
 | (ВЫБРАТЬ
 | ДокТЧ.Товар
 | ИЗ
 | ДокТЧ КАК ДокТЧ)) КАК Остатки
 |ГДЕ
 | Остатки.КоличествоОстаток < 0
 |;
 |
 |////////////////////////////////////////////////////////////////////////////////
 |ВЫБРАТЬ
 | ДокТЧ.Товар
 |ИЗ
 | ДокТЧ КАК ДокТЧ";
Запрос.УстановитьПараметр("Ссылка", Ссылка);
 
//5
Запрос.УстановитьПараметр("ТочкаИтогов", Новый Граница(МоментВремени(), ВидГраницы.Включая)); 
 
ПакетРезультатов = Запрос.ВыполнитьПакет();
РезультатЗапроса = ПакетРезультатов[1];
Если НЕ РезультатЗапроса.Пустой() Тогда
  //6
  Отказ = Истина;
  
  Выборка = РезультатЗапроса.Выбрать();
  Пока Выборка.Следующий() Цикл
   Сообщение = Новый СообщениеПользователю;
   Сообщение.Текст = "Мало товара " + Выборка.ТоварПредставление + " нужно еще " + (-Выборка.КоличествоОстаток);
   Сообщение.Сообщить(); 
  КонецЦикла;  
 КонецЕсли; 
 
 Если Отказ Тогда
  Возврат;
 КонецЕсли; 
 
 
Комментарии к модулю:
4. Привязываем к запросу менеджер временных таблиц. Это позволит использовать временные таблицы позже для проведения по регистру с партиями товаров.
В запросе выбираем из табличной части документа товары и количество, группируем все и индексируем по полю Товар. Это, в общем случае, благоприятно скажется на быстродействии запроса.
5. ТочкаИтогов, здесь мы используем объект Граница. Так как передав в запрос просто "МоментВремени()" мы получили бы остатки на начало проведения документа, то есть не включили бы в расчет итогов только что сформированные движения документа. А нам нужно понять, что произошло с итогами после проведения документа.
 
В целом все.
 
Мы используем новую методику проведения документа. Сначала записали данные в регистр, а потом через кэш транзакции смотрим не ушли ли мы в минус. Если ушли - транзакцию отказываем.
 
Но это далеко не все. Назревает вопрос о "грязном чтении".

Грязное чтение.

Что это такое?
Я не буду вдаваться в теорию (в отличии от вас, вам я советую в теорию копнуть, лишним не будет), поясню на примере:
Проводим две расходных. И в одной и в другой продаем 5 ложек. А в остатках всего 6. Так получилось, что продавать ложки мы умудрились в один и тот-же момент времени. Что произойдет?
Первая накладная сформирует движения и начнет читать запрос по остаткам через кэш собственной транзакции, что, собственно, будет делать и вторая накладная. Но ложек-то всего 6, а в сумме две накладные продадут 10... Потому-что не знают о том, что данные в таблицах уже не актуальны...
Что делать? 
Надо заблокировать данные от параллельного чтения.
В нашем примере это сделать очень просто. У набора записей есть свойство "БлокироватьДляИзменения". Это, как и свойство "Записывать", лишь маркер указывающий, что необходимо установить блокировку на те записи, которые были сформированы в наборе записей.
Когда устанавливать свойство "БлокироватьДляИзменения"? Не важно, главное до самой записи данных.
Когда произойдет блокировка записей? В момент записи данных.
Что означает эта блокировка?
Никто параллельно с нами читать данные из регистра по тем товарам, движения по которым были сформированы, не сможет.
Когда блокировка будет снята?
При окончании транзакции в которой она началась, в нашем примере, при завершении проведения документа.
 
Установим блокировку: 
 
 //2
 Движения.ОстаткиТоваров.Очистить();
 
 Для каждого Стр Из СписокТоваров Цикл
  Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
  Движение.Период = Дата;
  Движение.Товар = Стр.Товар;
  Движение.Количество = Стр.Количество;
 КонецЦикла; 
 
 //7 Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;
 
 //3
 Движения.Записать();
Казалось бы все, а давайте проверим какие свойства нужно установить у объектов, для  того, чтобы такая блокировка не просто работала, а еще и блокировала только те записи по которым были сформированы движения...
 
А. Свойство конфигурации "Режим управления блокировкой данных в транзакции" -  если, "Управляемый", то все хорошо. 
Если "Автоматический", то системе глубоко фиолетово на то что мы с вами написали. В нашем частном случае, блокировка в режиме "Автоматический" не будет установлена.
Если "и то и другое" то важно проверить настройки объектов. Помните, что вид транзакции наследуется всеми вложенными транзакциями. То есть если документ записывается в автоматической транзакции, а движения делает по регистрам с управляемой... То система немного расстроится и вывалится с ошибкой.
 
Б. Так как блокируем мы не весь регистр, за что нам отдельное спасибо, а только те данные по которым мы сформировали движения, за что спасибо ребятам из 1С, то важно установить свойство регистра "Разрешить разделение итогов".
Если разделение итогов не будет включено и в режиме пользователя, то в большей части случаев блокировка будет наложена на весь регистр с его таблицами.
 
Вот теперь точно с регистром "ОстаткиТоваров" все. Займемся себестоимостью.

Партионное списание.

При списании партий из регистра "СтоимостьТоваров" использовать методику оперативного проведения мы не можем. Почему? А для того, чтобы списать партии нужно узнать какие конкретно, то есть нам нужно сначала прочитать данные из регистра, а потом уже формировать движения.
 
 Если Отказ Тогда
  Возврат;
 КонецЕсли; 
 
 //7
 Запрос.Текст = "ВЫБРАТЬ
 | ДокТЧ.Товар КАК Товар,
 | ДокТЧ.Количество КАК Количество,
 | СтоимостьТоваров.Партия,
 | СтоимостьТоваров.КоличествоОстаток,
 | СтоимостьТоваров.СтоимостьОстаток
 |ИЗ
 | ДокТЧ КАК ДокТЧ
 | ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СтоимостьТоваров.Остатки(
 | &ТочкаИтоговДляСебестоимости,
 | Товар В
 | (ВЫБРАТЬ
 | ДокТЧ.Товар
 | ИЗ
 | ДокТЧ КАК ДокТЧ)) КАК СтоимостьТоваров
 | ПО ДокТЧ.Товар = СтоимостьТоваров.Товар
 |
 |УПОРЯДОЧИТЬ ПО
 | СтоимостьТоваров.Партия.МоментВремени
 |ИТОГИ
 | МИНИМУМ(Количество)
 |ПО
 | Товар";
       
 //8
 Запрос.УстановитьПараметр("ТочкаИтоговДляСебестоимости", МоментВремени());
 
 //9
 Движения.СтоимостьТоваров.Очистить();
 
 //10
 РезультатЗапроса = Запрос.Выполнить();
 ВыборкаТовар = РезультатЗапроса.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
 
 Пока ВыборкаТовар.Следующий() Цикл
  
  ОсталосьСписать = ВыборкаТовар.Количество;
  
  ВыборкаПартия = ВыборкаТовар.Выбрать();
  Пока ВыборкаПартия.Следующий() И ОсталосьСписать <> 0 Цикл
   
   Списать = МИН(ОсталосьСписать, ВыборкаПартия.КоличествоОстаток);
   
   Движение = Движения.СтоимостьТоваров.ДобавитьРасход();
   Движение.Период = Дата; 
   Движение.Товар = ВыборкаПартия.Товар;
   Движение.Партия = ВыборкаПартия.Партия;
   Движение.Количество = Списать;
   Движение.Стоимость = Списать / ВыборкаПартия.КоличествоОстаток * ВыборкаПартия.СтоимостьОстаток;
   
   ОсталосьСписать = ОсталосьСписать - Списать;

  КонецЦикла; 
  
 КонецЦикла; 
 
 //11
 Движения.СтоимостьТоваров.Записывать = Истина;

Комментарии к модулю:
7. После проверки будем ли мы проводить документ, описываем новый текст запроса. Новый объект запрос создавать нет смысла, будем использовать уже существующий, кроме всего к нему уже подключен менеджер временных таблиц в котором содержится проиндексированная таблица ДокТЧ.
8. Устанавливаем МоментВремени() как точку расчета итогов таблицы остатков. Как было описано выше, по умолчанию эта точка (то бишь старые движения, которые мог бы сформировать этот документ) в расчет итогов не попадут. Но тут есть одна хитрость к которой мы вернемся немного позже.
9. На всякий случай очистим движения документа, вдруг они были прочитаны.
10. Опишем списание по партиям.
11. Установим маркер необходимости записи данных по регистру "СтоимостьТоваров". 
Когда транзакция проведения будет завершена система самостоятельно запишет движения в базу.
 
Почти все, остались блокировки.

Управляемые блокировки.

По регистру "СтоимостьТоваров" воспользоваться флагом "БлокироватьДляИзменения" нам не удастся. Почему? Да потому-что блокировка с этим флагом происходит в момент записи данных набора записей, а нам блокировку нужно установить еще перед запросом, дабы не допустить параллельного чтения данных.
 
По этому, для установки блокировки будем использовать объект "БлокировкаДанных".
Объект "БлокировкаДанных" представляет таблицу, каждая строка которой описывает что и где нужно заблокировать.
 
 Если Отказ Тогда
  Возврат;
 КонецЕсли; 
 
 //12
 Блокировка = Новый БлокировкаДанных;
 //13
 ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.СтоимостьТоваров");
 ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
 //14
 ЭлементБлокировки.ИсточникДанных = ПакетРезультатов[2];
 //15
 ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Товар", "Товар");
 Блокировка.Заблокировать();   
 
 //7
 Запрос.Текст = "ВЫБРАТЬ
 
Перед нашим вторым текстом запроса опишем блокировку.
12. Создаем объект.
13. Добавляем в объект новую строку с описанием блокируемой таблицы.
14. Для того чтобы не блокировать весь регистр, установим фильтр по товарам, данные о том по каким товарам необходимо заблокировать таблицы хранятся у нас в результате первого запроса, из пакета результатов достаем последний. Можно было и саму табличную часть документа привязать к источнику данных, но тогда система еще раз строила бы запрос к табличной части документа, а так мы все данные уже получили, сгруппировали.
15. Так как в результате запроса поле содержащее список с товарами может называться не так как поле в регистре, описываем соответствие.
 
Установили блокировку. Теперь параллельно с нами никто не прочитает остатки по указанным товарам из регистра "СтоимостьТоваров". Обращаю внимание, так как мы не знаем заранее какие партии будут выбраны запросом, то фильтр по ним установить мы не можем и блокируем все партии. Чем меньше фильтров описано, тем больше данных блокируется.
 
И вот тут казалось бы все, а нет.

Проблема оперативного проведения.

Если сейчас попробовать провести документ оперативно 2 раза, указывая последние товары в регистре, то система вылетит с ошибкой. Почему?
При оперативном проведении, несмотря на то, что, мы указали в параметре второго запроса "МоментВремени()" и он вроде бы не должен включить старые движения документа, система рассчитает остатки на оперативную отметку времени, то есть старые движения будут включены в расчет итогов. Да, да... Вот такая "фишка".
Что делать? Отследим оперативное проведение и очистим старые движения.
Перед описание второго запроса вставим такой код:
 
 //16
 Если Режим = РежимПроведенияДокумента.Оперативный Тогда
  Движения.СтоимостьТоваров.Очистить();
  //17
  Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
  Движения.СтоимостьТоваров.Записать();
 КонецЕсли; 
 
 //7
 Запрос.Текст = "ВЫБРАТЬ
 
16. Проверяем оперативно ли проводится документ.
17. Устанавливаем свойство "БлокироватьДляИзменения". Это позволит заблокировать от чтения те данные которые сейчас будут удалены из регистра, вдруг транзакция будет отменена, не хотим чтобы кто-либо вместе с нами работал с этими данными.
Подобное действие не помешает и при смене даты или времени документа, а не только при оперативном проведении.
 
Вот теперь все. Полный текст модуля документа "Расходная":
 
Процедура ОбработкаПроведения(Отказ, Режим)

 //1
 Движения.ОстаткиТоваров.Записывать = Истина;
 
 //2
 Движения.ОстаткиТоваров.Очистить();
 
 Для каждого Стр Из СписокТоваров Цикл
  Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
  Движение.Период = Дата;
  Движение.Товар = Стр.Товар;
  Движение.Количество = Стр.Количество;
 КонецЦикла; 
 
 //7
 Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;
 
 //3
 Движения.Записать();

 Запрос = Новый Запрос;
 
 //4
 Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
 Запрос.Текст = "ВЫБРАТЬ
 | Док.Товар КАК Товар,
 | СУММА(Док.Количество) КАК Количество
 |ПОМЕСТИТЬ ДокТЧ
 |ИЗ
 | Документ.Расходная.СписокТоваров КАК Док
 |ГДЕ
 | Док.Ссылка = &Ссылка
 |
 |СГРУППИРОВАТЬ ПО
 | Док.Товар
 |
 |ИНДЕКСИРОВАТЬ ПО
 | Товар
 |;
 |
 |////////////////////////////////////////////////////////////////////////////////
 |ВЫБРАТЬ
 | Остатки.Товар.Представление КАК ТоварПредставление,
 | Остатки.КоличествоОстаток
 |ИЗ
 | РегистрНакопления.ОстаткиТоваров.Остатки(
 | &ТочкаИтогов,
 | Товар В
 | (ВЫБРАТЬ
 | ДокТЧ.Товар
 | ИЗ
 | ДокТЧ КАК ДокТЧ)) КАК Остатки
 |ГДЕ
 | Остатки.КоличествоОстаток < 0
 |;
 |
 |////////////////////////////////////////////////////////////////////////////////
 |ВЫБРАТЬ
 | ДокТЧ.Товар
 |ИЗ
 | ДокТЧ КАК ДокТЧ";
 Запрос.УстановитьПараметр("Ссылка", Ссылка);
 
 //5
 Запрос.УстановитьПараметр("ТочкаИтогов", Новый Граница(МоментВремени(), ВидГраницы.Включая)); 
 
 ПакетРезультатов = Запрос.ВыполнитьПакет();
 РезультатЗапроса = ПакетРезультатов[1];
 
 Если НЕ РезультатЗапроса.Пустой() Тогда
  //6
  Отказ = Истина;
  
  Выборка = РезультатЗапроса.Выбрать();
  Пока Выборка.Следующий() Цикл
   Сообщение = Новый СообщениеПользователю;
   Сообщение.Текст = "Мало товара " + Выборка.ТоварПредставление + " нужно еще " + (-Выборка.КоличествоОстаток);
   Сообщение.Сообщить(); 
  КонецЦикла;  
 КонецЕсли; 
 
 Если Отказ Тогда
  Возврат;
 КонецЕсли; 
 
 //12
 Блокировка = Новый БлокировкаДанных;
 //13
 ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.СтоимостьТоваров");
 ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
 //14
 ЭлементБлокировки.ИсточникДанных = ПакетРезультатов[2] ;
 //15
 ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Товар", "Товар");
 Блокировка.Заблокировать(); 
 
 //16
 Если Режим = РежимПроведенияДокумента.Оперативный Тогда
  Движения.СтоимостьТоваров.Очистить();
  //17
  Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
  движения.СтоимостьТоваров.Записать();
 КонецЕсли; 
 
 //7
 Запрос.Текст = "ВЫБРАТЬ
 | ДокТЧ.Товар КАК Товар,
 | ДокТЧ.Количество КАК Количество,
 | СтоимостьТоваров.Партия,
 | СтоимостьТоваров.КоличествоОстаток,
 | СтоимостьТоваров.СтоимостьОстаток
 |ИЗ
 | ДокТЧ КАК ДокТЧ
 | ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СтоимостьТоваров.Остатки(
 | &ТочкаИтоговДляСебестоимости,
 | Товар В
 | (ВЫБРАТЬ
 | ДокТЧ.Товар
 | ИЗ
 | ДокТЧ КАК ДокТЧ)) КАК СтоимостьТоваров
 | ПО ДокТЧ.Товар = СтоимостьТоваров.Товар
 |
 |УПОРЯДОЧИТЬ ПО
 | СтоимостьТоваров.Партия.МоментВремени
 |ИТОГИ
 | МИНИМУМ(Количество)
 |ПО
 | Товар";
       
 //8
 Запрос.УстановитьПараметр("ТочкаИтоговДляСебестоимости", МоментВремени());
 
 //9
 Движения.СтоимостьТоваров.Очистить();
 
 //10
 РезультатЗапроса = Запрос.Выполнить();
 ВыборкаТовар = РезультатЗапроса.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
 
 Пока ВыборкаТовар.Следующий() Цикл
  
  ОсталосьСписать = ВыборкаТовар.Количество;
  
  ВыборкаПартия = ВыборкаТовар.Выбрать();
  Пока ВыборкаПартия.Следующий() И ОсталосьСписать <> 0 Цикл
   
   Списать = МИН(ОсталосьСписать, ВыборкаПартия.КоличествоОстаток);
   
   Движение = Движения.СтоимостьТоваров.ДобавитьРасход();
   Движение.Период = Дата; 
   Движение.Товар = ВыборкаПартия.Товар;
   Движение.Партия = ВыборкаПартия.Партия;
   Движение.Количество = Списать;
   Движение.Стоимость = Списать / ВыборкаПартия.КоличествоОстаток * ВыборкаПартия.СтоимостьОстаток;
   
  КонецЦикла; 
  
 КонецЦикла; 
 
 //11
 Движения.СтоимостьТоваров.Записывать = Истина;
КонецПроцедуры
 
Надеюсь после этой статьи большая часть вопросов о "новой" методике проведения и о том почему нельзя повсеместно писать "БлокироватьДляИзменения = Истина" будут закрыты.
 
Актуальная версия статьи располагается тут.
Контакты автора на сайте chistov.pro 

Скачать файлы

Наименование Файл Версия Размер Кол. Скачив.
Выгрузка информационной базы с примером
.dt 29,33Kb
26.07.13
34
.dt 29,33Kb 34 Скачать

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Юрий Пермитин (YPermitin) 25.07.13 18:17
Отличная статья! Эх, увидеть бы ее 2 года назад)
2. Павел Чистов (GROOVY) 25.07.13 18:42
(1) YPermitin, так та статья на которую я ссылаюсь наверно года 3 года назад и вышла :)

http://1c.chistov.pro/2010/06/1-82.html
3. Анатолий Бритько (headMade) 25.07.13 20:42
Спасибо за статью!! Очень познавательно для меня.

Еще хотел уточнить один момент для себя. Насколько я понимаю даже если бы мы накладывали для регистра ОстаткиТоваров блокировку через объект "БлокировкаДанных", то всерано пришлось бы использовать "БлокироватьДляИзменения" т.к. для регистра включено разделение итогов ?

Спасибо.
4. Павел Чистов (GROOVY) 26.07.13 00:09
(3) headMade, А какая тут связь?
5. Антон Чарушкин (hulio) 26.07.13 08:54
(0) Павел, а подскажите, пожалуйста, еще такую вещь:
Не правильнее ли будет для контроля остатков получать данные не из табличной части документа, а уже из таблицы регистра? Я вижу несколько причин обращаться сразу к регистру:
1. В табличной части не готовые данные - требуется как минимум пересчитать количество из единиц в документе в единицы хранения остатков
2. Это более универсально - по одному регистру движения формируются разными документами, у которых названия табличных частей, реквизитов и т.д. могут быть разными, а если брать данные из регистра, то текст запроса будет одинаков для всех документов
Не думаю, что по скорости чтения данных из регистра будут какие-то проблемы, ведь регистратор, по которому устанавливается отбор для чтения данных, всегда входит в индекс регистра.
Если я ерунду говорю, сильно не пинайте, лучше объясните, в чем я не прав :)
Спасибо
6. Павел Чистов (GROOVY) 26.07.13 08:58
(5) hulio, прошу прощения, но вообще не понял вопроса.

|ВЫБРАТЬ
| Остатки.Товар.Представление КАК ТоварПредставление,
| Остатки.КоличествоОстаток
|ИЗ
| РегистрНакопления.ОстаткиТоваров.Остатки(

Мы берем данные из регистра. Все остальное, для оптимизации расчета временной таблицы.

Во втором запросе без данных ТЧ документа не обойтись.
7. Юрий Пермитин (YPermitin) 26.07.13 09:20
(2) GROOVY, в то время не попалась на глаза)
8. Антон Чарушкин (hulio) 26.07.13 09:28
(6) GROOVY, хотел сказать, что первый запрос (который для контроля остатков) можно было бы переписать таким образом:

Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
Запрос.Текст = "ВЫБРАТЬ
 | Док.Товар КАК Товар,
 | СУММА(Док.Количество) КАК Количество
 |ПОМЕСТИТЬ ДокТЧ
 |ИЗ
 | РегистрНакопления.ОстаткиТоваров КАК Док
 |ГДЕ
 | Док.Регистратор = &Ссылка
 |
 |СГРУППИРОВАТЬ ПО
 | Док.Товар
 |
 |ИНДЕКСИРОВАТЬ ПО
 | Товар
 |;
 |
 |////////////////////////////////////////////////////////////­////////////////////
 |ВЫБРАТЬ
 | Остатки.Товар.Представление КАК ТоварПредставление,
 | Остатки.КоличествоОстаток
 |ИЗ
 | РегистрНакопления.ОстаткиТоваров.Остатки(
 | &ТочкаИтогов,
 | Товар В
 | (ВЫБРАТЬ
 | ДокТЧ.Товар
 | ИЗ
 | ДокТЧ КАК ДокТЧ)) КАК Остатки
 |ГДЕ
 | Остатки.КоличествоОстаток < 0
 |;
 |
 |////////////////////////////////////////////////////////////­////////////////////
 |ВЫБРАТЬ
 | ДокТЧ.Товар
 |ИЗ
 | ДокТЧ КАК ДокТЧ";
...Показать Скрыть
9. Павел Чистов (GROOVY) 26.07.13 09:30
(8) hulio, ага, понял. Можно. Я традиционно делал.
10. Антон Чарушкин (hulio) 26.07.13 09:35
(9) GROOVY, про "традиционно" я понял :) Мне интересно ваше мнение, можно ли писать так, как предложил я? Просто я пока вижу только преимущества, но может есть и недостатки, которые их нивелируют?
11. Павел Чистов (GROOVY) 26.07.13 09:43
(10) hulio, чаще всего на основании данных ТЧ документа требуется сделать движения не по одному регистру. Да и сворачивать строки ТЧ документа при формировании движений будет не лишним. Вывод: то что Вы предлагаете, в конкретном частном случае можно использовать, и это удобно, но в общем случае, я думаю, будет довольно мало ситуаций, когда можно было бы применить подобную методику.
12. Епрст (Ёпрст) 26.07.13 09:50
(8) какая то бредятина написана..

Проводим первый раз документ - в регистре ОстаткиТоваров ничего нет при условии

ГДЕ
| Док.Регистратор = &Ссылка

не запрос, а мусор.
13. Антон Чарушкин (hulio) 26.07.13 09:53
(12) Ёпрст, сам ты мусор )))
Перед выполнением запроса вообще-то запись движений происходит ;)
14. Антон Чарушкин (hulio) 26.07.13 10:05
(11) GROOVY, да, что-то не учел, что данных в одном регистре может быть недостаточно для проведения по другому регистру :)
Тем не менее, считаю, что в угоду универсальности кода можно использовать чтение данных из регистра, а не из ТЧ.
Как правило регистров, по которым нужен контроль остатков не много, а документов, формирующих движения по ним - достаточно большое количество. Поэтому для каждого документа прописывать контроль муторно (надо учитывать, например, что у них может быть разный состав табличных частей и реквизитов), а так можно для контроля по конкретному регистру создать универсальную процедуру для любых видов регистраторов.
Само собой, что это может сказываться на производительности при большом количестве контролируемых регистров и серьезном документообороте, но думаю, такой подход имеет право на существование.
15. Епрст (Ёпрст) 26.07.13 10:12
(13) че-то про запись движения до того как не подумал.
16. Павел Чистов (GROOVY) 26.07.13 10:13
(14) hulio, ничего против комментария не имею, но замечу, что при формировании движений в регистры их имеет смысл оптимизировать (отбросить незначащие, свернуть ТЧ и пр). И в общем случае получится, что запрос к ТЧ документа в любом случае будет построен. А если уже есть выборка из ТЧ, то смысл обращаться к другой таблице пропадает. Это в общем случае... Это я по поводу универсальности...
17. Епрст (Ёпрст) 26.07.13 10:15
всё равно, без запроса к тч не обойтись, особенно в типовых.
Если только всё не переписывать.
Там повсеместно есть конструкции типа подготовитьтаблицу документа и т.д..
18. Tsaregorodtsev (TSSV) 26.07.13 11:42
Спасибо, полезно! В коде не увидел ОсталосьСписать = ОсталосьСписать - Списать;
19. Артем Целовальников (slazzy) 26.07.13 12:04
GROOVY, большое спасибо за статью, очень интересно. Но у меня пара вопросов, если можно.
1) А разве не нужно при оперативном проведении получать актуальные итоги, а не на момент времени? Как вообще работает этот процесс получения актуальных итогов? Обязательно ли их получать на пустую дату?
2) Вопрос немного не в тему, но может быть подскажете. По экзамену специалист на платформу. Решенная вами задача почти копия задачи 1.1 из сборника. Так вот, решить задачу можно и используя старую методику проведения, на одном регистре. Как всё таки правильно делать на экзамене? Использовать 2 регистра и новую методику, или 1 регистр и старую? Я спрашивал на вашем форуме, там предпочитают 1 регистр.

Спасибо :)
20. Павел Чистов (GROOVY) 26.07.13 13:24
(18) Tsaregorodtsev, спасибо, поправил.
(19) slazzy, 1. А кто такое сказал? 2. Снизят балл.
21. Артем Целовальников (slazzy) 26.07.13 14:07
(20) GROOVY,
1) так я сам испрашиваю. Просто неоднократно видел вот такую конструкцию.
МоментВремени = ?(Режим = РежимПроведенияДокумента.Неоперативный, МоментВремени(), '00010101'));
И это казалось логичным :) вы же в данном случае не использовали данную конструкцию, вот я и уточнил а нужна ли она.
2) То есть при партионном учете, на экзамене специалист, требуется делать именно так, как в вашей статье? Просто, на самом деле, смотрел десятки решенных билетов от разных людей и они все делали на одном регистре. Хотя мне вариант на двух тоже кажется более правильным.
22. Сергей Маслов (LexSeIch) 26.07.13 14:52
Мир этому дому!
Спасибо за интересный материал.
23. Павел Чистов (GROOVY) 26.07.13 15:43
(21) slazzy, По первому пункту, думаю, что правильнее будет уточнить у автора кода, какую цель он преследовал. По второму пункту я уже ответил - снизят балл.
24. Гость 26.07.13 15:56
>> раньше мы могли принудительно записать движения документа (наборы данных),
>> но при окончании транзакции проведения наборы данных записывались еще раз

Это точная информация? У документа два свойства: "Записывать выбранные" и "Записывать модифицированные". Если мы один раз принудительно записали набор движений, то свойство модифицированности у него пропадет и при окончании обработки проведения повторной записи не будет.

Сейчас уже не могу ручаться на 100%, но помню что проверял этот момент и повторной записи не происходило. Связал тогда это с тем, что свойство "Модифицированность" у уже записанных движений = Ложь.

По этому как минимум один плюс новой схемы можно вычеркнуть.
25. Павел Чистов (GROOVY) 26.07.13 16:11
(24) BH, контролировать запись/не запись мы могли? Нет. Про старую запись при окончании проведения Вы правы, однако признак модификации набора записей мы ни снять ни установить не можем.
26. Елена Пименова (Bukaska) 26.07.13 16:17
Мир этому дому))) Спасибо за интересный материал))))
27. Гость 26.07.13 16:25
Кстати, хотелось бы еще раз отметить важное свойство записи с установленным флагом БлокироватьДляИзменения, которое многие упускают из виду. При записи блокируются записи не только по тем измерениям, которые содержатся в записываемом наборе, но блокировка происходить и по тем записям, которые уже есть в базе по указанному в наборе записей отбору. Это не зависит от того, есть в записываемом наборе записи или нет.

В статье это отмечено, но несколько в другом контексте, при записи пустого набора записей
//16
 Если Режим = РежимПроведенияДокумента.Оперативный Тогда
  Движения.СтоимостьТоваров.Очистить();
  //17
  Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
  Движения.СтоимостьТоваров.Записать();
 КонецЕсли; 
...Показать Скрыть

Устанавливаем свойство "БлокироватьДляИзменения". Это позволит заблокировать от чтения те данные которые сейчас будут удалены из регистра


Извиняюсь за дублирование информации, но не раз на форумах встречал вопросы связанные с этим и именно этот момент ставил вызывал у людей затруднение и это кажется важным.
28. Павел Чистов (GROOVY) 26.07.13 16:31
(27) BH, да это многие упускают из виду.
29. Гость 26.07.13 16:36
(25) GROOVY,
однако признак модификации набора записей мы ни снять ни установить не можем.

Это так, однако после выполнения
Движения.Записать();

для каждого набора записей из этой коллекции Модифицированность() = Ложь.
Таким образом по окончании обработки проведения если мы записали движения вручную и у документа установлено свойство "Записывать модифицированные" запись произведена не будет.
30. Гость 26.07.13 16:38
Хотел написать, что повторная запись произведена не будет.
31. Гость 26.07.13 16:48
(21) slazzy,
Просто неоднократно видел вот такую конструкцию. 
МоментВремени = ?(Режим = РежимПроведенияДокумента.Неоперативный, МоментВремени(), '00010101'));


Лучше написать так:
Просто неоднократно видел вот такую конструкцию.
МоментВремени = ?(Режим = РежимПроведенияДокумента.Неоперативный, МоментВремени(), Неопределено));
Хотя не проверял, возможно эти выражения равнозначны.

Здесь такой момент. Установка параметров виртуальных таблиц в Неопределено равносильна тому, что мы его не указываем. Это, если можно так выразится по отношению к параметрам виртуальных таблиц, параметр по умолчанию. В этом случае в случае оперативного проведения вычисляются итоги на последнюю возможную дату.... с годом 3999 и указанным в справке днем и месяцем :)

Какие преимущества это дает? В случае если мы всегда будем указывать МоментВремени() , то в любом случае система будет вычислять остатки на этот момент времени. Хотя возможно есть какой-то аналог точки актуальности и если МоментВремени() оказывается больше нее то это равнозначно тому что параметр не указывается. Но я во всяком случае нигде не встречал такой информации.

Сам всегда предпочитаю писать
МоментВремени = ?(Режим = РежимПроведенияДокумента.Неоперативный, МоментВремени(), Неопределено));
Это простое выражение и гарантированно дает нужный результат.
32. Гость 26.07.13 17:06
И конечно же хочется сказать спасибо автору. Пожалуй лучшая статья на эту тему. Понравилось как описано последовательное проведение по оперативному и неоперативному регистрам. Обычно такой связки не приводят, а дают два разных варианта, отдельно по старой методике и отдельно по новой.
33. Артем Целовальников (slazzy) 26.07.13 17:17
(31) BH, я знаю что это означает и для чего пишется ) спасибо. Неопределено можно писать, но виртуальная таблица там ожидает увидеть всё таки дату. Поэтому можно(и как мне кажется правильнее) передавать пустую дату, хотя это и правда не имеет значения.
Я собственно и спросил, почему GROOVY не использовал такую возможность.
Ведь по логике, при оперативном проведении мы записываем пустой набор и мы вполне можем получать остатки из таблицы актуальных итогов, а не на момент времени. Так указывалось много где, к примеру
Я не эксперт и возможно есть какая-то причина ) именно поэтому и интересуюсь

К примеру в этой статье http://infostart.ru/public/146332/, да и вообще много где.
34. ZLENKO.PRO (ZLENKO) 26.07.13 17:41
После длительного изучения темы управляемых блокировок я для себя сделал следующие выводы как "правильно":
0) Используем 1С 8.3 - база MS SQL в режиме версионника (это важно), а не блокировщика. Для других СУБД вроде как и в 8.2 используется версионирование, но на практике ничего не могу сказать по ним - не пробовал.
1) Движения автоматически не удаляем при перепроведении (иначе сразу в начале проведения получим блокировку).
2) Движения явно в коде не пишем - записываются автоматически системой при записи самого документа (иначе получим деадлоки из-за разного порядка записи в регистры).
3) В регистрах накопления и бухгалтерии убираем возможность разделения итогов (иначе получим конфликт разделяемой и неразделяемой блокировки при контроле остатка).
4) Блокировки явно в коде не устанавливаем (устанавливаются платформой автоматически при записи движений в регистры).
5) Контроль остатков делаем после записи движений регистров (ну собственно "новая" методика :-)).

Почему именно так нужно объяснять подробнее по каждому пункту, но таким образом исключаются деадлоки на уровне СУБД и минимизируется время блокировки на уровне сервера приложений только на время записи движений в регистры.

Такой подход реально работает! Параллельность работы максимально возможная!

P.S.: Хуже всего конечно с регистром бухгалтерии т.к. там плохо разделяются блокировки, но это компенсируется тем что блокировка накладывается только на время записи в регистр, а не на все время проведения документа.
smaximaa; Droni; p1l1gr1m; +3 Ответить 4
35. ZLENKO.PRO (ZLENKO) 26.07.13 17:45
(34) На тему "версионника" можно тут почитать http://infostart.ru/public/91879/
36. ZLENKO.PRO (ZLENKO) 26.07.13 18:01
Еще важное замечание по поводу управляемых блокировок и MS SQL - перевод базы с автоматических на управляемые блокировки существенно улучшает параллельность работы, но если MS SQL работает в режиме блокировщика, остается изрядная "ложка дегтя" в виде того что MS SQL накладывает блокировки по своему усмотрению, что часто приводит к деадлокам на уровне MS SQL и существенной потере параллельности работы. Поэтому только версионник и так как я написал выше. Разработчики 1С много чего понаделали и понаписали на тему управляемых блокировок, но почему то так и не объяснили как выглядит "золотой грааль" :-)
37. Павел Чистов (GROOVY) 26.07.13 18:15
(34) ZLENKO.PRO, в настоящий момент в реальной эксплуатации юзать 8.3 будет только не очень далекий человек.
38. ZLENKO.PRO (ZLENKO) 26.07.13 18:22
(38) А кто говорил о реальной эксплуатации ? Вы ведь тоже про 8.3 написали в своей статье :-)
39. ZLENKO.PRO (ZLENKO) 26.07.13 18:24
"Интересную фишку, раньше мы могли принудительно записать движения документа (наборы данных), но при окончании транзакции проведения наборы данных записывались еще раз. Теперь мы вольны в выборе, что и когда нужно записывать. Маркер записи автоматически снимается при записи набора, тем самым, при окончании транзакции проведения, набор записей еще раз записываться не будет. К чему это приведет? Правильно, к уменьшению блокировок таблиц и к сокращению времени транзакций при проведении."

Правильным подходом является отсутствие явной записи регистров для исключения взаимоблокировки регистров при разном порядке записи. Правильно ?
40. ZLENKO.PRO (ZLENKO) 26.07.13 18:27
(37) GROOVY, На 8.2 такой подход тоже работает, но перевод базы MS SQL в режим версионника нарушает... сами знаете что :-) А вот в случае базы на постгри или оракле должно работать и на 8.2
41. Павел Чистов (GROOVY) 26.07.13 18:37
(38) ZLENKO.PRO, я не говорил про 8.3, я только уточнил на какой платформе я делал демопример.
42. ZLENKO.PRO (ZLENKO) 26.07.13 18:37
Одна из "проблем" повышения параллельности работы заключается в том что наложенная (явно в коде или автоматически самой системой) блокировка в процессе проведения документа сохраняется до окончания транзакции, т.е. до конца проведения документа. Поэтому наложение блокировок необходимо максимально отсрочить до самого конца проведения - система сама запишет движения регистров и сама наложит необходимые блокировки.
43. Павел Чистов (GROOVY) 26.07.13 18:37
44. Павел Чистов (GROOVY) 26.07.13 18:38
(42) ZLENKO.PRO, в частном случае, можно писать данные и не в транзакции проведения.
45. ZLENKO.PRO (ZLENKO) 26.07.13 18:44
(41) GROOVY, Все что я написал в (34) актуально и для 8.2, однако используя базу MS SQL на 8.2 несмотря на все ухищрения будут появляться ошибки ожидания на блокировках на уровне СУБД :-( (хотя "по мнению" сервера приложений их быть не должно :-))
Это не повод не пользоваться тем подходом который я описал, но идеала по параллельности работы таким образом для MS SQL не достигнем :-(
46. ZLENKO.PRO (ZLENKO) 26.07.13 18:50
(44) GROOVY, Пожалуй "отложенное проведение", характерное для некоторых западных систем, отделенное от записи самого документа, является правильным вектором движения и для 1С. Надеюсь что в будущем в типовых конфигурациях так и будет реализовано. Пока приходится работать с тем что есть - я не готов переписать полностью проведение документов даже в УТ, не говоря уже про УПП.
47. Вячеслав Гилёв (Gilev.Vyacheslav) 26.07.13 20:45
(37) GROOVY, ну к примеру мы уже как год предоставляем сервисы на 8.3...
48. Вячеслав Гилёв (Gilev.Vyacheslav) 26.07.13 20:49
Павел, могу сказать Вам как практик, теория это конечно хорошо, но версионник скуля обесценивает эту методику.
Более того, я сам преподавал, и очень хорошо помню как время от времени во всех курсах меняется "политика партии". Делайте так... А почему - а потому что так "методически верно"...

Проходит некоторое время, и на тех же курсах ТАК КАК РАНЬШЕ ДЕЛАТЬ НЕ ПРАВИЛЬНО, теперь политика партии ТАКАЯ...

И так по кругу...
49. Вячеслав Гилёв (Gilev.Vyacheslav) 26.07.13 20:51
короче, конечно методически верно делать как написал Павел :)
50. Анатолий Бритько (headMade) 26.07.13 21:44
(4) GROOVY,
Включение режима разделения итогов фактически добавляет в таблицу итогов регистра еще одно измерение, позволяющее распараллелить обновление записей итогов. Свойство БлокироватьДляИзменения этот механизм отключает.
51. Анатолий Бритько (headMade) 26.07.13 21:47
(48) Gilev.Vyacheslav,
объясните почему "версионник скуля обесценивает эту методику" ???
Пожалуйста...
52. Павел Чистов (GROOVY) 26.07.13 21:52
(50) headMade, это бред. Причем в УЦ1 Гончаров его массово продвигает.
53. Вячеслав Гилёв (Gilev.Vyacheslav) 26.07.13 21:59
(51) headMade, потому что прочитать версию в режиме версионника не вызвает взаимоблокировку, каждый читает свою версию, а если версия "устареет", то вылезет ошибка, не вызывающая взаимное блокирование
получилось ли у меня ответить на вопрос?
VladimirL; AllexSoft; +2 Ответить 2
54. Алексей Белоусов (AllexSoft) 26.07.13 22:22
прочитал статью, был на курсах в том числе и УЦ 1, конечно понимаю зачем так делать по новой методике, но всеравно пишу решение по старому... незнаю, какие то через чур сомнительные приимущества... кто вообще замерял какую это эффективность на реальной базе между старой и новой методикой... ну скажем на 100 юзерах, сильно заметно ?
55. Вячеслав Гилёв (Gilev.Vyacheslav) 26.07.13 22:22
Думаю еще методики поменяются, когда платформа к примеру научится "секционировать" данные, и они поделятся на нечто вроде "оперативные" и "архивные"...
56. Вячеслав Гилёв (Gilev.Vyacheslav) 26.07.13 22:23
(54) AllexSoft, что значит сомнительные - берете инструмент вроде ЦУПа и смотрите статистику, гадать не надо
57. Алексей Белоусов (AllexSoft) 26.07.13 22:27
(56) Gilev.Vyacheslav, у меня нет такой возможности (маленький город), у вас наверняка есть опыт конкретного сравнения, поделитесь ?
пс: сомнительные для меня, стоит ли заморачиваться если пользователей работает не более 15 ? я думаю нет.. у них даже транзакционных блокировок не возникает даже на автоматическом режиме + файловая бд )
58. Анатолий Бритько (headMade) 26.07.13 22:44
59. Вячеслав Гилёв (Gilev.Vyacheslav) 26.07.13 22:50
(57) AllexSoft, если проблемы нет у вас, это не означает что ее в природе нет
когда вернетесь к проблеме, соберите статистику например бесплатным http://www.gilev.ru/deadlock/ и будет понятно (оно/не оно) :)
60. Алексей Белоусов (AllexSoft) 26.07.13 23:07
(59) Gilev.Vyacheslav, я понимаю что вообще она есть, поэтому и попросил поделиться опытом у кого он есть, у кого возникали подобные проблемы, насколько перевод своих решений с старой методики на новую повлияло на проблему
ps: за ссылку спасибо, пригодится
61. Роман Озеряный (rozer) 27.07.13 00:33
(52)GROOVY, а заявление что "это бред" чем-то подкрепляется?
Все же кажется правдоподобным что

//3
Движения.Записать();

Блокирует до конца транзакции без "Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина" только по разделителю итогов а т.к. чтение выполняется без разделителя то для исключения взаимоблокировки и добавляют "Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина" но только если ВКЛЮЧЕН разделитель итогов это и имеет смысл. Иначе же если разделитель итогов ВЫКЛЮЧЕН - сама запись в регистр накладывает исключительную блокировку до конца транзакции.
Также здесь

Если "и то и другое" то важно проверить настройки объектов. Помните, что вид транзакции наследуется всеми вложенными транзакциями. То есть если документ записывается в автоматической транзакции, а движения делает по регистрам с управляемой... То система немного расстроится и вывалится с ошибкой.

кажется все наоборот. Если существующая транзакция автоматическая то начинаемая тоже. А вот если сначала управляемая а потом автоматическая - ошибка.
62. Павел Чистов (GROOVY) 27.07.13 00:38
(61) rozer, Про бред, было на "Свойство БлокироватьДляИзменения этот механизм отключает.".
"Иначе же если разделитель итогов ВЫКЛЮЧЕН - сама запись в регистр накладывает исключительную блокировку до конца транзакции. " об этом было указано в статье.
63. Роман Озеряный (rozer) 27.07.13 00:50

Если разделение итогов не будет включено и в режиме пользователя, то в большей части случаев блокировка будет наложена на весь регистр с его таблицами.

Здесь? Т.е. если разделителя нет то несмотря на управляемые режим блочиться весь регистр???


"Свойство БлокироватьДляИзменения этот механизм отключает."

Не ну момент проведения отключает конечно :)
64. Роман Озеряный (rozer) 27.07.13 00:54
65. ZLENKO.PRO (ZLENKO) 27.07.13 09:59
(53) Gilev.Vyacheslav, на уровне СУБД чтение версии конечно не вызовет взаимоблокировки, однако взаимоблокировка должна возникнуть на уровне сервера приложений, т.к. блокировка накладывается сервером приложений и сохраняется до конца транзакции (проведений). Я правильно понимаю ?
66. ZLENKO.PRO (ZLENKO) 27.07.13 10:07
(62) GROOVY, я думаю вместо тех сложных и запутанных объяснений которые исходят от 1С, надо объяснять проще.
По "новой методике" можно включать разделение у оборотных регистров накопления и отключать его у регистров накопления остатков (по которым делаем контроль остатков после записи). И при таком подходе вообще не нужно думать про "БлокироватьДляИзменения". Потому что получается бред - сначала мы разрещаем разделение, а потом программно через БлокироватьДляИзменения его по сути запрещаем. Ну и в чем тут глубокий смысл ?
67. ZLENKO.PRO (ZLENKO) 27.07.13 10:11
(54) AllexSoft, смотря какие пользователи, какая база и какая конфигурация. У меня на 100 пользователях с УПП с базой за 4 года было сильно заметно разницу.
68. ZLENKO.PRO (ZLENKO) 27.07.13 10:18
(60) AllexSoft, я в (34) описал вкратце свой опыт (упоминание про 8.3 чисто теоретическое - она на тот момент еще бетой была). Насколько помогло: в УПП в любое время можно запускать проведение по партиям (при том что документы сами проводятся по партиям) не мешая никому работать. Можно запустить 3-4 потока перепроведения документов и они будут идти параллельно без таймаутов. Вот такая разница.
Ну а новую методику контроля остатка я применяю с 2007 года, когда еще 1С говорила что это в корне неверный подход :-)
AllexSoft; +1 Ответить
69. ZLENKO.PRO (ZLENKO) 27.07.13 10:29
(61) rozer, вот объясните мне в чем смысл сначала разрешать разделение итогов, а затем накладывать блокировку, которая по сути запрещает его использовать ? Разработчики из 1С ответят что мы мол сделали функционал, а уж вы думайте пользоваться ним или нет :-) Ну а с практической точки зрения ? Как я уже писал я отказался от разделения итогов в принципе. В реальных ситуациях я думаю выигрыш от разделения незначительный. Я больше думал об уменьшении времени транзакционных блокировок.
70. Вячеслав Гилёв (Gilev.Vyacheslav) 27.07.13 11:50
(65) ZLENKO.PRO, не правильно

но если уж совсем честно подходит к этому вопросу, вызвать взаимную блокировку могут все перечисленные методики, включая последнюю, но вероятность их существенно ниже чем в исходной методике
71. Ivan Alekseev (IvanAlekseev) 27.07.13 11:54
Первая накладная сформирует движения и начнет читать запрос по остаткам через кэш собственной транзакции, что, собственно, будет делать и вторая накладная. Но ложек-то всего 6, а в сумме две накладные продадут 10... Потому-что не знают о том, что данные в таблицах уже не актуальны...


Откуда информация, что запросы модуля документа читают из кеша? Я поставил эксперимент, запустив одновременно две процедуры проведения из-под разных юзеров. Сначала до, а потом после записи набора регистра у меня стояла функция задержки для синхронизации юзеров. В обоих случаях один юзер провел документ, а второму выдалось сообщение о нехватке товара. Экспериментировал в файловом варианте.

	 //1
	 Движения.ОстаткиТоваров.Записывать = Истина;
	 
	 //2
	 Движения.ОстаткиТоваров.Очистить();
	 
	 Для каждого Стр Из СписокТоваров Цикл
	  Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
	  Движение.Период = Дата;
	  Движение.Товар = Стр.Товар;
	  Движение.Количество = Стр.Количество;
	 КонецЦикла; 
	 
	 //7
	 //Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;
	 
	 //Пока НЕ КаталогСуществует() Цикл
	 //	 Пауза(1);
	 //КонецЦикла; 

	 
		 //3
	 Движения.Записать();
	 
	 Пока НЕ КаталогСуществует() Цикл
		 Пауза(1);
	 КонецЦикла;

	 Запрос = Новый Запрос;
	 
	 //4
	 Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
	 Запрос.Текст = "ВЫБРАТЬ
	 | Док.Товар КАК Товар,
	 | СУММА(Док.Количество) КАК Количество
	 |ПОМЕСТИТЬ ДокТЧ
	 |ИЗ
	 | Документ.РасходнаяНакладная.СписокТоваров КАК Док
	 |ГДЕ
	 | Док.Ссылка = &Ссылка
	 |
	 |СГРУППИРОВАТЬ ПО
	 | Док.Товар
	 |
	 |ИНДЕКСИРОВАТЬ ПО
	 | Товар
	 |;
	 |
	 |////////////////////////////////////////////////////////////­////////////////////
	 |ВЫБРАТЬ
	 | Остатки.Товар.Представление КАК ТоварПредставление,
	 | Остатки.КоличествоОстаток
	 |ИЗ
	 | РегистрНакопления.ОстаткиТоваров.Остатки(
	 | &ТочкаИтогов,
	 | Товар В
	 | (ВЫБРАТЬ
	 | ДокТЧ.Товар
	 | ИЗ
	 | ДокТЧ КАК ДокТЧ)) КАК Остатки
	 |ГДЕ
	 | Остатки.КоличествоОстаток < 0
	 |;
	 |
	 |////////////////////////////////////////////////////////////­////////////////////
	 |ВЫБРАТЬ
	 | ДокТЧ.Товар
	 |ИЗ
	 | ДокТЧ КАК ДокТЧ";
	 Запрос.УстановитьПараметр("Ссылка", Ссылка);
	 
	 //5
	 Запрос.УстановитьПараметр("ТочкаИтогов", Новый Граница(МоментВремени(), ВидГраницы.Включая)); 
	 
	 ПакетРезультатов = Запрос.ВыполнитьПакет();
	 РезультатЗапроса = ПакетРезультатов[1];
	 
	 Если НЕ РезультатЗапроса.Пустой() Тогда
	  //6
	  Отказ = Истина;
	  
	  Выборка = РезультатЗапроса.Выбрать();
	  Пока Выборка.Следующий() Цикл
	   Сообщение = Новый СообщениеПользователю;
	   Сообщение.Текст = "Мало товара " + Выборка.ТоварПредставление + " нужно еще " + (-Выборка.КоличествоОстаток);
	   Сообщение.Сообщить(); 
	  КонецЦикла;  
	 КонецЕсли; 
	 
	 Если Отказ Тогда
	  Возврат;
	 КонецЕсли;
...Показать Скрыть
72. Вячеслав Гилёв (Gilev.Vyacheslav) 27.07.13 13:08
обсуждается методика в контексте MS SQL Server прежде всего
73. ZLENKO.PRO (ZLENKO) 27.07.13 14:57
(70) Gilev.Vyacheslav, Что именно неправильно ?
74. ZLENKO.PRO (ZLENKO) 27.07.13 15:00
(71) IvanAlekseev, Файловый вариант в данном контексте не представляет интереса.
75. Павел Чистов (GROOVY) 27.07.13 15:13
Файловый вариант вообще, ни в каком контексте интереса не представляет.
axelerleo; ZLENKO; +2 Ответить
76. ZLENKO.PRO (ZLENKO) 27.07.13 15:49
(54) AllexSoft, кстати по поводу 100 человек... Понятно что количество человек весьма условно - даже два человека могут запустить обработку перепроведения документов и начать получать блокировки. Понятно что без блокировок тоже обойтись невозможно. Необходимо повышать параллельность работы пользователей настолько, насколько это возможно и при этом помнить что вероятность возникновения и время ожидания на блокировке прямо пропорционально времени блокировки, а поскольку при проведении блокировки в транзакции, то надо уменьшать время от начала блокировки до конца транзакции. Вот основная отправная точка, а все остальное это уже методы достижения цели.
P.S.: Основная проблема масштабируемости 1С - длинные транзакции при проведении. Думаю что многим это и так понятно, но по опыту многие это не до конца понимают. Решать эту проблему можно по разному, но чаще всего приходится ее решать в уже существующих в том числе типовых конфигурациях и в связи с этим количество способов решения сильно сокращается (в некоторых случаях до нуля :-)).
AllexSoft; +1 Ответить
77. Роман Озеряный (rozer) 27.07.13 21:05
(69) разделение итогов на порядок повышает производительность записи а остальное-читайте внимательнее пост.
78. ZLENKO.PRO (ZLENKO) 29.07.13 11:04
(77) Разделение итогов снижает производительность, т.к. при расчете итогов обрабатывается больше записей :-)
А по поводу записи, теоретически можно писать параллельно в оборотные регистры накопления, а вот в регистры остатков при "новой" методике контроля остатков параллельно писать нельзя, поэтому и придумали "БлокироватьДляИзменения". Если почитаете форум разработчиков 1С, то там это достаточно подробно расписано. Т.е. фактически для тех регистров, по которым остатки проверяются после записи проще отключить возможность разделения итогов чтобы не заморачиваться с "БлокироватьДляИзменения". С другой стороны запись в такой регистр не всегда сопровождается последующим чтением (контролем остатка), но при этом надо точно понимать когда нужно блокировать, а когда нет. Так что в идеальном варианте "БлокироватьДляИзменения" нужное свойство, но где вы видели идеальные конфигурации ?
79. Александр Давыдов (frying) 29.07.13 12:38
GROOVY, поправьте терминалогию, грязным чтением называется совершенно другие ошибки.
80. Павел Чистов (GROOVY) 29.07.13 12:44
(79) frying, на мой взгляд с терминОлогией все правильно: http://goo.gl/Epi5Ff
81. Александр Давыдов (frying) 29.07.13 12:58
(80), «грязное» чтение (англ. dirty read) — чтение данных, добавленных или изменённых транзакцией, которая впоследствии не подтвердится (откатится);

На момент чтения ничего еще не изменилось. Иначе прочитать бы не удалось. При управляемых блокировках в транзакции проведения уровень изоляции READ COMMITED, что само собой исключает возможность грязного чтения.
82. Павел Чистов (GROOVY) 29.07.13 13:07
(81) frying, ок. Как назвать чтение данных уже измененных но не зафиксированных параллельной транзакцией?
83. Александр Давыдов (frying) 29.07.13 13:12
То, что Вы написали в вопросе и есть Грязное чтение. В статье описана другая проблема, которую решает или Repeatable read или Serializable. При проведении документов грязного чтения быть не может.

Извиняюсь, Repeatable read не решит.
84. ZLENKO.PRO (ZLENKO) 29.07.13 16:17
Если разделение итогов не будет включено и в режиме пользователя, то в большей части случаев блокировка будет наложена на весь регистр с его таблицами.

Кем будет наложена блокировка на весь регистр:
- Сервером приложений (если это так то это ошибка в логике работы сервера приложений) ?
- MS SQL Server (такое вполне возможно т.к. MS SQL сам принимает решение что блокировать) ?
85. ZLENKO.PRO (ZLENKO) 29.07.13 17:11
(8) hulio, вот это пожалуй лишнее - на документах с разумным количеством строк выигрыша от индексирования не получите, а замедление вполне реальное на создание индекса:
 |ИНДЕКСИРОВАТЬ ПО
 | Товар
86. ZLENKO.PRO (ZLENKO) 29.07.13 17:14
(8) hulio, судя по опыту с запросом получения остатков по партиям на MS SQL делать отбор в виртуальных таблицах остатков в виде подзапросов чревато нестабильностью времени выполнения запроса при не совсем актуальной статистике:
 | РегистрНакопления.ОстаткиТоваров.Остатки(
 | &ТочкаИтогов,
 | Товар В
 | (ВЫБРАТЬ
 | ДокТЧ.Товар
 | ИЗ
 | ДокТЧ КАК ДокТЧ)) КАК Остатки
...Показать Скрыть
87. Павел Чистов (GROOVY) 29.07.13 17:21
(86) ZLENKO.PRO, Да ладно, с таким запросом все примитивно очевидно. Вот если подзапрос к виртуальным таблицам, тогда да...
88. ZLENKO.PRO (ZLENKO) 29.07.13 17:35
(87) GROOVY, и тем не менее факты вещь упрямая :-) условие в соединении таблиц отрабатывается MS SQL быстрее чем в параметрах виртуальной таблицы в виде подзапроса. Я проводил множество экспериментов по оптимизации запроса получающего остатки партий при проведении по партиям. Хотя это и противоречит "официальной" теории но так на MS SQL работает существенно быстрее даже при актуальной статистике, чем с отборами в виртуальной таблице:
	|ИЗ
	| СписанныеТоварыРегистр КАК СписанныеТовары	
	| ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровНаСкладах.Остатки(&Дат, ) КАК ПартииТоваровНаСкладах
	| ПО СписанныеТовары.Склад = ПартииТоваровНаСкладах.Склад И СписанныеТовары.Номенклатура = ПартииТоваровНаСкладах.Номенклатура	


По поводу других СУБД ничего сказать не могу по этому поводу.
89. Вячеслав Гилёв (Gilev.Vyacheslav) 29.07.13 19:01
Извиняюсь что редко пишу.

По вашей переписке - имхо вы оба уходите в частности, есть список "ограничений" и "условий" при которых алгоритмы работают, даже банальное количество строк в обсуждаемых таблицах могут поменять "подход" к алгоритму...

Делить Вам нечего: Павел рассказывает про массовый подход, а вы (88) про частный - как бы не корректно под общий знаменатель это все делать...
90. ZLENKO.PRO (ZLENKO) 29.07.13 22:17
(89) Для общего случая лучше работает сначала отдельным запросом получить список номенклатуры и список складов и в виде параметра запроса их указать в отборе виртуальной таблицы вот так:
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровНаСкладах.Остатки(&Дат, Склад В (&СписокСкладов) И Номенклатура В (&СписокНоменклатуры)) КАК ПартииТоваровНаСкладах

На истину в последней инстанции не претендую :-) Просто поделился опытом.

Меня больше интересует ответ на (84).
91. ZLENKO.PRO (ZLENKO) 29.07.13 22:25
(89) Gilev.Vyacheslav, просто вот в том запросе по остаткам партий 1С применила массовый подход и страшно даже представить сколько сотен тысяч машино-лет потерянной производительности это стоило в масштабах страны. Все таки наиболее часто используется MS SQL (файловый вариант в расчет не берем).
92. Антон Чарушкин (hulio) 31.07.13 11:10
(85) ZLENKO.PRO,
hulio, вот это пожалуй лишнее - на документах с разумным количеством строк выигрыша от индексирования не получите, а замедление вполне реальное на создание индекса:
ИНДЕКСИРОВАТЬ ПО ТОВАР Товар

Я знаю, этот кусок кода я скопировал из статьи Павла
93. Вячеслав Гилёв (Gilev.Vyacheslav) 31.07.13 12:10
надо смотреть на количество строк во временной таблице, если там 2 строки, индекс сильно не даст выигрыша, но я бы не стал из этого делать "религию", потому что и время создания индекса милисекунды
если лень делать "исследования", и знаете что по полю временной таблице будет соединение, то индексирование более "надежно"

все начинает играть новыми красками, когда во временную таблицу приходит миллион строк )
crabzzy; headMade; hulio; +3 Ответить 1
94. Антон Чарушкин (hulio) 31.07.13 12:35
(93) Gilev.Vyacheslav,
все начинает играть новыми красками, когда во временную таблицу приходит миллион строк )

Это точно. Мне даже кажется, что эффект будет вполне заметен уже на 100+ строках :)
95. bulpi bulpi (bulpi) 31.07.13 15:06
Модуль, написанный по "новой методике", примерно в 2-3 раза сложнее и длиннее (в строках), чем по "старой". Поэтому применять этот подход ИМХО нужно, только если припечет с блокировкой транзакций. В толково написанной нетиповой конфигурации мне страшно даже представить объем нагрузки на сервер, при котором проблема станет актуальной. А вот для типовых - да, но переписывать модули проведения задолбаешься.
96. Павел Чистов (GROOVY) 31.07.13 15:11
(95) bulpi, конечно, оценивать эффективность методики по длине кода - это сильно...
97. ZLENKO.PRO (ZLENKO) 31.07.13 17:00
(94) hulio, на 100 строках эффекта точно не заметите :-)
98. ZLENKO.PRO (ZLENKO) 31.07.13 17:09
(95) bulpi, если 2-3 пользователя то можно вообще не заморачиваться с методиками. А вот когда их под сотню и база уже несколько десятков гигабайт, то проблема с блокировками становится очень даже актуальной.
И как я уже писал качественно решить эту проблему помогает только переход на версионную СУБД.
Перевести типовую конфигурацию на "новую" методику не так уж и сложно - вполне реально (описано в (34)).
Я вместе с изучением теоретической части и практическими опытами перевел типовую УПП за 4 дня (2 дня читал мануалы и форумы, 1 день на кодинг, 1 день на тестирование). Правда контроль остатков товара по новой методике там уже был (я сделал еще раньше).
99. kiruha Дронов (kiruha) 31.07.13 18:38
//16
Если Режим = РежимПроведенияДокумента.Оперативный Тогда
Движения.СтоимостьТоваров.Очистить();
//17
Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
Движения.СтоимостьТоваров.Записать();
КонецЕсли;


На больших наборах это может приводить к заметному торможению .
На текущей машине около минуты на 1000.
В запросе остатков просто достаточно исключить обороты по документу, если они были
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа