Исправление идентификаторов метаданных в конфигурации 1С

# language: ru
Функционал: Проверка предопределённых переключателей функциональности
	Как программист
	Я хочу запретить вручную создавать предопределённые элементы в релизном хранилище
	Чтобы при сравнении-объединении не дублировались элементы справочника

Сценарий: Получить идентификаторы предопределённых из release и master и сравнить их
    Когда Выполнить шелл скрипт получения предопределённых элементов
	Тогда Проверить идентичность идентификаторов

//Когда Выполнить шелл скрипт получения предопределённых элементов
//@ВыполнитьШеллСкриптПолученияПредопределённыхЭлементов()
Процедура ВыполнитьШеллСкриптПолученияПредопределённыхЭлементов() Экспорт
	КаталогПроекта = Лев(Ванесса.КаталогФич, Найти(Ванесса.КаталогФич, "\features")-1);
	
	СоздатьКаталог(КаталогПроекта + "\temp");
	УдалитьФайлы(КаталогПроекта + "\temp\release");
	
	//КаталогВременных = КаталогПроекта + "temp";
	ТекстКоманды = СтрШаблон("""C:\Program Files\Git\bin\bash.exe"" --cd=""%1"" -i -c ""git archive -o ./temp/release.zip origin/release ./src/cf/*/Predefined.xml""", КаталогПроекта);
	ЗапуститьПриложение(ТекстКоманды, КаталогПроекта, Истина);
	
	// появились файлы xml
	КаталогRelease = Новый Файл(КаталогПроекта + "\temp\release.zip");
	КаталогMaster = Новый Файл(КаталогПроекта + "\src\cf");
	
	Если НЕ КаталогRelease.Существует() Тогда
		ВызватьИсключение "Отсутствует каталог " + КаталогRelease.ПолноеИмя;
	КонецЕсли;
	
	// в версии 8.3.23 при попытке разархивировать пустой архив
	// возникает ошибка
	Попытка
		Архив = Новый ЧтениеZipФайла(КаталогRelease.ПолноеИмя); 
		Архив.ИзвлечьВсе(КаталогПроекта + "\temp\release",
		РежимВосстановленияПутейФайловZIP.Восстанавливать);
	Исключение
	КонецПопытки;

КонецПроцедуры

//Тогда Проверить идентичность идентификаторов
//@ПроверитьИдентичностьИдентификаторов()
Процедура ПроверитьИдентичностьИдентификаторов() Экспорт
	КаталогПроекта = Лев(Ванесса.КаталогФич, Найти(Ванесса.КаталогФич, "\features")-1);

	// появились файлы xml
	КаталогRelease = КаталогПроекта + "\temp\release";
	КаталогMaster = КаталогПроекта;
	
	ТаблицаПредопределённыхRelease = РаспарситьПредопределённые(КаталогRelease);
	ТаблицПредопределённыхMaster = РаспарситьПредопределённые(КаталогMaster);
	
	ТекстОшибки = "";
	Для Каждого ЭлементRelease Из ТаблицаПредопределённыхRelease Цикл
		Отбор = Новый Структура;
		Отбор.Вставить("ИмяФайла", ЭлементRelease.ИмяФайла);
		Отбор.Вставить("ИмяПредопределенныхДанных", ЭлементRelease.ИмяПредопределенныхДанных);
		Найденные = ТаблицПредопределённыхMaster.НайтиСтроки(Отбор);
		Если Найденные.Количество() <> 0 Тогда
			ЭлементMaster = Найденные[0];
			// сравним гуид в релизном и гуид в мастере
			Если ЭлементMaster.ИдентификаторМетаданных <> ЭлементRelease.ИдентификаторМетаданных Тогда
				 ТекстОшибки = ТекстОшибки
					+ ЭлементRelease.ИмяФайла +
					" - " + ЭлементRelease.ИмяПредопределенныхДанных
					+ ", ожидали " + ЭлементMaster.ИдентификаторМетаданных
					+ ", а получили " + ЭлементRelease.ИдентификаторМетаданных + Символы.ПС;
			КонецЕсли;
		КонецЕсли;
	КонецЦикла;
	Если ЗначениеЗаполнено(ТекстОшибки) Тогда
		ВызватьИсключение "Различаются идентификаторы предопределённых переключателей функциональности для релизного и мастера:
			| См. подробнее: https://wiki.rossko.ru/pages/viewpage.action?pageId=66363995 
			|" + ТекстОшибки;
	КонецЕсли;
КонецПроцедуры

// Парсинг Predefined.xml
//
// Пример входных данных:
//
//<?xml version="1.0" encoding="UTF-8"?>
//<PredefinedData xmlns="http://v8.1c.ru/8.3/xcf/predef" xmlns:v8="http://v8.1c.ru/8.1/data/core" xmlns:xr="http://v8.1c.ru/8.3/xcf/readable" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:type="CatalogPredefinedItems" version="2.6">
//	<Item id="c3ff4689-a1a3-430c-a51a-9244829f88f0">
//		<Name>АКласс</Name>
//		<Co de>000000001</Co de>
//		<Description>A - класс</Description>
//		<IsFolder>false</IsFolder>
//	</Item>
//
Функция РаспарситьПредопределённые(Каталог)
	тз = новый таблицазначений;
	тз.колонки.добавить("ИмяПредопределенныхДанных");
	тз.колонки.добавить("ИдентификаторМетаданных");
	тз.колонки.добавить("ИмяФайла");
	
	тз.Индексы.Добавить("ИмяПредопределенныхДанных");
	
	МассивФайлов = НайтиФайлы(Каталог + "\src\cf", "Predefined.xml", Истина);
	Для Каждого ТекФайл Из МассивФайлов Цикл
		ПутьФайла = Сред(ТекФайл.ПолноеИмя, СтрНайти(ТекФайл.ПолноеИмя, "\src\cf"));
		Парсер = Новый ЧтениеXML;
	    Парсер.ОткрытьФайл(ТекФайл.ПолноеИмя);
		Пока Парсер.Прочитать() Цикл
			Если 
	            Парсер.ТипУзла = ТипУзлаXML.НачалоЭлемента И Парсер.Имя = "Item"
	        Тогда
	            Название = Парсер.ЗначениеАтрибута("id");
	            Если Название <> Неопределено Тогда
	                //Сообщить("== " + Название + " ==");
					Парсер.Прочитать();
					Если Парсер.ТипУзла = ТипУзлаXML.НачалоЭлемента И Парсер.Имя = "Name" тогда
						Парсер.Прочитать();
	                    Если Парсер.ТипУзла = ТипУзлаXML.Текст Тогда
	                        //Сообщить(Парсер.Значение);
							НоваяСтрока = тз.ДОбавить();
							НоваяСтрока.ИдентификаторМетаданных = Название;
							НоваяСтрока.ИмяПредопределенныхДанных = Парсер.значение;
							НоваяСтрока.ИмяФайла = ПутьФайла;
	                    КонецЕсли;                
					КонецЕсли;
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;
	КонецЦикла;
	Возврат ТЗ;
КонецФункции