Как в СКД по щелчку на какой-либо ячейке в отчете получить значение другой ячейки

Публикация № 1028702

Разработка - Практика программирования

СКД УправляемыеФормы расшифровка

Задача: по щелчку на ячейке в определенной колонке в таблице отчета нужно получить значение ячейки из другой колонки в этой же строке и передать его в другой отчет (т.е. сделать расшифровку значения другим отчетом).

Дано: платформа 1С 8.3, сделан стандартный отчет на СКД (не важно внешний или встроенный).

Задача: по двойному щелчку на ячейке в определенной колонке в таблице отчета нужно получить значение ячейки из другой колонки в этой же строке и передать его в другой отчет (т.е. сделать расшифровку значения другим отчетом).

Главный вопрос здесь - как получить значение ячейки, по которой пользователь произвел щелчок? А также как получить значение из другой ячейки в этой же строке?

В сети много примеров, но мне они показались слишком сложными, поэтому привожу здесь более простой пример.

 

Вот функция, которая возвращает значение текущей ячейки СКД отчета (той, по которой произведен щелчок) (куда вставлять данную функцию написано ниже):

// Функция - Получить значение выбранного поля отчета
//
// Параметры:
//  Расшифровка           - Число    - ИД поля, по которому произведен щелчок
//  ИменаТекущихПолей   - Массив  - Массив наименований полей, для которых нужно вернуть значение 
//                                  (задает ограничение, для каких полей будет срабатывать данная функция)
// 
// Возвращаемое значение:
// Строка - значение поля, по которому произведен щелчок
&НаСервере
Функция ПолучитьЗначениеВыбранногоПоляНаСервере(Расшифровка, ИменаТекущихПолей)
    // получаем все данные из выведенного отчета
    ДанныеОтчета = ПолучитьИзВременногоХранилища(ДанныеРасшифровки); 
    // по факту возвращается только одно поле под номером в переменной "Расшифровка", поэтому его и зачитываем
    ПолеРасшифровки = ДанныеОтчета.Элементы.Получить(Расшифровка).ПолучитьПоля()[0];  
    Если Не ПолеРасшифровки = Неопределено Тогда 
        Если Не ИменаТекущихПолей.Найти (ПолеРасшифровки.Поле) = Неопределено Тогда
            // возвращаем значение только если расшифровываем конкретное поле, 
            // чтобы не срабатывало на других полях
            Возврат ПолеРасшифровки.Значение;
        КонецЕсли;
    КонецЕсли; 
    Возврат Неопределено;
КонецФункции

 

Наименование колонки текущего поля (полей) нужно для того, чтобы данная функция не срабатывала на других ячейках.

 

Вот функция, которая возвращает значение другой ячейки из этой же строки:

// Функция - Получить значение поля в строке отчета
//
// Параметры:
//  Расшифровка           - Число    - ИД поля, по которому произведен щелчок 
//  ИменаТекущихПолей   - Массив  - Массив наименований полей, для которых нужно вернуть значение 
//                                  (задает ограничение, для каких полей будет срабатывать данная функция) 
//  ИмяНужногоПоля         - Строка  - Имя поля, из которого нужно вернуть значение
//  НужноеПолеСлева       - Булево  - Признак - справа (Ложь) или слева (Истина) от текущего находтся нужное поле
// 
// Возвращаемое значение:
// Строка - значение поля, заданное в ИмяНужногоПоля
&НаСервере
Функция ПолучитьЗначениеПоляВСтрокеНаСервере(Расшифровка, ИменаТекущихПолей, ИмяНужногоПоля, НужноеПолеСлева = Истина)
    ДанныеОтчета = ПолучитьИзВременногоХранилища(ДанныеРасшифровки);
    ПолеРасшифровки = ДанныеОтчета.Элементы.Получить(Расшифровка).ПолучитьПоля()[0];
    Если Не ПолеРасшифровки = Неопределено Тогда
        Если Не ИменаТекущихПолей.Найти (ПолеРасшифровки.Поле) = Неопределено Тогда
            // поиск нужного поля в направлении, которое указано в НужноеПолеСлева
            ШагПоискаРасшифровки = ?(НужноеПолеСлева, -1, 1);
            КоличествоПолейОтчета = ДанныеОтчета.Элементы.Количество();
            СчетчикРасшифровки = Расшифровка + ШагПоискаРасшифровки;
            ПоказательВыходаЗаПределыТекущихПолей = Ложь;
            Пока СчетчикРасшифровки >= 0 И СчетчикРасшифровки < КоличествоПолейОтчета Цикл            
                ЭлементРасшифровки = ДанныеОтчета.Элементы.Получить(СчетчикРасшифровки);
                Если ТипЗнч(ЭлементРасшифровки) = Тип("ЭлементРасшифровкиКомпоновкиДанныхПоля") Тогда
                    ПолеРасшифровки = ЭлементРасшифровки.ПолучитьПоля()[0];
                    Если ПолеРасшифровки.Поле = ИмяНужногоПоля Тогда
                        Возврат ПолеРасшифровки.Значение;
                    Иначе
                        Если ИменаТекущихПолей.Найти (ПолеРасшифровки.Поле) = Неопределено Тогда                          
                            ПоказательВыходаЗаПределыТекущихПолей = Истина;
                        Иначе
                            Если ПоказательВыходаЗаПределыТекущихПолей Тогда Возврат Неопределено КонецЕсли;
                        КонецЕсли;
                    КонецЕсли;
                Иначе
                    Возврат Неопределено;
                КонецЕсли;
                СчетчикРасшифровки = СчетчикРасшифровки + ШагПоискаРасшифровки;
            КонецЦикла;       
        КонецЕсли;
    КонецЕсли;
Возврат Неопределено;    
КонецФункции

 

Помимо наименования колонки текущей ячейки (ячеек), нужно задать наименование колонки той ячейки, значение которой нужно получить, а также указать - находится ли она справа или слева от текущей/текущих (это задает направление поиска).

 

Куда вставить данный код?

Он вставляется на форму СКД отчета (если ее нет, то нужно создать типовую форму - Как добавить типовую форму для СКД)

 

Чтобы воспользоваться данными функциями понадобится создать процедуру для события ОбработкаРасшифровки элемента Результат:

 

 

В данной процедуре вызываем вышеназванные функции следующим образом:

&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка, ДополнительныеПараметры)     
    ЗначениеНужногоПоляВСтроке = Неопределено;
    // здесь пишем поля, на которых должна срабатывать расшифровка
    МассивИменТекущихПолей = Новый Массив();  
    МассивИменТекущихПолей.Добавить("Пол");
    МассивИменТекущихПолей.Добавить("ДатаРождения");
    
    // ПРИМЕР 1: показывает содержимое ячейки, 
    // на которой кликнули (если она указана в МассивИменТекущихПолей)
    //ЗначениеНужногоПоляВСтроке = ПолучитьЗначениеВыбранногоПоляНаСервере (Расшифровка, МассивИменТекущихПолей); 
    
    // ПРИМЕР 2: при щелчке на полях, указанных в МассивИменТекущихПолей, 
    // возвращаем ФИО 
    // (ФИО/Наименование находится левее от указанных полей)
    ИмяНужногоПоляВСтроке = "Наименование";
    ЗначениеНужногоПоляВСтроке = ПолучитьЗначениеПоляВСтрокеНаСервере (Расшифровка, 
            МассивИменТекущихПолей, 
            ИмяНужногоПоляВСтроке);
    
    // ПРИМЕР 3: при щелчке на поле ФИО, 
    // возвращаем дату рождения (она находится правее)
    //МассивИменТекущихПолей = Новый Массив();  
    //МассивИменТекущихПолей.Добавить("ФИО");
    //ИмяНужногоПоляВСтроке = "ДатаРождения";
    //ЗначениеНужногоПоляВСтроке = ПолучитьЗначениеПоляВСтрокеНаСервере (Расшифровка, 
    //      МассивИменТекущихПолей, 
    //      ИмяНужногоПоляВСтроке, Ложь);
    
    Если Не ЗначениеНужногоПоляВСтроке = Неопределено Тогда
        СтандартнаяОбработка = Ложь;
        ПараметрыОбработки = Новый Структура;
        ПараметрыОбработки.Вставить("Наименование", ЗначениеНужногоПоляВСтроке);
        ОткрытьВнешнийОтчетОбработкуПоИмениСДопПараметрами 
            ("ВнешняяОбработкаПример", ПараметрыОбработки, Ложь); 
    КонецЕсли; 
