Расписание: объект и примеры применения

Публикация № 1484154 21.07.21

Разработка - Практика программирования

Расписание регламентного задания расписание отгрузки акций.

Расписание в виде отдельного справочника (отдельно от регламентных заданий): пример реализации и возможные применения. - расписание рассылки отчетов без создания дополнительного регламента, - расписание скидок, - расписание отгрузки.

Когда обсуждается работа по расписанию, в указанный день и время, обычно имеется в виду установка регламентного задания на это время. Регламентные задания можно создавать программно, с разными расписаниями.

Возникла задача использовать расписания отдельно от регламента для следующих целей.

1) рассылка разнообразных отчетов по расписанию, в разные отделы и внешним контрагентам. Какие-то отчеты требуются ежедневно, какие-то в течение рабочих дней недели, раз в неделю, месяц. Заведение регламентного задания для каждого отчета не представляется целесообразным.

2) существуют задачи, которые невозможно выполнять по регламенту, но которые тем не менее требуют расписания. Например, задача отгрузки товара в определенные дни недели или месяца, либо например более гибкие настройки расписания срабатывания скидок или акций, чем день недели.

3) возможны требования использования расписания, которое невозможно реализовать через меню расписания регламентного задания - например "понедельник четной недели года", "15е и посл.день месяца" и т.п.

Недостатком данного метода является то, что у вас не будет привычного журналирования выполнения регламентных заданий. Также подразумевается, что у вас все эти задачи привязываются ко дню без учета времени.

Решить данную задачу предлагается созданием простенького справочника, содержащего либо строку с сериализованным объектом "Расписание регламентного задания", который превосходно работает и отдельно от самого регламентного задания, либо строку с формулой на языке 1с.

Далее - для рассылки вы добавляете поле "Расписание" в справочник настройки рассылки отчетов, устанавливаете регламент этой рассылки в ежедневный и при срабатывании регламента дополнительно проверяете срабатывание условия соответствия расписанию и только после этого высылаете отчет.

В случае с датой отгрузки можно искать следующую "правильную" дату после даты отгрузки указанной в заказе, и принудительно ставить дату отгрузки на нее.

В случае со скидками требуется аккуратная "прошивка" поля "Расписание" от документа установки скидки до функции вычисления результата скидки или акции.

 

Справочник расписание в конфигуратореМногострочное расписание

 

Справочник у меня будет с табличной частью с двумя реквизитами - оба строковые, длиной 0 (неограниченнаяя длина, чтобы сериализацию хранить).

Табличная часть сделана для того чтобы можно было соединять несколько расписаний. В программе они соединяются через "или", но конечно можно настроить какие угодно соединения.

Модуль обработки расписания я для простоты выложил в менеджер объекта:

// Преобразует объект расписание в сериализованную строку, для хранения в справочнике
Функция РасписаниеВСтроку(Расписание) Экспорт
	Если Строка(Расписание) = "один день; один раз в день" Тогда
		Возврат "";
	Иначе
		ЗаписьXML = Новый ЗаписьXML;
		ЗаписьXML.УстановитьСтроку();
		СериализаторXDTO.ЗаписатьXML(ЗаписьXML,Расписание);
		Возврат ЗаписьXML.Закрыть();
	КонецЕсли;
КонецФункции

//В реквизите расписания будем хранить либо сериализованный объект либо формулу для вычисления
Функция ЭтоОбъектРасписание(стрРасписание) Экспорт
	Возврат Лев(стрРасписание,12) = "<JobSchedule"
КонецФункции

//Обратное преобразование строки в объект
Функция СтрокаВРасписание(стрРасписание0) Экспорт
	
	Если ТипЗнч(стрРасписание0) = Тип("СправочникСсылка.Расписания") Тогда
		стрРасписание = стрРасписание0.Расписание;
	Иначе
		стрРасписание = стрРасписание0;
	КонецЕсли;
		
	Если стрРасписание = "" Тогда Возврат Новый РасписаниеРегламентногоЗадания КонецЕсли;
	
	Попытка
		ЧтениеXML = Новый ЧтениеXML;
		ЧтениеXML.УстановитьСтроку(стрРасписание);
		Расписание = СериализаторXDTO.ПрочитатьXML(ЧтениеXML,Тип("РасписаниеРегламентногоЗадания"));
	Исключение
		Расписание = Новый РасписаниеРегламентногоЗадания;
	КонецПопытки;

	Возврат Расписание;
