Сохранение запроса со всеми параметрами и временными таблицами

Публикация № 1054984

Разработка - Универсальные функции

Запрос сохранение параметры временные таблицы консоль запросов

Функция сохранения запроса со всеми параметрами и временными таблицами в формате *.q1c для открытия в консоли запросов с диска ИТС.

Предисловие

Наверное у каждого программиста 1С есть консоль запросов для управляемого приложения с диска ИТС. Она позволяет сохранять и открывать файлы в формате *.q1c, который представляет собой обычный xml. Я написал функцию, которая позволяет во время отладки сохранить запрос со всеми параметрами в формате *.q1c, чтобы можно было затем открыть его в режиме Предприятие с уже установленными параметрами и временными таблицами. 

Код основной функции и вспомогательных функций и процедур

Функция СохранитьЗапрос(Запрос, ИмяКаталогаИлиПолноеИмяФайла) Экспорт
	
	Попытка
		ИмяКаталогаСоСлэшем = ИмяКаталогаИлиПолноеИмяФайла + ?(Прав(ИмяКаталогаИлиПолноеИмяФайла,1)="\", "", "\");
		ИмяЗапроса = "Запрос_"+Формат(ТекущаяДата(), "ДФ=гггг-ММ-дд_ЧЧ-мм-сс");
		ПолноеИмяФайла  = ИмяКаталогаСоСлэшем + ИмяЗапроса + ".q1c";

		МассивСоздаваемыхВТекстеЗапросаВТ = МассивСоздаваемыхВременныхТаблицЗапроса(Запрос.Текст);
		
		//Добавим в начало текста запроса выборку во временные таблицы
		ТекстВыборкиВоВременныеТаблицы = "";
		МассивДанныхПоВременнымТаблицам = Новый Массив;
		Если Запрос.МенеджерВременныхТаблиц <> Неопределено Тогда
			Для Каждого ВременнаяТаблица Из Запрос.МенеджерВременныхТаблиц.Таблицы Цикл
				//Исключим временные таблицы, которые создаются в тексте этого запроса
				Если МассивСоздаваемыхВТекстеЗапросаВТ.Найти(ВременнаяТаблица.ПолноеИмя) <> Неопределено Тогда
					Продолжить;
				КонецЕсли;
				
				ТекРезультатЗапроса = ВременнаяТаблица.ПолучитьДанные();
				ТаблицаПустая = ТекРезультатЗапроса.Пустой();
				//Если временная таблица пустая, то в текст выборки добавим создание этой таблицы, но в МассивРезультатовВТ записывать не будем
				ТекстВыборкиВоВременныеТаблицы = ТекстВыборкиВоВременныеТаблицы + ПолучитьТекстВыборкиКолонокТаблицыЗначенийВЗапросе(ВременнаяТаблица.ПолноеИмя, ТекРезультатЗапроса.Колонки, ТаблицаПустая);
				Если НЕ ТаблицаПустая Тогда
					МассивДанныхПоВременнымТаблицам.Добавить(Новый Структура("ИмяВременнойТаблица,РезультатЗапроса", ВременнаяТаблица.ПолноеИмя, ТекРезультатЗапроса));
				КонецЕсли;
			КонецЦикла;
		КонецЕсли;
		
		ЗаписьXML = Новый ЗаписьXML;
		ЗаписьXML.ОткрытьФайл(ПолноеИмяФайла, "utf-8");
		ЗаписьXML.ЗаписатьОбъявлениеXML();

		ЗаписьXML.ЗаписатьНачалоЭлемента("querylist");

			ЗаписьXML.ЗаписатьНачалоЭлемента("query");
			ЗаписьXML.ЗаписатьАтрибут("name", ИмяЗапроса);

				ЗаписьXML.ЗаписатьНачалоЭлемента("text");
				ЗаписьXML.ЗаписатьТекст(ТекстВыборкиВоВременныеТаблицы + Запрос.Текст);
				ЗаписьXML.ЗаписатьКонецЭлемента(); //text

				ЗаписьXML.ЗаписатьНачалоЭлемента("parameters");

					Для Каждого КЗ Из Запрос.Параметры Цикл
						ЗаписьXML.ЗаписатьНачалоЭлемента("parameter");
						ЗаписьXML.ЗаписатьАтрибут("name", КЗ.Ключ);

						ЗначениеПараметра = КЗ.Значение;
						ТипЗнчПараметра = ТипЗнч(ЗначениеПараметра);

						Если ТипЗнчПараметра  = Тип("Граница") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "Граница");
							ЗаписьXML.ЗаписатьНачалоЭлемента("divide");
								ЗаписьXML.ЗаписатьАтрибут("type", "Дата");
								ЗаписьXML.ЗаписатьАтрибут("valueDiv", Строка(ЗначениеПараметра.ВидГраницы));
								ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ЗначениеПараметра.Значение));
							ЗаписьXML.ЗаписатьКонецЭлемента(); //divide

						ИначеЕсли ТипЗнчПараметра = Тип("МоментВремени") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "МоментВремени");
							ЗаписьXML.ЗаписатьНачалоЭлемента("item");
								ЗаписьXML.ЗаписатьАтрибут("type", XMLТипЗнч(ЗначениеПараметра.Ссылка).ИмяТипа);
								ЗаписьXML.ЗаписатьАтрибут("valueRef", XMLСтрока(ЗначениеПараметра.Ссылка));
								ЗаписьXML.ЗаписатьАтрибут("valueDate", XMLСтрока(ЗначениеПараметра.Дата));
							ЗаписьXML.ЗаписатьКонецЭлемента(); //item

						ИначеЕсли ТипЗнчПараметра = Тип("СписокЗначений") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "СписокЗначений");
							ЗаписатьЗначенияМассиваДляЭлементаПараметр(ЗаписьXML, ЗначениеПараметра.ВыгрузитьЗначения());
							
						ИначеЕсли ТипЗнчПараметра = Тип("Массив") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "СписокЗначений");
							ЗаписатьЗначенияМассиваДляЭлементаПараметр(ЗаписьXML, ЗначениеПараметра);

						ИначеЕсли ТипЗнчПараметра = Тип("ТаблицаЗначений") Тогда
							ЗаписьXML.ЗаписатьАтрибут("type", "ТаблицаЗначений");
							ЗаписатьТаблицуЗначенийВПараметрЗапроса(ЗаписьXML, ЗначениеПараметра, Ложь);

						Иначе
							ЗаписьXML.ЗаписатьАтрибут("type", ПолучитьИмяТипаЗначенияXML(ЗначениеПараметра));
							ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ЗначениеПараметра));

						КонецЕсли;

						ЗаписьXML.ЗаписатьКонецЭлемента(); //parameter
					КонецЦикла;

					//Все не пустые временные таблицы, создание которых мы добавили ранее к тексту запроса, запишем в параметры запроса как таблицы значений
					Если Запрос.МенеджерВременныхТаблиц <> Неопределено Тогда
						Для Каждого ТекСтрока Из МассивДанныхПоВременнымТаблицам Цикл
							тзВременнаяТаблица = ТекСтрока.РезультатЗапроса.Выгрузить();
							ЗаписатьТаблицуЗначенийВПараметрЗапроса(ЗаписьXML, тзВременнаяТаблица, Истина, ТекСтрока.ИмяВременнойТаблица);
						КонецЦикла;
					КонецЕсли;					
						
				ЗаписьXML.ЗаписатьКонецЭлемента(); //parameters

			ЗаписьXML.ЗаписатьКонецЭлемента(); //query
		
		ЗаписьXML.ЗаписатьКонецЭлемента(); //querylist
		
		ЗаписьXML.Закрыть();
		
		Возврат "Запрос с параметрами успешно сохранен в файл " + ПолноеИмяФайла;
		
	Исключение
		Возврат "Не удалось записать запрос с параметрами в файл по причине: " + ОписаниеОшибки();
		
	КонецПопытки;

