Как использовать ПоказатьВопрос в обработчике формы ПередЗаписью

Публикация № 372973

Разработка - Практика программирования

ПоказатьВопрос ПередЗаписью рефакторинг модальность

В данной статье будет рассмотрен пример, как без модальных методов задать вопрос пользователю в обработчике формы ПередЗаписью. В ИТС (http://its.1c.ru/docs/v8nonmodal/) есть конкретные примеры по уходу от модальных окон, но в теме «Вопрос в обработчике формы ПередЗаписью» нет конкретного примера, а есть только общая информация, куда надо двигаться при решении данной задачи.

Вступление

Для чего вообще стоит отказываться от модальности и, например, Вопрос заменять на ПоказатьВопрос?  Всё дело в том, что больше года назад 1С-ники объявили «войну» модальным окнам. Исключение составляют только те, у кого самописная конфигурация, работа с которой не будет вестись на IPad, в режиме сервиса или с помощью веб-клиента. А если у вас обычная Бухгалтерия 3.0 и вы не собираетесь бухгалтеру давать доступ к базе через IPad, всё равно вам придётся заменить все модальные методы на немодальные, т.к. рано или поздно «Режим использования модальности» станет «Не использовать»!

Что же думает по предлагаемому вопросу специалисты фирмы 1С? Для начала можно посмотреть на тему «Вопрос в обработчике формы ПередЗакрытием»:

Особенность диалога с пользователем в этом (и многих других) обработчиках заключается в том, что в зависимости от реакции пользователя принимается решение: продолжать дальнейшие действия, или отказаться от них. Для этого используется параметр процедуры Отказ. При одном ответе пользователя мы отказываемся от продолжения (Отказ = Истина). При другом ответе пользователя - продолжаем дальнейшие действия.

В данном случае сложность заключается в том, что ответ пользователя мы узнаем уже после того, как выйдем из контекста этого обработчика. В процедуре, обрабатывающей оповещение. А параметр Отказ нужно установить именно в этом обработчике.

Поэтому мы действуем в два приёма:

В первый раз безусловно отменяем дальнейшие действия (Отказ = Истина) и выводим вопрос пользователю;

В обработчике оповещения, в зависимости от реакции пользователя, либо снова программно закрываем форму, либо ничего не делаем.

Проблема заключается в том, что обработчик ПередЗакрытием будет выполнен два раза. И чтобы отличить первое его выполнение от второго (когда ответ пользователя уже известен) мы используем клиентскую переменную ВыполняетсяЗакрытие в качестве флага.

В первый проход её значение равно Ложь, и это значит, что нужно отказаться от закрытия и задать вопрос. Во второй проход её значение равно Истина, и это значит, что вопрос задавать не надо:

&НаКлиенте
Перем ВыполняетсяЗакрытие;
 
&НаКлиенте
Процедура ПередЗакрытием(Отказ, СтандартнаяОбработка)
        
         Если Не ВыполняетсяЗакрытие Тогда
                   Отказ=Истина;
                   ПоказатьВопрос(Новый ОписаниеОповещения("ПередЗакрытиемЗавершение", ЭтотОбъект),
                                                        "Закрывать форму?", РежимДиалогаВопрос.ДаНет);
         КонецЕсли;
        
КонецПроцедуры
 
&НаКлиенте
Процедура ПередЗакрытиемЗавершение(РезультатВопроса, ПараметрыЗаписи) Экспорт
        
         Если РезультатВопроса = КодВозвратаДиалога.Да Тогда
                   ВыполняетсяЗакрытие = Истина;
                   Закрыть();
         КонецЕсли;
        
КонецПроцедуры

ВыполняетсяЗакрытие = Ложь;

Этот пример схож с нашей темой и очень часто на него ссылаются в теме «ПоказатьВопрос в обработчике формы ПередЗаписью»:

В обработчике события формы ПередЗаписью также может возникнуть потребность задать вопрос. Как и в предыдущем примере. Однако здесь вопрос так просто не решается. Отличие заключается в следующем.

В предыдущем примере, оказываясь в обработчике ПередЗакрытием, мы однозначно знали действие, которое должно быть выполнено. Это закрытие формы. Поэтому в обработке оповещения мы смело писали Закрыть().

Но в обработчике ПередЗаписью мы такой однозначной информации не имеем. В этом обработчике мы можем оказаться по двум причинам: если пользователь нажал Записать, или если он нажал Записать и закрыть. То есть дальнейший сценарий действий нам неизвестен. Определить его стандартными способами, находясь внутри этого обработчика, мы не можем.

Поэтому тут можно предложить три варианта, но все они, к сожалению, обладают недостатками:

* Изменить логику прикладного решения так, чтобы не было диалога с пользователем в этом обработчике. Это не всегда возможно;

* В обработке оповещения с помощью собственной блокирующей формы задавать пользователю развернутый вопрос, предполагающий точное описание дальнейших действий: Отказаться?, Только записать?, Записать и закрыть? Это может выглядеть не очень красиво, ведь пользователь уже нажал "Записать и закрыть", а его опять об этом спрашивают;

* Не использовать стандартные команды формы Записать, "Записать и закрыть". Вместо них создать собственные команды, в которых и выполнять необходимые алгоритмы. Создание собственных команд потребует дополнительных трудозатрат.

Задача сложная, поэтому разработчики при задании вопроса ПередЗаписью, в первую очередь рекомендуют отказаться от этой идеи…

Дальше предлагают задать вопрос с множеством вариантов: «Отказаться, Только записать, Записать и закрыть». Помимо описанного минуса (пользователь и так уже заранее выбрать вариант, а его тут ещё раз спрашивают) есть ещё: в ПередЗаписью программа могла попасть и из «Отмена проведения». Т.е. надо добавлять ещё кнопку? Мне кажется этот вариант некрасивым.

Остаётся только третий вариант с использованием нестандартных команд формы. Его мы и будем реализовывать. И не стандартной командой у нас будет только «Провести и закрыть». Как и в примере к теме «Вопрос в обработчике формы ПередЗакрытием», нам придётся при первом заходе давать Отказ = Истина, и только во втором заходе выполнять реальную запись. И ещё нам где-то нужно будет запоминать, что это именно второй заход в процедуру «ПередЗаписью». 1С-ники предложили это сделать через общую клиентскую переменную, в рассматриваемом примере это можно сделать через ПараметрыЗаписи.

 

Пример использования ПоказатьВопрос в обработчике формы ПередЗаписью

1. Сначала нам нужно убрать стандартную команду «Провести и закрыть» из формы и создать свою команду и кнопку.

1.А. Если у вас уже кнопка «Провести и закрыть» не типовая – вам повезло, можете смело приступать к п. 2.

1.Б. Стандартная команда убирается через Свойства формы – Состав команд – Снимаем ненужную команду. Как добавлять команду и кнопку на форму, я не буду описывать, только напомню, что кнопку «Провести и закрыть» необходимо сделать кнопкой по умолчанию.

1.В. Теперь вариант сложнее в реализации, но проще в сопровождении типовой конфигурации. Практически в каждом обновлении Бухгалтерии программисты умудряются изменить 10-50% форм документов, поэтому в типовой конфигурации для сопровождения проще кодом убрать стандартную кнопку и добавить свою команду и кнопку.

Для начала в обработчике формы «ПриОткрытии» необходимо убрать стандартную кнопку «ПровестиИЗакрыть».

Элементы.ФормаПровестиИЗакрыть.Видимость = Ложь;

Замечание: у пользователя с большими ограничениями к документу в платформе 8.3.7 вообще не появляется кнопка "Провести и закрыть". Поэтому для платформы 8.3.7 корректней писать код:

	Если Элементы.Найти("ФормаПровестиИЗакрыть")<>Неопределено Тогда
		Элементы.ФормаПровестиИЗакрыть.Видимость = Ложь;
	КонецЕсли;

Дальше добавляем команду и кнопку в обработчике формы «ПриСозданииНаСервере»::

НоваяКоманда1 = ЭтаФорма.Команды.Добавить("ПровестиИЗакрыть2");
НоваяКоманда1.Действие = "ПровестиИЗакрыть";
НовыйЭлемент = Элементы.Добавить("ФормаПровестиИЗакрыть2" , Тип("КнопкаФормы"), Элементы.ФормаКоманднаяПанель);
НовыйЭлемент.Заголовок = "Провести и закрыть";
НовыйЭлемент.ИмяКоманды = НоваяКоманда1.Имя;
НовыйЭлемент.КнопкаПоУмолчанию = Истина;
Элементы.Переместить(НовыйЭлемент,НовыйЭлемент.Родитель,Элементы.ГруппаКнопкиКоманднойПанели);

Соответственно в этом коде заложены типовые наименования для ФормаДокументаОбщая документа «Поступление (акты, накладные)» (например Элементы.ГруппаКнопкиКоманднойПанели), которые в каждом конкретном случае необходимо будет менять на свои.

2. Дальше нам нужно в процедуру на новую кнопку «Провести и закрыть» написать код:

&НаКлиенте
Процедура ПровестиИЗакрыть(Команда)
 
         ПараметрыЗаписи = Новый Структура();
         ПараметрыЗаписи.Вставить("РежимЗаписи", ПредопределенноеЗначение("РежимЗаписиДокумента.Проведение"));
         ПараметрыЗаписи.Вставить("Закрыть", Истина);
        
         Если Записать(ПараметрыЗаписи) Тогда
              Закрыть();
         КонецЕсли;
        
КонецПроцедуры

Как я писал выше, мы будем обмениваться информацией между нашими процедурами через ПараметрыЗаписи. В ПередЗаписью мы не знаем, нажали мы «Записать», «Провести» или «Провести и закрыть», для этого в параметрах мы передаём параметр Закрыть. Если в параметрах записи есть этот параметр, значит надо закрыть форму после успешной записи.

3. Допустим, нам надо задавать вопрос не всегда, а только когда документ проведён. Теперь мы в процедуру «ПередЗаписью» добавляем (если эта процедура не существовала – создаём) новый код:

         Если Не ПараметрыЗаписи.Свойство("ВопросЗадан") И Объект.Проведен Тогда
                   Отказ = Истина;
                   Оповещение = Новый ОписаниеОповещения("ПоказатьВопросЗавершение", ЭтаФорма, ПараметрыЗаписи);
                   ТекстВопроса = "Данный документ уже проведён. Вы действительно хотите перепровести или отменить проведение документа?";
                   ПоказатьВопрос(Оповещение, ТекстВопроса, РежимДиалогаВопрос.ДаНет, 20, КодВозвратаДиалога.Нет,, КодВозвратаДиалога.Нет);
         КонецЕсли;

Свойство «ВопросЗадан» мы будем заполнять в оповещении, чтобы узнавать, когда в процедуру «ПередЗаписью» мы зашли во второй раз (в примере 1С в процедуре ПередЗакрытием это делалось через переменную «ВыполняетсяЗакрытие»). Другими словами: в структуре «ПараметрыЗаписи» есть свойство «ВопросЗадан», значит, вопрос уже задавали, и пользователь уже ответил утвердительно, если же свойства нет, значит, в процедуре «ПередЗаписью» мы первый раз.

После метода ПоказатьВопрос можно ещё написать «Возврат», если у вас есть ещё какой-то код в процедуре «ПередЗаписью», выполняемый после вопроса.

4. Создаём процедуру «ПоказатьВопросЗавершение», в которую программа будет входить, когда пользователь ответит на вопрос (или произошёл таймаут).

&НаКлиенте
Процедура ПоказатьВопросЗавершение(Результат, ПараметрыЗаписи) Экспорт
        
         Если Результат = КодВозвратаДиалога.Да Тогда
                   ПараметрыЗаписи.Вставить("ВопросЗадан", Истина);
                   Если Записать(ПараметрыЗаписи) И ПараметрыЗаписи.Свойство("Закрыть") Тогда
                            Закрыть();
                   КонецЕсли;
         КонецЕсли;
        
КонецПроцедуры

В этой процедуре мы и используем переданное ранее свойство «Закрыть». Если свойства нет, значит, закрывать не надо. 

5. Теперь нам надо обработать нажатие «крестика» пользователем. Для этого нам нужна обработчик формы «ПередЗакрытием». Если его нет, то его можно создать на форме «ручками» или программно в обработчике «ПриСозданииНаСервере»:

         ЭтаФорма.УстановитьДействие("ПередЗакрытием","ПередЗакрытием");

Далее добавляем код в ПередЗакрытием и создаём ещё одну процедуру:

&НаКлиенте
Процедура ПередЗакрытием(Отказ, СтандартнаяОбработка)
        
         Если Модифицированность Тогда
                   Отказ = Истина;
                   ТекстВопроса = НСтр("ru = 'Данные были изменены. Сохранить изменения?'");
                   Оповещение = Новый ОписаниеОповещения("ВопросПередЗакрытиемЗавершение", ЭтотОбъект);
                   ПоказатьВопрос(Оповещение, ТекстВопроса, РежимДиалогаВопрос.ДаНетОтмена);
         КонецЕсли;
        
КонецПроцедуры
 
&НаКлиенте
Процедура ВопросПередЗакрытиемЗавершение(Результат, ДополнительныеПараметры) Экспорт
        
         Если Результат = КодВозвратаДиалога.Да Тогда
                   ПараметрыЗаписи = Новый Структура();
                   ПараметрыЗаписи.Вставить("Закрыть", Истина);
                   Если Записать(ПараметрыЗаписи) Тогда
                            Закрыть();
                   КонецЕсли;
         ИначеЕсли Результат = КодВозвратаДиалога.Нет Тогда
                   Модифицированность = Ложь;
                   Закрыть();
         КонецЕсли;
        
КонецПроцедуры

Получается, что пользователь когда нажал крестик ответит сначала на вопрос «Сохранить изменения?» и потом задастся ещё вопрос, который у вас прописан «ПередЗаписью». Если вас это не устраивает, можно передать параметр «ВопросЗадан» в «ВопросПередЗакрытиемЗавершение» и тогда второго вопроса не будет.

 

Вопрос против ПоказатьВопрос

А как бы мы решили задачу, если бы можно было использовать модальные вызовы? А очень просто, мы бы написали в процедуре «ПередЗаписью» следующий код:

         Если Объект.Проведен Тогда
                   ТекстВопроса = "Данный документ уже проведён. Вы действительно хотите перепровести или отменить проведение документа?";
                   Ответ = Вопрос(ТекстВопроса,РежимДиалогаВопрос.ДаНет,20,КодВозвратаДиалога.Нет,,КодВозвратаДиалога.Нет);
                   Если Не Ответ=КодВозвратаДиалога.Да Тогда
                            Отказ = Истина;
                            Возврат;
                   КонецЕсли;
         КонецЕсли;

И всё! Никаких «заморочек» типа «А что пользователь нажал: Провести или ПровестиИЗакрыть?». И ещё надо будет отработать нажатие крестика в «ПередЗакрытием».

 

 

P.s.

Изначально похожий код я реализовывал у себя в Бухгалтерии предприятия 3.0. Задача заключалась в следующем: при определённом наборе условий (это не одно условие Объект.Проведен, как указано в примере в данной публикации) из ФормаДокументаОбщая документа ПоступлениеТоваровУслуг спрашивать дополнительно подтверждения его действий. Ниже перечислены нюансы, которые мне не пришлось обходить, т.к. не подпадали под задачу.

В обработчик формы «ПередЗаписью» программа не заходит, если: 1) пользователь нажал на кнопку «Пометить на удаление / снять пометку»; 2) если пользователь нажал на не проведённом документе кнопку «ДТ/КТ».  И это не всё: если вы на форме документа создали всё, как я написал, и пользователь из формы списка перепроведёт документ – то никаких вопросов программа ему не задаст. Необходимо все интересующие вас кнопки на форме списка заменять на свои и отслеживать действия пользователя. Ещё у документа может быть не одна форма документа, а несколько (например, документ ПоступлениеТоваровУслуг в БП 3.0, где 3 формы: общая, товары и услуги). В каждой форме документа надо написать много кода…

