Программная корректировка при выводе отчета СКД

Публикация № 1290155 08.10.20

Пикалев Николай (dabu-dabu)

Рейтинг: 245

СКД КомпоновщикМакетаКомпоновкиДанных ПроцессорКомпоновкиДанных МакетКомпоновкиДанных ЭлементРезультатаКомпоновкиДанных Оборотно-сальдовая ведомость

–

Большинство отчетов на СКД, требующих программной корректировки, реализуются с помощью программной настройки СКД или обработки табличного документа уже после вывода отчета. Но во многих случаях более оптимально будет выполнять программную корректировку в процессе вывода отчета. Для этого существуют программные объекты, о которых я расскажу в данной статье.

Введение

Программное формирование отчета на СКД выполняется с помощью следующего кода, который очень многие не раз использовали:

Стандартное программное формирование отчета на СКД

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ИтоговыеНастройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	//Можем редактировать настройки компоновки (ИтоговыеНастройки)
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, ИтоговыеНастройки, ДанныеРасшифровки);
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновкиДанных, , ДанныеРасшифровки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	
	//Можем редактировать табличный документ (ДокументРезультат)
	
КонецПроцедуры

Программное формирование используется очень многими разработчиками, в том числе, встречается и в типовых системах. Стандартные причины использования - это необходимость программной доработки отчета, которая обычно выполняется через программную доработку настройки компоновки или через корректировки итогового табличного документа. Но, по каким-то причинам (я таких примеров не видел), не используются возможности объектов МакетКомпоновкиДанных и ПроцессорКомпоновкиДанных. Ключевое удобство их использования состоит в том что на момент их выполнения мы одновременно имеем данные и по настройкам (структуре) отчета, и итоговые данные, рассчитанные для вывода. Далее я опишу возможности использования данных объектов и приведу примеры. Некоторые примеры, возможно, покажутся выдуманными, а для некоторых могут быть другие пути решения, но цель данных примеров показать возможности неиспользуемых механик СКД, а как вы их будете применять на практике, вам виднее. Кроме того, в прикрепленных файлах приложу отчет со всеми приведенными здесь примерами и даже более. Для формирования отчета нужен регистр бухгалтерии Хозрасчетный, но я проверял его только на 1С: Бухгалтерия 3.0.

Всё, что будет описано далее, это предмет моих личных изысканий и не претендует на полноту.

МакетКомпоновкиДанных - хранит и предоставляет возможность редактировать все макеты табличного документа, которые подготовлены компоновщиком и будут использоваться при выводе отчета.

ПроцессорКомпоновкиДанных - позволяет не только сформировать весь отчет единовременно, но и может заполнять табличный документ по элементам (строкам) отчета используя объект ЭлементРезультатаКомпоновкиДанных.

С учетом вышесказанного, текст кода программного формирования отчета можно представить в виде:

Расширенное программное формирование отчета на СКД

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ИтоговыеНастройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	//Можем редактировать настройки компоновки (ИтоговыеНастройки)
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, ИтоговыеНастройки, ДанныеРасшифровки);
	
	//Можем редактировать итоговые наборы данных и макеты табличного документа (МакетКомпоновкиДанных)
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновкиДанных, , ДанныеРасшифровки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	//Формируем отчет поэлементно
	//Вместо стандартного вывода одним методом - ПроцессорВывода.Вывести(ПроцессорКомпоновки)
	ПроцессорВывода.НачатьВывод();
	Пока Истина Цикл
		ЭлементРезультата = ПроцессорКомпоновки.Следующий();
		Если ЭлементРезультата = Неопределено Тогда
			Прервать;
		КонецЕсли;
		
		//Можем редактировать данные, внешний вид и расшифровку выводимого элемента (ЭлементРезультата)
		
		ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
	КонецЦикла;
	ПроцессорВывода.ЗакончитьВывод();
	
	//Можем редактировать табличный документ (ДокументРезультат)
	
КонецПроцедуры

Макет компоновки данных

Посмотрим какие свойства есть у объекта МакетКомпоновкиДанных:

Свойства Макета компоновки данных

Из представленных свойств нам сейчас будут наиболее интересны Тело и Макеты, с помощью которых можно редактировать макеты табличного документа, подготовленные компоновщиком для формирования отчета. В них можно менять значения и расшифровку ячеек, изменять выражения для расчета параметров, менять внешний вид, объединять и разъединять ячейки по строкам и колонкам, и многое другое. Все свойства более-менее понятны и вы сможете сами подробно их посмотреть через отладчик, но я приведу их краткое описание:

Описание Тела Макета компоновки данных

Тело макета компоновки состоит из массива элементов, описывающих отображение данных отчета в порядке их вывода.

Стандартный перечень элементов отчета:

Индекс	Значение элемента	Макет	Идентификатор	...	МакетШапки	МакетПодвала	Тело	ТелоИерархии
0	МакетОбластиМакетаКомпоновкиДанных	"Макет1"	<>	...	<>	<>	<>	<>
1	МакетОбластиМакетаКомпоновкиДанных	"Макет2"	<>	...	<>	<>	<>	<>
2	МакетОбластиМакетаКомпоновкиДанных	"Макет3"	<>	...	<>	<>	<>	<>
3	ГруппировкаМакетаКомпоновкиДанных	<>	""	...	""	""	ТелоМакетаКомпоновкиДанных	ТелоМакетаКомпоновкиДанных
4	МакетОбластиМакетаКомпоновкиДанных	"Макет5"	<>	...	<>	<>	<>	<>
5	МакетОбластиМакетаКомпоновкиДанных	"Макет6"	<>	...	<>	<>	<>	<>
6	МакетОбластиМакетаКомпоновкиДанных	"Макет7"	<>	...	<>	<>	<>	<>
7	ГруппировкаМакетаКомпоновкиДанных	<>	"Группировка"	...	""	"Макет9"	ТелоМакетаКомпоновкиДанных	ТелоМакетаКомпоновкиДанных

Первые 1-3 элемента - это заголовок отчета.

Далее идет группировка, выводящая информацию об актуальности выводимых данных. Это типовой элемент, который показывает актуальность при получении данных из Копии базы.

Далее могут присутствовать макеты с выводом Параметров и Отборов отчета.

Последний макет перед второй группировкой (индекс 6 из примера) - это шапка таблицы отчета. Найдя макет по имени "Макет7" в перечне макетов МакетКомпоновкиДанных.Макеты, мы можем программно его откорректировать и получить нужную нам шапку для отчета. Зачастую, это гораздо удобнее, чем пользоваться макетами в соответствующем разделе настроек СКД, а иногда, это единственный удобный выход для формирования необходимой шапки таблицы отчета. По редактированию шапки будет приведен пример.

Последний элемент - это, собственно, наша таблица с отчетом. В колонках Тело и ТелоИерархии мы можем найти макеты для вывода строк отчета. В случае использования нескольких группировок, в колонке Тело будут указаны, в том числе, нижестоящие группировки.

В элементе тела с типом ГруппировкаМакетаКомпоновкиДанных есть еще множество свойств, определяющих формирование отчета, в том числе, Выражения по отбору записей и группировок и Выражения для определения порядка.

Есть еще множество типов элементов тела для описания таблиц, диаграмм и других составных частей отчета, но здесь их рассматривать не буду.

Все макеты, указанные в Теле макета компоновки данных, определены в МакетКомпоновкиДанных.Макеты:

Описание Макетов областей Макета компоновки данных

В свойстве Макеты у Макета компоновки данных содержится перечень всех макетов, используемых для вывода отчета и указанных в Теле Макета компоновки данных.

Данный перечень мы можем дополнить своим Описанием макета области и использовать его при выводе отчета, и, конечно, можем отредактировать каждое существующее описание макетов.

У Описания макета области есть следующие свойства:

Имя - необходимо для идентификации макета, в том числе, в Теле Макета компоновки данных.
Макет - собственно, содержит все данные об оформлении и содержании выводимых данных. Стандартный тип объекта для табличного отчета - МакетОбластиКомпоновкиДанных, но могут быть и другие типы при выводе диаграмм и др.
Параметры - содержит перечень параметров, используемых в представленном Макете. Есть 2 типа параметров - выражение и расшифровка. Мы можем, например, поменять выражение, определенное из настроек, можем добавить дополнительный параметр, результат которого мы будем использовать при выводе области по данному макету, и пр.

МакетОбластиКомпоновкиДанных представляет собой массив описаний строк области, каждое из которых содержит перечень ячеек (суть, колонок), каждая из которых содержит:

Перечень элементов ПолеОбластиКомпоновкиДанных с перечнем значений, выводимых в ячейку, с указанием правил оформления по каждому значению.
Принципы оформления ячейки области, в том числе, с указанием на параметр расшифровки, с указанием принципов объединения и т.д.

Таким образом код МакетКомпоновкиДанных.Макеты["Макет7"].Макет[0].Ячейки[0].Элементы[0].Значение покажет текст верхней левой ячейки шапки таблицы.

