Правила работы с транзакциями 1С

На 3 из 4 поддерживаемых СУБД, при вызове НачатьТранзакцию платформа идет в СУБД и открывает там транзакцию. В этот момент может произойти все что угодно: нехватка памяти для очередного соединения с СУБД, разрыв связи, ошибка дисковой подсистемы.
Давайте делать, как написано в документации: НачатьТранзакцию до начала Попытки, Зафиксировать — внутри, Откатить — в обработке исключения. Стандартная для всех языков практика, в общем-то.

Хотя науке и неизвестны случаи выброса перехватываемых исключений из НачатьТранзакцию().

Alexey Lab Sosnoviy
я не пользую ТранзакцияАктивна т.к. не понял зачем оно =) Я транзакцияю начал, я же отменил, а вские там маскировки того что внутри имхо зло

Nikita Fedkin
Использование этого метода на любом уровне означает, что на уровне ниже есть ошибка в обработке транзакций. Ошибку надо исправить, и метод будет не нужен :)

Вот если код нельзя исправить (например, внешнее решение без исходников или запрет на изменение даже расширениями), короче, если не доверяешь коду и знаешь, что он может стрельнуть, при этом после верхнеуровневой транзакции есть какой-то код, который тоже работает с бд, то да, тогда в верхнем уровне можно это вставить. Но лучше втащить автору кода ниже, это продуктивнее

Андрей Овсянкин
В той статье есть еще комментарии. И там я согласился с доводами, что есть более хорошее решение "общего вида". Мое решение тоже хорошее, но для условий, когда "вокруг говнокод и никому верить нельзя". Для вменяемой кодовой базы и с вменяемой командой - лучше брать паттерн с ИТС

Артур Аюханов
в модульных тестах активно юзаю этот метод перед отменой транзакции и рекомендую всем его юзать в серверных модульных тестах
т.к. не всегда можно гарантировать наличие транзакции из-за ошибок в коде и т.п.

Сергей Старых
Так делать не всегда неправильно. Более правильной я считаю безусловную отмену транзакции в исключении.

Олег Тымко
Я считаю, что проверка «ТранкзакцияАктивна» перед отменой - это заметание под ковер. Но иногда это нужно делать, как, например, с безумными обменами через КД, когда там в любой момент могут попорить активную транкзакцию. 

 Чего только не находилось за последние несколько лет в транзакциях проведения документов или записи набора регистров:

  - Предупреждение() или Вопрос() - это самое любимое

  - вывод на печать на принтер (ага, прям в транзакции.. и потом появляются претензии "на бумаге написано что в документе одно, а в базу залезешь - там другое" - это при откате таких блокирующих транзакций)

  - разнообразные файловые операции

  - обращения к другим базам через com-объекты

  - обращения к другим базам посредством Новый COMОбъект("ADODB.Connection")  (ага, а на соседнем сервере уже запрос через то самое ADODB... тоже висит на блокировке! и такое было..) 

 - работа с ftp

 - обращение к web-сервису

 - запуск на исполнение сторонних программ

Кроме счетчика транзакций есть неявный флаг, булевая переменная "Запрет фиксации тразакции" (с) Апресов Игорь, см. Видео

Отмена "вложенной" явной транзакции:

НачатьТранзакцию();
НачатьТранзакцию();
ОтменитьТранзакцию();
ЗафиксироватьТранзакцию();

20:43.385006-0,SDBL,5,process=1CV8,OSThread=12256,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Trans=1, Func=BeginTransaction, Context='ВнешняяОбработка.ВнешняяОбработка2.Форма.Форма.Форма : 3 : НачатьТранзакцию();'
20:43.385010-1,SDBL,5,process=1CV8,OSThread=12256,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Trans=1, Func=setRollbackOnly, Context='ВнешняяОбработка.ВнешняяОбработка2.Форма.Форма.Форма : 5 : ОтменитьТранзакцию();'
20:43.385013-8,SDBL,4,process=1CV8,OSThread=12256,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Trans=0,Func=Transaction, Func=RollbackTransaction, Context='ВнешняяОбработка.ВнешняяОбработка2.Форма.Форма.Форма : 6 : ЗафиксироватьТранзакцию();'
20:43.400000-14996,SDBL,3,process=1CV8,OSThread=12256,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Trans=0, Func=HoldConnection, Context='ВнешняяОбработка.ВнешняяОбработка2.Форма.Форма.Форма : 6 : ЗафиксироватьТранзакцию();'