В связи с кучей нюансов остаётся актуальным первый совет от 1С (который сначала, без подробного вникания в задачу, может вызвать улыбку): «Изменить логику прикладного решения так, чтобы не было диалога с пользователем в этом обработчике».

 

Специальные предложения

Лучшие комментарии
4. Поручик 4428 03.07.15 09:43 Сейчас в теме
В форме контрагента в бухгалтерии 3.0 последних релизов тоже используется вопрос перед записью примерно по описанной методике.
brunen9; serg__k; klinval; +3 Ответить
Остальные комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Fragster 1019 02.07.15 11:22 Сейчас в теме
Сколько уже лучей любви послано в торону 1с по поводу этой "асинхронности". по факту ни для пользователя, ни для программиста. Более того, если попробовать использовать асинхронность, например для параллельного помещения файлов, или нескольких подтверждений пользователя - легко получаем вылеты платформы.
Всю эту "асинхронность ради гуглохрома и айпада" можно было от прикладных 1с программистов спрятать, что обеспечило бы намного более высокую обратную совместимость для внешних обработок и подсистем.
user597231_DNorov; dorstroy-rnd; koltunov.sp; creatermc; tiniji; Krio2; orfos; MoshkovEV; babys; Serg3141; 7OH; logos; yuri76; bow; veretennikoff; wolfsoft; andogskiy; ffgnebel; bulpi; +19 Ответить
2. klinval 296 02.07.15 12:12 Сейчас в теме
(1) Fragster, А что поделать, приходится исходить (кодить) из того что дают...
"Лучи любви" очень обильно можно наблюдать в статье http://infostart.ru/public/302910/ (не везде я со статьёй согласен, но в целом автор пишет верно). Кому интересна тема модальности - рекомендую прочитать статью и коменты под ней.
3. webester 32 03.07.15 05:15 Сейчас в теме
(1)
Сколько уже лучей любви послано в торону 1с по поводу этой "асинхронности"