КонецФункции

Функция ПолучитьИмяТипаЗначенияXML(ЗначениеПараметра)
	
	ТипЗнчПараметра = ТипЗнч(ЗначениеПараметра);
	
	Если ТипЗнчПараметра = Тип("Строка") ИЛИ ТипЗнчПараметра = Тип("Неопределено") Тогда
		Возврат "Строка";
	
	ИначеЕсли ТипЗнчПараметра = Тип("Число") Тогда
		Возврат "Число";
	
	ИначеЕсли ТипЗнчПараметра = Тип("Дата") Тогда
		Возврат "Дата";
	
	ИначеЕсли ТипЗнчПараметра = Тип("Булево") Тогда
		Возврат "Булево";
	
	Иначе
		Возврат XMLТипЗнч(ЗначениеПараметра).ИмяТипа;
	
	КонецЕсли;

КонецФункции

Процедура ЗаписатьЗначенияМассиваДляЭлементаПараметр(ЗаписьXML, Массив)

	Для Каждого ТекущееЗначение Из Массив Цикл
		ЗаписьXML.ЗаписатьНачалоЭлемента("item");

			ЗаписьXML.ЗаписатьАтрибут("type", ПолучитьИмяТипаЗначенияXML(ТекущееЗначение));
			ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ТекущееЗначение));

		ЗаписьXML.ЗаписатьКонецЭлемента(); //item
	КонецЦикла;

КонецПроцедуры

