() нет, даже крайний Универсальный модуль версии 4.31 не работает с RLS.
Я пошел немного другим путем:
1) в Diadoc_4_31_0.epf в табчасть СписокДокументов добавил реквизит "врт_СкрытьСтроку" (булево)
2) в Подключаемом модуле добавил (комменты //+++//roz //---//roz):
// Обработчики заполнения доп. колонок, которые задали в ПолучитьНастройкиДополнительныхКолонокСпискаДокументов
Функция ПослеОбновленияСпискаДокументов(Параметры)
//http://1c-pro-docs.diadoc.ru/ru/latest/func/pm/Posle_Obnovleniya_Spiska_Dokumentov.html
СписокДокументов = Параметры.СписокДокументов;
Режим = Параметры.Режим;
//+++//roz//2021-11-12 [93078]
Если Режим = "ПолученныеДокументы" ИЛИ Режим = "ОтправленныеДокументы" Тогда
Запрос = Новый Запрос(
"ВЫБРАТЬ
| ТЧСписокДокументов.НомерСтроки КАК НомерСтроки
|ПОМЕСТИТЬ вт_СписокДокументов
|ИЗ
| &СписокДокументов КАК ТЧСписокДокументов
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ТЧСписокДокументовСКонтрагентами.НомерСтроки КАК НомерСтроки,
| ТЧСписокДокументовСКонтрагентами.Контрагент КАК Контрагент,
| ТЧСписокДокументовСКонтрагентами.Организация КАК Организация
|ПОМЕСТИТЬ вт_СписокДокументовСКонтрагентами
|ИЗ
| &СписокДокументовСКонтрагентами КАК ТЧСписокДокументовСКонтрагентами
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ РАЗРЕШЕННЫЕ
| вт_СписокДокументовСКонтрагентами.НомерСтроки КАК НомерСтроки,
| вт_СписокДокументовСКонтрагентами.Контрагент КАК Контрагент,
| вт_СписокДокументовСКонтрагентами.Организация КАК Организация
|ПОМЕСТИТЬ вт_СписокДокументовСКонтрагентамиРазрешенные
|ИЗ
| вт_СписокДокументовСКонтрагентами КАК вт_СписокДокументовСКонтрагентами
|ГДЕ
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(вт_СписокДокументовСКонтрагентами.Контрагент) = ТИП(Справочник.Контрагенты)
| ТОГДА ВЫРАЗИТЬ(вт_СписокДокументовСКонтрагентами.Контрагент КАК Справочник.Контрагенты).Ссылка ЕСТЬ НЕ NULL
| КОГДА ТИПЗНАЧЕНИЯ(вт_СписокДокументовСКонтрагентами.Контрагент) = ТИП(Справочник.Организации)
| ТОГДА ВЫРАЗИТЬ(вт_СписокДокументовСКонтрагентами.Контрагент КАК Справочник.Организации).Ссылка ЕСТЬ НЕ NULL
| КОГДА ТИПЗНАЧЕНИЯ(вт_СписокДокументовСКонтрагентами.Организация) = ТИП(Справочник.Организации)
| ТОГДА ВЫРАЗИТЬ(вт_СписокДокументовСКонтрагентами.Организация КАК Справочник.Организации).Ссылка ЕСТЬ НЕ NULL
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| вт_СписокДокументов.НомерСтроки КАК НомерСтроки,
| ВЫБОР
| КОГДА вт_СписокДокументовСКонтрагентамиРазрешенные.НомерСтроки ЕСТЬ NULL
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК врт_СкрытьСтроку
|ИЗ
| вт_СписокДокументов КАК вт_СписокДокументов
| ЛЕВОЕ СОЕДИНЕНИЕ вт_СписокДокументовСКонтрагентамиРазрешенные КАК вт_СписокДокументовСКонтрагентамиРазрешенные
| ПО вт_СписокДокументов.НомерСтроки = вт_СписокДокументовСКонтрагентамиРазрешенные.НомерСтроки"
);
Запрос.УстановитьПараметр("СписокДокументов", СписокДокументов.Выгрузить( ,"НомерСтроки"));
Запрос.УстановитьПараметр("СписокДокументовСКонтрагентами", СписокДокументов.Выгрузить( ,"НомерСтроки, Контрагент, Организация"));
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
СписокДокументов[Выборка.НомерСтроки - 1].врт_СкрытьСтроку = Выборка.врт_СкрытьСтроку;
КонецЦикла;
КонецЕсли;
//---//roz//2021-11-12
Возврат Истина;
КонецФункции
Показать
3) в модуле Diadoc_4_31_0.epf поправил:
Процедура ТаблицаОтборов_УстановитьОтборы(Таблица, АдресСхемы, мКомпоновщик) Экспорт
Если ТипЗнч(АдресСхемы) = Тип("СхемаКомпоновкиДанных") Тогда
СхемаСКД = АдресСхемы;
Иначе
СхемаСКД = ПолучитьИзВременногоХранилища(АдресСхемы);
КонецЕсли;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
Если ТипЗнч(Таблица) = Тип("ТаблицаЗначений") Тогда
ИсточникДанных = Новый Структура("ТаблицаДанных", Таблица);
Иначе
ИсточникДанных = Новый Структура("ТаблицаДанных", Таблица.Выгрузить());
КонецЕсли;
Макет = КомпоновщикМакета.Выполнить(СхемаСКД, мКомпоновщик.ПолучитьНастройки(), , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
ПроцессорКомпановки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпановки.Инициализировать(Макет, ИсточникДанных);
ТЗРезультат = Новый ТаблицаЗначений;
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ПроцессорВывода.УстановитьОбъект(ТЗРезультат);
ПроцессорВывода.Вывести(ПроцессорКомпановки, Истина);
Для Каждого Стр Из Таблица Цикл
Стр.Видимость = Ложь;
КонецЦикла;
//+++//roz//2021-11-23 [93078]
вртПроверятьСкрытьСтроку = Таблица.Колонки.Найти("врт_СкрытьСтроку") <> Неопределено;
//---//roz//2021-11-23
Для Каждого Стр Из ТЗРезультат Цикл
СтрокаИсходнойТаблицы = Таблица.Найти(Стр.НомерСтроки, "НомерСтроки");
//+++//roz//2021-11-23 [93078]
Если вртПроверятьСкрытьСтроку И СтрокаИсходнойТаблицы <> Неопределено Тогда
Если СтрокаИсходнойТаблицы.врт_СкрытьСтроку Тогда
Продолжить;
КонецЕсли;
КонецЕсли;
//---//roz//2021-11-23
Если СтрокаИсходнойТаблицы <> Неопределено Тогда
СтрокаИсходнойТаблицы.Видимость = Истина;
КонецЕсли;
КонецЦикла;
КонецПроцедуры
Показать