Элемент результата компоновки данных

При поэлементном выводе отчета в табличный документ, мы (как показано выше в "расширенном" программном формировании) на каждом шаге получаем объект типа ЭлементРезультатаКомпоновкиДанных. Посмотрим какие у него есть свойства:

Свойства Элемента результата компоновки данных

Макет - имя макета, который используется при выводе данного элемента в отчет;
ЗначенияПараметров - массив значений параметров, определенных в Описании макетов областей компоновки данных;
ТипЭлемента

Возможные значения: Начало / Конец / Начало и конец

Элементы с типом Начало / Конец не служат для вывода данных, а нужны только для фиксации того что начинается (заканчивается) вывод нижестоящей группировки по Телу отчета.

Первый элемент будет всегда с типом Начало и фиксирует начало вывода отчета.

Подсчитывая количество начатых и завершенных элементов можно определить какая позиция Тела Макета компоновки в настоящий момент выводится.

Макеты - перечень Описаний макетов областей компоновки данных, используемых текущим элементом или нижестоящими элементами (только если тип элемента - Начало).

В типовой ситуации данное свойство заполнено только у первого Элемента, и в нем приведены все описания макетов, определенные в МакетКомпоновкиДанных.Макеты.

При необходимости, для отдельных элементов или группировок можно переопределить используемое Описание макетов, на что-то индивидуальное.

РасположениеВложенныхЭлементов - актуально только для элементов с типом Начало. Определяет горизонтальный или вертикальный вывод подчиненных элементов. Используется, например, при выводе колонок отчета вида Сводная таблица.
ПроцентВывода - определяет выводимый процент от завершения формирования отчета.

Далее я приведу несколько примеров, показывающих как можно использовать данные механики СКД для "допилки" отчетов.

Все примеры сформированы для реализации выдуманного отчета вида Оборотно-сальдовая ведомость для 1С:Бухгалтерия 3.0. Такой пример использован по причине актуальности приведенных примеров в рамках одного отчета.

Для каждого примера используется абсолютно простая СКД с запросом к регистру Хозрасчетный.ОстаткиИОбороты. СКД можете найти в приложенных к статье файлах или сделать свою.

Настройка компоновки для примеров

Пример 1: Приведение шапки отчета к "нормальному" виду

Это часто встречающаяся проблема, когда не хватает возможностей настроек СКД. В том числе, использование макетов из настроек СКД не всегда помогает, например, по причине использования широких пользовательских настроек в итоговом отчете.

В примере выводим ОСВ с показателями БУ и НУ, выводящимся в вертикальной последовательности. Считаем, что в данной ОСВ пользователь сможет настраивать группировки, в том числе с выводом в нескольких колонках.

Хотим преобразовать шапку следующим образом:

Реализация Примера 1

Для такого преобразования можно программно отредактировать соответствующий макет в МакетКомпоновкиДанных.Макеты.

Программный код модуля объекта:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ИтоговыеНастройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, ИтоговыеНастройки, ДанныеРасшифровки);
	
	/////////////////////////////////////////////////////////
	//Обрабатываем шапку отчета приводя ее к желаемому виду
	
	//Шапка таблицы отчета будет находиться в предпоследнем элементе Тела, т.к. отчет содержит только одну таблицу
	ИмяМакетаШапки = МакетКомпоновкиДанных.Тело[МакетКомпоновкиДанных.Тело.Количество()-2].Макет;
	ОписаниеМакетаШапки = МакетКомпоновкиДанных.Макеты.Найти(ИмяМакетаШапки);
	
	//Ищем номер колонки первого поля - ресурса, в котором у нас всегда будет значение "Показатели"
	НомерКолонкиПервогоРесурса = 0;
	Для Каждого ЯчейкаТаблицыОбласти Из ОписаниеМакетаШапки.Макет[0].Ячейки Цикл
		НомерКолонкиПервогоРесурса = НомерКолонкиПервогоРесурса + 1;
		Если ЯчейкаТаблицыОбласти.Элементы.Количество() и ЯчейкаТаблицыОбласти.Элементы[0].Значение = "Показатели" Тогда
			Прервать;
		КонецЕсли;
	КонецЦикла;
	
	//Определяем сколько необходимо строк в шапке для вывода имен группировок
	КолвоСтрокСИменамиГруппировок = 0;
	Для НКолонки = 1 По НомерКолонкиПервогоРесурса-1 Цикл
		Для НСтроки = 1 По ОписаниеМакетаШапки.Макет.Количество() Цикл
			Если НЕ ОписаниеМакетаШапки.Макет[НСтроки-1].Ячейки[0].Элементы.Количество() Тогда
				Прервать;
			КонецЕсли;
			КолвоСтрокСИменамиГруппировок = Макс(КолвоСтрокСИменамиГруппировок, НСтроки);
		КонецЦикла;
	КонецЦикла;
	
	//Удаляем лишние строки (для ресурсов надо 2, для группировок выяснили ранее)
	НадоСтрокДляШапки = Макс(КолвоСтрокСИменамиГруппировок, 2);
	Для й = НадоСтрокДляШапки+1 По ОписаниеМакетаШапки.Макет.Количество() Цикл
		ОписаниеМакетаШапки.Макет.Удалить(ОписаниеМакетаШапки.Макет.Количество()-1);
	КонецЦикла;
	
	//Центрируем весь текст во всех ячейках шапки
	Для Каждого Строка Из ОписаниеМакетаШапки.Макет Цикл
		Для Каждого Ячейка Из Строка.Ячейки Цикл
			Ячейка.Оформление.УстановитьЗначениеПараметра("ГоризонтальноеПоложение", ГоризонтальноеПоложение.Центр);
			Ячейка.Оформление.УстановитьЗначениеПараметра("ВертикальноеПоложение", ВертикальноеПоложение.Центр);
		КонецЦикла;
	КонецЦикла;
	
	//Очищаем текст во всех ячейках колонок-ресурсов начиная со 2й строки и объединяем их с верхними
	Для НСтроки = 3 По ОписаниеМакетаШапки.Макет.Количество() Цикл
		
		СтрокаМакета = ОписаниеМакетаШапки.Макет[НСтроки-1];
		Для НКолонки = НомерКолонкиПервогоРесурса По СтрокаМакета.Ячейки.Количество() Цикл
			
			Ячейка = СтрокаМакета.Ячейки[НКолонки-1];
			Ячейка.Элементы.Очистить();
			Ячейка.Оформление.УстановитьЗначениеПараметра("ОбъединятьПоВертикали", Истина);
			
		КонецЦикла;
	КонецЦикла;
	
	//Объединяем ячейки в колонке с надписью Показатели
	Для НСтроки = 2 По ОписаниеМакетаШапки.Макет.Количество() Цикл
		
		Ячейка = ОписаниеМакетаШапки.Макет[НСтроки-1].Ячейки[НомерКолонкиПервогоРесурса-1];
		Ячейка.Элементы.Очистить();
		Ячейка.Оформление.УстановитьЗначениеПараметра("ОбъединятьПоВертикали", Истина);
		
	КонецЦикла;
	///////////////////////////////////////////////////////////
	//Далее - типовой вывод
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновкиДанных, , ДанныеРасшифровки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	
КонецПроцедуры

Пример 2: Различные элементы группировки отчета выводим по-разному

В нашем ОСВ выводятся показатели БУ и НУ в вертикальной последовательности. Т.е. по каждой строке группировки получаем 2 строки в таблице отчета.

Но не все счета учитываются по НУ, соответственно, по ним не имеет смысла выводить показатель НУ.

В типовых это решено через установку максимальной высоты = 1 в условном оформлении, что, как мне кажется, не лучший вариант.

Должно выводиться следующим образом:

Реализация Примера 2

Для упрощения программного кода реализации примера, предполагаем, что в отчете может быть только одна группировка - по счетам с иерархией, и расшифровка невозможна. Исключить данные ограничения не сложно самостоятельно, или можете посмотреть в приложенном к статье отчете.

Алгоритм реализации (укрупнено):

