Пробуем отправлять уведомления с сервера на клиент в 8.3.26

12.08.25

Разработка - Механизмы платформы 1С

Новый механизм УведомленияКлиента из тестовой версии платформы 8.3.26.

Файлы

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование Скачано Купить файл
Демонстрационная внешняя обработка
.epf 7,18Kb
13 1 850 руб. Купить

Подписка PRO — скачивайте любые файлы со скидкой до 85% из Базы знаний

Оформите подписку на компанию для решения рабочих задач

Оформить подписку и скачать решение со скидкой

Введение

Некоторое время назад 1С выпустила тестовые релизы новой версии платформы 8.3.26. Среди прочего, в ней был реализован новый механизм "Уведомления клиента".

 

Теория

В глобальном контексте появилось новое свойство УведомленияКлиента, содержащее три метода:

  • ПодключитьОбработчик - назначает обработчик для входящего уведомления в клиентском коде;
  • ОтключитьОбработчик - отключает ранее подключенный обработчик;
  • ОтправитьУведомление - отправляет уведомление клиентским сеансам с сервера.

Уведомление может быть отправлено всем активным сеансам, либо определенному множеству сеансов. Для этого в ОтправитьУведомление можно передать массив номеров сеанса.

Также, в типе ФоновоеЗадание появилось новое свойство НомерРодительскогоСеанса. Его можно использовать, например, для отправки уведомлений о прогрессе выполнения длительной фоновой операции.

Разработчики заявляют, что механизм уведомлений клиента гарантирует доставку уведомления - уведомление не будет утеряно из-за временного обрыва соединения со стороны клиентского приложения или при падении рабочего процесса сервера 1С.

 

Пример использования

В качестве примера реализуем простейший мессенджер:

 

 

Подготовка клиентского кода

Пропишем подключение и отключение обработчика:

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	Обработчик = Новый ОписаниеОповещения("ПриПриемеСообщения", ЭтотОбъект);
	УведомленияКлиента.ПодключитьОбработчик("СообщениеПереписки", Обработчик);
КонецПроцедуры

&НаКлиенте
Процедура ПриЗакрытии(ЗавершениеРаботы)
	УведомленияКлиента.ОтключитьОбработчик("СообщениеПереписки");
КонецПроцедуры

 

Реализуем сам обработчик:

&НаКлиенте
Процедура ПриПриемеСообщения(ДанныеСообщения, ДополнительныеПараметры = Неопределено) Экспорт
	СтрСообщения = Сообщения.Вставить(0);
	СтрСообщения.Отправитель = ДанныеСообщения.Отправитель;
	СтрСообщения.Текст = ДанныеСообщения.Текст;
	СтрСообщения.Дата = МестноеВремя(ДанныеСообщения.Дата);
	
	Состояние(ДанныеСообщения.Отправитель + " пишет!",, ДанныеСообщения.Текст);
КонецПроцедуры

 

Реализация отправки и доставки сообщений

В обработчике кнопки "Отправить сообщение" ничего необычного - спрашиваем текст и вызываем некоторую серверную процедуру:

&НаКлиенте
Асинх Процедура НаписатьСообщение(Команда)
	Если Не ЗначениеЗаполнено(МоеИмя) Тогда
		ПоказатьПредупреждение(, "Чтобы написать сообщение, укажите свое имя");
		Возврат;
	КонецЕсли;
	
	Текст = Ждать ВвестиСтрокуАсинх("", "Наберите сообщение");
	Если Текст = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	НаписатьСообщениеНаСервере(МоеИмя, Текст);
КонецПроцедуры

 

А как отправить сообщение уже с сервера другим сеансам, в которых открыта эта же обработка? Записывать данные в какой-то регистр и стучаться в него раз в несколько секунд? Писать тонну кода для отправки и приема из системы взаимодействия? Нет, все гораздо проще:

&НаСервереБезКонтекста
Процедура НаписатьСообщениеНаСервере(Знач МоеИмя, Знач Текст)
	ДанныеСообщения = Новый Структура("Дата, Отправитель, Текст");
	ДанныеСообщения.Дата = ТекущаяУниверсальнаяДата();
	ДанныеСообщения.Отправитель = МоеИмя;
	ДанныеСообщения.Текст = Текст;
	
	УведомленияКлиента.ОтправитьУведомление("СообщениеПереписки", ДанныеСообщения);
КонецПроцедуры

 

В процедуре я подготовил произвольную структуру данных сообщения (в отличие от системы взаимодействия, я могу передавать не только строку) и вызвал УведомленияКлиента.ОтправитьУведомление. Т.к. я не передавал массив с номерами сеансов, уведомление отправится всем активным сеансам ИБ (включая текущий).

 

Демонстрация

Проверено на следующих конфигурациях и релизах:

  • Управление торговлей, редакция 11, релизы 11.5.18.46

Вступайте в нашу телеграмм-группу Инфостарт

платформа 8.3.26 уведомленияклиента

См. также

Механизмы платформы 1С Программист Бесплатно (free)

Разберем 15 мифов о работе платформы «1С:Предприятие 8» – как распространенных, так и малоизвестных. Начнем с классики: «Код, написанный в одну строку, работает быстрее, чем многострочный». Так ли это на самом деле?

16.07.2025    17398    TitanLuchs    99    

127

Механизмы платформы 1С Работа с интерфейсом Программист Стажер 1С v8.3 Бесплатно (free)

Про ООП в 1С и о том, как сделать свой код более кратким и выразительным при помощи использования текучего интерфейса (fluent interface).

03.02.2025    10806    bayselonarrend    126    

63

Механизмы платформы 1С WEB-интеграция Программист 1С v8.3 Бесплатно (free)

В платформе 8.3.27 появилась возможность использовать WebSocket-клиент. Давайте посмотрим, как это все устроено и чем оно нам полезно.

14.01.2025    17167    dsdred    77    

126

Механизмы платформы 1С Программист Стажер 1С v8.3 1C:Бухгалтерия Бесплатно (free)

Эта небольшая статья - некоторого рода шпаргалка по файловым потокам: как и зачем с ними работать, какие преимущества это дает.

23.06.2024    18941    bayselonarrend    22    

168

Механизмы платформы 1С Программист Стажер 1С v8.3 1C:Бухгалтерия Бесплатно (free)

Пример использования «Сервисов интеграции» без подключения к Шине и без обменов.

13.03.2024    10895    dsdred    22    

84

Механизмы платформы 1С Программист Стажер 1С v8.3 Бесплатно (free)

Все мы используем массивы в своем коде. Это один из первых объектов, который дают ученикам при прохождении обучения программированию. Но умеем ли мы ими пользоваться? В этой статье я хочу показать все методы массива, а также некоторые фишки в работе с массивами.

24.01.2024    39792    YA_418728146    35    