Лучи добра, заключались в основном в "опять надо писать по новому, почему нельзя писать по старому", всегда слышу это нытье при вводе чего то нового и удивляюсь когда не слышу. Насчет "спрятать" логику от программиста, не понимаю зачем это делать? Явное лучше неявного и по моему там все логично и просто.
6. klinval 296 03.07.15 12:10 Сейчас в теме
(3) webester, всё это спорно... В комментариях к статье вы с автором статьи долго спорили по этому вопросу. Не хотелось бы начинать спор заново, но всё-таки поправлю вас:
Лучи добра, заключались в основном в "опять надо писать по новому, почему нельзя писать по старому", всегда слышу это нытье при вводе чего то нового и удивляюсь когда не слышу.

Вы слышали негатив по поводу введения СтрНайти() вместо Найти()? Тоже новшество, писать надо по новому, но никто не "ноет", потому что это новое лучше старого и не требует больших трудозатрат (по сравнение со старым методом). А ПоказатьВопрос вместо Вопрос предполагает большее количество кода + общее ухудшение читабельности. Я не пишу, что мне прям так уж плохо читать стало код с ПоказатьВопрос, но однозначно читабельность ухудшилась. А количество кода (и количество заморочек/трудностей) у ПоказатьВопрос в сравнении с Вопрос вы можете увидеть из моей статьи. И всё это ради чего? Чтобы пользователь мог работать на Ipad с 1С?
Я смирился с новой реальностью: теперь нужно использовать новые не модальные методы. Я не посылаю "лучи добра" 1С-никам, но в то-же время и не считаю что они сделали лучше чем было.
AnderWonder; 7OH; +2 Ответить
8. Fragster 1019 03.07.15 17:27 Сейчас в теме
(3) почему было не сделать на время "модального" вызова сохранение состояния в "стек" и по завершении - его восстановление? А теперь приходится писать две версии обработки - с использованием модальности, и без. писать в 1,5-2 больше кода и т.п.

