gifts2017

Оптимизация работы в списке "ПриПолученииДанных"

Опубликовал Андрей Куришко (boggonzikov) в раздел Программирование - Практика программирования

Оптимизация работы в списке "ПриПолученииДанных"

 

Статья Оптимизация работы в списке "ПриПолученииДанных"

Очень часта бухгалтера, хотят чтобы формы списка были раскрашены во все цвета радуги в зависимости от значений реквизитов документа. Пример: Если товар не получен то в форме списка строка документа должна быть красная, если товар ... т.д., и так еще много много хотелок. Есть конечно отчеты, но не всегда выход. Приступим

Получаем код типа:

Процедура ДокументСписокПриПолученииДанных(Элемент, ОформленияСтрок)

   
ЦветКрасный = Новый Цвет(255,130,124);

    Для каждого
ОформлениеСтроки Из ОформленияСтрок Цикл
       
Данныестроки = ОформлениеСтроки.Данныестроки;

        Если
ДанныеСтроки.Ссылка.НеПолученТовар Тогда
           
ОформлениеСтроки.ЦветФона = ЦветКрасный;
        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

Вроде все красиво. Разукрашиваем в "ПриПолученииДанных", а не в "ПриВыводеСтроки", Цвет вынесен из цикла.

Проходим отладчик и видим, узкое место

ДанныеСтроки.Ссылка.НеПолученТовар

т.е 1С-ка каждый раз запросом получает значение реквизита. Можно конечно добавить этот реквизит в форму списка и скрыть, но условие и может быть сложным.

Попробуем это ускорить.

Получаем массив ссылок

Функция ПолучитьМассивСсылокОформленияСтрок(ОформленияСтрок)

   
Массив = Новый Массив;

    Для каждого
ОформлениеСтроки Из ОформленияСтрок Цикл
       
Массив.Добавить(ОформлениеСтроки.Данныестроки.Ссылка);
    КонецЦикла;


    Возврат
Массив;

КонецФункции
// ПолучитьСписокСсылок(ОформленияСтрок)

Получаем одним запросом необходимые нам данные.

 Пример

Функция ПолучитьТаблицаОформленияСтрок(МассивСсылокОформления)

   
Запрос = Новый Запрос;
   
Запрос.Текст =
       
"ВЫБРАТЬ
        |   ПриходнаяНакладнаяБезнал.Ссылка,
        |   ПриходнаяНакладнаяБезнал.НеПолученТовар
        |ИЗ
        |   Документ.ПриходнаяНакладнаяБезнал КАК ПриходнаяНакладнаяБезнал
        |ГДЕ
        |   ПриходнаяНакладнаяБезнал.Ссылка В(&МассивСсылокОформления)"
;

   
Запрос.УстановитьПараметр("МассивСсылокОформления", МассивСсылокОформления);

    Возврат
Запрос.Выполнить().Выгрузить();

КонецФункции
// ПолучитьСписокСсылок(ОформленияСтрок)()

В результате получаем код процедуры ДокументСписокПриПолученииДанных

 Процедура ДокументСписокПриПолученииДанных(Элемент, ОформленияСтрок)

   
ЦветКрасный = Новый Цвет(255,130,124);

   
МассивСсылокОформления = ПолучитьМассивСсылокОформленияСтрок(ОформленияСтрок);
   
ТаблицаДанныхОформленияСтрок = ПолучитьТаблицаОформленияСтрок(МассивСсылокОформления);

    Для каждого
ОформлениеСтроки Из ОформленияСтрок Цикл
       
Данныестроки = ОформлениеСтроки.Данныестроки;
       
СтрокаОформленияСтрок = ТаблицаДанныхОформленияСтрок.Найти(ОформлениеСтроки.Данныестроки.Ссылка, "Ссылка");

        Если
СтрокаОформленияСтрок.НеПолученТовар Тогда
           
ОформлениеСтроки.ЦветФона = ЦветКрасный;
        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

Ну а теперь тесты, как же без них.

Первый вариант

Документ.ПриходнаяНакладнаяБезнал.Форма.ФормаВыбора.Форма    36 ДокументСписокПриПолученииДанных1(Элемент, ОформленияСтрок);          81        12,558905       96,65

Второй вариант после оптимизации

    Документ.ПриходнаяНакладнаяБезнал.Форма.ФормаВыбора.Форма   37  ДокументСписокПриПолученииДанных2(Элемент, ОформленияСтрок);    81  0,426953    3,29 "

Результат, ускорение в 36 раз.

Вывод: Запрос для получения данных должен быть один. 

Спасибо за внимание.

 

См. также

Подписаться Добавить вознаграждение

Комментарии