75
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. starik-2005 3188 26.07.24 15:37 Сейчас в теме
Вполне себе приличная реализация от 1Са данного функционала, который я как-то запилил левой пяткой. Так что плюс ))
livenebo2; rusrus; +2 Ответить
2. siamagic 27.07.24 04:14 Сейчас в теме
...Всегда делали через подключить обработчик ожидания который мониторил очередь, по коду строк столько же. Думаю под копотом оно же )
3. Igor_Ryaboff 101 27.07.24 20:35 Сейчас в теме
(2) После Вашего комментария появился интерес запустить Wireshark и глянуть, что за сетевой обмен идет с базой, если к ней подключиться через веб-клиент. Мне кажется, что под капотом сидит WebSocket-соединение. У 1С как раз были планы по внедрению поддержки WebSocket в следующих версиях платформы (прямо в 8.3.27, если я не ошибаюсь).
4. starik-2005 3188 29.07.24 11:54 Сейчас в теме
(3)
WebSocket
А зачем 1С-у вебсоекет для реализации подобного поведения, если тонкий клиент и так подоткнут к серверу через win/*nix-сокет? Просто добавили еще пару-тройку сигналов, предположу...
5. pchelov_ia 6 11.12.24 19:11 Сейчас в теме
Где храняться эти отправленные уведомления? Что будет, если сервер отправил уведомление, но клиент его ещё не успел получить, т.к. в этот момент отключили электричество? Потом при повторном входе в систему эти уведомления будут получены клиентом?
6. Igor_Ryaboff 101 14.01.25 10:33 Сейчас в теме
(5)
Где храняться эти отправленные уведомления? Что будет, если сервер отправил уведомление, но клиент его ещё не успел получить, т.к. в этот момент отключили электричество? Потом при повторном входе в систему эти уведомления будут получены клиентом?


Информация из ИТС (https://its.1c.ru/db/v8326doc/bookmark/dev/TI000002786):

С точки зрения доставки уведомлений, необходимо различать описываемый сервис и механизмы системы взаимодействия. Система взаимодействия позволяет отправить сообщение пользователю (пользователям) информационной базы вне зависимости от того, работает сейчас пользователь с информационной базой или нет. Уведомления клиентского приложения отправляются сеансу (сеансам) информационной базы, который должен ожидать поступление уведомлений (подписаться на обработку уведомлений). Система будет пытаться доставить уведомления всем сеансам, о которых имеется информация на момент отправки уведомления. Во время отправки уведомление записывается в специальное хранилище, в котором и будет находиться до момента получения адресатом или до удаления. Успешное выполнение метода ОтправитьУведомление() означает, что уведомление сохранено в хранилище. Уведомление удаляется из хранилища после того, как система «1С:Предприятие» теряет информацию о том сеансе, для которого предназначено уведомление. Обслуживанием хранилища уведомлений (доставкой уведомлений и очисткой хранилища) занимается:

● В клиент-серверном варианте информационной базы ‑ специальный сервис кластера.
● В файловом варианте информационной базы с прямым доступом ‑ любое клиентское приложение, подключенное к этой информационной базе.
● В файловом варианте информационной базы с доступном через веб-сервер ‑ расширение веб-сервера, обслуживающее публикацию.
7. user1475907 22.03.25 09:06 Сейчас в теме
Если так выкладывать информацию то никакой ИИ не сможет понять по вашим картинкам.
Это неприлично в наше время картинками выкладывать программный код.
8. askv 24 25.07.25 15:25 Сейчас в теме
(7) Почему же не сможет? В Я.Браузере есть команда на картинку "распознать текст" и она работает!
9. Igor_Ryaboff 101 12.08.25 13:34 Сейчас в теме
(7) Сорян, внес правку в статью)
10. WWWolfy 135 29.08.25 19:20 Сейчас в теме
Обнаружилась следующая ситуация.

Использовали уведомления для принудительного закрытия документов.
Т.е. чтобы удалённо закрыть документ, открытый у пользователя.
Для этого в форме документа стартовали в ПриОткрытии таким кодом:
УведомленияКлиента.ПодключитьОбработчик("Уведомление_Завершить", Обработчик);


В работе выяснилась такая ситуация:
если открыты два (или более) документа в одном сеансе пользователя и надо завершить более одного (например два),
то после закрытия первой формы вторая не получает Уведомлений.
Получается что при закрытии формы происходит отключение обработчика в целом для сеанса. При этом команду "ОтключитьОбработчик" не использовали.

Решение было таким - сделать имя Обработичка уникальным для каждого документа.
УведомленияКлиента.ПодключитьОбработчик("Уведомление_Завершить"+Объект.Номер, Обработчик)


Таким образом получили работоспособность в нескольких документах,
плюс упрощается уведомление - оно летит сразу в нужный документ.
Помимо номера можно использовать ID дока, например.
Для отправки сообщения требуется регистрация/авторизация