Предыдущее возмущение было связано с "изменение данных формы не допустимо" и костылем копироватьДанныеФормы (когда хочется не весь контекст обработать на сервере - функция с передачей данных формы по значению, изменением и возврата их копии, и потом копирования их в исходные данные формы), но текущая боль при необходимости использования цепочки асинхронных вызовов или асинхронных вызовов в цикле, или использования диалога в функции, которая раньше возвращала значение на основе данных пользователя (или добавление ввода данных пользователя в подобную функцию, которая используется в куче мест). Или когда необходимость в вводе данных пользователя не определена. Обслуживающего кода реально становится больше, чем работающего с бизнес логикой.
9. wolfsoft 2423 08.07.15 14:14 Сейчас в теме
(3) webester,
Лучи добра, заключались в основном в "опять надо писать по новому, почему нельзя писать по старому"

Да-да, нашим аборигенам обязательно надо чтоб по-новому. Без этого никак, ага.

Насчет "спрятать" логику от программиста, не понимаю зачем это делать? Явное лучше неявного и по моему там все логично и просто.


Так зачем же вы на 1С программируете? Пишите в машинных кодах. 1С скрывает от вас очень многое, вы не в курсе?

Прорыв 1С в своё время был основан именно на том, что она скрыла ненужное и предоставила удобную платформу для создания бизнес-приложений. Если бы не это, писали бы на других языках, а не на 1с - 100%. Даже в своих типовых 1С уже прикручивает целую кучу стандартных процедур и функций, чтобы обходить ограниченность своей же платформы. Хотя всё то же самое можно было реализовать на уровне платформы, и работало бы это значительно быстрее.
AnderWonder; artemka; andogskiy; logos; veretennikoff; +5 Ответить
4. Поручик 4428 03.07.15 09:43 Сейчас в теме
В форме контрагента в бухгалтерии 3.0 последних релизов тоже используется вопрос перед записью примерно по описанной методике.
brunen9; serg__k; klinval; +3 Ответить
7. klinval 296 03.07.15 14:16 Сейчас в теме
(4) Поручик, спасибо за наводку, не заметил, что 1С-ники в БП 3.0 уже используют ПоказатьВопрос ПередЗаписью. Они там обошли ситуацию с нажатием крестика, а я не знал как это сделать. Позже дополню статью.
(5) DitriX. Честно признаюсь: механизм расширения конфигурации ещё не пробовал, но официальное описание и статьи на Инфостарте читал. Есть сомнения, что станет проще обновляться, если мы реализуем этот код через расширения. Точнее сказать обновлять то станет проще, но может быть мы упустим какое-либо изменение, например очередное изменение кнопки "Провести и закрыть" со стандартной на нетиповую (и наоборот) - тогда у пользователя появится 0 или 2 кнопки "Провести и закрыть" (в зависимости от варианта изменения)
5. DitriX 1824 03.07.15 11:20 Сейчас в теме
А можно использовать расширение конфигурации :)
10. androgin 08.07.15 20:33 Сейчас в теме
ужасный код!
и 1С не объявляла никому войны с модальными окнами, а всего лишь подстроилась под веб-технологии.
veretennikoff; +1 1 Ответить
12. klinval 296 09.07.15 09:25 Сейчас в теме
(10) androgin,
ужасный код!

Не совсем понял к кому эти слова: ко мне или к разработчикам платформы, которые заставляют нас так писать? Если ко мне, то опишите конкретно где ошибка и я подправлю статью.
11. DrAku1a 1315 09.07.15 01:58 Сейчас в теме
Может не совсем в тему, но
Для начала можно посмотреть на тему «Вопрос в обработчике формы ПередЗакрытием»
- как реализовать этот вопрос для формы, которая выведена на рабочий стол. Ведь для такой формы нельзя использовать метод "Закрыть()"
13. klinval 296 09.07.15 09:26 Сейчас в теме
(11) DrAku1a,
как реализовать этот вопрос для формы, которая выведена на рабочий стол. Ведь для такой формы нельзя использовать метод "Закрыть()"