КонецФункции

//Функция проверки.
//Тестовая строка должна выглядеть как обычное логическое выражение над переменной "Дата".
Функция ТребуетсяВыполнение(Расписание, тестДата)
	Если ЭтоОбъектРасписание(Расписание) Тогда
		обРасписание = СтрокаВРасписание(Расписание);
		Возврат обРасписание.ТребуетсяВыполнение(тестДата);
	Иначе
		стрРасписание = СтрЗаменить(Расписание,"Дата","ТестДата");
		Возврат Вычислить(стрРасписание);
	КонецЕсли;
КонецФункции

//Интерфейс справочника. Предоставляем элемент справочника, и дату,
//Возвращаем истина если дата подходит под условия расписания.
Функция ВыполнятьЗадание(Расписание, ТестДата) Экспорт
	
	Если НЕ ЗначениеЗаполнено(Расписание) Тогда Возврат Истина КонецЕсли;

	Если ТипЗнч(Расписание) = Тип("Строка") Тогда
		Если Расписание = "" Тогда Возврат Истина КонецЕсли;
		Возврат ТребуетсяВыполнение(Расписание, тестДата);
	Иначе
		обРасписание = Расписание;
		фВыполнять = Ложь;
		Для каждого р из обРасписание.ДетальноеРасписание Цикл
			Если Не ЗначениеЗаполнено(р.Расписание) Тогда Продолжить КонецЕсли;
			фВыполнять = фВыполнять или ТребуетсяВыполнение(р.Расписание, тестДата);
		КонецЦикла;
		Возврат фВыполнять;
	КонецЕсли;	

КонецФункции

//Выводит представление сериализованного расписания в виде стандартной строки его представления
Функция ПолучитьПредставление(стрРасписание) Экспорт
	
	Если ТипЗнч(стрРасписание) = Тип("Строка") Тогда
		Если стрРасписание = "" Тогда Возврат "Расписание отсутствует" КонецЕсли;
		Если ЭтоОбъектРасписание(стрРасписание) Тогда
			обРасписание = СтрокаВРасписание(стрРасписание);
		Иначе
			обРасписание = стрРасписание;
		КонецЕсли;
	ИначеЕсли ТипЗнч(стрРасписание) = Тип("РасписаниеРегламентногоЗадания") Тогда
		обРасписание = стрРасписание;
	Иначе
		обРасписание = СтрокаВРасписание(стрРасписание.Расписание);
	КонецЕсли;	

	Возврат Строка(обРасписание);

КонецФункции

//Переборка дат для получения следующей даты.
//рекомендуется вынести в модуль с повторным использованием если быстродействие
//будет снижаться
Функция ПолучитьСледующуюДату(Расписание, ДатаОтгрузки) Экспорт
	Если НЕ ЗначениеЗаполнено(Расписание) Тогда Возврат ДатаОтгрузки КонецЕсли;
	//Условно считаем что хотя бы раз в месяц должно выполняться
	максДата = ДобавитьМесяц(ДатаОтгрузки, 1);
	ТекДата = ДатаОтгрузки;
	Пока ТекДата<=максДата Цикл
		Если ВыполнятьЗадание(Расписание,ТекДата) Тогда Возврат ТекДата КонецЕсли;
		ТекДата = ТекДата + 86400;
	КонецЦикла;
	Возврат ДатаОтгрузки; // Не нашли - грузим по факту.
КонецФункции

Для формы элемента предлагается такая начинка