КонецПроцедуры

 

В зависимости от задач можно использовать первую, вторую или обе функции сразу.

Здесь приведено три примера вызова данных функций.

В принципе это всё, главное сделано, значения получены. Дальше всего лишь нужно вызвать форму другого отчета или обработки, передав полученное ранее значение как параметр.

Подробнее смотрите статью - Как при помощи БСП программно открыть внешний отчет из "Дополнительные отчеты и обработки" и передать параметры

Пример вывода отчета:

 

 

Отчет тестировался на демо-базе БСП версии 2.4.5.

Содержимое архива:

  • ВнешнийОтчетСКДПримерРасшифровка.erf - пример внешнего отчета на СКД,  для теста нужно щелкнуть на поле "Пол" или "Дата рождения". Отчет можно открывать просто через Файл-Открыть.
  • ВнешняяОбработкаПример.epf - пример внешней обработки, принимающей параметр, переданный из СКД. Нужно загрузить в "Дополнительные отчеты и обработки" (задать имя ВнешняяОбработкаПример)

Скачать файлы

Наименование Файл Версия Размер
Как в СКД по щелчку на какой-либо ячейке в отчете получить значение другой ячейки (архив с примером)

.zip 12,85Kb
26.03.19
77
.zip 12,85Kb 77 Скачать бесплатно

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Fominro 29.03.19 12:59 Сейчас в теме
Спасибо, полезно.
FilatovRA; ellavs; +2 Ответить
2. mentozavr 49 01.04.19 09:04 Сейчас в теме
Воспользовался. Спасибо.
3. Ulus 275 19.04.19 06:12 Сейчас в теме
для этого вы свою форму создали в отчете.
Например, в ERP/KA запускается общая форма "ФормаОтчета", которая интегрирована в контекст типового решения.
При определении своей формы косячки лезут, например, при выборе/сохранение вариантов отчетом и.т.п.
unichkin; +1 Ответить
10. s_vidyakin 63 05.07.19 11:22 Сейчас в теме
(3) можно в общую форму подпихнуть дополнительный обработчик расшифровки, ведущий в какой то свой модуль при определенных условиях, а можно даже в определенную процедуру модуля объекта того же отчета. Делов-то
4. MiniMuk 10 03.07.19 13:11 Сейчас в теме
В самой скд вроде есть параметр расшифровки
starik-2005; +1 Ответить
6. palsergeich 04.07.19 00:07 Сейчас в теме
(4)
В самой скд вроде есть параметр расшифровки

К сожалению, из расшифровки можно узнать только значение этого поля и всех родителей вверх по группировкам, а вот соседа, если он ресурс или поле детальной записи - увы нет.
7. MiniMuk 10 04.07.19 06:45 Сейчас в теме
(6)
поля и всех родителей вверх по группировкам, а вот соседа, если он ресурс или поле детальной за


точнее так
делаем ссылку на нужное поле для расшифровки а в представление поля выводим данные которые хотим видить
Прикрепленные файлы:
user1114234; +1 Ответить
8. palsergeich 04.07.19 10:32 Сейчас в теме
(7) И как представление мне поможет расшифровать отчет другим отчетом? Передать именно значение в отбор к примеру.
А если полей несколько надо в отборы передать?
9. s_vidyakin 63 05.07.19 11:14 Сейчас в теме
(6) обычно нужные поля заранее известны, проще их сразу в макете запихать в расшифровку ячейки и не строить дирижабль
Прикрепленные файлы:
5. palsergeich 04.07.19 00:06 Сейчас в теме
Любая модификация отчета может привести к провалу, потому что есть чуть чуть но хардкода.
1) Нужно заранее знать поле левее или правее, а этого нельзя гарантировать, потому что пользователь может изменить положение полей в отчете.
2) Ориентация на имя поля, иногда их переименовывают.

