Причиной создания данной статьи послужил разбор непонятной ситуации, когда работал себе обмен более года и все было отлично, но, как обычно, в один прекрасный момент стали вылазить непонятные ситуации, о которых я попытаюсь подробно описать.
В детали обмена я вникать не буду, так как это никому не нужно, но в саму сущность придется все же посветить, например, куда идет обмен, сколько узлов там задействовано, какой принцип регистрации обмена (так как в этом вся важность), ну, и самое интересное - почему обмен перестал работать.
Смысл заложен таков, что есть определенное количество баз, которые обмениваются в одну "Базу отчетности". В этой базе никто ничего не вводит, она только аккумулирует все базы в единое целое для управленческой отчетности.
Опишу прикрепленный рисунок "BaseExchange". В нем отражено, что в базу для отчетности по какой-то причине перестали доходить движения по документам (сами же документы доходили).
Также видно, что при обмене используется два разных плана обмена, а это значит, что когда данные получает база "Магазин Самара" от базы "Магазин Владимир", то на узлах регистрации плана обмена "TraidePoint" должна произойти регистрация обмена по выделенным обработчикам событий: "ПередЗаписьюДокументаДляTradePointОбмен", "ПриЗаписиРегистрыНакопленияДляTradePointОбмен" (есть еще обработчики справочников и регистров сведений).
На этих обработчиках прописан соответствующий код с условиями, например обмен должен идти только по организации "ООО Добро".
При отладке кода стало ясно, что когда пытался зарегистрироваться набор записей регистра накоплений, условие по Регистратор.Организация не срабатывало лишь потому, что документ загружался позже. То есть он в файле загрузке был, но очередность его была после наборов записей и таким образом условие не срабатывало.
Здесь есть два выхода из ситуации:
- это попытаться использовать отбор по измерениям где есть Организация. Таким образом условие накладывается на текущий набор и на его измерение (данный метод меня не устроил, так как не все регистры которые мне нужны при обмене имеют измерение "Организация" или ссылку на этот справочник).
- при выгрузке обмена прописать правила очередности, а именно:
Функция ВыгрузитьИзмененияДанныхДляУзла(УзелОбмена, КолвоЭлементовВТранзакцииНаВыгрузкуДанных, ЗаписьXML) Экспорт
ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();
ЗаписьСообщения.НачатьЗапись(ЗаписьXML,УзелОбмена);
ВыборкаИзменений = ПланыОбмена.ВыбратьИзменения(ЗаписьСообщения.Получатель,ЗаписьСообщения.НомерСообщения);
//1. Справочники
Пока ВыборкаИзменений.Следующий() Цикл
#Если Клиент Тогда
ОбработкаПрерыванияПользователя();
#КонецЕсли
ТекОбъектОбмена = ВыборкаИзменений.Получить();
Если ТипЗнч(ТекОбъектОбмена) = Тип("УдалениеОбъекта") Тогда
ЗаписатьXML(ЗаписьXML,ТекОбъектОбмена);
Продолжить;
КонецЕсли;
МетаданныеОбъекта = ТекОбъектОбмена.Метаданные();
Если Не ОбщегоНазначения.ПринадлежностьКлассуМетаданных("Справочники",МетаданныеОбъекта) Тогда
Продолжить;
КонецЕсли;
ЗаписатьXML(ЗаписьXML,ТекОбъектОбмена);
КонецЦикла;
//2.Документы
ВыборкаИзменений.Сбросить();
Пока ВыборкаИзменений.Следующий() Цикл
#Если Клиент Тогда
ОбработкаПрерыванияПользователя();
#КонецЕсли
ТекОбъектОбмена = ВыборкаИзменений.Получить();
Если ТипЗнч(ТекОбъектОбмена) = Тип("УдалениеОбъекта") Тогда
ЗаписатьXML(ЗаписьXML,ТекОбъектОбмена);
Продолжить;
КонецЕсли;
МетаданныеОбъекта = ТекОбъектОбмена.Метаданные();
Если Не ОбщегоНазначения.ПринадлежностьКлассуМетаданных("Документы",МетаданныеОбъекта) Тогда
Продолжить;
КонецЕсли;
ЗаписатьXML(ЗаписьXML,ТекОбъектОбмена);
КонецЦикла;
//3.Регистры
ВыборкаИзменений.Сбросить();
Пока ВыборкаИзменений.Следующий() Цикл
#Если Клиент Тогда
ОбработкаПрерыванияПользователя();
#КонецЕсли
ТекОбъектОбмена = ВыборкаИзменений.Получить();
Если ТипЗнч(ТекОбъектОбмена) = Тип("УдалениеОбъекта") Тогда
ЗаписатьXML(ЗаписьXML,ТекОбъектОбмена);
Продолжить;
КонецЕсли;
МетаданныеОбъекта = ТекОбъектОбмена.Метаданные();
Если Не ОбщегоНазначения.ПринадлежностьКлассуМетаданных("РегистрыСведений",МетаданныеОбъекта)
и НЕ ОбщегоНазначения.ПринадлежностьКлассуМетаданных("РегистрыНакопления",МетаданныеОбъекта) Тогда
Продолжить;
КонецЕсли;
ЗаписатьXML(ЗаписьXML,ТекОбъектОбмена);
КонецЦикла;
ЗаписьСообщения.ЗакончитьЗапись();
ЗаписьXML.Закрыть();
Возврат Истина;
КонецФункции
Вот собственно и все! А, кстати, чуть не забыл, а как оно работало раньше, Вы спросите?! Каким образом в базу отчетности движения попадали, и никто ничего не трогал в коде по обмену и данные вдруг перестали доходить.
Здесь все просто, как оказалось человек, который ежедневно перепроводил всю пачку документов ушел в отпуск. А когда документы он перепроводил - то срабатывала подписка, и если документ в базе уже был, то, естественно, условие уже на Регистратор.Организация успешно срабатывало.
Будьте внимательны и бдительны при разработке такого рода обмена.
Диме - отдельная благодарность за нахождение и устранение ошибочной ситуации.