К сожалению не сталкивался с конкретно этой проблемой, поэтому не могу подсказать... Думаю есть смысл на форуме создать тему - может кто поможет.
14. veretennikoff 31 16.11.15 12:10 Сейчас в теме
Я реализовал без создания доп кнопок. Вроде бы работает.

1. Создаете переменную на клиенте, называете ее например ЗаписьРазрешена
2. Инициализируете ее в модуле формы значением Ложь
3. В обработчике ПередЗаписью() в зависимости от значения этой переменной вы продолжаете выполнение кода в нормальном режиме или ставите Отказ в Истина и задаете вопрос пользователю
Если ЗаписьРазрешена Тогда
	ЗаписьРазрешена = Ложь;
	// продолжим в нормальном режиме
Иначе 
	Отказ = Истина;
	// диалог пользователю
КонецЕсли;
Показать

4. В обработчике оповещения об ответе пользователя при согласии пользователя записать документ изменяем нашу переменную и вызываем запись документа еще раз
Если Не РезультатВопроса = КодВозвратаДиалога.Нет Тогда
	ЗаписьРазрешена = Истина;
	Записать();
КонецЕсли;

5. Профит

P.S.: в 3 можно добавить дополнительное условие на режим записи документа (например мне нужно было исключить проверку для режима отмены проведения)
Если Не ПараметрыЗаписи.РежимЗаписи = РежимЗаписиДокумента.ОтменаПроведения Тогда 
	Если ЗаписьРазрешена Тогда
...


Принимаю замечания
15. klinval 296 16.11.15 12:41 Сейчас в теме
(14) veretennikoff,
Я реализовал без создания доп кнопок. Вроде бы работает.

Нажимаете вы кнопку "Провести и закрыть" у вас задаётся вопрос. Ответ - "да" - записывается, но форма не закрывается. Я прав?

Кнопка нужна только для того чтобы отслеживать, что пользователь нажал "Записать" или "Записать и закрыть". Кодом никак ПередЗаписью это не увидеть. Поэтому если кнопка изначально типовая - придётся её добавлять... Или мириться с тем, что "Записать и закрыть" не закрывает форму.

Что касается:
Создаете переменную на клиенте, называете ее например ЗаписьРазрешена

Работать будет, но зачем плодить новые сущности, если и так есть "ПараметрыЗаписи"?
16. veretennikoff 31 16.11.15 14:14 Сейчас в теме
(15)
Согласен
Невнимательно прочитал, что вам нужно именно отслеживать, какая кнопка была нажата: Записать или Записать и закрыть
ИМХО: преимущественно пользуются кнопкой Записать и закрыть , а не Записать, поэтому можно закрывать форму тоже программно
(в итоге конечно все зависит от того, какие кнопки нажимают пользователи)
17. HystriX 10.11.16 08:38 Сейчас в теме
Спасибо за статью и советы, взял образец из Бухгалтерии 3.0. Однако у этого метода есть недостаток - при такой нестандартной обработке команды "Записать и закрыть" платформа автоматом не выдает стандартное затухающее оповещение о перезаписи в углу. По крайней мере, так дело обстоит на 8.3.5.
18. ProDeveloper 23.11.17 11:29 Сейчас в теме
Странные решения. Если курить мануал https://its.1c.ru/db/metod8dev/content/5272/hdoc, то есть же метод ВыполнитьОбработкуОповещения()
в том же синтаксис помощнике к этому методу написано:
Используется в реализации процедур, которые внутри себя могут открывать блокирующие окна (например, вызывать метод ПоказатьВопрос) и при этом должны каким-то образом вернуть свой результат в вызывающие процедуры.
19. klinval 296 23.11.17 14:35 Сейчас в теме
(18) Не понимаю вашего решения. Можете подробнее написать? Перед записью на форме какой код (неужели там без Отказ=Истина обошлись)?
20. ProDeveloper 24.11.17 10:15 Сейчас в теме
Беру свои слова назад. Вот официальный ответ от 1С - "красиво это никак не сделать":

http://its.1c.ru/docs/v8nonmodal/#25


Вопрос в обработчике формы ПередЗаписью

В обработчике события формы ПередЗаписью также может возникнуть потребность задать вопрос. Как и в предыдущем примере. Однако здесь вопрос так просто не решается. Отличие заключается в следующем.

В предыдущем примере, оказываясь в обработчике ПередЗакрытием, мы однозначно знали действие, которое должно быть выполнено. Это закрытие формы. Поэтому в обработке оповещения мы смело писали Закрыть().

Но в обработчике ПередЗаписью мы такой однозначной информации не имеем. В этом обработчике мы можем оказаться по двум причинам: если пользователь нажал Записать, или если он нажал Записать и закрыть. То есть дальнейший сценарий действий нам неизвестен. Определить его стандартными способами, находясь внутри этого обработчика, мы не можем.

Поэтому тут можно предложить три варианта, но все они, к сожалению, обладают недостатками:

Изменить логику прикладного решения так, чтобы не было диалога с пользователем в этом обработчике. Это не всегда возможно;
В обработке оповещения с помощью собственной блокирующей формы задавать пользователю развернутый вопрос, предполагающий точное описание дальнейших действий: Отказаться?, Только записать?, Записать и закрыть? Это может выглядеть не очень красиво, ведь пользователь уже нажал "Записать и закрыть", а его опять об этом спрашивают;
Не использовать стандартные команды формы Записать, "Записать и закрыть". Вместо них создать собственные команды, в которых и выполнять необходимые алгоритмы. Создание собственных команд потребует дополнительных трудозатрат.
21. klinval 296 24.11.17 14:02 Сейчас в теме
(20)
Не использовать стандартные команды формы Записать, "Записать и закрыть". Вместо них создать собственные команды, в которых и выполнять необходимые алгоритмы. Создание собственных команд потребует дополнительных трудозатрат.