МассивИменТекущихПолей.Добавить("Пол");
    МассивИменТекущихПолей.Добавить("ДатаРождения");

Для этой задачи увы, до сих пор ничего кроме парсинга заголовка отчета + ориентира на типы - нет. И даже это решение не дает 100% гарантии.
Но в любом случае - статья полезная. Спасибо.
11. lmnlmn 64 06.07.19 15:35 Сейчас в теме
Простите, возможно я не до конца понял задачу, но если требуется узнать имена и значения полей по строке отчета, то почему не поступить проще? Например:
&НаСервере
Процедура РезультатОбработкаРасшифровкиНаСервере(НомерСтрокиТабДок);
	ДанныеРасшифр = ПолучитьИзВременногоХранилища(ДанныеРасшифровки);
	
	Для Сч = 1 По Результат.ШиринаТаблицы Цикл
		Поля = ДанныеРасшифр.Элементы[Результат.Область(НомерСтрокиТабДок, Сч).Расшифровка].ПолучитьПоля();
		
		Для Каждого Поле из Поля Цикл
			Сообщить("Имя поля: " + Поле.Поле + ", Значение: " + Поле.Значение);
		КонецЦикла
	КонецЦикла;
КонецПроцедуры

&НаКлиенте
Процедура РезультатОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
	СтандартнаяОбработка = Ложь;
	
	НомерСтрокиТабДок = Элемент.ТекущаяОбласть.Верх;
	
	РезультатОбработкаРасшифровкиНаСервере(НомерСтрокиТабДок);
КонецПроцедуры
Показать

А потом уже делайте с ними что хотите.
Оставьте свое сообщение

См. также

Использование программных перечислений, ч.1: строковые константы Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Часто ли у вас возникает необходимость в коде выполнять сравнение на строку?

10.12.2016    37819    unichkin    74    

Программная работа с настройками СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Нюансы программной работы с настройками системы компоновки данных в отчетах и динамических списках. Обзор всех видов настроек компоновки. Что в каких случаях правильно применять. В качестве примера рассмотрена работа с отборами и группировками.

27.01.2020    30898    ids79    26    

[СКД] Программное создание схемы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Сделаем отчет на СКД полностью программно, без использования макета "схема компоновки данных".

15.01.2020    26603    John_d    22    

Последовательности событий при проведении документа 1С. Шпаргалка + про формы + про расширения

Практика программирования v8 Россия Бесплатно (free)

Собрал информацию о событиях/подписках/расширениях в одном месте.

30.12.2019    20283    kuzyara    38    

Вспомогательные инструкции в коде 1С Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    31018    tormozit    100    

30 задач. Странных и не очень

Практика программирования v8 Бесплатно (free)

30 задач на знание языка программирования 1С и некоторого поведения платформы. Маленьких. Странных и не очень.

02.12.2019    17702    YPermitin    72    

Как передать IP адрес, который вызвал HTTP запрос в 1C (для веб-сервера Apache)

Практика программирования v8 Бесплатно (free)

Столкнулся с задачей получения IP адреса, который вызывает http сервис 1С. Итак, решение:

22.11.2019    8828    Sibars    19    

Полезные процедуры и функции для программиста

Практика программирования Универсальные функции v8 1cv8.cf Россия Бесплатно (free)

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    30963    HostHost    40    

Оформление и рефакторинг сложных логических выражений Промо

Практика программирования v8 Россия Бесплатно (free)

В сложных логических выражениях нередко самому автору спустя какое-то время тяжело разобраться, не говоря уже о других программистах. Предлагаемая методика позволяет повысить наглядность таких выражений путем оформления в виде И-ИЛИ дерева и одновременно выполнять их рефакторинг.

20.09.2012    78525    tormozit    131    

Таблица значений. Нюансы

Практика программирования v8 Бесплатно (free)

Обзор некоторых аспектов использования общеизвестного инструмента 1С.

01.10.2019    35823    Yashazz    50    

СКД. Отчеты с картинками

Практика программирования Работа с интерфейсом v8::СКД 1cv8.cf Бесплатно (free)