1. Андрей Куришко (boggonzikov) 10.02.11 16:14
как раскрасить код. Раньше красил через html, сейчас я не нашел :cry: ?
2. Алексей Константинов (alexk-is) 10.02.11 16:24
3. Андрей Куришко (boggonzikov) 10.02.11 16:28
(2) как красить я знаю, куда это вставлять чтобы получился раскрашенный код
4. Михаил Ражиков (tango) 10.02.11 16:32
это, (0), делается по-другому, через Соответствие. но минус не дам :)
5. Андрей Куришко (boggonzikov) 10.02.11 16:34
(4) Как через Соответствие?
что-то не понял
6. Алексей Константинов (alexk-is) 10.02.11 16:40
7. Алексей Константинов (alexk-is) 10.02.11 16:49
Я бы сделал так

Перем ЦветКрасный;
Перем
Запрос;

Процедура
ДокументСписокПриПолученииДанных(Элемент, ОформленияСтрок)

   
Массив = Новый Массив;
    Для каждого
ОформлениеСтроки Из ОформленияСтрок Цикл Массив.Добавить(ОформлениеСтроки.Данныестроки.Ссылка); КонецЦикла;

   
Запрос.УстановитьПараметр("МассивСсылокОформления", Массив);
   
МассивСсылокОформления = Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку(0);

    Для каждого
ОформлениеСтроки Из ОформленияСтрок Цикл Если МассивСсылокОформления.Найти(ОформлениеСтроки.Данныестроки.Ссылка) <> Неопределено Тогда ОформлениеСтроки.ЦветФона = ЦветКрасный; КонецЕсли; КонецЦикла;

КонецПроцедуры

ЦветКрасный = Новый Цвет(255,130,124);
Запрос = Новый Запрос(
"ВЫБРАТЬ
|   ПриходнаяНакладнаяБезнал.Ссылка
|ИЗ
|   Документ.ПриходнаяНакладнаяБезнал КАК ПриходнаяНакладнаяБезнал
|ГДЕ
|   ПриходнаяНакладнаяБезнал.Ссылка В(&МассивСсылокОформления)
|   И ПриходнаяНакладнаяБезнал.НеПолученТовар"
);
MyNameIs; e.kogan; +2 Ответить 2
8. Андрей Куришко (boggonzikov) 10.02.11 16:58
(7) спб, нашел, просто моя опера глючила или резала и при редактировании в html, не было кнопки update.
9. Андрей Куришко (boggonzikov) 10.02.11 17:03
(7) Кстати спб за разукрашку :)
10. Сергей Ожерельев (Поручик) 10.02.11 17:45
Угу, очередная статья из серии "Как я дошёл своим ум до (..нужное вписать..) или Гугл - это для лошар"

Размещение колонки с остатками в списке справочника
http://www.kb.mista.ru/article.php?id=310
11. Александр Полетаев (Alias) 11.02.11 00:30
Можно и через Соответствие, как кто-то уже заметил.
Но вообще сейчас уже появилась возможность индексировать и таблицы значений. Так что не знаю самодельный это код или идея подсказана (уже приводимая статья на мисте http://www.kb.mista.ru/article.php?id=310 датирована 2009 годом), в любом случае -- сейчас, на 8.1-8.2, индексирование ТЗ (ТаблицаДанныхОформленияСтрок) в данном случае ОБЯЗАТЕЛЬНО.
12. Ярослав Радкевич (WKBAPKA) 11.02.11 10:38
статья конешно полезная, но для ленивых... када сталкиваешся с дикими тормозами, уже умом начинаешь доходить, что не плохо бы через запросы работать... ;)
13. Андрей Куришко (boggonzikov) 11.02.11 15:58
(11) >ОБЯЗАТЕЛЬНО.
Не факт. На построение индекса может уйти больше времени чем на поиск каждый раз по всем таблице. Таблицы ведь маленькая. По мне так индексы стоит использовать когда большое количество данных.
СКЛ по-моему использует индекс если таблицы больше 2000 строк, а так скан.
14. Андрей Куришко (boggonzikov) 11.02.11 16:08
(10)(11)
Решил написать статью из-за того что захотелось сделать количество статей по 1С +1. Мне кажется инфы по 1С связанных с практикой мало, или приходится выуживать по крупицам. Я не спорю, что инфы в ней для гуру нет, но для 1С-ка выше подавана подойдет. Кстати читая коменты (10), желание на написание таких статей совсем отпадает.