Именно это я и сделал, т.к. примера кода у них именно на эту ситуацию нет. Остальные варианты (1. Отказаться от использования или 2. Задать пользователю доп. вопросы Отказаться?, Только записать?, Записать и закрыть?) и так понятно как реализовать.
22. ProDeveloper 24.11.17 17:31 Сейчас в теме
Нашел как теперь делают это 1Сники в свежих конфах аля ERP2, KA2.
Нужно курить модуль формы, процедура ПередЗаписью

&НаКлиенте
Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)

СобытияФормКлиент.ПередЗаписью(ЭтотОбъект, Отказ, ПараметрыЗаписи);


P.S. В структуре ПараметрыЗаписи хранят признак - ПараметрыЗаписи.ЕстьВопросыПередЗаписью
23. ProDeveloper 24.11.17 17:36 Сейчас в теме
Как я и писал ранее используют метод ВыполнитьОбработкуОповещения()
Суть в чем, от записи формы они отказываются, после чего вызывают обёртку, в которой задаются вопросы ПоказатьВопрос() и т.д.
Далее прыгают из процедуры в процедуру как в кроличью нору , использьуя ВыполнитьОбработкуОповещения() , в самом конце используют вызов ОбщегоНазначенияУТКлиент.ОбработатьЗаписьОбъектаВФорме(ДополнительныеПараметры.Форма, ДополнительныеПараметры.ПараметрыЗаписи); с программной записью этой формы, т.е. Форма.Записать(ПараметрыЗаписи);
24. dialogsoft 72 12.07.18 16:20 Сейчас в теме
он спер с сайта 1с:
http://its.1c.ru/docs/v8nonmodal/

и забыл в первом случае написать внизу:

ВыполняетсяЗакрытие = Ложь;


из- за этого ошибка
Прикрепленные файлы:
25. klinval 296 13.07.18 15:27 Сейчас в теме
(24)
он спер с сайта 1с:http://its.1c.ru/docs/v8nonmodal/

Вы обвиняете меня, что после слов
Что же думает по предлагаемому вопросу специалисты фирмы 1С? Для начала можно посмотреть на тему «Вопрос в обработчике формы ПередЗакрытием»:

Я спер текст из 1С... Смысл фразы и выделение в блок цитирования предполагает, что дальше будет цитата. В анонсе статьи я даже ссылку дал откуда спер процитировал.

Сама же статья про "Как использовать ПоказатьВопрос в обработчике формы ПередЗаписью". Примеров этого случая в http://its.1c.ru/docs/v8nonmodal/ нет, что я и пытался исправить. Про "Вопрос в обработчике формы ПередЗакрытием" я статью не писал, т.к. на ИТС достаточно подробно описан алгоритм.

А то что в цитируемом коде нет строчки "ВыполняетсяЗакрытие = Ложь; " - согласен, не заметил.
28. dialogsoft 72 13.12.18 08:52 Сейчас в теме
(25) А то что в цитируемом коде нет строчки "ВыполняетсяЗакрытие = Ложь; " - согласен, не заметил.

Дак это же и самое важное. Я потратил время на ваш недосмотр. Если сливаете - то сливайте корректно и со ссылкой на первоисточник.
26. berezin84 11.10.18 11:24 Сейчас в теме
Код для использования в расширении, для обработки события "ПередЗаписью", в случае если нам нужно записывать или нет после ответа пользователя.

&НаКлиенте
Процедура БЕА_ПередЗаписьюПеред(Отказ, ПараметрыЗаписи)
		
	СуммаЗатрат = Объект.Затраты.Итог("Сумма");	
	Если СуммаЗатрат > Объект.СуммаДокумента И НЕ ПараметрыЗаписи.Свойство("ВопросЗадан") Тогда
		Сообщить("Сумма затрат превышает сумму документа!",СтатусСообщения.Важное);
		Отказ = Истина;
	ИначеЕсли СуммаЗатрат < Объект.СуммаДокумента И НЕ ПараметрыЗаписи.Свойство("ВопросЗадан") Тогда
		Отказ = Истина;
		Режим = РежимДиалогаВопрос.ДаНет;
		Оповещение = Новый ОписаниеОповещения("ПослеЗакрытияВопросаПользователю",ЭтаФорма, ПараметрыЗаписи);
		ПоказатьВопрос(Оповещение, "Сумма затрат меньше суммы документа, продолжить запись?", Режим, 0);
	КонецЕсли;
		
КонецПроцедуры

&НаКлиенте
Функция ПослеЗакрытияВопросаПользователю(Результат, ПараметрыЗаписи) Экспорт
	
	Если Результат = КодВозвратаДиалога.Да Тогда
		 ПараметрыЗаписи.Вставить("ВопросЗадан");
		 Записать(ПараметрыЗаписи);
	КонецЕсли;
	 
КонецФункции 
Показать
27. klinval 296 11.10.18 16:25 Сейчас в теме
(26) А как вы определяете нужно ли закрывать форму (нажал ПровестиИЗакрыть или просто Провести)?
29. SiroJah 28.05.19 09:24 Сейчас в теме
(26) Спасибо! Работает "Провести" и "Провести и закрыть"
30. ah7777777 663 19.08.19 08:13 Сейчас в теме
сделал немного по другому:
&НаКлиенте
Перем флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента;

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента=0;
КонецПроцедуры

&НаКлиенте
Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)
	
	Если флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента<=1 тогда		//Если =0 Значит вопрос задается впервые если 1 после исправления повторно
		Отказ=истина;																	//Нам надо вернутся в форму
		Если ДатаДоговораРавнаДатеДокументаСервер() тогда
			Оповещение = Новый ОписаниеОповещения("ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДокумента",ЭтотОбъект,ПараметрыЗаписи);//Параметры записи передадим в функцию ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДокумента
			ПоказатьВопрос(Оповещение, "Дата создания договора совпадает с датой платежа.Верно ли указан договор?",РежимДиалогаВопрос.ДаНет,0,КодВозвратаДиалога.Да);
			Возврат;
		КонецЕсли;
		Возврат;
	КонецЕсли;	