Отмена "вложенной" неявной транзакции:

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
    // пример ошибки "В данной транзакции уже происходили ошибки" в неявной транзакции
    Попытка
        ДокументОбъект = Документы.Документ1.СоздатьДокумент();
        ДокументОбъект.ВызыватьОтказ = Истина;
        ДокументОбъект.Записать(РежимЗаписиДокумента.Проведение); // ломаем транзакцию
    Исключение
    КонецПопытки;
КонецПроцедуры

15:46.832029-_0,SDBL,5,process=1cv8,OSThread=16468,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Trans=1, Func=BeginTransaction
15:46.848001_1,SDBL,5,process=1cv8,OSThread=16468,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Trans=1, Func=setRollbackOnly, Context='Документ.Документ1.МодульОбъекта : 14 : ДокументОбъект.Записать(РежимЗаписиДокумента.Проведение); // ломаем транзакцию'
15:46.910004_0,EXCP,6,process=1cv8,OSThread=16468,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Exception=DataBaseException, Descr=В данной транзакции уже происходили ошибки!
15:46.910008_77980,SDBL,4,process=1cv8,OSThread=16468,Usr=DefUser, DBMS=DBV8DBEng, DataBase=InfoBase75, Trans=0, Func=Transaction, Func=RollbackTransaction

Формат записей ТЖ:

https:// /articles/технологический-журнал-анализ-логов/

Настройка logcfg.xml:

<?xml version="1.0" encoding="UTF-8"?>
<config xmlns="http://v8.1c.ru/v8/tech-log">
    <dump create="false" type="0" prntscrn="false"/>
    <log history="2" location="D:\Database\Log">
        <property name="all"/>
        <event>
            <eq property="name" value="SDBL"/>
            <eq property="func" value="setRollbackOnly"/>
        </event>
    </log>
</config>

Транзакции, как явные, так и неявные, могут быть вложенными. Обычный случай, например, запись элемента одного справочника из процедуры ПриЗаписи модуля другого справочника или из подписок на события, обрабатываемых внутри транзакции. Применение такого подхода при всем его удобстве, однако, может создавать проблемы производительности, поэтому пользоваться им надо аккуратно, а злоупотреблять, создавая каскады записывающихся друг из друга объектов, не стоит вообще. 

Если внутри транзакции произошла исключительная ситуация, она откатывается. Если внутри транзакции были вложенные транзакции или она сама являлась вложенной, откатываются все транзакции, независимо от того, на каком из уровней вложенности это произошло.

Проще говоря, никто не запрещает начинать одну транзакцию внутри другой, но ведет себя все это почти всегда как одна транзакция самого верхнего уровня, т. е. вложенные транзакции игнорируются. Нюансы поведения, связанные с отработкой некоторых ошибок в коде, приведены ниже.

Если исключительную ситуацию отработать с помощью скобок Попытка... Исключение... КонецПопытки, расположенных внутри транзакции, то транзакция не завершится в момент возникновения исключительной ситуации, она дойдет до
следующего обращения к данным – чтения или записи, продолжая при этом блокировать ресурсы, и откатится с сообщением: «В данной транзакции уже происходили ошибки!».

Если таких ошибок много и они начинают создавать проблемы пользователям, то без модификации кода, удаления этих скобок очень трудно найти, где они произошли и почему.

Описанное поведение системы позволяет говорить о том, что при возникновении ситуации, когда внутри транзакций нужно использовать скобки Попытка... Исключение... КонецПопытки, необходимо, отработав исключительную ситуацию, вызывать оператор ВызватьИсключение.

Случается, однако, что транзакция, встретившись с ошибкой, находящейся в скобках Попытка... Исключение... КонецПопытки, продолжает работу. Такое различие в поведении будет зависеть от типа исключительной ситуации. Исключительные ситуации бывают восстановимыми (после которых можно продолжить работу и завершить транзакцию) и невосстановимыми (после которых нельзя продолжить работу и завершить транзакцию, например, ошибка базы данных). Внешне это может выглядеть как зависимость от того, как код, вызвавший исключение, и скобки Попытка... Исключение... КонецПопытки расположены относительно ближайшей к ним транзакции.

Пример 1

НачатьТранзакцию();
    Попытка
        ЭтотОбъект.ВыполнитьНесуществующийМетод(); 
        // (такого метода у объекта не создавали)
    Исключение
        
    КонецПопытки;
 
    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ
    | ПлатежноеПоручение.Ссылка
    |ИЗ
    | Документ.ПлатежноеПоручение КАК ПлатежноеПоручение";
    
    Результат = Запрос.Выполнить();
    
    СпрСсылка = Справочники.Организации.НайтиПоКоду("000001");
    СпрОбъект = СпрСсылка.ПолучитьОбъект();
    СпрОбъект.НаименованиеПолное = ТекущаяДата(); 
    // это чтобы отследить, зафиксирована транзакция или нет
    СпрОбъект.Записать();