Процедура ЗаписатьТаблицуЗначенийВПараметрЗапроса(ЗаписьXML, Таблица, ПараметрЦеликом, ИмяПараметра="")

	Если ПараметрЦеликом Тогда
		ЗаписьXML.ЗаписатьНачалоЭлемента("parameter");
		ЗаписьXML.ЗаписатьАтрибут("name", ИмяПараметра);
		ЗаписьXML.ЗаписатьАтрибут("type", "ТаблицаЗначений");
	КонецЕсли;
	
	ЗаписьXML.ЗаписатьАтрибут("colcount", Формат(Таблица.Колонки.Количество(), "ЧН=0; ЧГ=0"));
	ЗаписьXML.ЗаписатьАтрибут("rowcount", Формат(Таблица.Количество(), "ЧН=0; ЧГ=0"));
	
	ТекИндексСтроки = 0;
	Для Каждого ТекСтрокаТЗ Из Таблица Цикл
		ТекИндексКолонки = 0;
		Для Каждого ТекКолонкаТЗ Из Таблица.Колонки Цикл
			ЗаписьXML.ЗаписатьНачалоЭлемента("item");
			
			ТекущееЗначение = ТекСтрокаТЗ[ТекКолонкаТЗ.Имя];
			
			ЗаписьXML.ЗаписатьАтрибут("nameCol", ТекКолонкаТЗ.Имя);
			ЗаписьXML.ЗаписатьАтрибут("row", Формат(ТекИндексСтроки, "ЧН=0; ЧГ=0"));
			ЗаписьXML.ЗаписатьАтрибут("col", Формат(ТекИндексКолонки, "ЧН=0; ЧГ=0"));
			ЗаписьXML.ЗаписатьАтрибут("type", ПолучитьИмяТипаЗначенияXML(ТекущееЗначение));
			ЗаписьXML.ЗаписатьАтрибут("length", "0");
			ЗаписьXML.ЗаписатьАтрибут("value", XMLСтрока(ТекущееЗначение));
			
			ЗаписьXML.ЗаписатьКонецЭлемента(); //item
			
			ТекИндексКолонки = ТекИндексКолонки + 1;
		КонецЦикла;

		ТекИндексСтроки = ТекИндексСтроки + 1;
	КонецЦикла;
	
	Если ПараметрЦеликом Тогда
		ЗаписьXML.ЗаписатьКонецЭлемента(); //parameter
	КонецЕсли;
КонецПроцедуры

Функция МассивСоздаваемыхВременныхТаблицЗапроса(ТекстЗапроса)

	Перем МассивВТ;
	
	МассивВТ = Новый Массив;
	
	//Запрос может не открываться объектом СхемаЗапроса, но при этом выполняться,
	//в этой ситуации лучше вернуть пустой массив, чем завершить работу с ошибкой
	Попытка
		СхемаЗапроса = Новый СхемаЗапроса();
		СхемаЗапроса.УстановитьТекстЗапроса(ТекстЗапроса);
		Для Каждого Пакет Из СхемаЗапроса.ПакетЗапросов Цикл
			Если ТипЗнч(Пакет) = Тип("ЗапросВыбораСхемыЗапроса") Тогда
				Если ЗначениеЗаполнено(Пакет.ТаблицаДляПомещения) Тогда
					МассивВТ.Добавить(Пакет.ТаблицаДляПомещения);
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;
	Исключение
	КонецПопытки;
	
	Возврат МассивВТ;

КонецФункции

Функция ПолучитьТекстВыборкиКолонокТаблицыЗначенийВЗапросе(ИмяПараметра, Колонки, ПустаяТаблица)

	Перем Текст;
	
	ПоляТаблицы = "";
	Для Каждого ТекКолонка Из Колонки Цикл
		Если ПоляТаблицы <> "" Тогда
			ПоляТаблицы = ПоляТаблицы + "
			|	";
		Иначе
			ПоляТаблицы = ПоляТаблицы + "	";
		КонецЕсли;
		
		СтруктураТипа = СтруктураТипаКолонкиДляЗапроса(ТекКолонка.ТипЗначения.Типы());
		
		Если ПустаяТаблица Тогда
			ПоляТаблицы = ПоляТаблицы + СтруктураТипа.ЗначениеПоУмолчанию + " КАК "+ТекКолонка.Имя + ",";
			
		Иначе
			Если СтруктураТипа.ИмяДляПриведенияТипов <> "" Тогда
				ПоляТаблицы = ПоляТаблицы + "ВЫРАЗИТЬ(Т."+ТекКолонка.Имя + " КАК "+СтруктураТипа.ИмяДляПриведенияТипов+") КАК "+ТекКолонка.Имя + ",";
			Иначе
				ПоляТаблицы = ПоляТаблицы + "Т."+ТекКолонка.Имя + " КАК "+ТекКолонка.Имя + ",";
			КонецЕсли;
			
		КонецЕсли;
	КонецЦикла;
	//Уберем последнюю запятую
	ПоляТаблицы = Лев(ПоляТаблицы, СтрДлина(ПоляТаблицы)-1);
	
	Текст = 
	"ВЫБРАТЬ
	|"+ПоляТаблицы+"
	|ПОМЕСТИТЬ "+ИмяПараметра;
	
	Если НЕ ПустаяТаблица Тогда
		Текст = Текст + "
		|ИЗ
		|	&"+ИмяПараметра+" КАК Т"
		;
	КонецЕсли;
	
	Текст = Текст + "
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|";
	
	Возврат Текст;