Программный код модуля объекта:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ИтоговыеНастройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	/////////////////////////////////////////////////////////
	//Обрабатываем Настройки компоновки
	//Нам нужно добавить обязательный расчет поля Счет.НалоговыйУчет, причем и для элементов и для иерархии
	//Это можно сделать, например, добавив элемент условного оформления, который ничего не будет делать
	НовоеУсловноеОформление = ИтоговыеНастройки.УсловноеОформление.Элементы.Добавить();
	НовоеУсловноеОформление.Использование = Истина;
	НовыйЭлементОтбора = НовоеУсловноеОформление.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	НовыйЭлементОтбора.Использование = Истина;
	НовыйЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Счет.НалоговыйУчет");
	НовыйЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
	НовыйЭлементОтбора.ПравоеЗначение = Ложь;
	
	
	/////////////////////////////////////////////////////////
	//Продолжаем вывод
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, ИтоговыеНастройки, ДанныеРасшифровки);
	
	/////////////////////////////////////////////////////////
	//Обрабатываем МакетКомпоновкиДанных
	
	//Группировка (таблица) отчета будет находиться в последнем элементе Тела, т.к. отчет содержит только одну таблицу
	ГруппировкаМакетаТаблицы = МакетКомпоновкиДанных.Тело[МакетКомпоновкиДанных.Тело.Количество()-1];
	
	//Определяем макеты строк отчета, предполагая что есть только иерархическая группировка по счетам
	ИмяМакетаГруппировки = ГруппировкаМакетаТаблицы.Тело[0].Макет;
	ОписаниеМакетаГруппировки = МакетКомпоновкиДанных.Макеты.Найти(ИмяМакетаГруппировки);
	ИмяМакетаГруппировкиИерархии = ГруппировкаМакетаТаблицы.ТелоИерархии[0].Макет;
	ОписаниеМакетаГруппировкиИерархии = МакетКомпоновкиДанных.Макеты.Найти(ИмяМакетаГруппировкиИерархии);
	
	//В макетах строк отчета добавляем параметр для определения, что счет относиться к НУ
	НовыйПараметр = ОписаниеМакетаГруппировки.Параметры.Добавить(Тип("ПараметрОбластиВыражениеКомпоновкиДанных"));
	НовыйПараметр.Имя = "ВыводитьНУ";
	НовыйПараметр.Выражение = "НаборДанных1.Счет.НалоговыйУчет";
	НовыйПараметр = ОписаниеМакетаГруппировкиИерархии.Параметры.Добавить(Тип("ПараметрОбластиВыражениеКомпоновкиДанных"));
	НовыйПараметр.Имя = "ВыводитьНУ";
	НовыйПараметр.Выражение = "СчетИерархия.Счет.НалоговыйУчет";
	
	//Формируем макеты для строк отчета, у которых не будет выводиться показатель НУ
	НовоеОписаниеМакета = МакетКомпоновкиДанных.Макеты.Добавить();
	НовоеОписаниеМакета.Имя = ИмяМакетаГруппировки+"БезНУ";
	СкопироватьОписаниеМакета(НовоеОписаниеМакета, ОписаниеМакетаГруппировки);
	НовоеОписаниеМакета.Макет.Удалить(1);
	
	НовоеОписаниеМакета = МакетКомпоновкиДанных.Макеты.Добавить();
	НовоеОписаниеМакета.Имя = ИмяМакетаГруппировкиИерархии+"БезНУ";
	СкопироватьОписаниеМакета(НовоеОписаниеМакета, ОписаниеМакетаГруппировкиИерархии);
	НовоеОписаниеМакета.Макет.Удалить(1);
	
	/////////////////////////////////////////////////////////
	//Продолжаем вывод
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновкиДанных, , ДанныеРасшифровки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	
	/////////////////////////////////////////////////////////
	//Формируем отчет поэлементно
	//Отслеживаем вывод строк отчета и при необходимости меняем используемый макет
	ПроцессорВывода.НачатьВывод();
	Пока Истина Цикл
		ЭлементРезультата = ПроцессорКомпоновки.Следующий();
		Если ЭлементРезультата = Неопределено Тогда
			Прервать;
		КонецЕсли;
		
		//Убираем строки НУ, в случае если по счету не ведется налоговый учет
		Если ЭлементРезультата.Макет = ИмяМакетаГруппировки Тогда
			Если НЕ ЭлементРезультата.ЗначенияПараметров.ВыводитьНУ.Значение Тогда
				ЭлементРезультата.Макет = ИмяМакетаГруппировки+"БезНУ";
			КонецЕсли;
		ИначеЕсли ЭлементРезультата.Макет = ИмяМакетаГруппировкиИерархии Тогда
			Если НЕ ЭлементРезультата.ЗначенияПараметров.ВыводитьНУ.Значение Тогда
				ЭлементРезультата.Макет = ИмяМакетаГруппировкиИерархии+"БезНУ";
			КонецЕсли;
		КонецЕсли;
		
		ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
	КонецЦикла;
	ПроцессорВывода.ЗакончитьВывод();
	
КонецПроцедуры

Процедура СкопироватьОписаниеМакета(НовоеОписаниеМакета, ИсходноеОписаниеМакет)
	
	НовоеОписаниеМакета.Макет = СкопироватьОбъектЧерезСериализациюXML(ИсходноеОписаниеМакет.Макет);
	Для Каждого ИсхПараметр Из ИсходноеОписаниеМакет.Параметры Цикл
		ТипПараметра = ТипЗнч(ИсхПараметр);
		НовыйПараметр = НовоеОписаниеМакета.Параметры.Добавить(ТипПараметра);
		ЗаполнитьЗначенияСвойств(НовыйПараметр, ИсхПараметр);
		Если ТипПараметра = Тип("ПараметрОбластиРасшифровкаКомпоновкиДанных") Тогда
			Для Каждого ИсхВыражение Из ИсхПараметр.ВыраженияПолей Цикл
				НовоеВыражение = НовыйПараметр.ВыраженияПолей.Добавить();
				ЗаполнитьЗначенияСвойств(НовоеВыражение, ИсхВыражение);
			КонецЦикла;
		КонецЕсли;
	КонецЦикла;
	
КонецПроцедуры

//Служит для создания копии программного объекта, в случаях отсутствия у него конструктора
Функция СкопироватьОбъектЧерезСериализациюXML(ИсходныйОбъект)
	
	ЗаписьXML = Новый ЗаписьXML;
    ЗаписьXML.УстановитьСтроку();
    СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ИсходныйОбъект);
    ТекстXML = ЗаписьXML.Закрыть();
	
	ЧтениеXML = Новый ЧтениеXML;
    ЧтениеXML.УстановитьСтроку(ТекстXML);
    Возврат СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
	
КонецФункции

Пример 3: Выводим дополнительную информацию для отдельных элементов группировки

Реализуем в нашем ОСВ контроль отрицательных остатков. Т.е. чтобы на активных счетах было только дебетовое сальдо, а на пассивных только кредитовое, а также проконтролируем отсутствие отрицательного количества, если счет количественный.

Выглядеть это должно следующим образом:

Реализация Примера 3

Алгоритм реализации (укрупнено):