Процедура ДетальноеРасписаниеПередНачаломИзменения(Элемент, Отказ)
	Если Элемент.ТекущаяКолонка.Имя = "Расписание" Тогда
		Если НЕ ПустаяСтрока(Элемент.ТекущиеДанные.Расписание) и НЕ Справочники.Расписания.ЭтоОбъектРасписание(Элемент.ТекущиеДанные.Расписание) Тогда Возврат КонецЕсли;
		Отказ = Истина;
		Расписание = Справочники.Расписания.СтрокаВРасписание(Элемент.ТекущиеДанные.Расписание);
		Диалог = Новый ДиалогРасписанияРегламентногоЗадания(Расписание);
		Если Диалог.ОткрытьМодально() Тогда
			Попытка
				Если Строка(Диалог.Расписание) = "один день; один раз в день" Тогда
					Возврат;
				Иначе
					Элемент.ТекущиеДанные.Расписание = Справочники.Расписания.РасписаниеВСтроку(Диалог.Расписание);
				КонецЕсли;
			Исключение
				Сообщить(ОписаниеОшибки());
			КонецПопытки;
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры

Процедура ДетальноеРасписаниеПриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)
	ОформлениеСтроки.Ячейки.Расписание.УстановитьТекст(Справочники.Расписания.ПолучитьПредставление(ДанныеСтроки.Расписание));
КонецПроцедуры

Процедура ДетальноеРасписаниеРасписаниеНачалоВыбора(Элемент, СтандартнаяОбработка)
	ДетальноеРасписаниеПередНачаломИзменения(Элемент,СтандартнаяОбработка);
	СтандартнаяОбработка = Ложь;
КонецПроцедуры

При двойном клике на колонке расписания будет вызван стандартный диалог расписания регламентного задания (естественно без самого задания).

 

Открытие окна диалога расписания регламентного задания

 

При редактировании расписания учтите что в нем не будут работать настройки меньше чем то, что вы поставите в регламенте, кроме того не будет проверяться предыдущее выполнение, поэтому "один день" и "каждый день" при проверке будут выдавать один и тот же результат, настройка "повторять каждые" тоже не работает, так как в данном случае 1с эти самые каждые не хранит. А вот настройка периода с какой даты и по какую - работает.

Другой вариант - задание строки формулы. Для этого вам надо будет обойти двойной клик - сначала войти в редактирование строки скажем в колонке Период, а затем перейти в колонку Расписание и внести корректную формулу. Например - понедельник нечетной недели: ДеньНедели(Дата)=1 и НеделяГода(Дата)%2=1

 

Расписание формулой

 

Тестирование даты на картинке выше:

Сообщить(Расписание.Наименование + ", " + пТестДаты + " - " + Справочники.Расписания.ВыполнятьЗадание(Расписание,пТестДаты));

где пТестДаты - поле тестовой даты.

Чтобы вернуться обратно в режим открытия окна расписания, нужно сначала стереть эту формулу и выйти из редактирования.

Примеры использования.

1) для рассылки моя компания использует замечательную разработку Автоматическая рассылка отчетов из 1С: Управление торговлей 10.3 и 1С:УПП по электронной почте.

В справочник "Настройка рассылки отчетов" я поместил реквизит Расписание, поместил его на форме и для его обработки добавил в модуль РассылкаОтчетов в процедуру РассылкаОтчетов (которая вызывается по регламентному заданию) следующий фрагмент

	//...........начало пропущено.
	//далее идет цикл выборки по записям справочника настроек отчетов для рассылки.
	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
		
		Попытка
			
			НастройкаРассылки = ВыборкаДетальныеЗаписи.НастройкаРассылки;
			
			//+++++ Расписание в расписании
			Если НЕ Справочники.Расписания.ВыполнятьЗадание(НастройкаРассылки.Расписание,ТекущаяДата()) Тогда
				Продолжить;
			КонецЕсли;

			//+++++ Конец вставки

Расписание для регламентного задания РассылкаОтчетов подразумевается ежедневное один раз в день. Время отправки вы настраиваете именно в этом расписании. Отдельные регламенты для каждого отчета создавать после этой добавки не нужно.

2) Для корректировки даты отгрузки в модуль ПередЗаписью, или на форму в событие заполнения/изменения даты/даты отгрузки достаточно добавить строчку

	Если (ЭтоНовый() или Не Проведен) Тогда
		 ДатаОтгрузки = Справочники.Расписания.ПолучитьСледующуюДату(Контрагент.Расписание,ДатаОтгрузки);
	КонецЕсли;