КонецФункции

Функция СтруктураТипаКолонкиДляЗапроса(МассивТиповКолонки)
	
	Перем Результат;
	
	Результат = Новый Структура;
	Результат.Вставить("ЗначениеПоУмолчанию", "НЕОПРЕДЕЛЕНО");
	Результат.Вставить("ИмяДляПриведенияТипов", "");
	
	//Если колонка имеет единственный тип, либо 2 типа, один из которых Null, то в запросе выборки во временную таблицу будем приводить к этому типу, 
	//чтобы избежать ошибок открытия конструктора запросов, если дальше где-то идет выбор "через точку"
	ЕдинственныйТип = Неопределено;
	Если МассивТиповКолонки.Количество() = 1 Тогда
		ЕдинственныйТип = МассивТиповКолонки[0];
	
	ИначеЕсли МассивТиповКолонки.Количество() = 2 Тогда
		Если МассивТиповКолонки[0] = Тип("Null") Тогда
			ЕдинственныйТип = МассивТиповКолонки[1];
		
		ИначеЕсли МассивТиповКолонки[1] = Тип("Null") Тогда
			ЕдинственныйТип = МассивТиповКолонки[0];
		
		КонецЕсли;
	КонецЕсли;
	
	Если ЕдинственныйТип <> Неопределено Тогда
		
		Если ЕдинственныйТип = Тип("Число") Тогда
			Результат.ЗначениеПоУмолчанию = "0";
			
		ИначеЕсли ЕдинственныйТип = Тип("Строка") Тогда
			Результат.ЗначениеПоУмолчанию = """""";
			
		ИначеЕсли ЕдинственныйТип = Тип("Дата") Тогда
			Результат.ЗначениеПоУмолчанию = "ДАТАВРЕМЯ(1,1,1)";
			
		ИначеЕсли ЕдинственныйТип = Тип("Булево") Тогда
			Результат.ЗначениеПоУмолчанию = "ЛОЖЬ";
			
		ИначеЕсли ЕдинственныйТип = Тип("ВидДвиженияНакопления") Тогда
			Результат.ЗначениеПоУмолчанию = "ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)";
			
		Иначе
			ИмяТипаXML = XMLТип(ЕдинственныйТип);
			Если СтрНайти(ИмяТипаXML, "Ref.") > 0 Тогда
				ПустаяСсылка = Новый(ЕдинственныйТип);
				ПолноеИмяМетаданного = ПустаяСсылка.Метаданные().ПолноеИмя();
				Если ЗначениеЗаполнено(ПолноеИмяМетаданного) Тогда
					Результат.ЗначениеПоУмолчанию = "ЗНАЧЕНИЕ("+ПолноеИмяМетаданного+".ПустаяСсылка)";
					Результат.ИмяДляПриведенияТипов = ПолноеИмяМетаданного;
				КонецЕсли;
			КонецЕсли;
		
		КонецЕсли;
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

Как это использовать?

Просто скопируйте эти функции и процедуры в общий модуль с флажком "Серверный" (или в общий модуль расширения, если основная конфигурация на полной поддержке). Пусть общий модуль называется, например "Отладка". Затем запускаем отладку интересующего запроса, останавливаем отладку на строке с Запрос.Выполнить(), нажимаем Shift+F9 и печатаем Отладка.СохранитьЗапрос(Запрос, "\\Host\Share"). Здесь Отладка - это имя общего модуля, Запрос - имя переменной типа "Запрос", \\Host\Share - имя сетевого каталога, куда будет сохранен запрос (этот каталог должен быть доступен для записи пользователем, под которым запущен сервер 1С Предприятие).

Запрос со всеми параметрами будет сохранен в файл \\Host\Share\Запрос_{ТекущаяДатаИВремя}.q1c. При открытии файла *.q1c в консоли запросов запрос и все параметры будут восстановлены. 

Временные таблицы

Если у менеджера временных таблиц запроса есть временные таблицы, они будут сохранены как параметры типа ТаблицаЗначений с именем временной таблицы. Также к началу текста запроса при сохранении будет добавлен текст для создания временных таблиц из параметров типа ТаблицаЗначений. Таким образом открыв сохраненный запрос мы можем сразу выполнить его, он уже будет настроен таким же образом, каким он был настроен в момент выполнения отладки.