Программный код модуля объекта:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ИтоговыеНастройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	
	/////////////////////////////////////////////////////////
	//Обрабатываем Схему компоновки данных
	//Все измерения, по которым будем контролировать остатки, должны быть в итоговом запросе
	//Установим по всем полям, используемым для контроля, признак Обязательный
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("СуммаНачальныйОстаток").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("СуммаКонечныйОстаток").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("КоличествоНачальныйОстаток").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("КоличествоКонечныйОстаток").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("Организация").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("Субконто1").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("Субконто2").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("Субконто3").Роль.Обязательное = Истина;
	//Конечно это можно сделать в графическом режиме при настройке схемы
	
	
	//Обрабатываем Настройки компоновки
	//Нам нужно добавить обязательный расчет поля Счет.Количественный
	//Это можно сделать, например, добавив элемент условного оформления, который ничего не будет делать
	НовоеУсловноеОформление = ИтоговыеНастройки.УсловноеОформление.Элементы.Добавить();
	НовоеУсловноеОформление.Использование = Истина;
	НовыйЭлементОтбора = НовоеУсловноеОформление.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	НовыйЭлементОтбора.Использование = Истина;
	НовыйЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Счет.Количественный");
	НовыйЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
	НовыйЭлементОтбора.ПравоеЗначение = Ложь;
	
	
	/////////////////////////////////////////////////////////
	//Продолжаем вывод
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, ИтоговыеНастройки, ДанныеРасшифровки);
	
	
	/////////////////////////////////////////////////////////
	//Обрабатываем МакетКомпоновкиДанных
	//Нам нужно добавить расчет служебного параметра для определения отрицательного остатка по счетам
	
	//Группировка (таблица) отчета будет находиться в последнем элементе Тела, т.к. отчет содержит только одну таблицу
	ГруппировкаМакетаТаблицы = МакетКомпоновкиДанных.Тело[МакетКомпоновкиДанных.Тело.Количество()-1];
	
	//Определяем макет строк отчета, предполагая что есть только иерархическая группировка по счетам
	//Нам нужны только счета - элементы. Для групп проверять остатки не имеет смысла.
	ИмяМакетаГруппировки = ГруппировкаМакетаТаблицы.Тело[0].Макет;
	ОписаниеМакетаГруппировки = МакетКомпоновкиДанных.Макеты.Найти(ИмяМакетаГруппировки);
	
	//В макете добавляем служебный параметр для определения отрицательных остатков
	НовыйПараметр = ОписаниеМакетаГруппировки.Параметры.Добавить(Тип("ПараметрОбластиВыражениеКомпоновкиДанных"));
	НовыйПараметр.Имя = "КонтрольОстатков";
	//Определяем отрицательные остатки на начало и конец периода по сумме и по количеству
	//В качестве результата у нас будет возвращена таблица значений с представлениями аналитик
	НовыйПараметр.Выражение = 
	"ВычислитьВыражениеСГруппировкойТаблицаЗначений(
	|""Представление(НаборДанных1.Субконто1) КАК Субконто1, Представление(НаборДанных1.Субконто2) КАК Субконто2, Представление(НаборДанных1.Субконто3) КАК Субконто3"",
	|""НаборДанных1.Счет, НаборДанных1.Организация, НаборДанных1.Субконто1, НаборДанных1.Субконто2, НаборДанных1.Субконто3"",
	|,
	|""ВЫБОР НаборДанных1.Счет.Вид
	|	КОГДА ЗНАЧЕНИЕ(ВидСчета.Активный)
	|		ТОГДА Сумма(НаборДанных1.СуммаНачальныйОстаток) < 0 или Сумма(НаборДанных1.СуммаКонечныйОстаток) < 0
	|	КОГДА ЗНАЧЕНИЕ(ВидСчета.Пассивный)
	|		ТОГДА Сумма(НаборДанных1.СуммаНачальныйОстаток) > 0 или Сумма(НаборДанных1.СуммаКонечныйОстаток) > 0
	|	ИНАЧЕ Ложь
	|КОНЕЦ ИЛИ
	|ВЫБОР
	|	КОГДА НаборДанных1.Счет.Количественный
	|		ТОГДА Сумма(НаборДанных1.КоличествоНачальныйОстаток) < 0 или Сумма(НаборДанных1.КоличествоКонечныйОстаток) < 0
	|	ИНАЧЕ Ложь
	|КОНЕЦ"")";
	//А если добавить группировку ПериодДень, то контроль будет выполняться по каждому дню за выбранный период
	
	//В макете добавляем служебный параметр содержащий данные для расшифровки описания ошибки
	// далее его можно будет обрабатывать, например, для открытия дополнительного отчета
	НовыйПараметр = ОписаниеМакетаГруппировки.Параметры.Добавить(Тип("ПараметрОбластиРасшифровкаКомпоновкиДанных"));
	НовыйПараметр.Имя = "РасшифровкаКонтроляОстатков";
	НовоеПолеРасшифровки = НовыйПараметр.ВыраженияПолей.Добавить();
	НовоеПолеРасшифровки.Поле = "КонтрольОстатковПоСчету";
	НовоеПолеРасшифровки.Выражение = "НаборДанных1.Счет";
	НовыйПараметр.ОсновноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.Нет;
	
	
	/////////////////////////////////////////////////////////
	//Продолжаем вывод
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновкиДанных, , ДанныеРасшифровки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	
	/////////////////////////////////////////////////////////
	//Формируем отчет поэлементно
	//Отслеживаем вывод строк отчета и при необходимости выводим данные по контролю остатков
	ПроцессорВывода.НачатьВывод();
	Пока Истина Цикл
		ЭлементРезультата = ПроцессорКомпоновки.Следующий();
		Если ЭлементРезультата = Неопределено Тогда
			Прервать;
		КонецЕсли;
		
		Если ЭлементРезультата.Макет = ИмяМакетаГруппировки
			И ЭлементРезультата.ЗначенияПараметров.КонтрольОстатков.Значение.Количество()
			Тогда
			//Обнаружили наличие отрицательных остатков
			
			ОтрицательныеОстатки = ЭлементРезультата.ЗначенияПараметров.КонтрольОстатков.Значение;
			
			//Сформируем текст описания ошибок, содержащего перечень аналитик
			ТекстОписанияОшибки = "По счету есть отрицательные остатки по аналитикам:";
			Для й=1 По Мин(3, ОтрицательныеОстатки.Количество()) Цикл
				АналитикиСтроки = ОтрицательныеОстатки[й-1];
				ТекстОписанияОшибки = ТекстОписанияОшибки+"
				|	- " + АналитикиСтроки.Субконто1 + "; " + АналитикиСтроки.Субконто2 + "; " + АналитикиСтроки.Субконто3;
			КонецЦикла;
			Если ОтрицательныеОстатки.Количество() > 3 Тогда
				ТекстОписанияОшибки = ТекстОписанияОшибки+"
				|	- ... (всего "+ОтрицательныеОстатки.Количество()+" аналитик)";
			КонецЕсли;
			
			//Сформируем значение расшифровки, по которому мы сможем вывести какой-нибудь дополнительный отчет
			РасшифровкаОписанияОшибки = ЭлементРезультата.ЗначенияПараметров.РасшифровкаКонтроляОстатков.Значение;
			
			//Для вывода описания добавим под счетом дополнительную строку,
			// для чего можно переопределить выводимый макет непосредственно в выводимом элементе
			СформироватьМакетСДобавлениемСтрокиДляВыводаОписанияТекстаОшибок(ЭлементРезультата, ОписаниеМакетаГруппировки, ТекстОписанияОшибки, РасшифровкаОписанияОшибки);
		КонецЕсли;
		
		ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
	КонецЦикла;
	ПроцессорВывода.ЗакончитьВывод();
	
КонецПроцедуры


Процедура СформироватьМакетСДобавлениемСтрокиДляВыводаОписанияТекстаОшибок(ЭлементРезультата, ИсходноеОписаниеМакета, ТекстОписанияОшибки, РасшифровкаОписанияОшибки)
	
	НовыйОписаниеМакета = ЭлементРезультата.Макеты.Добавить();
	НовыйОписаниеМакета.Имя = ЭлементРезультата.Макет;
	НовыйОписаниеМакета.Макет = СкопироватьОбъектЧерезСериализациюXML(ИсходноеОписаниеМакета.Макет);
	ИндексПоследнейСтроки = НовыйОписаниеМакета.Макет.Количество()-1;
	СтрокаИсходная = НовыйОписаниеМакета.Макет[ИндексПоследнейСтроки];
	НоваяСтрокаМакета = НовыйОписаниеМакета.Макет.Добавить(Тип("СтрокаТаблицыОбластиКомпоновкиДанных"));
	НоваяСтрокаМакета.ИдентификаторТаблицы = НовыйОписаниеМакета.Макет[0].ИдентификаторТаблицы;
	
	//Оформление новой строки будет совпадать с предыдущей
	//Текст описания ошибок в остатках будет в первой следующей колонке после группировок
	
	//Заполняем оформление ячеек группировок
	Для НомКолонки = 1 По СтрокаИсходная.Ячейки.Количество() Цикл
		ЯчейкаИсходная = СтрокаИсходная.Ячейки[НомКолонки-1];
		
		ЗначениеОбъединения = ЯчейкаИсходная.Оформление.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("ОбъединятьПоВертикали"));
		Если НЕ ЗначениеОбъединения = Неопределено
			И ЗначениеОбъединения.Использование
			И ЗначениеОбъединения.Значение = Истина
			Тогда
			//Ячейка присоеденена к верхней, а значит относиться к группировке
		Иначе
			Прервать;
		КонецЕсли;
		
		НоваяЯчейка = НоваяСтрокаМакета.Ячейки.Добавить();
		СкопироватьКоллекциюЗначенийПараметровОформления(НоваяЯчейка.Оформление.Элементы, ЯчейкаИсходная.Оформление.Элементы);
	КонецЦикла;
	НомерКолонкиСТекстомОписания = НомКолонки;
	
	//Заполняем оформление ячейки с текстом описания ошибки
	НоваяЯчейка = НоваяСтрокаМакета.Ячейки.Добавить();
	СкопироватьКоллекциюЗначенийПараметровОформления(
		НоваяЯчейка.Оформление.Элементы,
		СтрокаИсходная.Ячейки[НомерКолонкиСТекстомОписания-1].Оформление.Элементы,
		"ЦветФона, ЦветГраницы, СтильГраницы, Шрифт");
	НоваяЯчейка.Оформление.УстановитьЗначениеПараметра(
		Новый ПараметрКомпоновкиДанных("ЦветТекста"), WebЦвета.Красный);
		
	//Заполняем оформление остальных ячеек
	Для НомКолонки = (НомерКолонкиСТекстомОписания+1) По СтрокаИсходная.Ячейки.Количество() Цикл
		ЯчейкаИсходная = СтрокаИсходная.Ячейки[НомКолонки-1];
		НоваяЯчейка = НоваяСтрокаМакета.Ячейки.Добавить();
		
		СкопироватьКоллекциюЗначенийПараметровОформления(
			НоваяЯчейка.Оформление.Элементы,
			ЯчейкаИсходная.Оформление.Элементы,
			"ЦветФона, ЦветГраницы, СтильГраницы, Шрифт");
			
		НоваяЯчейка.Оформление.УстановитьЗначениеПараметра(
			Новый ПараметрКомпоновкиДанных("ОбъединятьПоГоризонтали"), Истина);
	КонецЦикла;
	
	//Выводим текст и расшифровку описания ошибок в остатках
	ПолеТекстаОшибки = НоваяСтрокаМакета.Ячейки[НомерКолонкиСТекстомОписания-1].Элементы.Добавить(Тип("ПолеОбластиКомпоновкиДанных"));
	ПолеТекстаОшибки.Значение = ТекстОписанияОшибки;
	НоваяСтрокаМакета.Ячейки[НомерКолонкиСТекстомОписания-1].Оформление.УстановитьЗначениеПараметра(
		Новый ПараметрКомпоновкиДанных("Расшифровка"), РасшифровкаОписанияОшибки);
	