- это при условии что у вас реквизит Расписание добавлен в справочник Контрагенты.

Естественно что вам необходимо тщательно продумать проверку, в каких случаях можно автоматически переставлять дату отгрузки в соответствии с бизнес-условиями вашего предприятия. Желательно проверять наличие уже выданной накладной и закрытие заказа.

Если вашему бизнесу требуется возможность корректировки даты отгрузки, скажем если у вас машина отправляется по средам но на следующей неделе вам необходимо ее отправить в четверг, то придется заводить дополнительный документ, записывающий соответствие типовой следующей даты и той, которая должна быть.

3) для проставления расписания для скидки вам потребуется:

- внести реквизит Расписание в документ "Установка скидок номенклатуры", вывести его на форму;

- Заведем также реквизит в регистре сведений СкидкиНаценкиНоменклатуры, если вы добавляли реквизит расписания в основные реквизиты документа, то в модуле проведения добавляется строчка записи в регистр из СтруктураШапкиДокумента.

- в модуле ОбработкаТабличныхЧастей в запросе в функции ЗапросПоСкидкам в запрос вписывается реквизит Расписание,

- в функцию РассчитатьСкидкиПриПродаже вставляется проверка расписания, такая же как для рассылки отчетов.

P.S. Естественно при необходимости можно создавать Календари, События, добавить в справочник время и т.п. У меня пока таких задач не стояло.

P.P.S. Версия для УТ11 и управляемых форм будет скоро.

Специальные предложения

Оставьте свое сообщение

См. также

Аналог PIVOT в запросе 1С (как выполнить транспонирование таблицы в запросе 1С) Промо

Практика программирования v8 Бесплатно (free)

В статье показывается простой метод реализации аналога оператора PIVOT в запросе 1С без использования соединений.

12.12.2020    3375    Eugen-S    20    

Полезные примеры СКД, ч.2

Практика программирования v8 v8::СКД Бесплатно (free)

Еще несколько примеров решения задач в СКД.

06.04.2021    9481    Neti    8    

Неочевидные нюансы записи управляемой формы

Практика программирования v8 v8::УФ Платформа 1C v8.2 1cv8.cf Бесплатно (free)

Разберем несколько нюансов записи управляемой формы.

02.04.2021    10749    SeiOkami    52    

Обзор полезных методов БСП 3.1.4

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Бесплатно (free)

Библиотека стандартных подсистем (далее - БСП) является частью любой типовой конфигурации, поэтому умение применять готовые процедуры и функции повышает качество разработки и избавляет от написания лишнего кода. К сожалению, не у всех есть время и упорство овладеть всей документацией, поэтому я собрал воедино наиболее популярный функционал.

25.03.2021    34157    rayastar    50    

Использование классов .Net в 1С для новичков Промо

Практика программирования Разработка внешних компонент Универсальные функции v7.7 v8 Бесплатно (free)

Руководство для новичков. Написав статью http://infostart.ru/public/238584/, я понял, что многие не понимают того, что написано. Поэтому в этой статье постараюсь более подробно остановиться на азах и без кода на вражеском языке (C#)

27.01.2016    84482    Serginio    113    

Звуковое управление в 1С 8.3

Практика программирования v8 1cv8.cf Бесплатно (free)

В данной статье описано создание библиотеки для звукового управления (выполнение команд голосом) для платформы 1С 8.3. Задача была поставлена так, чтобы модуль функционировал непосредственно на клиенте 1С, осуществляя управление формами, и взаимодействовал с интерфейсом.

16.03.2021    6582    velemir    31    

Доработка проведения в ERP 2.5. (Регистры накопления, Регистры сведений)

Практика программирования v8 ERP2 БУ Бесплатно (free)

Покажу точки входа для доработки "типового" проведения документов в ERP для регистров оперативного учета. Рассмотрим три основные ситуации: нужно изменить имеющееся проведение документа; нужно сделать записи в существующие регистры; нужно с нуля описать алгоритм проведения в добавленный регистр. Пример реализован на 1С:ERP Управление предприятием 2 (2.5.4.120)