Тестовое окружение

Функции проверялись на платформе 8.3.10.2667.

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Evg-Lylyk 3441 13.05.19 12:59 Сейчас в теме
2. Serge R 177 13.05.19 15:50 Сейчас в теме
Я знаю о существовании этой и подобных ей консолей запросов. Моя статья о том, как можно улучшить удобство использования ИТС-ной консоли запросов.
Созинов; +1 Ответить
3. yk1979 21.05.19 13:44 Сейчас в теме
Работает, автору спасибо!
4. Xershi 1152 21.05.19 14:03 Сейчас в теме
А в тонком клиенте это будет работать?
5. Serge R 177 21.05.19 19:28 Сейчас в теме
(4) Да, в тонком клиенте работает
Оставьте свое сообщение

См. также

Использование классов .Net в 1С для новичков Промо

Практика программирования Разработка внешних компонент Универсальные функции v7.7 v8 Бесплатно (free)

Руководство для новичков. Написав статью http://infostart.ru/public/238584/, я понял, что многие не понимают того, что написано. Поэтому в этой статье постараюсь более подробно остановиться на азах и без кода на вражеском языке (C#)

27.01.2016    80791    Serginio    113    

Чтение CSV (быстрое)

Универсальные функции v8 Бесплатно (free)

Почему то из гугла до сих пор нет ссылки на код процедуры быстро читающей csv... Загрузка из файла CSV c помощью ADODB.Connection провайдера Microsoft.Jet.OLEDB.

31.03.2021    842    kuzyara    4    

Последний раз про срез последних (на каждую дату в запросе)

Инструментарий разработчика Практика программирования Консоль запросов Универсальные функции v8 v8::Запросы Бесплатно (free)

Срез последних на каждую дату в запросе. Известные факты о задаче: часто встречается на испытаниях соискателей на работу программистом 1с, постоянно провоцирует споры об оптимальном решении. В данном тексте приводятся замеры производительности различных вариантов решения задачи.

15.02.2021    6283    randomus    47    

Serverless (Faas) в 1С. Создание и вызов Yandex Cloud Functions

Универсальные функции Практика программирования v8 Бесплатно (free)

"Я не могу просто взять и скопировать код с гитхаба", "у нас 1С микросервисами окружена", "возможностей мало" - частые фразы 1С разработчиков. которым не хватает возможностей платформы в современном мире. Faas, конечно, история не новая, но нас сдерживало 152ФЗ и задержки по пингам. Для того, чтобы действительно использовать в 1С код, к примеру, на Python, надо было приложить усилия. Теперь всё намного проще - берём и используем.

28.12.2020    5952    comol    31    

Универсальные функции с примерами использования Промо

Универсальные функции v8 Бесплатно (free)

14 универсальных функций, с примерами использования - для обычного и управляемого интерфейса

26.02.2016    42534    unichkin    47    

Ускоряем медленный/долгий и тормозной стандартный поиск по динамическому списку, настраиваем его под себя

Практика программирования Универсальные функции v8 v8::УФ 1cv8.cf Бесплатно (free)

Пользователи привыкли искать на форме списка, но, вбивая в поиск некорректные данные, могут завесить всю систему, а если еще искать нужно по НЕ полям списка, то решение только в своём поиске - все это решим в публикации с открытым кодом.

14.12.2020    12840    SizovE    2    

Отображение и редактирование в дереве большого количества настроек/параметров/опций программы, конфигурации, документа, справочника - без программного создания элементов формы

Практика программирования Универсальные функции Работа с интерфейсом v8 1cv8.cf Бесплатно (free)

Очень много реквизитов (настроечные опции, параметры) у справочника или документа, и их все необходимо разместить на управляемую форму - лень! Хочется - добавил в метаданные и всё! В публикации отличное, простое и олдскульное решение с открытым кодом, научимся работать с ДанныеФормыДерево, ДеревомЗначений, сделаем быстрый поиск, создадим универсальный инструмент.

11.12.2020    862    SizovE    6    

Программное условное оформление динамического списка, раскраска строк списка по цветам справочника или любым другим условиям (условное оформление)

Практика программирования Универсальные функции Работа с интерфейсом v8 v8::УФ 1cv8.cf Бесплатно (free)

Большое количество динамических списков на форме, большое количество условий, долгое интерактивное добавление условий, оформление по значению элементов справочников - всё это не позволяет использовать интерактивный режим назначения условного оформления динамического списка. В публикации с открытым кодом детально разберем программное решение назначения условного оформления, создадим универсальную функцию для оформления списка.

30.11.2020    4032    SizovE    3    

Минимализмы 3 Промо

