Произвольные колонтитулы и повтор шапки таблицы в табличном документе (функция)

// Функция вывода в табличный документ колонтитулов и повторения шапки таблицы.
//
// Параметры:
//  ТабДок - ТабличныйДокумент - Итоговый табличный документ (размеры должны быть заданы заранее).
//  ВыводимаяОбласть - ОбластьТабличногоДокумента - Текущая выводимая область.
//  ОбластьПустойСтроки	 - ОбластьТабличногоДокумента - Область с пустой строкой.
//  ОбластьВерхнегоКолонтитула - ОбластьТабличногоДокумента - Необязательный, 
//    область с верхним колонтитулом.
//  ОбластьНижнегоКолонтитула - ОбластьТабличногоДокумента - Необязательный, 
//    область с нижним колонтитулом.
//  ОбластьШапкаТаблицы - ОбластьТабличногоДокумента - Необязательный, 
//    область шапки текущей выводимой таблицы.
//  НомерСтраницы - Число - Необязательный, номер страницы 
//   (по умолчанию добавляется на нижний колонтитул).
// 
// Возвращаемое значение:
//  Число - текущий номер страницы.
//
Функция ВыводВТабДокСКолонтитулами(ТабДок,
				ВыводимаяОбласть,
				ОбластьПустойСтроки,
				ОбластьВерхнегоКолонтитула = Неопределено,
				ОбластьНижнегоКолонтитула = Неопределено,
				ОбластьШапкаТаблицы = Неопределено,
				НомерСтраницы = 0)
	
	// Фиксированно заданный параметр: не выводить шапку таблицы, 
	// если при добавлении к ней пустой строки происходит перенос на след. страницу
	ЗапретВисячихШапокТаблицы = Истина;
	
	// Проверка наличия областей.
	ЕстьВыводимаяОбласть = ?(ВыводимаяОбласть = Неопределено, Ложь, Истина);
	ЕстьВерхнийКолонтитул = ?(ОбластьВерхнегоКолонтитула = Неопределено, Ложь, Истина);
	ЕстьНижнийКолонтитул = ?(ОбластьНижнегоКолонтитула = Неопределено, Ложь, Истина);
	ЕстьШапкаТаблицы = ?(ОбластьШапкаТаблицы = Неопределено, Ложь, Истина);
	
	// Проверка, является ли эта итерация функции выводом шапки таблицы.
	ЭтоВыводШапкиТаблицы = (ЕстьШапкаТаблицы И ВыводимаяОбласть = ОбластьШапкаТаблицы);
	
	// Формирование области с нижним колонтитулом.
	ОбластьСНижнимКолонтитулом = Новый Массив;
	ОбластьСНижнимКолонтитулом.Добавить(?(ЕстьВыводимаяОбласть, ВыводимаяОбласть, ОбластьПустойСтроки));
	
	// Если параметр задан, то добавляем к шапке пустую строку для дальнейшей проверки.
	Если ЗапретВисячихШапокТаблицы Тогда
		Если ЭтоВыводШапкиТаблицы Тогда
			ОбластьСНижнимКолонтитулом.Добавить(ОбластьПустойСтроки);
		КонецЕсли;
	КонецЕсли;
	
	// Добавлем непосредственно сам нижний колонтитул в формируемую область нижнего колонтитула.
	Если ЕстьНижнийКолонтитул Тогда
		ОбластьСНижнимКолонтитулом.Добавить(ОбластьНижнегоКолонтитула);
	КонецЕсли;
	
	Если ВыводимаяОбласть = Неопределено И ЕстьНижнийКолонтитул Тогда
		// если не задана область вывода, то считаем, 
		// что нужно сделать завершение текущей страницы (вставить только нижний колонтитул)
		// В цикле дополняем текущую страницу пустыми строками до области нижнего колонтитула.
		Пока ТабДок.ПроверитьВывод(ОбластьСНижнимКолонтитулом) Цикл
			ТабДок.Вывести(ОбластьПустойСтроки);
		КонецЦикла;
		// Добавляем номер страницы в нижний колонтитул, если их более одной.
		Если НомерСтраницы > 1 Тогда
			ОбластьНижнегоКолонтитула.Параметры.НомерСтраницы = НомерСтраницы;
		КонецЕсли;
		ТабДок.Вывести(ОбластьНижнегоКолонтитула);
	Иначе
		// Проверка - помещается ли выводимая секция на текущую страницу или нужно перейти на новую.
		Если Не ТабДок.ПроверитьВывод(ОбластьСНижнимКолонтитулом) Тогда
			Если ВыводимаяОбласть = ОбластьПустойСтроки Тогда 
				Возврат НомерСтраницы;
			КонецЕсли;
			// Проверка, осталось ли место для пустой строки (если да, то добавляется до колонтитула).
			НомерСтраницы = ВыводВТабДокСКолонтитулами(ТабДок,
								ОбластьПустойСтроки,
								ОбластьПустойСтроки,
								ОбластьВерхнегоКолонтитула,
								ОбластьНижнегоКолонтитула,
								ОбластьШапкаТаблицы,
								НомерСтраницы);
			// Вывод нижнего колонтитула.
			Если ЕстьНижнийКолонтитул Тогда
				Если НомерСтраницы > 0 Тогда
					ОбластьНижнегоКолонтитула.Параметры.НомерСтраницы = НомерСтраницы;
					НомерСтраницы = НомерСтраницы + 1;
				КонецЕсли;
				ТабДок.Вывести(ОбластьНижнегоКолонтитула);
			КонецЕсли;
			ТабДок.ВывестиГоризонтальныйРазделительСтраниц();
			// Вывод верхнего колонтитула.
			Если ЕстьВерхнийКолонтитул Тогда
				ТабДок.Вывести(ОбластьВерхнегоКолонтитула);
			КонецЕсли;
			// Повтор шапки таблицы на новой странице.
			Если ЕстьШапкаТаблицы и Не ЭтоВыводШапкиТаблицы Тогда
				ТабДок.Вывести(ОбластьШапкаТаблицы);
			КонецЕсли;
		КонецЕсли;
		// Вывод основных данных в документ.
		ТабДок.Вывести(ВыводимаяОбласть);
		Если ВыводимаяОбласть = ОбластьПустойСтроки Тогда 
			// Продолжение вывода пустых строк до окончания страницы.
			НомерСтраницы = ВыводВТабДокСКолонтитулами(ТабДок,
								ОбластьПустойСтроки,
								ОбластьПустойСтроки,
								ОбластьВерхнегоКолонтитула,
								ОбластьНижнегоКолонтитула,
								ОбластьШапкаТаблицы,
								НомерСтраницы);
		КонецЕсли;
	КонецЕсли;
	Возврат НомерСтраницы;