КонецПроцедуры


Процедура СкопироватьКоллекциюЗначенийПараметровОформления(Приемник, Источник, ОграничитьПараметры="", ИсключаяПараметры="")
	
	Для Каждого ЭлементИсходный Из Источник Цикл
		Если НЕ ЭлементИсходный.Использование Тогда
			Продолжить;
		ИначеЕсли НЕ ПустаяСтрока(ОграничитьПараметры) и СтрНайти(ОграничитьПараметры, Строка(ЭлементИсходный.Параметр)) = 0 Тогда
			Продолжить;
		ИначеЕсли СтрНайти(ИсключаяПараметры, Строка(ЭлементИсходный.Параметр)) > 0 Тогда
			Продолжить;
		КонецЕсли;
		НовыйЭлемент = Приемник.Найти(ЭлементИсходный.Параметр);
		НовыйЭлемент.Использование = Истина;
		НовыйЭлемент.Значение = ЭлементИсходный.Значение;
		СкопироватьКоллекциюЗначенийПараметровОформления(НовыйЭлемент.ЗначенияВложенныхПараметров, ЭлементИсходный.ЗначенияВложенныхПараметров);
	КонецЦикла;
	
КонецПроцедуры


//Служит для создания копии программного объекта, в случаях отсутствия у него конструктора
Функция СкопироватьОбъектЧерезСериализациюXML(ИсходныйОбъект)
	
	ЗаписьXML = Новый ЗаписьXML;
    ЗаписьXML.УстановитьСтроку();
    СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ИсходныйОбъект);
    ТекстXML = ЗаписьXML.Закрыть();
	
	ЧтениеXML = Новый ЧтениеXML;
    ЧтениеXML.УстановитьСтроку(ТекстXML);
    Возврат СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
	
КонецФункции

Пример 4: Выводим диаграммы в ячейках отчета

Для большей информативности о динамике финансовых показателей, добавим в наш ОСВ вывод графиков со значениями сальдо на каждый день по каждому счету.

Выглядеть это будет следующим образом:

Реализация Примера 4

Для упрощения программного кода реализации примера, добавим поле "График сальдо" в графическом режиме настройки СКД. Для этого, добавим пустое вычисляемое поле, сделаем его ресурсом и выведем в отчет первым показателем.

Кроме того, будем считать, что в отчете может быть только одна группировка - по счетам с иерархией, и расшифровка невозможна.

Исключить данные ограничения не сложно самостоятельно, или можете посмотреть в приложенном к статье отчете.

Алгоритм реализации (укрупнено):

Программный код модуля объекта:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ИтоговыеНастройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	/////////////////////////////////////////////////////////
	//Обрабатываем Схему компоновки данных
	//Поля сальдо и день должны быть в итоговом запросе
	//Установим по ним признак Обязательный
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("ПериодДень").Роль.Обязательное = Истина;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("СуммаНачальныйОстаток").Роль.Обязательное = Истина;
	//Т.к. для поля СуммаНачальныйОстаток по умолчанию устанавливается роль остатка, мы ее должны снять,
	// как и у симметричного поля СуммаКонечныйОстаток
	// Если этого не сделать, то при формировании макета будет выведена ошибка,
	// т.к. система не понимает как поля преобразовать с учетом роли
	// ведь использование полей мы пропишем программно уже в сформированном макете.
	// Роль, в данном случае, по этим полям нам не нужна.
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("СуммаНачальныйОстаток").Роль.Остаток = Ложь;
	СхемаКомпоновкиДанных.НаборыДанных[0].Поля.Найти("СуммаКонечныйОстаток").Роль.Остаток = Ложь;
	//Конечно, все это можно сделать в графическом режиме при настройке схемы
	
	/////////////////////////////////////////////////////////
	//Продолжаем вывод
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, ИтоговыеНастройки, ДанныеРасшифровки);
	
	
	/////////////////////////////////////////////////////////
	//Обрабатываем МакетКомпоновкиДанных
	//Нам нужно добавить расчет служебного параметра для получения сальдо на каждый день
	
	//Группировка (таблица) отчета будет находиться в последнем элементе Тела, т.к. отчет содержит только одну таблицу
	ГруппировкаМакетаТаблицы = МакетКомпоновкиДанных.Тело[МакетКомпоновкиДанных.Тело.Количество()-1];
	
	//Определяем макеты строк отчета, предполагая что есть только иерархическая группировка по счетам
	ИмяМакетаГруппировки = ГруппировкаМакетаТаблицы.Тело[0].Макет;
	ОписаниеМакетаГруппировки = МакетКомпоновкиДанных.Макеты.Найти(ИмяМакетаГруппировки);
	ИмяМакетаГруппировкиИерархии = ГруппировкаМакетаТаблицы.ТелоИерархии[0].Макет;
	ОписаниеМакетаГруппировкиИерархии = МакетКомпоновкиДанных.Макеты.Найти(ИмяМакетаГруппировкиИерархии);
	
	//В макетах элементов и иерархии добавляем служебный параметр с расчетом сальдо на каждый день
	ВыражениеРасчетаСальдо =
	"ВычислитьВыражениеСГруппировкойТаблицаЗначений(
	|""НаборДанных1.ПериодДень КАК ПериодДень, Сумма(НаборДанных1.СуммаНачальныйОстаток) КАК Сальдо"",
	|""НаборДанных1.ПериодДень"",
	|,
	|)";
	
	НовыйПараметр = ОписаниеМакетаГруппировки.Параметры.Добавить(Тип("ПараметрОбластиВыражениеКомпоновкиДанных"));
	НовыйПараметр.Имя = "СальдоНаКаждыйДень";
	НовыйПараметр.Выражение = ВыражениеРасчетаСальдо;
	
	НовыйПараметр = ОписаниеМакетаГруппировкиИерархии.Параметры.Добавить(Тип("ПараметрОбластиВыражениеКомпоновкиДанных"));
	НовыйПараметр.Имя = "СальдоНаКаждыйДень";
	НовыйПараметр.Выражение = ВыражениеРасчетаСальдо;
	
	
	//В макетах настраиваем ячейки, где будут выводиться диаграммы
	//Исходя из настроек компоновки, для вывода диаграммы используется вторая колонка отчета
	ОписаниеМакетаГруппировки.Макет[0].Ячейки[1].Элементы.Очистить();
	ОписаниеМакетаГруппировки.Макет[0].Ячейки[1].Оформление.УстановитьЗначениеПараметра(
		Новый ПараметрКомпоновкиДанных("РазмерКартинки"), РазмерКартинки.Пропорционально);
	ОписаниеМакетаГруппировки.Макет[0].Ячейки[1].Оформление.УстановитьЗначениеПараметра(
		Новый ПараметрКомпоновкиДанных("Картинка"), Новый ПараметрКомпоновкиДанных("КартинкаДиаграммыПоСтроке"));
		
	ОписаниеМакетаГруппировкиИерархии.Макет[0].Ячейки[1].Элементы.Очистить();
	ОписаниеМакетаГруппировкиИерархии.Макет[0].Ячейки[1].Оформление.УстановитьЗначениеПараметра(
		Новый ПараметрКомпоновкиДанных("РазмерКартинки"), РазмерКартинки.Пропорционально);
	ОписаниеМакетаГруппировкиИерархии.Макет[0].Ячейки[1].Оформление.УстановитьЗначениеПараметра(
		Новый ПараметрКомпоновкиДанных("Картинка"), Новый ПараметрКомпоновкиДанных("КартинкаДиаграммыПоСтроке"));
	//Указанный параметр КартинкаДиаграммыПоСтроке мы установим уже в элементе результата (см. далее)
		
	
	/////////////////////////////////////////////////////////
	//Продолжаем вывод
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновкиДанных, , ДанныеРасшифровки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	
	/////////////////////////////////////////////////////////
	//Формируем отчет поэлементно
	ПроцессорВывода.НачатьВывод();
	Пока Истина Цикл
		ЭлементРезультата = ПроцессорКомпоновки.Следующий();
		Если ЭлементРезультата = Неопределено Тогда
			Прервать;
		КонецЕсли;
		
		Если ЭлементРезультата.Макет = ИмяМакетаГруппировки
			ИЛИ ЭлементРезультата.Макет = ИмяМакетаГруппировкиИерархии
			Тогда
			//Добавляем значение параметра, из которого в ячейку будет устанавливаться картинка
			ЗначениеПараметраКартинки = ЭлементРезультата.ЗначенияПараметров.Добавить();
			ЗначениеПараметраКартинки.Имя = "КартинкаДиаграммыПоСтроке";
			ЗначениеПараметраКартинки.Значение = ПолучитьКартикуДиаграммы(ЭлементРезультата.ЗначенияПараметров.СальдоНаКаждыйДень.Значение);
		КонецЕсли;
		
		ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
	КонецЦикла;
	ПроцессорВывода.ЗакончитьВывод();
	