По поводу соответсвие.
По мне так нет смысла его использовать, ведь количество строк в ТаблицаДанныхОформленияСтрок мало, а запись в соответсвие на много дольше чем в массив, здесь где-то тесты были.
15. Игорь Исхаков (Ish_2) 11.02.11 16:12
(11) Сравнение соответствия и индексированной таблицы значений подробно исследовано у ildarovich
http://infostart.ru/public/79285/
Индексированная таблица проигрывает.
16. Eugeneer (Eugeneer) 11.02.11 16:22
(14) чем больше мониторы тем больше строк. а мониторы делают все больше и больше.
К тому же незачем обращаться ДанныеСтроки.Ссылка.Ляляреквизит.
Реашется все горадно проще если этот реквизит вывести в список и тогда будет данныеСтроки.ляляреквизит.
И никаких тормозов и запросов.
А во вторых все это уже становистя неактуальным на 8.2 и управляемых формах. Там нету и не будет не вывода строк ни обработчика получения данных.
Статья уже морально устарела. Да и проблемы как таковой не было. Опять же с соответствиями. а разукраску лучше делать все таки через вывод строки.
17. Андрей Куришко (boggonzikov) 11.02.11 16:50
(16)
>К тому же незачем обращаться ДанныеСтроки.Ссылка.Ляляреквизит.
Для примера из статьи согласен, но условие и может быть сложным, или использовать данные не из текущего документа.
По 8.2 и управляемые формы согласен, но толстый клиент отомрет очень, очень не скоро, так что будет актуально еще долго.

Короче во всем есть "палка о 2-ух концах" :)
18. Eugeneer (Eugeneer) 11.02.11 16:53
19. Александр Полетаев (Alias) 14.02.11 11:54
(13) я замерял производительность, поиск по ТЗ с индексированием при сотне строк уже опережает такой же поиск по ТЗ без индекса.
Конечно, на таких объёмах экономия времени незаметна, но "копейка рубль бережёт". К тому же сразу приучает к хорошему стилю программирования.
По мне так лучше всегда делать индексы для искомых данных уже только потому, что лучше потратить микросекунду на построение возможно ненужного индекса для маленькой таблицы, чем забыть построить его для большой таблицы. Стоимость ошибки в этом случае будет гораздо бОльшей.
Однако вынужден согласиться, что в данном примере, только для ОформленийСтрок (коих скорее всего будет не более 50-ти), создание индекса не является обязательным.
20. Модератор раздела Артур Аюханов (artbear) 09.01.12 18:14
Очередной баян на тему сабжа http://infostart.ru/public/101149/
Повторяются все ошибки начинающих :) Разбор ошибок в комментах http://forum.infostart.ru/forum24/topic48235/message547297 и следующие комменты.

Кстати, в каждом из представленных вариантов (сабж, миста, ссылка выше и т.п.) есть небольший методический недочет -
После запроса к данных везде юзается код по всем строкам (оформлениям строк), быстрее прямо в запросе выполнять ограничения и обходить цикл по выборке, а не по всем строкам.
Из личного опыта и опыта изучения чужого кода знаю, что чаще меняется только часть строк, а не все строки :)

ЗЫ случайно повторно наткнулся на статью :) и решил поднять тему.
Для начинающих будет полезно знать.
22. Dpotapov (Danil.Potapov) 28.03.13 09:35
оптимизация:

Процедура ДокументСписокПриПолученииДанных(Элемент, ОформленияСтрок)

ЦветКрасный = Новый Цвет(255,130,124);
Для каждого ОформлениеСтроки Из ОформленияСтрок Цикл
Данныестроки = ОформлениеСтроки.Данныестроки;
Если Данныестроки.НеПолученТовар Тогда
ОформлениеСтроки.ЦветФона = ЦветКрасный;
КонецЕсли;
КонецЦикла;

КонецПроцедуры

в модуле формы добавляешь строку:
СправочникСписок.Колонки.Добавить("НеПолученТовар", Истина);

Итого: раз данные хранятся в таблице реквизитов объекта, можно "скрытно" от пользователя сразу вытаскивать данные. Для этого и добавляем в модуле формы код для принудительного добавления поля в запрос при выборке очередной порции данных.
23. Андрей Куришко (boggonzikov) 28.03.13 10:00
(22) Было уже такое предложение
>К тому же незачем обращаться ДанныеСтроки.Ссылка.Ляляреквизит.
Для примера из статьи согласен, но условие и может быть сложным, или использовать данные не из текущего документа.
24. Андрей Пашин (Andryxa) 29.03.13 17:54
Спасибо, очень помог данный пример в разукрашивании журнала заказов в УТ 10.3
25. uri1978 uri1978 (uri1978) 05.01.15 18:08
Статья хорошая и я так выводил и "оптимизировал", пока отладчиком не посмотрел как работает платформа.
Очень часто "ПриПолученииДанных" отрабатывает по-строчно, а не для всех строк сразу. Даже в типовых в отладчике посмотрите сколько строк возвращает "ОформлениеСтрок" :))) Заметил эту особенность еще в 2009 году, на платформе 8.1. На улице уже 2015 год, в 8.3 всё тоже самое.
Так что 1С как обычно пошутила.
Для написания сообщения необходимо авторизоваться
Прикрепить файл
Дополнительные параметры ответа