Решение популярных кейсов с картинками в отчетах на СКД.

25.09.2019    22660    YPermitin    40    

СКД не только для отчетов

Практика программирования v8::СКД 1cv8.cf Бесплатно (free)

СКД позволяет получать данные из информационной базы не только для вывода в отчеты, но и для других целей. Пример такого использования рассматривается в настоящей статье.

18.09.2019    19759    YPermitin    36    

Запись значения в поле ввода/формы со срабатыванием события ПриИзменении Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Иногда возникает необходимость после записи значения в какое либо поле ввода/формы вызвать для него обработчик события ПриИзменении, а о вызове самого события приходится только мечтать. В этой статье приводится программный способ вызова этого события.

11.07.2007    49077    tormozit    42    

[Шпаргалка] Программное создание элементов формы

Практика программирования Работа с интерфейсом v8 1cv8.cf Бесплатно (free)

Программное создание практически всех популярных элементов формы.

06.09.2019    55884    rpgshnik    63    

Агрегатные функции СКД, о которых мало кто знает

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    52768    ids79    54    

Регистры бухгалтерии. Общая информация

Практика программирования Математика и алгоритмы v8 v8::БУ БУ Бесплатно (free)

Общая информация о внутреннем устройстве регистров бухгалтерии.

05.09.2019    30203    YPermitin    24    

Как сделать из &НаКлиентеНаСервереБезКонтекста почти &НаКлиентеНаСервере Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Как сделать метод формы, доступный на клиенте и на сервере одновременно, и сохранить при этом удобство разработки

10.09.2017    45530    tormozit    74    

Три костыля. Сказ про фокусы в коде

Практика программирования v8 Бесплатно (free)

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    26097    YPermitin    80    

Отслеживание выполнения фонового задания

Практика программирования Универсальные функции Разработка v8 1cv8.cf Бесплатно (free)

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    32866    ids79    16    

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    91847    ids79    56    

Выгрузка документа по условию Промо

Практика программирования Разработка v8 Бесплатно (free)

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    16206    m-rv    2    

Фоновое выполнение кода в 1С - это просто

Практика программирования v8 1cv8.cf Бесплатно (free)

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    38815    avalakh    25    

Разбираемся с параметрами редактирования СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Связь по типу, Параметры выбора, Связи параметров выбора

31.07.2019    25820    json    15    

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    65841    ids79    12    

Как прикрутить ГУИД к регистру сведений Промо

Практика программирования Перенос данных из 1C8 в 1C8 Разработка v8 Бесплатно (free)

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    20596    m-rv    17    

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ

Инструментарий разработчика Практика программирования v8 v8::СКД Бесплатно (free)

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    37436    ids79    27    

Регистры сведений. За кулисами

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Небольшие заметки по внутреннему устройству регистров сведений.

09.07.2019    26986    YPermitin    14    

"Меньше копипаста!", или как Вася универсальную процедуру писал

Практика программирования Разработка v8 v8::СКД 1cv8.cf Бесплатно (free)

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    19977    SeiOkami    50    

Как сделать запрос на изменение данных Промо

Практика программирования v8 v8::Запросы 1cv8.cf Бесплатно (free)

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    31339    m-rv    21    

Работа с настройками системы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Варианты отчетов, работа с настройками вариантов: структура группировок, поля отчета, отборы, сортировка, условное оформление, другие настройки, настройки отображения диаграмм.

02.07.2019    51451    ids79    17    

Создание отчетов с помощью СКД - основные понятия и элементы

Практика программирования Математика и алгоритмы v8 v8::СКД Бесплатно (free)

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    55629    ids79    25    

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017

Практика программирования Производительность и оптимизация (HighLoad) v8 v8::Запросы Бесплатно (free)

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    25957    dmurk    146    

Метод формирования движений в типовых регистрах нетиповыми регистраторами Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    28513    itriot11    34    

Регистры накопления. Структура хранения в базе данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    45487    YPermitin    30    

О расширениях замолвите слово...

Практика программирования Разработка v8 Бесплатно (free)

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    36268    ellavs    126    

Git-репозитории для 1С-кода (опыт использования при небольших проектах)