КонецПроцедуры

Функция ПолучитьКартикуДиаграммы(ДанныеГрафика)
	
	Диаграмма = Новый Диаграмма;
	Диаграмма.СерииВСтроках = Ложь;
	Диаграмма.ТипДиаграммы = ТипДиаграммы.ГрафикСОбластями;
	Диаграмма.ИсточникДанных = ДанныеГрафика;
	Диаграмма.ОбластьЗаголовка.Расположение = РасположениеОбластиЗаголовкаДиаграммы.Нет;
	Диаграмма.ОбластьЛегенды.Расположение = РасположениеЛегендыДиаграммы.Нет;
	Диаграмма.ОбластьПостроения.ЛинииШкал = Новый Линия(ТипЛинииДиаграммы.НетЛинии);
	Диаграмма.ОбластьПостроения.ШкалаТочек.ОтображениеЗаголовка = ОтображениеЗаголовкаШкалыДиаграммы.НеОтображать;
	Диаграмма.ОбластьПостроения.ШкалаТочек.ПоложениеПодписейШкалы = ПоложениеПодписейШкалыДиаграммы.Нет;
	Диаграмма.ОбластьПостроения.ШкалаЗначений.ОтображениеЗаголовка = ОтображениеЗаголовкаШкалыДиаграммы.НеОтображать;
	Диаграмма.ОбластьПостроения.ШкалаЗначений.ПоложениеПодписейШкалы = ПоложениеПодписейШкалыДиаграммы.Нет;
	
	Возврат Диаграмма.ПолучитьКартинку(60,30);
	//Размеры картинки подобрал экспериментально
	
КонецФункции

Отчёт, прикрепленный к статье

В отчёте собраны все приведенные здесь примеры, но с возможностями группировки и расшифровки по периоду и субконто, и, в целом, реализованные в несколько более универсальном виде.

Отчет проверен на 1С: Бухгалтерия 3.0 версии 3.0.79.14 на платформе 8.3.16.1063. Но должен работать на любой Бухгалтерии 3.0 и ERP.

Прикрепленные файлы отличаются только количеством СМ. Кто хочет отблагодарить таким образом - я против не буду.

–

Скачать файлы

Наименование	Файл	Размер
Пример отчета ОСВ .erf 15,58Kb 21	.erf	15,58Kb	21	Скачать
Пример отчета ОСВ (1) .erf 15,58Kb 5	.erf	15,58Kb	5	Скачать
Пример отчета ОСВ (2) .erf 15,58Kb 4	.erf	15,58Kb	4	Скачать
Схема компоновки, используемая в примерах (ничего необычного нет) .xml 30,58Kb 5	.xml	30,58Kb	5	Скачать

Специальные предложения

Комментарии

В избранное Подписаться на ответы

Свернуть все

1. maslyann 12 09.10.20 07:18 Сейчас в теме

Полезная статья. +

2. herres 09.10.20 10:44 Сейчас в теме

Просто бомба.
18 лет назад появилась восьмёрка. Все посмотрели на поэлементный вывод, все поняли что это здорово, но ни кто не знал что с этим делать, включая самих разработчиков 1С

Ответить

3. dabu-dabu 245 09.10.20 11:54 Сейчас в теме

(2) Лучше не скажешь. Но все-таки СКД появилась несколько позже.

4. mikl79 117 09.10.20 14:16 Сейчас в теме

круто

5. boln 1038 11.10.20 23:25 Сейчас в теме

Вот это я бы хотел видеть в недавнем митапе по СКД!

6. SizovE 243 12.10.20 09:31 Сейчас в теме

красиво

7. triviumfan 79 13.10.20 00:44 Сейчас в теме

Знал, пару раз встречал, но сам никогда не использовал.
А тут детальный разбор с примерами. Спасибо.

8. chuff 19.10.20 05:08 Сейчас в теме

Как просто решается и как эффектно получается. Спасибо!

9. vazelin 112 02.01.21 19:01 Сейчас в теме

Интересно... Часто приходится делать постобработку отчета, например, объединять ячейки и центрировать наименования в шапке. Какие видите преимущества программной работы с объектами СКД вместо выгрузки данных в дерево и самостоятельного вывода в табличный документ?

10. dabu-dabu 245 05.01.21 12:29 Сейчас в теме

(9) Работа через промежуточное дерево или таблицу считаю очень плохим способом реализации отчета, т.к. уменьшает производительность, снижает читабельность кода, увеличивает трудоемкость разработки, хоть может казаться что это не так.

11. wing 21 11.06.21 04:29 Сейчас в теме

Не могу понять, как найти свою группировку. Цель как в 3 варианте - вывести дополнительную информацию, которую СКД своими средствами показать не может, но изначальные настройки - это таблица. Сколько ни пытался в отладке разгрести макет, - не смог понять, как он устроен...

12. wing 21 11.06.21 07:47 Сейчас в теме

(11) Разобрался:

ГруппировкаМакетаОтчета = МакетКомпоновкиДанных.Тело[МакетКомпоновкиДанных.Тело.Количество() - 1];
ГруппировкаМакетаТаблицы = Неопределено;
// Ищем таблицу
Для Каждого ЭлТела Из ГруппировкаМакетаОтчета.Тело Цикл
	Если ТипЗнч(ЭлТела) = Тип("ТаблицаМакетаКомпоновкиДанных") Тогда
		ГруппировкаМакетаТаблицы = ЭлТела;
		Прервать;
	КонецЕсли;
КонецЦикла;
Если ГруппировкаМакетаТаблицы = Неопределено Тогда
	ВызватьИсключение "Нарушена структура настроек - не найдена таблица";
КонецЕсли;
ГруппировкаМакетаСтроки = ГруппировкаМакетаТаблицы.Строки[ГруппировкаМакетаТаблицы.Строки.Количество() - 1];
ГруппировкаТелаСтроки = ГруппировкаМакетаСтроки.Тело[ГруппировкаМакетаСтроки.Тело.Количество() - 1];
ИмяМакетаГруппировки = ГруппировкаТелаСтроки.Тело[ГруппировкаТелаСтроки.Тело.Количество() - 1].Макет;

Показать

13. dabu-dabu 245 11.06.21 08:56 Сейчас в теме

(12) Для конкретного простого отчета нормальный вариант.
Согласен, даже в отладчике не очень понятно как устроен Макет
Я планировал сделать обработку для удобного просмотра настроек макета, но руки так и не дошли. Может быть в будущем.

14. Yashazz 4506 14.07.21 13:15 Сейчас в теме

Теоретическая часть, мягко скажем, слабовата; ни о чём. А вот практические примеры достаточно дельные.

17. fatman78 16 07.08.22 19:49 Сейчас в теме

(14) А зачем повторятся, на Инфостарте много качественных статей на эту тему.
Создание отчетов с помощью СКД - основные понятия и элементы.
Работа с настройками системы компоновки данных
Пользовательские настройки системы компоновки данных
СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ
СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты
Программная работа с настройками СКД

15. Wezoowy 71 22.08.21 15:26 Сейчас в теме

Добрый день!
Подскажите пожалуйста, как при программном выводе отчета СКД, выводить отчет в компактном режиме?
А то получается, что галка на кнопке в меню "Еще - Компактный режим" установлена, отчет формируется в "некомпактном режиме". Приходится 2 раза нажимать кнопку "Компактный режим". Тогда отчет действительно переходит в компактный режим по ширине формы.
Пробовал вызывать
Результат = Результат.ПолучитьКомпактныйДокумент();
Результат.УстановитьРастягиваниеПоГоризонтали(Истина);
Ничего не получается...

16. dabu-dabu 245 23.08.21 12:36 Сейчас в теме

(15) Никогда этим не пользовался, но указанный код должен работать.
Но, предполагаю, что его надо вызывать в модуле формы, чтобы система понимала ширину экрана.
Или нужно заполнять параметры метода ПолучитьКомпактныйДокумент.
И, конечно, вызов данных функций должен происходить после программного формирования СКД и вывода результата табличный документ.

18. angabanga5 03.11.22 15:41 Сейчас в теме

да использовать это для замены данных даже не знаю как- в ячейка не возможно подцепиться в принципе ни по типу данных, ни по чему-то еще

Оставьте свое сообщение

E-mail:

Скачать файлы

Заказать с доработкой

Статистика:

Просмотры 25125

Загрузки 35

Рейтинг 236