ЗафиксироватьТранзакцию();

Код выполнится. Транзакция успешно завершится. Исключительная ситуация оказалась расценена как восстановимая.

Пример 2

Сначала в процедуру ПриЗаписи модуля справочника Организации добавим строку:

ЭтотОбъект.ВыполнитьНесуществующийМетод(); 
// (такого метода у объекта не создавали)

Далее изменим код из примера 1:

НачатьТранзакцию();
    Попытка
        СпрСсылка = Справочники.Организации.НайтиПоКоду("000001");
        СпрОбъект = СпрСсылка.ПолучитьОбъект();
        СпрОбъект.НаименованиеПолное = ТекущаяДата(); 
        //это чтобы отследить, зафиксирована транзакция или нет
        СпрОбъект.Записать(); // неявная транзакция, там, как помним, ошибка
    Исключение
    
    КонецПопытки;
    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ
    | ПлатежноеПоручение.Ссылка
    |ИЗ
    | Документ.ПлатежноеПоручение КАК ПлатежноеПоручение";
    Результат = Запрос.Выполнить();

ЗафиксироватьТранзакцию();

Получим ошибку:

Ошибка при вызове метода контекста (Выполнить) 
Результат = Запрос.Выполнить();
По причине: Ошибка выполнения запроса. 
По причине: В данной транзакции уже происходили ошибки!

Исключительная ситуация, хотя она вызвана аналогичной строкой кода, потянула за собой дополнительные последствия (откат транзакции записи элемента справочника) и оказалась расценена как невосстановимая.

 Не рекомендуется:

Исключение

    ОтменитьТранзакцию();   

    СтруктураРезультат.Успех = Ложь;

    СтруктураРезультат.ОписаниеОшибки = ОписаниеОшибки();

    Возврат СтруктураРезультат;

КонецПопытки;

При переиспользовании такой функции/процедеры другими разработчиками на запись в ЖР обычно забивают - неумышленно или по незнанию как правильно использовать. В результате в ЖР нет лога ошибок, а прятать исключения от администартора v8std нам не разрашает. Поэтому рекомендую писать текст ошибки в ЖР сразу.

 Не следует передавать параметр при вызове исключение в блоке Исключение...КонецПопытки.

Неправильно:

Исключение

    ОтменитьТранзакцию();

    ИнформацияОбОшибке = ИнформацияОбОшибке();

    ЗаписьЖурналаРегистрации("Удаление файла в MinIO", УровеньЖурналаРегистрации.Ошибка, , ПрисоединенныйФайл, ПодробноеПредставлениеОшибки(ИнформацияОбОшибке));

    ВызватьИсключение ОписаниеОшибки(); // <- неправильно, потерян стек

КонецПопытки;

Для этого следует вызывать оператор ВызватьИсключение; без параметров. Это позволяет сохранить стек ошибок и передать изначальное исключение в неизменённом виде. Подробнее смотри статью //infostart.ru/1c/articles/1513676/

Правильно:

Исключение

    ОтменитьТранзакцию();

    ВызватьИсключение;

КонецПопытки;

При вызове оператора ВызватьИсклюение; не следует делать запись в журнал регистрации, так как это вызовет дублирование записей в журнале появятся 2 одинаковых записи. Неперехваченное исключение платформа сама делает запись в ЖР.

Исключение составляют случаи,
- когда исключение перехватывается на клиенте, где метод ЗаписьЖурналаРегистрации недоступен,
- или когда необходимо уточнить текст ошибки, дополнив его прикладной информацией
- или когда для подсистемы логируется имя события в ТЖ, типа "РаботаСФайлами.Удаление файла в MinIO".
Подробнее смотри: infostart: Шаблоны для применения cтандартов и методик разработки конфигураций 1С и ИТС: Перехват исключений в коде

Не следует использовать функцию ОписаниеОшибки, т.к. она неинформативна для разработчика, потому что не возвращает стек в тексте ошибки.

 При наличии нескольких обработчиков(потоков) на загрузку объектов из очереди следует учитывать ситуацию когда два сообщения с одним и тем же объектом но с разной версией данных может начать обрабатываться двумя потоками одновременно. Это вызовет состояние гонки и второй, более медленный поток не сможет обработать сообщение из-за изменившихся данных объекта (см. Оптимистическая блокировка).

Потоконебезопасный код:

Процедура Записать(Документ, Значение) Экспорт

    ДокументОбъект = Документ.ПолучитьОбъект();

    ДокументОбъект.Реквизит = Значение;

    ДокументОбъект.Записать(РежимЗаписиДокумента.Запись); // <- ошибка "нарушение целостности чтения объекта базы данных из-за параллельного изменения объекта другим сеансом"

КонецПроцедуры

Избежать ошибки можно организовав очередь к документу наложив явную управляемую блокировку перед записью документа.

Потокобезопасный код:

Процедура ЗаписатьСБлокировкой(Документ, Значение) Экспорт

    НачатьТранзакцию();

    Попытка

        Блокировка = Новый БлокировкаДанных;
        ЭлементБлокировки = Блокировка.Добавить();
        ЭлементБлокировки.Область = "Документ.РеализацияТоваровУслуг";
        ЭлементБлокировки.УстановитьЗначение("Ссылка", Документ);
        Блокировка.Заблокировать();

        ДокументОбъект = Документ.ПолучитьОбъект();
        ДокументОбъект.Реквизит = Значение;
        ДокументОбъект.Записать(РежимЗаписиДокумента.Запись);

        ЗафиксироватьТранзакцию();

    Исключение

        ОтменитьТранзакцию();
        ВызватьИсключение;

    КонецПопытки;

КонецПроцедуры

При успешном наложении блокировки и 2 поток будет ожидать, пока не отработает 1

Подробнее в статье: Разбор причины ошибки "Нарушение целостности чтения объекта базы данных из-за параллельного изменения объекта другим сеансом"

С точки зрения СУБД работа с транзакциями ограничивается командами BeginTransaction, CommitTransaction и RollbackTransaction, и об вложенности транзакций внутри 1С она ничего не знает. Таким образом один вызов ОтменитьТранзакцию() на уровне 1С откатывает всю транзакцию на уровне СУБД

Филиппов Е.В., Настольная книга 1С:Эксперта по технологическим вопросам. 2-е издание, с.48:

"Если внутри транзакции произошла исключительная ситуация, она откатывается. Если внутри транзакции были вложенные транзакции или она сама являлась вложенной, откатываются все транзакции, независимо от того, на каком из уровней вложенности это произошло. Проще говоря, никто не запрещает начинать одну транзакцию внутри другой, но ведет себя все это почти всегда как одна транзакция самого верхнего уровня, т. е. вложенные транзакции игнорируются."

Поэтому в результате выполнения ОтменитьТранзакцию() будут отменены и вложенная, и внешняя транзакция.

Филиппов Е.В., Настольная книга 1С:Эксперта по технологическим вопросам. 2-е издание, стр. 48-49:

"Если исключительную ситуацию отработать с помощью скобок Попытка... Исключение... КонецПопытки, расположенных внутри транзакции, то транзакция не завершится в момент возникновения исключительной ситуации, она дойдет до следующего обращения к данным –чтения или записи, продолжая при этом блокировать ресурсы, и откатится с сообщением: «В данной транзакции уже происходили ошибки!».

Если таких ошибок много и они начинают создавать проблемы пользователям, то без модификации кода, удаления этих скобок, очень трудно найти, где они произошли и почему. Описанное поведение системы позволяет говорить о том, что при возникновении ситуации, когда внутри транзакций нужно использовать скобки Попытка... Исключение... КонецПопытки, необходимо, отработав исключительную ситуацию, вызывать оператор ВызватьИсключение.

Случается, однако, что транзакция, встретившись с ошибкой, находящейся в скобках Попытка... Исключение... КонецПопытки, продолжает работу. Такое различие в поведении будет зависеть от типа исключительной ситуации. Исключительные ситуации бывают восстановимыми (после которых можно продолжить работу и завершить транзакцию) и невосстановимыми (после которых нельзя продолжить работу и завершить транзакцию, например, ошибка базы данных).

Пример 1

НачатьТранзакцию();
Попытка
ЭтотОбъект.ВыполнитьНесуществующийМетод();
// (такого метода у объекта не создавали)
Исключение
КонецПопытки;
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ПлатежноеПоручение.Ссылка
|ИЗ
| Документ.ПлатежноеПоручение КАК ПлатежноеПоручение";
Результат = Запрос.Выполнить();
СпрСсылка = Справочники.Организации.НайтиПоКоду("000001");
СпрОбъект = СпрСсылка.ПолучитьОбъект();
СпрОбъект.НаименованиеПолное = ТекущаяДата();
// это чтобы отследить, зафиксирована транзакция или нет
СпрОбъект.Записать();
ЗафиксироватьТранзакцию();

Код выполнится. Транзакция успешно завершится. Исключительная ситуация оказалась расценена как восстановимая.

Пример 2
Сначала в процедуру ПриЗаписи модуля справочника Организации добавим строку:

ЭтотОбъект.ВыполнитьНесуществующийМетод(); // (такого метода у объекта не создавали)

Далее изменим код из примера 1:

НачатьТранзакцию();
Попытка
СпрСсылка = Справочники.Организации.НайтиПоКоду("000001");
СпрОбъект = СпрСсылка.ПолучитьОбъект();
СпрОбъект.НаименованиеПолное = ТекущаяДата();
//это чтобы отследить, зафиксирована транзакция или нет
СпрОбъект.Записать(); // неявная транзакция, там, как помним, ошибка
Исключение
КонецПопытки;
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ПлатежноеПоручение.Ссылка
|ИЗ
| Документ.ПлатежноеПоручение КАК ПлатежноеПоручение";
Результат = Запрос.Выполнить();
ЗафиксироватьТранзакцию();

Получим ошибку:

Ошибка при вызове метода контекста (Выполнить)
Результат = Запрос.Выполнить();
По причине: Ошибка выполнения запроса.
По причине: В данной транзакции уже происходили ошибки!

Исключительная ситуация, хотя она вызвана аналогичной строкой кода, потянула за собой дополнительные последствия (откат транзакции записи элемента справочника) и оказалась расценена как невосстановимая."

Подытоживая, использование конструкции Попытка...Исключение...КонецПопытки внутри транзакции может быть бессмысленным (при невосстановимой исключительной ситуации транзакция все равно откатится), может быть оправданным (при восстановимой исключительной ситуации транзакция продолжится и зафсиксируется), а также скрывает источник возникновения ошибки, мешая понять, что на самом деле произошло.

 Рассмотрим пример в источнике: Филиппов Е.В., Настольная книга 1С:Эксперта по технологическим вопросам. 2-е издание, стр. 49: "Пример 1

НачатьТранзакцию();
Попытка
ЭтотОбъект.ВыполнитьНесуществующийМетод();
// (такого метода у объекта не создавали)
Исключение
КонецПопытки;
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ПлатежноеПоручение.Ссылка
|ИЗ
| Документ.ПлатежноеПоручение КАК ПлатежноеПоручение";
Результат = Запрос.Выполнить();
СпрСсылка = Справочники.Организации.НайтиПоКоду("000001");
СпрОбъект = СпрСсылка.ПолучитьОбъект();
СпрОбъект.НаименованиеПолное = ТекущаяДата();
// это чтобы отследить, зафиксирована транзакция или нет
СпрОбъект.Записать();
ЗафиксироватьТранзакцию();

Код выполнится. Транзакция успешно завершится. Исключительная ситуация оказалась расценена как восстановимая."

Поскольку данная транзакция выполнилась, нет никаких оснований для предположения, что транзакция, внешняя по отношению к данной, должна быть отменена. То есть на уровне общей транзакции исключительная ситуация также будет расценена как восстановимая. Необходимо иметь в виду, что при таком наличии внешней (общей) транзакции - фиксация транзакции из примера произойдет при фиксации общей транзакции.

Ответ на вопрос разобран в примере в источнике: Филиппов Е.В., Настольная книга 1С:Эксперта по технологическим вопросам. 2-е издание, стр. 49-50:
"Пример 2
Сначала в процедуру ПриЗаписи модуля справочника Организации добавим строку:

ЭтотОбъект.ВыполнитьНесуществующийМетод(); // (такого метода у объекта не создавали)

Далее изменим код из примера 1:

НачатьТранзакцию();
Попытка
    СпрСсылка = Справочники.Организации.НайтиПоКоду("000001");
    СпрОбъект = СпрСсылка.ПолучитьОбъект();
    СпрОбъект.НаименованиеПолное = ТекущаяДата();
    //это чтобы отследить, зафиксирована транзакция или нет
    СпрОбъект.Записать(); // неявная транзакция, там, как помним, ошибка
Исключение
КонецПопытки;
Запрос = Новый Запрос;
Запрос.Текст = 
    "ВЫБРАТЬ
    | ПлатежноеПоручение.Ссылка
    |ИЗ
    | Документ.ПлатежноеПоручение КАК ПлатежноеПоручение";
Результат = Запрос.Выполнить();
ЗафиксироватьТранзакцию();

Получим ошибку:

Ошибка при вызове метода контекста (Выполнить)
Результат = Запрос.Выполнить();
По причине: Ошибка выполнения запроса.
По причине: В данной транзакции уже происходили ошибки!

Исключительная ситуация, хотя она вызвана аналогичной строкой кода, потянула за собой дополнительные последствия (откат транзакции записи элемента справочника) и оказалась расценена как невосстановимая."