Практика программирования v8 Бесплатно (free)

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    27869    ellavs    90    

Использование классов .Net в 1С для новичков Промо

Практика программирования Разработка внешних компонент Универсальные функции v7.7 v8 Бесплатно (free)

Руководство для новичков. Написав статью http://infostart.ru/public/238584/, я понял, что многие не понимают того, что написано. Поэтому в этой статье постараюсь более подробно остановиться на азах и без кода на вражеском языке (C#)

27.01.2016    77194    Serginio    110    

Как программно открыть внешний отчет из "Дополнительных отчетов и обработок" и передать параметры (при помощи БСП)

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Бесплатно (free)

Пример, как при помощи БСП программно открыть внешний отчет/обработку из "Дополнительные отчеты и обработки" и передать параметры...

25.03.2019    25181    ellavs    15    

Как добавить типовую форму для СКД (для начинающих) (1С 8.3, управляемые формы)

Инструментарий разработчика Работа с интерфейсом v8 v8::УФ v8::СКД Бесплатно (free)

Кастомизация СКД, нестандартная расшифровка, загрузка параметров и другие действия требуют наличия формы отчета. При создании СКД отчета по умолчанию форма не создается, в большинстве случаев это и не требуется. Однако при ситуациях, перечисленных выше, форму все же нужно создать. Это простая инструкция по созданию такой типовой формы.

25.03.2019    13945    ellavs    9    

Трюки с внешними источниками данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    32431    YPermitin    53    

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С Промо

Математика и алгоритмы Практика программирования v8 v8::blocking 1cv8.cf Бесплатно (free)

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    35735    ids79    40    

Добавление отчетов в типовые конфигурации 1С

Практика программирования Универсальные функции БСП (Библиотека стандартных подсистем) v8::УФ v8::СКД 1cv8.cf Бесплатно (free)

Описание различных способов добавления общих и контекстных отчетов в конфигурации 1С, построенные на базе БСП. Основные моменты и нюансы.

07.03.2019    57112    ids79    46    

Ошибки при работе с хранилищем конфигурации и способы их решения

Практика программирования v8 Бесплатно (free)

В статье собраны наиболее распространенные ошибки при работе с хранилищем конфигурации и способы их обхода и решения.

01.03.2019    42551    Смешной 1С    30    

Разработка и сценарное тестирование с Vanessa-ADD. Отчетность Allure. Автоматизация запуска сценариев

Практика программирования Vanessa Automation v8 Россия Бесплатно (free)

Формируем отчетность о результатах выполнения сценариев. Автоматизируем запуск.

26.02.2019    22899    Vladimir Litvinenko    27    

Тестер: частые вопросы Промо

Практика программирования v8 Бесплатно (free)

Ошибкам бой - тесты норма жизни!

25.07.2018    29603    grumagargler    28    

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS)

Практика программирования БСП (Библиотека стандартных подсистем) Роли и права v8 v8::Права Бесплатно (free)

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    42157    ids79    9    

Ускоряем 1С: модули с повторным использованием возвращаемых значений Промо

Практика программирования v8 Бесплатно (free)

По роду своей деятельности, мне часто приходится обсуждать с программистами детали реализации той или иной функциональности. Очень часто, разговаривая даже с квалифицированными специалистами я сталкиваюсь с незнанием сути платформенной функциональности Повторного использования возвращаемых значений общих модулей. В данной статье я постараюсь дать краткий обзор и основные особенности этой функциональности.

04.09.2017    53591    m-rv    61    

EnterpriseData – часть 2. Процесс выгрузки данных

Практика программирования Обмен через XML v8 v8::УФ Россия Бесплатно (free)

Основные этапы выгрузки данных через ED, обработчики событий выгрузки, правила обработки данных, правила конвертации объектов, конвертация свойств первого и второго этапов, процедуры БСП, используемые при выгрузке данных, структура «КомпонентыОбмена».

26.12.2018    27741    ids79    31    

Новый подход к обмену данными EnterpriseData

Практика программирования Обмен через XML v8 v8::УФ Россия Бесплатно (free)

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    42926    ids79    72