Комментарии 18

Создание 08.10.20 18:00

Обновление 08.10.20 18:00

№ Публикации 1290155

Характеристики:

Рубрики СКД

Кому Программист

Тип файла Внешний отчет (ert,erf)

Платформа Платформа 1С v8.3 ,
Система компоновки данных

Конфигурация Конфигурации 1cv8

Операционная система Не имеет значения

Страна Не имеет значения

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Не имеет значения

Доступ к файлу Абонемент ($m)

Код открыт Да

Посмотреть все

См. также

Выборочная свертка группировок для СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

Методика разработки отчета на СКД с возможностью свёртки части группировок по заданному программно условию. - свертка по значению поля (неотрицательные - сворачиваются); - свертка подчиненных в иерархии с произвольным количеством уровней.

1 стартмани

16.01.2023 1695 schthaxe 3

Отчет на СКД с использованием форм из БСП. Варианты передачи списка значений в параметр СКД

БСП (Библиотека стандартных подсистем) СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

Показаны способы передачи списка значений в значение по умолчанию параметра СКД типового отчета из БСП, с возможностью последующей модификации пользователем.

1 стартмани

20.04.2022 5233 eugene-p 8

По-настоящему свои макеты в отчетах СКД. Исследование процесса компоновки и генерация кода отчета

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Как скрестить формирование отчетных данных с помощью СКД и вывод в табличный документ с помощью Макет.ПолучитьОбласть(...) и ТабДок.Вывести(Секция)? А также сделать этот процесс простым и удобным? Об этом в статье ниже.

1 стартмани

22.03.2022 4803 Alxby 8

Доработка типового отчета на СКД с помощью расширения

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Доработка типового отчета на СКД в БП 3.0 с помощью расширения конфигурации. Пример, как можно внести изменения в типовой отчет "Бухгалтерии предприятия" 3.0 без снятия конфигурации с поддержки. Описан пошаговый алгоритм действий и способы решения возникающих при этом проблем.

1 стартмани

09.01.2022 9186 Spacer 9

Как я с отчетом СКД боролся (произвольный макет)!

СКД Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия государственного учреждения Государственные, бюджетные структуры Бухгалтерский учет Абонемент ($m)

Здравствуйте. Необходимо сделать было отчет, который при кнопке сформировать заполняется автоматически! При этом форма определенная (использовал произвольный макет), сделал на основании отчета "Расчетсреднегодовой...", где источником данных является внешний набор (набор данных - объект), а мне по мимо этого нужно было еще кучу всего! Статью в первую очередь пишу для себя (чтобы не забыть), но может еще кому пригодится! (БГУ 2.0.82.11, платформа 8.3.18.1483).

1 стартмани

08.12.2021 1168 VID1234 2

Динамическая расшифровка СКД (на примере отчета)

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Предлагаю Вашему неподкупному вниманию вариант более-менее унифицированной реализации динамически формирующейся расшифровки СКД на примере простейшего отчета для конфигурации УТ 11.

1 стартмани

08.12.2020 3644 mr_sav 3

СКД: все, что вы хотели знать о подмене схемы компоновки данных в отчетах и обработках

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Довольно часто на различных тематических форумах задается вопрос, можно ли использовать в отчете/обработке несколько схем компоновки данных, подменяя одну другой по мере надобности? При этом желательно, чтобы и пользовательские настройки при смене схемы менялись соответственно.

1 стартмани

07.12.2020 11889 user1502278 23

Строка по шаблону с помощью СКД

СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Иногда необходимо получить строку по шаблону с различными условиями или с возможностью изменения формата вывода. Например, заполнение поля "Назначение платежа" в платежном поручении. Для формирования такой строки может быть использована система компоновки данных, что и демонстрирует данная статья.

1 стартмани

28.08.2020 1733 Keyman 2

СКД: штрихкоды в несколько колонок

СКД Система компоновки данных 1С:ERP Управление предприятием 2 Россия Абонемент ($m)

СКД. Ресурсы в несколько колонок, на примере РС Штрихкоды номенклатуры.

1 стартмани

02.03.2020 3834 shetill 3

Процедура ПриКомпоновкеРезультата

СКД Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Коллекция кода

1 стартмани

26.07.2019 84960 vasilev2015 72

520

Многоуровневая нумерация в отчете СКД (программный вывод)

СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Реализация многоуровневой нумерации при программном выводе отчета СКД основываясь на его структуре.

1 стартмани

01.07.2019 8613 lmnlmn 7

Простые примеры сложных отчетов на СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Подписи в отчете. Особенности соединения наборов: как соединить несоединяемое. Остатки на дату и обороты по месяцам в одном отчете. Курс валюты на каждую дату без группировок и соединений в запросе. Отчет с произвольными колонками и с произвольной последовательностью. "Неадекватный отчет".

1 стартмани

12.06.2019 44269 Hatson 32

338

Вывод вариантов СКД в таблицы на управляемой форме

СКД Платформа 1С v8.3 Управляемые формы Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Задача стояла такая: есть 2 различных запроса, результаты которых выгружаются на форму обработки в таблицы значений (далее ТЗ) и программно "соприкасаются" между собой определенным образом (как именно- в рамках данной статьи неважно). Нюанс в том, что запросы должны иметь свой компоновщик настроек и могут интерактивно на форме изменяться пользователем. На оригинальность публикации не претендую - изначально в рамках поставленной задачи пытался найти что-то подобное (уже готовый шаблон) на инфостарте, возможно "плохо искал" ;)

05.04.2019 15526 artkor 1

Пример использования СКД и данных расшифровки на мобильной платформе

СКД Платформа 1С v8.3 Мобильная платформа Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

СКД в мобильном приложении и меню действий на основе данных расшифровки (отчет, совместимый с мобильной платформой 8.3.13.45).

1 стартмани

12.03.2019 6986 majoram 0

Сквозной рейтинг по иерархии в отчете на СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Сквозная нумерация (рейтинг) по группам и элементам справочника в отчете СКД согласно убыванию количества/суммы и т.д.

1 стартмани

07.02.2019 6411 MaxxiMiliSan 2

Особенность встроенной функции Представление() в СКД [поход на грабли]

СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Система компоновки данных может доставить достаточно мороки не только новичкам, но и опытным разработчикам. Стоит внести, казалось бы, незначительную правку, и начинает стрелять в самых неожиданных местах. Но давайте уже переходить к делу и рассмотрим маленькую ошибку выполнения встроенной функции СКД, которую я обнаружил на днях в работе стандартного бухгалтерского отчета "Карточка счета".

1 стартмани

15.01.2019 15641 Dementor 6

СКД. Сортировка

СКД Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

Показана реализация сортировки по двойному щелчку на заголовке колонки отчета и отображение направления сортировки в заголовках колонок.

1 стартмани

03.12.2018 13297 slimper 21

Группировка измерений в заголовках СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Методика создания общей шапки над измерениями в таблице созданной при помощи СКД. Без всякого кода. Только штатными средствами.

1 стартмани

07.11.2018 27534 dusha0020 12

Вывод товаров в СКД как на весах в Ашане

Розничная торговля СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Небольшая хитрость, которая позволяет выводить информацию на СКД плиткой.

2 стартмани

23.05.2018 14695 Kutuzov 14

Как выполнить отчет на СКД через COM и получить данные отчета?

СКД Платформа 1С v8.3 1С:Управление производственным предприятием Россия Абонемент ($m)

Для чего это нужно. Например, нужно в одной базе получить какой-либо показатель из другой базы. Этот показатель вычисляется в каком-либо сложном отчете, который написан на СКД. Можно, конечно, "скопипастить" текст запроса из другой базы, немного подправить его и выполнять в том же COM подключении. Но с этим теряется гибкость: если отчет изменился, то нужно помнить о том, что где-то есть его "немного модифицированная" копия. В статье будет рассмотрен пример получения данных из базы ЗУП.

2 стартмани

08.05.2018 48139 wowik 3

106

Работа с расшифровкой отчета на СКД

СКД Управляемые формы Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

В данной статье рассмотрим механизм работы с расшифровкой отчета, созданного при помощи системы компоновки данных, в управляемом приложении.

1 стартмани

27.02.2018 37174 Isonic 14

1с8.2-8.3.Вывод на экран данных запроса с переданными Параметрами из Документа! 8 различных вариантов:от Сообщений, Таблицы и Отчетов до СКД без объекта-отчета