Практика программирования Универсальные функции v8 Бесплатно (free)

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    48863    ildarovich    47    

Выгрузка HTML описаний с картинками (Base64) товаров на сайт/интернет-магазин/B2B, разберем регулярное выражение получения тега body, ПолучитьHTML, ФорматированныйДокумент

Практика программирования WEB Универсальные функции v8 v8::УФ 1cv8.cf Бесплатно (free)

Редактор HTML платформы 1С простой и очень удобный для небольших задач, однако ПолучитьHTML возвращает отдельно картинки и отдельно целиком HTML страницу со ссылкой на имена этих картинок, что неудобно для отправки в базу данных сайта/интернет-магазина/веб-приложения/B2B. Разберем на открытом коде, как решить эту проблему, напишем универсальную функцию получения значения любого тега HTML на регулярных выражениях. Бонусом - возможность редактировать теги HTML в текстовом режиме.

24.11.2020    921    SizovE    4    

Сохранение настроек

Практика программирования Универсальные функции БСП (Библиотека стандартных подсистем) v8 1cv8.cf Бесплатно (free)

Делюсь еще одним не самым очевидным способом хранения настроек в базах на БСП без доработки конфигурации. Весь код в статье.

22.11.2020    3292    the1    8    

Чтение вложенных свойств Структур Структуры, Соответствий, свойства через точку, разбор JSON

Практика программирования WEB Интеграция Универсальные функции v8 Бесплатно (free)

JSON: {user.device.type} - как получить значение {type}? А если вложенность значительно глубже? Как проверить, что оно заполнено или удалить его - всё это в публикации с открытым кодом и даже без рекурсии. Бонусом разбор дерева значений - ДанныеФормыЭлементДерева, СтрокаДереваЗначений.

17.11.2020    1890    SizovE    2    

Универсальная функция для программного выполнения СКД Промо

Инструментарий разработчика Универсальные функции v8::СКД 1cv8.cf Бесплатно (free)

Часто встречаются вопросы на форумах о программном формировании СКД. Вроде и информации много по этому поводу, но... Все как всегда :) Собственно, в описании без лишних слов выложен текст общей функции, в которую, для выполнения отчета, нужно передать (минимум 2 параметра): СКД и ТабличныйДокумент.

20.05.2015    31208    dj_serega    18    

Сохранение настроенного запроса набора данных СКД

Универсальные функции v8 v8::СКД 1cv8.cf Бесплатно (free)

Как сохранить запрос набора данных СКД в том виде, каким он будет выполнен системой для открытия в консоли запросов с диска ИТС.

09.11.2020    1545    Serge R    0    

Отпускной период (период основного отпуска) - как его узнать

Зарплата Универсальные функции v8 v8::СПР v8::УФ ЗУП3.x Россия БУ Бесплатно (free)

Пришла мне задача где нужно получить отпускной период, на просторах сети решения я не нашел. Решил поделиться с вами своим решением.

26.10.2020    691    Danila7Zz    2    

Произвольные колонтитулы и повтор шапки таблицы в табличном документе (функция)

Универсальные функции v8 Бесплатно (free)

Пример рекурсивной функции, при помощи которой в табличный документ можно выводить верхний или нижний колонтитулы с произвольным содержимым, а также делать повтор шапки таблицы (или таблиц, если их несколько).

07.10.2020    3500    ellavs    2    

Выполнение произвольного кода в фоновых заданиях Промо

Универсальные функции v8 Бесплатно (free)