КонецПроцедуры

&НаКлиенте
Процедура ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДокумента(Результат, Параметры) Экспорт 
//****************************************************
	Если Результат = КодВозвратаДиалога.Нет Тогда							//Надо остаться в форме
		флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента=1;
	Иначе																	
		флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента=2;//Записать с параметрами и закрыть форму
		Записать(Параметры);
		Закрыть();
	КонецЕсли;
КонецПроцедуры

Показать
31. klinval 296 19.08.19 10:06 Сейчас в теме
(30) Да, как вариант можно в переменной хранить ответ. Только один нюанс по вашему коду: если нажать "Записать" (без закрыть) и ответить на вопрос "Да" то форма закроется. Отслеживание/определение "нужно ли закрывать?" добавляет дополнительных трудностей (кода) к задаче.
32. ah7777777 663 19.08.19 20:15 Сейчас в теме
тут по условиям задачи надо форму закрыть.
33. Gaster 24.09.19 14:16 Сейчас в теме
в первом примере, в этой части кода:
Если Не ВыполняетсяЗакрытие Тогда

Вылетает ошибка что не может привести к типу Булево. Естественно, там же в первом проходе неопределено будет, как он может сравнивать... Как быть?

Добавлено спустя 15 минут...
странно, в другом документе не вылетает
34. klinval 296 24.09.19 14:27 Сейчас в теме
(33) похоже забыли объявить переменную:
&НаКлиенте
Перем ВыполняетсяЗакрытие;

Или:
ВыполняетсяЗакрытие = Ложь;
35. klinval 296 24.09.19 17:41 Сейчас в теме
(33) И ещё, не знаю обратили ли вы внимание, но пример который вы смотрите это к теме «Вопрос в обработчике формы ПередЗакрытием» и взят код из http://its.1c.ru/docs/v8nonmodal/ . Данный код в публикации для примера, т.к. очень близок с темой "Как использовать ПоказатьВопрос в обработчике формы ПередЗаписью"
Оставьте свое сообщение

См. также

Использование программных перечислений, ч.1: строковые константы Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Часто ли у вас возникает необходимость в коде выполнять сравнение на строку?

10.12.2016    37241    unichkin    74    

Программная работа с настройками СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Нюансы программной работы с настройками системы компоновки данных в отчетах и динамических списках. Обзор всех видов настроек компоновки. Что в каких случаях правильно применять. В качестве примера рассмотрена работа с отборами и группировками.

27.01.2020    25578    ids79    26    

[СКД] Программное создание схемы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Сделаем отчет на СКД полностью программно, без использования макета "схема компоновки данных".

15.01.2020    23046    John_d    22    

Последовательности событий. Шпаргалка

Практика программирования v8 Россия Бесплатно (free)

Собрал информацию о событиях/подписках/расширениях в одном месте.

30.12.2019    17605    kuzyara    33    

Вспомогательные инструкции в коде 1С Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    30100    tormozit    100    

30 задач. Странных и не очень

Практика программирования v8 Бесплатно (free)

30 задач на знание языка программирования 1С и некоторого поведения платформы. Маленьких. Странных и не очень.

02.12.2019    16877    YPermitin    72    

Как передать IP адрес, который вызвал HTTP запрос в 1C (для веб-сервера Apache)

Практика программирования v8 Бесплатно (free)

Столкнулся с задачей получения IP адреса, который вызывает http сервис 1С. Итак, решение:

22.11.2019    8274    Sibars    19    

Таблица значений. Нюансы

Практика программирования v8 Бесплатно (free)

Обзор некоторых аспектов использования общеизвестного инструмента 1С.

01.10.2019    32550    Yashazz    50    

Оформление и рефакторинг сложных логических выражений Промо

Практика программирования v8 Россия Бесплатно (free)

В сложных логических выражениях нередко самому автору спустя какое-то время тяжело разобраться, не говоря уже о других программистах. Предлагаемая методика позволяет повысить наглядность таких выражений путем оформления в виде И-ИЛИ дерева и одновременно выполнять их рефакторинг.

20.09.2012    77861    tormozit    131    

О программе Postman для тестирования API и для чего она нужна 1С-нику

Практика программирования Программное обеспечение (software) v8 Бесплатно (free)

Для чего нужна программа Postman для тестирования API и какая от него польза для 1С-программиста.

24.09.2019    11615    budidich    28    

[Шпаргалка] Программное создание элементов формы

Практика программирования Работа с интерфейсом v8 1cv8.cf Бесплатно (free)

Программное создание практически всех популярных элементов формы.

06.09.2019    48567    rpgshnik    63    

Агрегатные функции СКД, о которых мало кто знает

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    48485    ids79    54    

Запись значения в поле ввода/формы со срабатыванием события ПриИзменении Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Иногда возникает необходимость после записи значения в какое либо поле ввода/формы вызвать для него обработчик события ПриИзменении, а о вызове самого события приходится только мечтать. В этой статье приводится программный способ вызова этого события.

11.07.2007    48205    tormozit    41    

Регистры бухгалтерии. Общая информация

Практика программирования Математика и алгоритмы v8 v8::БУ БУ Бесплатно (free)

Общая информация о внутреннем устройстве регистров бухгалтерии.

05.09.2019    27930    YPermitin    24    

Три костыля. Сказ про фокусы в коде

Практика программирования v8 Бесплатно (free)

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    25336    YPermitin    80    

Отслеживание выполнения фонового задания

Практика программирования Универсальные функции Разработка v8 1cv8.cf Бесплатно (free)

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    31175    ids79    16    

Как сделать из &НаКлиентеНаСервереБезКонтекста почти &НаКлиентеНаСервере Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Как сделать метод формы, доступный на клиенте и на сервере одновременно, и сохранить при этом удобство разработки

10.09.2017    44640    tormozit    74    

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    79853    ids79    49    

Фоновое выполнение кода в 1С - это просто

Практика программирования v8 1cv8.cf Бесплатно (free)

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    34479    avalakh    22    