СКД Платформа 1С v8.3 Управляемые формы Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Самый важный аспект 1С - это быстро получить данные из базы. Например, по результату набранного в КонсолиЗапросов запроса вывести этот результат на экран. А еще лучше, когда мы вызываем выборку данных из конкретного документа и, конечно, желаем, чтобы параметры по этому документу тоже были переданы в выборку. Здесь мы будем выводить данные на экран по нажатию кнопки в документе, обязательно с получением в параметрах значений из документа. Рассмотрим 8 вариантов вывода подобной информации на экран: 1.Вывод результатов запроса командой Сообщить() из ТаблицыЗначений; 2.Вывод результатов запроса - просто в табличный документ; 3.Вывод результатов запроса с помощью ДвумерногоМассива; 4.Вывод результатов запроса с помощью МассиваСтруктур (с двумя вариантами); 5.Вывод обычным объект-Отчетом без СКД; 6.Вывод объект-Отчетом-СКД+УстановкаПараметров; 7.Вывод объект-Отчетом-СКД+ВнешняяВременнаяТаблица; 8.Вывод программно СКД без объекта-Отчета с Параметром=ВнешняяВременнаяТаблица.

1 стартмани

14.01.2018 33542 jan-pechka 5

Расшифровка СКД. Управляемые формы

СКД Платформа 1С v8.3 Управляемые формы Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Отчеты СКД классные. Они значительно упрощают жизнь и позволяют пользователям меньше зависеть от программистов. Но иногда все же случаются проблемы при разработке таких отчетов. Сегодня обсудим как выводить отчет в произвольной форме или АРМ’е, а так же проблемы с которыми мы при этом встретимся. Для тех, кто предпочитает сразу готовый результат - обработка во вложении. Остальных приглашаю почитать эту статью.

1 стартмани

21.11.2017 35794 opx 5

100

Особенность работы отбора по характеристикам (свойствам) в СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

Замечено, что в отчете созданном на СКД с использованием характеристик (свойств) объектов при установке отбора в отчет не попадают данные с незаполненными свойствами.

1 стартмани

18.08.2017 17582 kkv90 9

Вывод результата СКД в таблицу значений

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

Вывод результата СКД в таблицу значений по Отбору Компоновки Данных

1 стартмани

04.08.2017 81783 yalex9 26

Макеты СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Рассмотрены некоторые типовые задачи, которые решаются с помощью предопределенных макетов, а также перечислены несколько случаев, для которых макеты не подходят

1 стартмани

25.07.2017 131979 json 32

379

Методика расчета отклонений данных между любыми двумя датами в отчете на СКД

СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Иногда требуется сравнить данными между двумя указанными датами. В данной статье описана методика расчета таких отклонений между двумя, указанными пользователем датами (с помощью СКД).

1 стартмани

13.05.2017 15083 tata_1211 8

Пример универсальной функции для создания схемы компоновки данных

СКД Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

Если вам приходится часто создавать схему компоновки данных программно или вы начинающий специалист и пытаетесь разобраться, что же за зверь такой СКД, то эта статья может оказаться вам полезной. Функция создает схему компоновки с минимально необходимой структурой данных. С помощью передачи дополнительных параметров есть возможность добавления ресурсов и оформления.

1 стартмани

12.01.2017 40875 dbachinsky 34

320

СКД. Дополнительная строка итогов.

СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Вариант добавления дополнительной строки итогов при выводе в таблицу СКД.

1 стартмани

23.05.2014 39641 droplet 16

Полезные примеры составления схемы компоновки данных #1

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Данная статья появилась благодаря периодически появляющимся вопросам на сайте http://1cskd.ru/. Задачи, которые задают авторы вопросов совсем не тривиальные, но их можно решить с помощью СКД.

5 стартмани

09.04.2014 179382 SITR-utyos 51

725

Сложные отчеты для управляемых форм с использованием СКД: просто. На примере отчета ABC анализ номенклатуры, клиентов для УТ11

Оптовая торговля СКД Система компоновки данных 1С:Управление торговлей 11 Управленческий учет Абонемент ($m)

Не очень часто, но все же, иногда приходится сталкиваться с необходимостью создания отчета, который очень сложно скомпоновать на "чистом" СКД, в этом случае альтернативой может являться следующая последовательность действий для получения итогового отчета: 1. при помощи одной схемы компоновки данных получить необходимую выборку данных; 2. запрограммировать (на языке 1С) некое преобразование этих данных; 3. при помощи другой схемы компоновки данных - произвести вывод необходимой информации в табличный документ. Как оказалось эта процедура не слишком сложная, хотя и немного запутанная.

1 стартмани

12.08.2013 64133 mxm2 21

Хитрости системы компоновки данных на примере решения тестового задания проекта "Доминикана"

СКД Платформа 1С v8.3 Абонемент ($m)

Недавно мне встретилось тестовое задание проекта "Доминикана", а также выложенные решения, которые показались мне слишком тривиальными, поэтому было решено сделать тестовое задание, используя минимум возможностей языка запросов и максимум возможностей СКД. О том как это было и пойдет речь в данной публицации. В публикации опишем лишь основные моменты, которые будут нам полезны в будущем, сами настройки подробно рассматривать не будем, для этого есть специлизированные курсы :).

1 стартмани

12.06.2013 47554 InformSES 39

105

Использование отборов в СКД

СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Речь пойдет о назначение расширения языка запросов для описания отборов в СКД и о том как я вижу его применение. Статья для тех кто знаком с СКД. Для новичков рекомендую предварительно ознакомиться с этим: - видео-уроки по СКД (легко ищется в интернете)

1 стартмани

26.05.2013 57994 echo77 14

Уровни группировок в отчете СКД в управляемых формах

СКД Оперативный учет Система компоновки данных 1С:Управление нашей фирмой 1.6 Абонемент ($m)

Сверуть и развернуть группировки можно через контекстное меню, горячими клавишами, можно разместить соответствующие кнопки на форме отчета как описал mxm2, но мы пойдем другим, более информативным путем.

1 стартмани

08.05.2013 25236 Pralva 16

Кнопки сворачивания и разворачивания группировок в отчете СКД в управляемых формах

СКД Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

Сверуть и развернуть группировки можно через контекстное меню, горячими клавишами, а можно разместить соответствующие кнопки на форме отчета. Как оказалось, для этого не нужно ни строчки кода.

1 стартмани

10.04.2013 55529 mxm2 11

Несколько слов о вложенных схемах компоновки данных

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Абонемент ($m)

За 2 года работы предприятия с конфигурацией «Управление торговлей 11» у нас накопилось немалое число внешних отчетов пользователей (около 30). Соответственно пользователям стало трудно ориентироваться в таком количестве отчетов, поэтому было принято решение сгруппировать отчеты по смыслу и перенести часть отчетов во вложенные схемы компоновки данных. Статья будет полезна тем, кто только начинает знакомиться с компоновкой данных. Примеры из статьи работают как УТ 11 так и в УТ 3.0 (для Украины).

1 стартмани

12.02.2013 53076 akomar 23

Нестандартная расшифровка СКД или расшифровка одного отчета СКД при помощи другого отчета СКД установкой пользовательских настроек (в управляемых формах, методика + пример для УТ11)

СКД Оперативный учет Система компоновки данных 1С:Управление торговлей 11 Россия Абонемент ($m)

Если требуется расшифровка одного отчета СКД при помощи другого отчета СКД, можно использовать представленный вариант. Казалось-бы все просто, однако дело усложняется тем, что с одной стороны, нужно предусмотреть разделение функционала между клиентом и сервером, с другой, нет достаточно четкого описания поведения передачи параметров расшифровки. В итоге: все решается "элементарно", но чтобы дойти до этого, лично мне пришлось убить уйму времени, так что экономьте своё ))). Под "нестандартной расшифровкой" имеется ввиду расшифровка данных одного вида отчета - другим видом, отличным от первого (с предварительной установкой нужных параметров и отборов в отчете-расшифровке).

1 стартмани

12.09.2012 97513 mxm2 51

174

Пример вывода всех изображений номенклатуры в отчет СКД, 1С 8,2 УПП

СКД Платформа 1С v8.3 1С:Управление производственным предприятием Россия Абонемент ($m)

Доброго время суток, потребовалось вывести все изображения номенклатуры, посмотрел публикацию http://infostart.ru/public/95442/, поискал в интернете ничего подходящего (готового) не нашел и слепил из того что было. Сыровата, но у меня работает. Не смог программно установить ширину колонки для основного изображения, но для других работает (выведено в параметры).

1 стартмани

06.08.2012 16325 savv67 5

Инструкция по настройке отчета на СКД

Инструкции пользователю СКД Система компоновки данных Конфигурации 1cv8 Россия Абонемент ($m)

Что такое отчет на СКД? Как простому пользователю выполнить простейшую настройку отчета?

1 стартмани

23.07.2012 40712 echo77 24

115 полезностей по курсу СКД Евгения Гилёва

СКД Платформа 1С v8.3 Конфигурации 1cv8 Россия Абонемент ($m)

Посмотрел 5,5 часовой курс по системе компоновки данных. Нашел невероятное количество не только необходимого, но и примеры не очевидного поведения СКД. У многих не хватает времени и терпения досмотреть курс до конца. Прочитав 115 полезностей, вы сможете понять в каком уроке освещен интересующий вас вопрос и быстро открыть его, чтобы посмотреть видео.

1 стартмани

08.04.2012 45990 Flashill 70

366