КонецФункции

Функция СформироватьПечатнуюФорму() 
	
	// Получение макета.
	Макет = Документы.п_ВыпискаИзЭлектроннойЗачетнойКнижки.ПолучитьМакет("МакетСКолонтитулами");
	ОбластьВерхнегоКолонтитула = Макет.ПолучитьОбласть("ВерхнийКолонтитул");
	ОбластьНижнегоКолонтитула = Макет.ПолучитьОбласть("НижнийКолонтитул");
	ОбластьПустойСтроки = Макет.ПолучитьОбласть("ПустаяСтрока");
	
	//Получаем данные для QR-кода
	QRCode = Новый Картинка(УправлениеПечатью.ДанныеQRКода("СтрокаДляКодирования", 0, 100));
	ОбластьНижнегоКолонтитула.Параметры.QRCode = QRCode;
	
	ТабДок = Новый ТабличныйДокумент;
	// размер и параметры страницы (необходимо для вычислений страниц)
	ТабДок.РазмерСтраницы = "A4";
	ТабДок.ОриентацияСтраницы = ОриентацияСтраницы.Ландшафт;
	ТабДок.МасштабПечати = 100; // 100%
	ТабДок.ПолеСверху = 10;
	ТабДок.ПолеСнизу = 5;
	ТабДок.ПолеСлева = 15;
	ТабДок.ПолеСправа = 10;
	НомерСтраницы = 1;
	
	// Первый вывод верхнего колонтитула.
	ТабДок.Вывести(ОбластьВерхнегоКолонтитула);
	
	ПараметрыОтчетаВВидеСтруктуры = Новый Структура("ФамилияИмяОтчество, НомерДокумента", 
			ЭтотОбъект.ФизическоеЛицо, ЭтотОбъект.ЗачетнаяКнига);
	
	Область = Макет.ПолучитьОбласть("ШапкаДокумента");
	// заполняем значениями параметров.
	Область.Параметры.Заполнить(ПараметрыОтчетаВВидеСтруктуры); 
	// Выводим в табличный документ.
	НомерСтраницы = ВыводВТабДокСКолонтитулами(ТабДок, Область, 
				ОбластьПустойСтроки, ОбластьВерхнегоКолонтитула, 
				ОбластьНижнегоКолонтитула,, НомерСтраницы);

	// Таблица курсовых работ.
	Если ЭтотОбъект.КурсовыеРаботы.Количество() > 0 Тогда 
		ОбластьШапкаТаблицы = Макет.ПолучитьОбласть("КурсовыеРаботыШапкаТаблицы");
		// Вывод шапки таблицы (с проверкой ЗапретВисячихШапокТаблицы)
		НомерСтраницы = ВыводВТабДокСКолонтитулами(ТабДок, ОбластьШапкаТаблицы, 
					ОбластьПустойСтроки, ОбластьВерхнегоКолонтитула, 
					ОбластьНижнегоКолонтитула, ОбластьШапкаТаблицы, НомерСтраницы);
		// Построчный вывод строк таблицы с данными.
		Для каждого СтрокаКР из ЭтотОбъект.КурсовыеРаботы Цикл
			Область = Макет.ПолучитьОбласть("КурсовыеРаботыДанные");			
			Область.Параметры.Заполнить(СтрокаКР); // заполняем значениями параметров.
			// Вывод очередной строки таблицы с проверкой переноса и повтором шапки таблицы.
			НомерСтраницы = ВыводВТабДокСКолонтитулами(ТабДок, Область, 
						ОбластьПустойСтроки, ОбластьВерхнегоКолонтитула, 
						ОбластьНижнегоКолонтитула, ОбластьШапкаТаблицы, НомерСтраницы);
		КонецЦикла;
	КонецЕсли;
	
	Область = Макет.ПолучитьОбласть("Подвал");
	НомерСтраницы = ВыводВТабДокСКолонтитулами(ТабДок, Область, 
					ОбластьПустойСтроки, ОбластьВерхнегоКолонтитула, 
					ОбластьНижнегоКолонтитула,, НомерСтраницы);

	// Завершающий вывод.
	НомерСтраницы = ВыводВТабДокСКолонтитулами(ТабДок,, ОбластьПустойСтроки,, 
					ОбластьНижнегоКолонтитула,, НомерСтраницы);
		
	Возврат ТабДок;
КонецФункции