10.01.2021    9827    BuriyLesha    10    

Serverless (Faas) в 1С. Создание и вызов Yandex Cloud Functions

Универсальные функции Практика программирования v8 Бесплатно (free)

"Я не могу просто взять и скопировать код с гитхаба", "у нас 1С микросервисами окружена", "возможностей мало" - частые фразы 1С разработчиков. которым не хватает возможностей платформы в современном мире. Faas, конечно, история не новая, но нас сдерживало 152ФЗ и задержки по пингам. Для того, чтобы действительно использовать в 1С код, к примеру, на Python, надо было приложить усилия. Теперь всё намного проще - берём и используем.

28.12.2020    8249    comol    31    

Использование программных перечислений, ч.1: строковые константы Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Часто ли у вас возникает необходимость в коде выполнять сравнение на строку?

10.12.2016    40585    unichkin    74    

Базовые вещи БСП, которые облегчат жизнь программисту 1С

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Россия Бесплатно (free)

В данной публикации я опишу полезные процедуры и функции модуля общего назначения библиотеки стандартных подсистем, обязательные к использованию любым программистом 1С.

30.08.2020    18688    quazare    34    

Серверные вызовы, которые нельзя вызывать

Практика программирования v8 v8::УФ 1cv8.cf Бесплатно (free)

Не баян, а классика. Рассмотрим особенность платформы настолько же древнюю, как сами УФ.

12.05.2020    8816    SeiOkami    34    

Вспомогательные инструкции в коде 1С Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    35434    tormozit    106    

Форма выбора (подбор) в управляемых формах

Практика программирования v8 v8::УФ 1cv8.cf Россия Бесплатно (free)

Разбор небольших примеров того, как правильно открывать форму выбора (подбора) в управляемых формах, не прибегая к модальным окнам.

08.05.2020    68299    user5300    19    

Программная работа с настройками СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Нюансы программной работы с настройками системы компоновки данных в отчетах и динамических списках. Обзор всех видов настроек компоновки. Что в каких случаях правильно применять. В качестве примера рассмотрена работа с отборами и группировками.

27.01.2020    60497    ids79    26    

[СКД] Программное создание схемы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Сделаем отчет на СКД полностью программно, без использования макета "схема компоновки данных".

15.01.2020    41110    John_d    22    

Оформление и рефакторинг сложных логических выражений Промо

Практика программирования v8 Россия Бесплатно (free)

В сложных логических выражениях нередко самому автору спустя какое-то время тяжело разобраться, не говоря уже о других программистах. Предлагаемая методика позволяет повысить наглядность таких выражений путем оформления в виде И-ИЛИ дерева и одновременно выполнять их рефакторинг.

20.09.2012    82294    tormozit    131    

Последовательности событий при проведении документа 1С. Шпаргалка + про формы + про расширения

Практика программирования v8 Россия Бесплатно (free)

Собрал информацию о событиях/подписках/расширениях в одном месте.

30.12.2019    32839    kuzyara    38    

30 задач. Странных и не очень

Практика программирования v8 Бесплатно (free)

30 задач на знание языка программирования 1С и некоторого поведения платформы. Маленьких. Странных и не очень.

02.12.2019    23043    YPermitin    62    

Как передать IP адрес, который вызвал HTTP запрос в 1C (для веб-сервера Apache)

Практика программирования v8 Бесплатно (free)

Столкнулся с задачей получения IP адреса, который вызывает http сервис 1С. Итак, решение:

22.11.2019    11756    Sibars    19    

Запись значения в поле ввода/формы со срабатыванием события ПриИзменении Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Иногда возникает необходимость после записи значения в какое либо поле ввода/формы вызвать для него обработчик события ПриИзменении, а о вызове самого события приходится только мечтать. В этой статье приводится программный способ вызова этого события.

11.07.2007    53571    tormozit    51    

Полезные процедуры и функции для программиста

Практика программирования Универсальные функции v8 1cv8.cf Россия Бесплатно (free)

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    38569    HostHost    41    

Таблица значений. Нюансы

Практика программирования v8 Бесплатно (free)

