Появилась необходимость в формировании документа MS Word из макета, однако попытка использования COM-объекта на сервере не увенчалась успехом. Решено было обратиться к БСП.
Основная идея данной статьи - показать способ подстановки закладок в документ MS Word, но так как была использована и библиотека стандартных подсистем, решил сформировать документ ".docx" с её помощью и заодно составить шпаргалку для подобных задач.
Статья получилась достаточно громоздкая, поэтому cпрятал формирование документа с помощью БСП под спойлер.
Для нуждающихся приложена обработка, которую можно самостоятельно поковырять и разобрать, а я же, в свою очередь, поковыряю и разберу её в этой статье.
Для формирования закладок исходил из того, что файл, формируемый MS Word с расширением .docx, по сути, является архивом, содержащим xml файлы с данными и настройками основного файла. Если разархивировать его как обычный архив, он будет выглядеть следующим образом:
Сами же данные (в т.ч. и закладки) находятся в xml файле "document.xml", который, в свою очередь, находится в папке "word".
Таким образом, ныряем в код:
&НаСервере
Процедура СформироватьИПрисоединитьФайлыMSWord(ИмяМакета, КаталогСохранения, КаталогВременныхФайлов)
ПутиДляРаботыСФайлами = СформироватьПутиДляРаботыСФайлами(ИмяМакета, КаталогСохранения, КаталогВременныхФайлов);
// Формирование документа MS Word с использованием процедур БСП
СформироватьШаблонВMSWord(ПутиДляРаботыСФайлами.ПутьКФайлуШаблон, ИмяМакета);
// Заполнение закладок в созданном документе
ЗаполнитьЗакладкиКакZIP(ИмяМакета,
ПутиДляРаботыСФайлами.ПутьКФайлуШаблон,
ПутиДляРаботыСФайлами.ПутьКВыгрузкеДляАрхива,
ПутиДляРаботыСФайлами.ПутьКРедактируемомуФайлу,
ПутиДляРаботыСФайлами.ПутьКФайлуСЗакладками);
УдалитьФайлы(КаталогВременныхФайлов);
КонецПроцедуры
Первые две строчки процедуры были разобраны под спойлером, там же можно увидеть и изюминку формирования путей, для работы с xml файлами, а сейчас разберем процедуру "ЗаполнитьЗакладкиКакZIP".
Первым делом необходимо разархивировать полученный документ с расширением ".docx":
&НаСервере
Процедура ЗаполнитьЗакладкиКакZIP(ИмяМакета, ПутьКФайлуШаблон, ПутьКВыгрузкеДляАрхива, ПутьКРедактируемомуФайлу, ПутьКФайлуСЗакладками)
АрхивZip = Новый ЧтениеZipФайла(ПутьКФайлуШаблон);
АрхивZip.ИзвлечьВсе(ПутьКВыгрузкеДляАрхива, РежимВосстановленияПутейФайловZIP.Восстанавливать);
АрхивZip.Закрыть();
ОтредактироватьФайлTXT(ИмяМакета, ПутьКРедактируемомуФайлу);
НовыйАрхивZip = Новый ЗаписьZipФайла(ПутьКФайлуСЗакладками,,,МетодСжатияZIP.Копирование,УровеньСжатияZIP.Оптимальный,МетодШифрованияZIP.Zip20);
НовыйАрхивZip.Добавить(ПутьКВыгрузкеДляАрхива + "_rels\",РежимСохраненияПутейZIP.СохранятьОтносительныеПути,РежимОбработкиПодкаталоговZIP.ОбрабатыватьРекурсивно);
НовыйАрхивZip.Добавить(ПутьКВыгрузкеДляАрхива + "customXml\",РежимСохраненияПутейZIP.СохранятьОтносительныеПути,РежимОбработкиПодкаталоговZIP.ОбрабатыватьРекурсивно);
НовыйАрхивZip.Добавить(ПутьКВыгрузкеДляАрхива + "docProps\",РежимСохраненияПутейZIP.СохранятьОтносительныеПути,РежимОбработкиПодкаталоговZIP.ОбрабатыватьРекурсивно);
НовыйАрхивZip.Добавить(ПутьКВыгрузкеДляАрхива + "word\",РежимСохраненияПутейZIP.СохранятьОтносительныеПути,РежимОбработкиПодкаталоговZIP.ОбрабатыватьРекурсивно);
НовыйАрхивZip.Добавить(ПутьКВыгрузкеДляАрхива + "*.xml",РежимСохраненияПутейZIP.НеСохранятьПути,РежимОбработкиПодкаталоговZIP.НеОбрабатывать);
НовыйАрхивZip.Записать();
КонецПроцедуры
В теле данной процедуры мы сначала разархивируем файл, затем вызываем процедуру, редактирующую файл "document.xml", и, после, собираем его обратно в файл с расширением ".docx".
Переходим к процедурам, добавляющим закладки:
&НаСервере
Процедура ОтредактироватьФайлTXT(ИмяМакета, ПутьКРедактируемомуФайлу)
Текст = Новый ТекстовыйДокумент;
Текст.Прочитать(ПутьКРедактируемомуФайлу);
СтрокаXML = Текст.ПолучитьТекст();
//**********************************************************************************
// Вторым параметром передаем строку поиска, от которой будем отталкиваться
// w:name="ИмяЗакладки"
// для каждой последующей закладки увеличиваем id на 1
ВставитьЗакладку(СтрокаXML, "ДАТАРЕГ", "<w:bookmarkStart w:id=""1"" w:name=""ДатаРегистрации""/>", "<w:bookmarkEnd w:id=""1""/>");
ВставитьЗакладку(СтрокаXML, "РЕГНОМЕР", "<w:bookmarkStart w:id=""2"" w:name=""РегистрационныйНомер""/>", "<w:bookmarkEnd w:id=""2""/>");
//**********************************************************************************
Текст.УстановитьТекст(СтрокаXML);
Текст.Записать(ПутьКРедактируемомуФайлу);
КонецПроцедуры
&НаСервере
Процедура ВставитьЗакладку(СтрокаXML, СтрокаПоиска, ЗакладкаНачало, ЗакладкаКонец)
//**********************************************************************************
// Открытие закладки
ПозицияНайденнойСтроки = СтрНайти(СтрокаXML, СтрокаПоиска);
ПозицияВставкиНачалаЗакладки = СтрНайти(СтрокаXML, "<w:r", НаправлениеПоиска.СКонца, ПозицияНайденнойСтроки) - 1;
ЧислоСимволовСлева = ПозицияВставкиНачалаЗакладки;
ДлинаСтроки = СтрДлина(СтрокаXML);
ЧислоСимволовСправа = ДлинаСтроки - ПозицияВставкиНачалаЗакладки;
ТекстСлева = Лев(СтрокаXML, ЧислоСимволовСлева);
ТекстСправа = Прав(СтрокаXML, ЧислоСимволовСправа);
ТекстВставки = ЗакладкаНачало;
СтрокаXML = ТекстСлева + ТекстВставки + ТекстСправа;
//**********************************************************************************
// Закрытие закладки
ПозицияНайденнойСтроки = СтрНайти(СтрокаXML, СтрокаПоиска);
ПозицияВставкиКонцаЗакладки = СтрНайти(СтрокаXML, "</w:r>", НаправлениеПоиска.СНачала, ПозицияНайденнойСтроки) + СтрДлина("</w:r>") - 1;
ЧислоСимволовСлева = ПозицияВставкиКонцаЗакладки;
ДлинаСтроки = СтрДлина(СтрокаXML);
ЧислоСимволовСправа = ДлинаСтроки - ПозицияВставкиКонцаЗакладки;
ТекстСлева = Лев(СтрокаXML, ЧислоСимволовСлева);
ТекстСправа = Прав(СтрокаXML, ЧислоСимволовСправа);
ТекстВставки = ЗакладкаКонец;
СтрокаXML = ТекстСлева + ТекстВставки + ТекстСправа;
//**********************************************************************************
КонецПроцедуры
По-хорошему, стоит работать с xml файлами как, собственно, с xml файлами, открывая один на чтение, другой на запись, но до меня, к сожалению, не дошло как это можно сделать, поэтому решил работать с xml как с текстовой строкой.
В общем случае, сначала в строке ищем точку вхождения текста, куда нужно вставить закладку. В нашем случае это "ДАТАРЕГ" и "РЕГНОМЕР". Их мы передаем вторым параметром в процедуру "ВставитьЗакладку". Третий и четвертый параметры - это, соответственно, конструкции, которыми Word обозначает закладки, которые, мы, собственно, и вставляем в нужные места. В этих же конструкциях мы задаем id закладки (важно увеличивать для каждой последующей закладки id на 1) и имя закладки (ДатаРегистрации и РегистрационныйНомер в нашем случае).
В процедуре "ВставитьЗакладку" после того, как была найдена строка вхождения, в нужные места по тегам вставляются переданные конструкции открытия и закрытия закладки. Такие дела.
ХОЧУ ОБРАТИТЬ ВНИМАНИЕ, что не стоит называть текст вхождения по типу "&!ВхождениеТекста123!&". Дело в том, что Word по-своему записывает некоторые слова. Таким образом, множество знаков (&#$!,. и прч.) он, вероятно, сохранит в виде кодировки символа, а не непосредственно сам символ. Также длинные слова он может разделить на несколько. Визуально, в документе, это будет единое слово, но в xml файле оно будет разделено на несколько, что не позволит отыскать его. Так что для подобных изощрений имеет смысл поэкспериментировать и найти короткое слово.
Так это выглядит в MS Word:
Так это выглядит в xml: <w:t xml:space="preserve">РЕГНОМЕР</w:t>
Так это выглядит в MS Word:
Так это выглядит в xml: <w:t xml:space="preserve">егистрацонныйНомер</w:t>
Как можно видеть, знак амперсанда и букву "Р" Word где-то съел, закодировав по-своему.
На этом у меня всё, спасибо за внимание!
Вступайте в нашу телеграмм-группу Инфостарт