Если надо быстро провести 100`000 документов...

13.01.2016    25022    unichkin    13    

Печать в word, pdf через html

Печать Практика программирования Универсальные функции v8 Россия Бесплатно (free)

При работе с клиентами возникла задача: использовать форматированный документ. Итак, существует справочник, в нем табличная часть. Для каждой строки требуется ввести описание, причем описание имеет тип форматированный документ. Потребовалось организовать печать табличной части справочника с описанием для каждой строки. Тип данных "Форматированный документ" не может выводится в табличный документ, поэтому пришлось организовывать печать через Microsoft Word.

11.09.2020    1627    arr    4    

Самый простой парсинг и обработка веб-страниц в 1С

WEB Универсальные функции v8 1cv8.cf Бесплатно (free)

Рассмотрим самый простой парсинг веб-страниц средствами платформы 1С и еще некоторые полезные приемы работы с веб-страницами.

07.08.2020    9009    YPermitin    22    

Выполнение внешней обработки по расписанию для управляемого и обычного приложения

БСП (Библиотека стандартных подсистем) Универсальные функции v8 1cv8.cf Россия Бесплатно (free)

Использование БСП для выполнения внешних обработок в управляемом и обычном приложении

06.08.2020    7576    RPGrigorev    0    

Распределение оплаты по товарам Промо

Практика программирования Универсальные функции v8 1cv8.cf Бесплатно (free)

Учебная задача. Оплата приходит по заказу. Требуется запросом распределить её по товарам. Практическая задача была сложнее. Упростил специально для иллюстрации. Сначала собираем в одну таблицу заказы и товары. Затем ОБЪЕДИНТЬ ВСЕ с оплатами. Потом намазываем оплату на товар.

04.08.2014    19398    Трактор    5    

Пользовательское поле СКД одной процедурой

Практика программирования Универсальные функции v8 Бесплатно (free)

Быстрое создание пользовательского поля "выражение" одной процедурой

05.08.2020    2059    Yashazz    0    

Полезные встроенные функции для работы с печатными формами и не только на УТ 11.4 и БП 3.0 (сравнение)

Универсальные функции v8 БП3.0 УТ11 Россия Бесплатно (free)

В данном обзоре приведу примеры встроенных используемых функций для работы с печатными формами на примерах конфигураций Управление торговлей 11.4 и Бухгалтерия 3.0.

10.07.2020    5690    quazare    5    

Вывод дерева в табличный документ СКД

Практика программирования Универсальные функции v8 v8::СКД Бесплатно (free)

Вывод содержимого элемента формы "ДанныеФормыДерево" в табличный документ средствами СКД.

09.07.2020    3728    Yashazz    7    

Сканируем без сканера или MXL to JPG Промо

Внешние источники данных Универсальные функции Печатные формы документов v8 1cv8.cf Бесплатно (free)

Хотите конвертировать документы в формат изображения менее чем за минуту, не имея сканера? Тогда эта статья для вас.

24.05.2012    34566    shakmaev    47    

Команда "Вывести список" для динамического списка. Программное выполнение (вариант)

Универсальные функции v8::УФ 1cv8.cf Бесплатно (free)

Делаем свою кнопку вместо "Вывести список" из пункта "ещё" динамического списка.

11.06.2020    4077    DanDy    61    

Ещё немного функционального стиля в 1С или Как нам отфильтровать таблицу значений

Универсальные функции v8 Россия Бесплатно (free)

Потребовалось накладывать хитрые отборы на таблицу значений в сотни строк и десятки колонок, однако Скопировать со структурой отбора мне не подошло. Пришлось немного покреативить, подсмотрев, как это делается в других языках - возможно, получилось несколько топорно, но тем не менее - работает.

16.05.2020    3442    GlebHappy    34    

Сходство Джаро - Винклера. Нечеткое сравнение строк

Универсальные функции v8 Россия Бесплатно (free)

В области информатики и статистики сходство Джаро - Винклера представляет собой меру схожести строк для измерения расстояния между двумя последовательностями символов. В публикации рассмотрены некоторые особенности алгоритма, и представлен вариант его реализации на языке 1С.

25.12.2019    7949    brooho    19    

Функция - Формат государственного номера автомобиля

Универсальные функции v8 Автомобили, автосервисы Россия Бесплатно (free)

Возникла необходимость в приведении к единому формату хранящихся, и вводимых вновь, автомобильных Регистрационных знаков - Гос.номер.

23.12.2019    5300    brooho    5    

Полезности | Дерево значений | Обычные формы |

Практика программирования Универсальные функции v8 Бесплатно (free)

Полезные функции при работе с деревом значений.

04.12.2019    7475    Mellow    7    

Обработка расширением на клиенте

Расширения Универсальные функции v8::УФ 1cv8.cf Бесплатно (free)

Описываю нетривиальный прием работы с расширением, который позволит относительно быстро реализовывать некоторые обработки данных. Суть: обработка данных на клиенте с использованием методов, которые реализованы разработчиком конфигурации на форме объекта. Если эти методы есть вне модуля формы объекта (общий модуль, модуль менеджера, модуль объекта)- лучше сделать обработку более простым способом.

31.10.2019    7648    EvgenURNN    10    

Использование XML-схемы из макета внешней обработки

Обмен через XML Универсальные функции v8 1cv8.cf Бесплатно (free)

Простой способ использования XML-схем из макета внешней обработки.

28.10.2019    12384    Olesia_Matusevich    10    

Быстрое создание наполненных коллекций

Практика программирования Универсальные функции v8 1cv8.cf Бесплатно (free)

Разберем самые частые способы создания коллекции, значения которой известны заранее. И сравним скорость их выполнения.

28.10.2019    7719    SeiOkami    66    

Преобразование XML в таблицу значений или иной объект 1С методом XSL преобразования

Универсальные функции Обмен через XML v8 1cv8.cf Бесплатно (free)

Сразу открою интригу, напрямую прочитать XML, не содержащий объект 1С, не удастся. Статья раскрывает способы привести XML к формату, который возможно прочитать средствами платформы.

24.10.2019    13784    kraspila    32    

Обертка функций Excel на русском. Ускорение процесса разработки.

Загрузка и выгрузка в Excel Универсальные функции v8 Бесплатно (free)

Устали переключаться с русского на английский и обратно при работе с таблицами Excel из 1С? Сборка наиболее необходимых функций и методов работы с Excel, обернутых в функции 1С на русском языке.

24.10.2019    7800    DmitryKotov    6    

Функция СтрШаблон с именованными маркерами

Универсальные функции v8 1cv8.cf Бесплатно (free)

Функция позволяет задавать именованные маркеры формата [Имя], в отличии от типовых нумерованных формата %n

1 стартмани

21.10.2019    5741    kirinalex    27    

Полезняшки по СКД и построителям. Просто код

Практика программирования Универсальные функции v8 v8::СКД Бесплатно (free)

Полезные процедуры и функции для работы с построителями и СКД. Просто исходник.

10.10.2019    11223    Yashazz    47    

Полезные процедуры и функции для программиста

Практика программирования Универсальные функции v8 1cv8.cf Россия Бесплатно (free)

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    35632    HostHost    41    

Отслеживание выполнения фонового задания

Практика программирования Универсальные функции Разработка v8 1cv8.cf Бесплатно (free)

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    40007    ids79    19    

Добавление возможности подключения внешних отчетов и обработок к объектам конфигурации при помощи расширения

Универсальные функции v8::УФ ERP2 Бесплатно (free)

Часто приходится сталкиваться с тем, что необходимо внести изменения в типовую конфигурацию, но очень не хочется снимать её с поддержки. Для этого в 1С существует ряд инструментов. Эта короткая статья посвящена тому, как подучить возможность подключения внешних отчетов к объекту конфигурации при помощи расширения на примере 1С:ERP Управление предприятием 2 (проверено на 1С:ERP Управление предприятием 2 (2.4.6.230)).

15.04.2019    4941    user995537    0    

Иерархия справочника Сверху Вниз. Получаем произвольное количество родителей "верхнего" уровня

Практика программирования Универсальные функции Разработка v8 1cv8.cf Бесплатно (free)

Иерархия справочника Сверху Вниз. Функция для получения произвольного количества родителей "верхнего" уровня. На примере справочника "Номенклатура".

28.03.2019    6349    obsfromekb    11    

Доработка проведения типовых документов в УТ 11.4, КА 2.4, ЕРП 2.4

Практика программирования Универсальные функции Разработка v8 v8::УФ ERP2 УТ11 КА2 Россия УУ Бесплатно (free)

Различные варианты корректировки типовых механизмов проведения документов, без корректировки основной конфигурации. Использование расширений, подписок на событие и механизма локализации типовых документов.

22.03.2019    20092    ids79    16    

Добавление отчетов в типовые конфигурации 1С

Практика программирования Универсальные функции БСП (Библиотека стандартных подсистем) v8::УФ v8::СКД 1cv8.cf Бесплатно (free)

Описание различных способов добавления общих и контекстных отчетов в конфигурации 1С, построенные на базе БСП. Основные моменты и нюансы.

07.03.2019    69451    ids79    49    

Расширение конструктора мобильного рабочего места для варианта "клиент 1С+RDP" (для любых wi-fi терминалов). Экосистема решений Simple WMS

Инструментарий разработчика Сканер штрих-кода Терминал сбора данных Универсальные функции Мобильная разработка Производство готовой продукции (работ, услуг) Розничная торговля Учет ОС и НМА Учет ТМЦ Производство готовой продукции (работ, услуг) Розничная торговля Учет ОС и НМА Учет ТМЦ v8::УФ УУ Бесплатно (free)

Развитие проекта «Конструктор мобильного клиента на Android» https://infostart.ru/public/976636/ для устройств не на Андроиде (работающих в режиме RDP). В отличие от варианта Android работа на терминалах происходит в режиме 1С:Предприятие через RDP а конфигурации мобильных клиентов полностью совместимы для обоих версий. Т.е. конфигурация единая, создается один раз и ее может читать как Android -устройство, так и 1С-клиент на RDP без необходимости какой либо переделки.

05.02.2019    13807    informa1555    10    

Работа со строками: от простого к сложному

Практика программирования Универсальные функции v8 Бесплатно (free)

Простые примеры работы со строками, в конце более читаемый разбор сложных текстов.

14.01.2019    54908    Evg-Lylyk    25    

Нумерация колонок субконто при выгрузке набора записей регистра бухгалтерии в таблицу значений

Универсальные функции v8 Бесплатно (free)

Решение проблемы несовпадения номеров колонок с номерами субконто на счете при выгрузке в таблицу значений.

14.01.2019    5944    The Ded    9