Обзор некоторых аспектов использования общеизвестного инструмента 1С.

01.10.2019    50783    Yashazz    56    

О программе Postman для тестирования API и для чего она нужна 1С-нику

Практика программирования Программное обеспечение (software) v8 Бесплатно (free)

Для чего нужна программа Postman для тестирования API и какая от него польза для 1С-программиста.

24.09.2019    19271    budidich    31    

Как сделать из &НаКлиентеНаСервереБезКонтекста почти &НаКлиентеНаСервере Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Как сделать метод формы, доступный на клиенте и на сервере одновременно, и сохранить при этом удобство разработки

10.09.2017    50350    tormozit    74    

[Шпаргалка] Программное создание элементов формы

Практика программирования Работа с интерфейсом v8 1cv8.cf Бесплатно (free)

Программное создание практически всех популярных элементов формы.

06.09.2019    94365    rpgshnik    72    

Агрегатные функции СКД, о которых мало кто знает

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    73653    ids79    55    

Регистры бухгалтерии. Общая информация

Практика программирования Математика и алгоритмы v8 v8::БУ БУ Бесплатно (free)

Общая информация о внутреннем устройстве регистров бухгалтерии.

05.09.2019    44054    YPermitin    25    

Выгрузка документа по условию Промо

Практика программирования Разработка v8 Бесплатно (free)

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    17686    m-rv    3    

Три костыля. Сказ про фокусы в коде

Практика программирования v8 Бесплатно (free)

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    29742    YPermitin    81    

Отслеживание выполнения фонового задания

Практика программирования Универсальные функции Разработка v8 1cv8.cf Бесплатно (free)

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    43702    ids79    19    

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    142099    ids79    75    

Как прикрутить ГУИД к регистру сведений Промо

Практика программирования Перенос данных из 1C8 в 1C8 Разработка v8 Бесплатно (free)

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    22911    m-rv    18    

Фоновое выполнение кода в 1С - это просто

Практика программирования v8 1cv8.cf Бесплатно (free)

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    57604    avalakh    26    

Разбираемся с параметрами редактирования СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Связь по типу, Параметры выбора, Связи параметров выбора

31.07.2019    39301    json    15    

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    99970    ids79    16    

Как сделать запрос на изменение данных Промо

Практика программирования v8 v8::Запросы 1cv8.cf Бесплатно (free)

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    36063    m-rv    23    

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ

Инструментарий разработчика Практика программирования v8 v8::СКД Бесплатно (free)

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    46821    ids79    27    

Регистры сведений. За кулисами

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Небольшие заметки по внутреннему устройству регистров сведений.

09.07.2019    32973    YPermitin    14    

"Меньше копипаста!", или как Вася универсальную процедуру писал

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    22212    SeiOkami    53    

Метод формирования движений в типовых регистрах нетиповыми регистраторами Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    30517    itriot11    34    

Работа с настройками системы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Варианты отчетов, работа с настройками вариантов: структура группировок, поля отчета, отборы, сортировка, условное оформление, другие настройки, настройки отображения диаграмм.

02.07.2019    79834    ids79    18    

Создание отчетов с помощью СКД - основные понятия и элементы

Практика программирования Математика и алгоритмы v8 v8::СКД Бесплатно (free)

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    73032    ids79    27    

Регистры накопления. Виртуальные таблицы. Часть №2: "Остатки" и "Остатки и обороты"

Практика программирования v8 1cv8.cf Бесплатно (free)

Описание работы платформы 1С:Предприятие 8.2 с виртуальными таблицами регистров накопления "Остатки" и "Остатки и обороты". Анализ SQL-запрос при работе с виртуальными таблицами

22.05.2019    41849    YPermitin    8    

Регистры накопления. Структура хранения в базе данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    60792    YPermitin    31    

О расширениях замолвите слово...

Практика программирования Разработка v8 Бесплатно (free)

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    41825    ellavs    131    

Git-репозитории для 1С-кода (опыт использования при небольших проектах)

Практика программирования v8 Бесплатно (free)

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    31454    ellavs    90    

Трюки с внешними источниками данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    40096    YPermitin    53