Разбираемся с параметрами редактирования СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Связь по типу, Параметры выбора, Связи параметров выбора

31.07.2019    23315    json    13    

Выгрузка документа по условию Промо

Практика программирования Разработка v8 Бесплатно (free)

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    16013    m-rv    2    

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    58322    ids79    11    

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ

Инструментарий разработчика Практика программирования v8 v8::СКД Бесплатно (free)

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    35436    ids79    27    

Регистры сведений. За кулисами

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Небольшие заметки по внутреннему устройству регистров сведений.

09.07.2019    25867    YPermitin    14    

Как прикрутить ГУИД к регистру сведений Промо

Практика программирования Перенос данных из 1C8 в 1C8 Разработка v8 Бесплатно (free)

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    20143    m-rv    17    

"Меньше копипаста!", или как Вася универсальную процедуру писал

Практика программирования Разработка v8 v8::СКД 1cv8.cf Бесплатно (free)

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    19554    SeiOkami    50    

Работа с настройками системы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Варианты отчетов, работа с настройками вариантов: структура группировок, поля отчета, отборы, сортировка, условное оформление, другие настройки, настройки отображения диаграмм.

02.07.2019    45563    ids79    17    

Создание отчетов с помощью СКД - основные понятия и элементы

Практика программирования Математика и алгоритмы v8 v8::СКД Бесплатно (free)

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    51764    ids79    25    

Как сделать запрос на изменение данных Промо

Практика программирования v8 v8::Запросы 1cv8.cf Бесплатно (free)

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    30488    m-rv    21    

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017

Практика программирования Производительность и оптимизация (HighLoad) v8 v8::Запросы Бесплатно (free)

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    24840    dmurk    145    

Регистры накопления. Виртуальные таблицы. Часть №2: "Остатки" и "Остатки и обороты"

Практика программирования v8 1cv8.cf Бесплатно (free)

Описание работы платформы 1С:Предприятие 8.2 с виртуальными таблицами регистров накопления "Остатки" и "Остатки и обороты". Анализ SQL-запрос при работе с виртуальными таблицами

22.05.2019    24323    YPermitin    7    

Регистры накопления. Структура хранения в базе данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    42474    YPermitin    30    

Метод формирования движений в типовых регистрах нетиповыми регистраторами Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    28205    itriot11    34    

О расширениях замолвите слово...

Практика программирования Разработка v8 Бесплатно (free)

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    35152    ellavs    126    

Git-репозитории для 1С-кода (опыт использования при небольших проектах)

Практика программирования v8 Бесплатно (free)

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    27298    ellavs    89    

Трюки с внешними источниками данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    31157    YPermitin    53    

Использование классов .Net в 1С для новичков Промо

Практика программирования Разработка внешних компонент Универсальные функции v7.7 v8 Бесплатно (free)

Руководство для новичков. Написав статью http://infostart.ru/public/238584/, я понял, что многие не понимают того, что написано. Поэтому в этой статье постараюсь более подробно остановиться на азах и без кода на вражеском языке (C#)

27.01.2016    76210    Serginio    108    

Ошибки при работе с хранилищем конфигурации и способы их решения

Практика программирования v8 Бесплатно (free)

В статье собраны наиболее распространенные ошибки при работе с хранилищем конфигурации и способы их обхода и решения.

01.03.2019    38674    Смешной 1С    28    

Разработка и сценарное тестирование с Vanessa-ADD. Отчетность Allure. Автоматизация запуска сценариев

Практика программирования Vanessa Automation v8 Россия Бесплатно (free)

Формируем отчетность о результатах выполнения сценариев. Автоматизируем запуск.

26.02.2019    21788    Vladimir Litvinenko    27    

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С Промо

Математика и алгоритмы Практика программирования v8 v8::blocking 1cv8.cf Бесплатно (free)

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    34532    ids79    40    

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS)

Практика программирования БСП (Библиотека стандартных подсистем) Роли и права v8 v8::Права Бесплатно (free)

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    38942    ids79    9    

Тестер: частые вопросы Промо

Практика программирования v8 Бесплатно (free)

Ошибкам бой - тесты норма жизни!

25.07.2018    29176    grumagargler    28    

EnterpriseData – часть 2. Процесс выгрузки данных

Практика программирования Обмен через XML v8 v8::УФ Россия Бесплатно (free)

Основные этапы выгрузки данных через ED, обработчики событий выгрузки, правила обработки данных, правила конвертации объектов, конвертация свойств первого и второго этапов, процедуры БСП, используемые при выгрузке данных, структура «КомпонентыОбмена».

26.12.2018    26617    ids79    31    

Новый подход к обмену данными EnterpriseData

Практика программирования Обмен через XML v8 v8::УФ Россия Бесплатно (free)

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    41102    ids79    72    

EnterpriseData - пример доработки правил конвертации без использования КД 3.0 в расширении конфигурации

Практика программирования Обмен через XML v8 v8::УФ БП3.0 УТ11 Россия Бесплатно (free)

В статье подробно описан реальный пример доработки обмена данными через EnterpriseData (универсальный формат обмена) между конфигурациями УТ 11.4 и Бухгалтерия 3.0

16.11.2018    36768    ids79    42    

Ускоряем 1С: модули с повторным использованием возвращаемых значений Промо

Практика программирования v8 Бесплатно (free)

По роду своей деятельности, мне часто приходится обсуждать с программистами детали реализации той или иной функциональности. Очень часто, разговаривая даже с квалифицированными специалистами я сталкиваюсь с незнанием сути платформенной функциональности Повторного использования возвращаемых значений общих модулей. В данной статье я постараюсь дать краткий обзор и основные особенности этой функциональности.

04.09.2017    52498    m-rv    61    

Программное заполнение пользовательских параметров и отборов СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Публикация представляет из себя краткие примеры того, как можно заполнять параметры СКД программно так, чтобы все параметры и отборы были доступны в быстрых настройках и в обычных (типовых) настройках параметров и отборов СКД.

13.11.2018    46904    Unk92    25