Распределение остатков по партиям прихода

21.06.18

Разработка - Запросы

Распределение свободных остатков номенклатуры по документам прихода по убыванию даты поступления товаров в РАУЗ.

  Всем доброго времени суток. Как известно партионный учет вещь полезная но увы неудобная, причины описывать не буду кому надо знает. Учет в нашей организации ведется в Комплексной автоматизации 1, применяется метод расчета себестоимости РАУЗ. Для целей ценообразования хорошо бы знать поступления, по которым имеется остаток на складе.

  Как известно любую задачу можно решить используя вложенные циклы и отборы при обработке данных полученных простыми запросами. Например задача поиска приходов по имеющемуся остатку решается циклическим обходом таблицы остатков с поиском и распределением их по таблице приходов.

  Но мы не будем искать простых путей и попробуем реализовать это запросом.

  Для понимания методов, которые применены в построении запроса необходимо описать особенности входящих данных, имеем:

  - 1С Комплексная автоматизация 1.1, метод расчета себестоимости РАУЗ

  - Имеем несколько виртуальных и реальных складов: два склада наличия, склад транзитных товаров, склад возвратов и бракованных товаров, виртуальный склад недостач

  - Имеем несколько схем движения товара по складам:

  • товар приходуется на склад наличия
  • товар приходуется на транзитный склад, возвращается через склад возвратов на наличие
  • товар приходуется на виртуальный склад (например недостач)  далее двигается на наличие
  • товар приходуется на наличие далее перемещается на склады уценки либо брака 

  По сути это и есть остатки по интересующим нас складам, однако оборот нас интересует по всем складам включенным в схему движения т.к. товар мог поступить на наличие через транзитный склад, остатки которого нас не интересуют.

Таким образом склад как разрез полученных данных нас не интересует, однако его необходимо учесть, что мы сделаем объединив все склады из выборки под единым флагом, например это будет склад наличия номер 3 (как в предоставленном запросе).

Данные необходимые для идентификации партии (ГТД, заказ поставщику, цена, входящая сф) в том виде котором нам необходимо располагаются только в ТЧ поступления (в других местах не нашел, может я тупанул, но к примеру если у нас в поступлении одна и та же деталь разделена по строкам не только по номеру ГТД но и по заказам поставщику внутри которых еще деление по ценам обнаружить такое деление с нужными реквизитами у меня не вышло).

 

Замеры производительности:

Исполнял на своем компе

 Operating System: Windows 7 Профессиональная 64-bit (6.1, Build 7601) Service Pack 1 (7601.win7sp1_ldr.170913-0600)
 Processor: Intel(R) Core(TM) i3-3210 CPU @ 3.20GHz (4 CPUs), ~3.2GHz
 Memory: 16384MB RAM

База под управлением SQL весит 200 гб, 130 юзеров в онлайне

Входящая таблица остатков 50-60 тысяч строк

Исходящая  распределенная по партиям таблица 70-80 тысяч строк

Время исполнения запроса 40-50 сек (на сервере ~ 20 сек)

Вопросом оптимизации запроса заниматься лень пока все устраивает.

При исполнении проверочного запроса (соединение с остатками и контроль количества) вылезают косяки учета (например развал остатка по сериям)

В запросе из оборота исключен склад возвратов т.к. возврат от покупателя это не та партия которая нас интересует.

Финальное распределенное количество это колонка ОстатокПоСтроке (остальные колонки промежуточные выведены в итоговый результат для информации)

Так же данную конструкцию (чисто теоретически можно использовать например для определения партий при отгрузке заменив соответствующие таблицы)

Сам запрос:

ВЫБРАТЬ
	ТоварыНаСкладахОстатки.Номенклатура КАК Номенклатура,
	ТоварыНаСкладахОстатки.СерияНоменклатуры,
	СУММА(ТоварыНаСкладахОстатки.КоличествоОстаток) КАК КоличествоОстаток,
	ВЫБОР
		КОГДА НЕ ТоварыНаСкладахОстатки.Склад = &Склад_3
			ТОГДА &Склад_3
		ИНАЧЕ ТоварыНаСкладахОстатки.Склад
	КОНЕЦ КАК Склад
ПОМЕСТИТЬ НаСкладах
ИЗ
	РегистрНакопления.ТоварыНаСкладах.Остатки(, Склад В (&Склады)) КАК ТоварыНаСкладахОстатки

СГРУППИРОВАТЬ ПО
	ТоварыНаСкладахОстатки.Номенклатура,
	ТоварыНаСкладахОстатки.СерияНоменклатуры,
	ТоварыНаСкладахОстатки.Склад

ИНДЕКСИРОВАТЬ ПО
	Номенклатура,
	Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	НаСкладах.Номенклатура КАК Номенклатура,
	НаСкладах.Склад КАК Склад,
	СУММА(НаСкладах.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ НаСкладах2
ИЗ
	НаСкладах КАК НаСкладах

СГРУППИРОВАТЬ ПО
	НаСкладах.Склад,
	НаСкладах.Номенклатура

ИНДЕКСИРОВАТЬ ПО
	Номенклатура,
	Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ТоварыВРезервеНаСкладахОстатки.Номенклатура КАК Номенклатура,
	СУММА(ТоварыВРезервеНаСкладахОстатки.КоличествоОстаток) КАК КоличествоОстаток,
	ВЫБОР
		КОГДА НЕ ТоварыВРезервеНаСкладахОстатки.Склад = &Склад_3
			ТОГДА &Склад_3
		ИНАЧЕ ТоварыВРезервеНаСкладахОстатки.Склад
	КОНЕЦ КАК Склад
ПОМЕСТИТЬ Резервы_Пром
ИЗ
	РегистрНакопления.ТоварыВРезервеНаСкладах.Остатки(
			,
			Склад В (&Склады)
				И Номенклатура В
					(ВЫБРАТЬ
						скл.Номенклатура
					ИЗ
						НаСкладах2 КАК скл)) КАК ТоварыВРезервеНаСкладахОстатки
ГДЕ
	ТоварыВРезервеНаСкладахОстатки.КоличествоОстаток > 0

СГРУППИРОВАТЬ ПО
	ТоварыВРезервеНаСкладахОстатки.Склад,
	ТоварыВРезервеНаСкладахОстатки.Номенклатура

ИНДЕКСИРОВАТЬ ПО
	Номенклатура,
	Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	рег.Номенклатура,
	СУММА(рег.КоличествоОстаток) КАК КоличествоОстаток,
	рег.Склад
ПОМЕСТИТЬ Резервы
ИЗ
	Резервы_Пром КАК рег

СГРУППИРОВАТЬ ПО
	рег.Номенклатура,
	рег.Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	НаСкладах.Номенклатура КАК Номенклатура,
	СУММА(НаСкладах.КоличествоОстаток - ЕСТЬNULL(ТоварыВРезервеНаСкладахОстатки.КоличествоОстаток, 0)) КАК Количество,
	НаСкладах.Склад КАК Склад
ПОМЕСТИТЬ СвободныйОстаток
ИЗ
	НаСкладах2 КАК НаСкладах
		ЛЕВОЕ СОЕДИНЕНИЕ Резервы КАК ТоварыВРезервеНаСкладахОстатки
		ПО НаСкладах.Номенклатура = ТоварыВРезервеНаСкладахОстатки.Номенклатура
			И НаСкладах.Склад = ТоварыВРезервеНаСкладахОстатки.Склад
ГДЕ
	НаСкладах.КоличествоОстаток - ЕСТЬNULL(ТоварыВРезервеНаСкладахОстатки.КоличествоОстаток, 0) > 0

СГРУППИРОВАТЬ ПО
	НаСкладах.Номенклатура,
	НаСкладах.Склад

ИНДЕКСИРОВАТЬ ПО
	Номенклатура,
	Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	НаСкладах.Номенклатура,
	НаСкладах.СерияНоменклатуры,
	СУММА(НаСкладах.КоличествоОстаток) КАК КоличествоОстаток,
	НаСкладах.Склад,
	СвободныйОстаток.Количество,
	СвободныйОстаток.Номенклатура.Артикул
ПОМЕСТИТЬ СводноПоСериям
ИЗ
	СвободныйОстаток КАК СвободныйОстаток
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ НаСкладах КАК НаСкладах
		ПО СвободныйОстаток.Номенклатура = НаСкладах.Номенклатура
			И СвободныйОстаток.Склад = НаСкладах.Склад

СГРУППИРОВАТЬ ПО
	НаСкладах.Номенклатура,
	СвободныйОстаток.Номенклатура.Артикул,
	НаСкладах.Склад,
	НаСкладах.СерияНоменклатуры,
	СвободныйОстаток.Количество
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	СводноПоСериям.Номенклатура,
	СводноПоСериям.СерияНоменклатуры,
	СводноПоСериям.КоличествоОстаток,
	СводноПоСериям.Склад,
	СводноПоСериям.Количество,
	СводноПоСериям.НоменклатураАртикул,
	СУММА(СводноПоСериям1.КоличествоОстаток) КАК ОстатокВыше
ПОМЕСТИТЬ ГруппаПоСериям
ИЗ
	СводноПоСериям КАК СводноПоСериям
		ЛЕВОЕ СОЕДИНЕНИЕ СводноПоСериям КАК СводноПоСериям1
		ПО СводноПоСериям.Номенклатура = СводноПоСериям1.Номенклатура
			И СводноПоСериям.Склад = СводноПоСериям1.Склад
			И СводноПоСериям.СерияНоменклатуры > СводноПоСериям1.СерияНоменклатуры

СГРУППИРОВАТЬ ПО
	СводноПоСериям.Склад,
	СводноПоСериям.Номенклатура,
	СводноПоСериям.НоменклатураАртикул,
	СводноПоСериям.СерияНоменклатуры,
	СводноПоСериям.КоличествоОстаток,
	СводноПоСериям.Количество
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ГруппаПоСериям.Номенклатура,
	ГруппаПоСериям.СерияНоменклатуры,
	ГруппаПоСериям.КоличествоОстаток,
	ГруппаПоСериям.Склад,
	ГруппаПоСериям.Количество,
	ГруппаПоСериям.НоменклатураАртикул,
	ГруппаПоСериям.ОстатокВыше,
	ВЫБОР
		КОГДА ГруппаПоСериям.Количество - ЕСТЬNULL(ГруппаПоСериям.ОстатокВыше, 0) - ГруппаПоСериям.КоличествоОстаток >= 0
			ТОГДА ГруппаПоСериям.КоличествоОстаток
		ИНАЧЕ ГруппаПоСериям.КоличествоОстаток + (ГруппаПоСериям.Количество - ЕСТЬNULL(ГруппаПоСериям.ОстатокВыше, 0) - ГруппаПоСериям.КоличествоОстаток)
	КОНЕЦ КАК Остаток
ПОМЕСТИТЬ ОстаткиПоСериям
ИЗ
	ГруппаПоСериям КАК ГруппаПоСериям
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ТоварыНаСкладахОбороты.Номенклатура,
	ТоварыНаСкладахОбороты.СерияНоменклатуры,
	СУММА(ТоварыНаСкладахОбороты.КоличествоПриход) КАК КоличествоПриход,
	ТоварыНаСкладахОбороты.Регистратор,
	ТоварыНаСкладахОбороты.Период,
	ТоварыНаСкладахОбороты.НомерСтроки
ПОМЕСТИТЬ ОборотТовары
ИЗ
	РегистрНакопления.ТоварыНаСкладах.Обороты(
			,
			,
			Запись,
			Номенклатура В
					(ВЫБРАТЬ
						ост.Номенклатура
					ИЗ
						СвободныйОстаток КАК ост)
				И НЕ Склад В (&СкладВозвратов)) КАК ТоварыНаСкладахОбороты
ГДЕ
	ТоварыНаСкладахОбороты.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг

СГРУППИРОВАТЬ ПО
	ТоварыНаСкладахОбороты.Номенклатура,
	ТоварыНаСкладахОбороты.СерияНоменклатуры,
	ТоварыНаСкладахОбороты.Регистратор,
	ТоварыНаСкладахОбороты.Период,
	ТоварыНаСкладахОбороты.НомерСтроки
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОборотТовары.Номенклатура,
	ОборотТовары.СерияНоменклатуры,
	СУММА(ОборотТовары.КоличествоПриход) КАК КоличествоПриход,
	ОборотТовары.Регистратор,
	ОборотТовары.Период
ПОМЕСТИТЬ ОборотТоварыГрупп_1
ИЗ
	ОборотТовары КАК ОборотТовары

СГРУППИРОВАТЬ ПО
	ОборотТовары.Период,
	ОборотТовары.Номенклатура,
	ОборотТовары.СерияНоменклатуры,
	ОборотТовары.Регистратор
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОстаткиПоСериям.Номенклатура,
	ОстаткиПоСериям.СерияНоменклатуры,
	ОстаткиПоСериям.Остаток,
	ОборотТовары.Период,
	ОборотТовары.Регистратор,
	СУММА(ОборотТовары.КоличествоПриход) КАК КоличествоПриход,
	ОстаткиПоСериям.Склад
ПОМЕСТИТЬ ОборотОстаткиПервая
ИЗ
	ОстаткиПоСериям КАК ОстаткиПоСериям
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ОборотТоварыГрупп_1 КАК ОборотТовары
		ПО ОстаткиПоСериям.Номенклатура = ОборотТовары.Номенклатура
			И ОстаткиПоСериям.СерияНоменклатуры = ОборотТовары.СерияНоменклатуры

СГРУППИРОВАТЬ ПО
	ОстаткиПоСериям.Номенклатура,
	ОстаткиПоСериям.СерияНоменклатуры,
	ОборотТовары.Период,
	ОборотТовары.Регистратор,
	ОстаткиПоСериям.Склад,
	ОстаткиПоСериям.Остаток
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОборотОстаткиПервая.Номенклатура,
	ОборотОстаткиПервая.СерияНоменклатуры,
	ОборотОстаткиПервая.Остаток,
	ОборотОстаткиПервая.Период,
	ОборотОстаткиПервая.Регистратор,
	ОборотОстаткиПервая.КоличествоПриход КАК КоличествоПриход,
	ОборотОстаткиПервая.Склад,
	ОборотОстаткиПервая1.КоличествоПриход КАК КоличествоПриходДалее
ПОМЕСТИТЬ ПромИтогСверткаПериод
ИЗ
	ОборотОстаткиПервая КАК ОборотОстаткиПервая
		ЛЕВОЕ СОЕДИНЕНИЕ ОборотОстаткиПервая КАК ОборотОстаткиПервая1
		ПО ОборотОстаткиПервая.Номенклатура = ОборотОстаткиПервая1.Номенклатура
			И ОборотОстаткиПервая.СерияНоменклатуры = ОборотОстаткиПервая1.СерияНоменклатуры
			И ОборотОстаткиПервая.Регистратор.МоментВремени < ОборотОстаткиПервая1.Регистратор.МоментВремени

СГРУППИРОВАТЬ ПО
	ОборотОстаткиПервая.Номенклатура,
	ОборотОстаткиПервая.СерияНоменклатуры,
	ОборотОстаткиПервая.Период,
	ОборотОстаткиПервая.Регистратор,
	ОборотОстаткиПервая.Склад,
	ОборотОстаткиПервая.Остаток,
	ОборотОстаткиПервая.КоличествоПриход,
	ОборотОстаткиПервая1.Период,
	ОборотОстаткиПервая1.КоличествоПриход
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПромИтогСверткаПериод.Номенклатура,
	ПромИтогСверткаПериод.СерияНоменклатуры,
	ПромИтогСверткаПериод.Остаток,
	ПромИтогСверткаПериод.Период,
	ПромИтогСверткаПериод.Регистратор,
	ПромИтогСверткаПериод.КоличествоПриход,
	ПромИтогСверткаПериод.Склад,
	СУММА(ПромИтогСверткаПериод.КоличествоПриходДалее) КАК КоличествоПриходДалее
ПОМЕСТИТЬ ОборотОстаткиВторая
ИЗ
	ПромИтогСверткаПериод КАК ПромИтогСверткаПериод

СГРУППИРОВАТЬ ПО
	ПромИтогСверткаПериод.Регистратор,
	ПромИтогСверткаПериод.Номенклатура,
	ПромИтогСверткаПериод.Склад,
	ПромИтогСверткаПериод.СерияНоменклатуры,
	ПромИтогСверткаПериод.Период,
	ПромИтогСверткаПериод.Остаток,
	ПромИтогСверткаПериод.КоличествоПриход
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОборотОстаткиВторая.Номенклатура,
	ОборотОстаткиВторая.СерияНоменклатуры,
	СУММА(ОборотОстаткиВторая.Остаток) КАК Остаток,
	ОборотОстаткиВторая.Период,
	ОборотОстаткиВторая.Регистратор,
	ОборотОстаткиВторая.КоличествоПриход КАК КоличествоПриход,
	ОборотОстаткиВторая.Склад,
	ОборотОстаткиВторая.КоличествоПриходДалее КАК КоличествоПриходДалее,
	СУММА(ВЫБОР
			КОГДА ОборотОстаткиВторая.Остаток - ЕСТЬNULL(ОборотОстаткиВторая.КоличествоПриходДалее, 0) <= ОборотОстаткиВторая.КоличествоПриход
				ТОГДА ОборотОстаткиВторая.Остаток - ЕСТЬNULL(ОборотОстаткиВторая.КоличествоПриходДалее, 0)
			ИНАЧЕ ЕСТЬNULL(ОборотОстаткиВторая.КоличествоПриход, 0)
		КОНЕЦ) КАК ОстатокЗдесь,
	ОборотОстаткиВторая.Номенклатура.Артикул КАК НоменклатураАртикул
ПОМЕСТИТЬ ИтогСерии
ИЗ
	ОборотОстаткиВторая КАК ОборотОстаткиВторая
ГДЕ
	ВЫБОР
			КОГДА ОборотОстаткиВторая.Остаток - ЕСТЬNULL(ОборотОстаткиВторая.КоличествоПриходДалее, 0) <= ОборотОстаткиВторая.КоличествоПриход
				ТОГДА ОборотОстаткиВторая.Остаток - ЕСТЬNULL(ОборотОстаткиВторая.КоличествоПриходДалее, 0)
			ИНАЧЕ ЕСТЬNULL(ОборотОстаткиВторая.КоличествоПриход, 0)
		КОНЕЦ > 0

СГРУППИРОВАТЬ ПО
	ОборотОстаткиВторая.Номенклатура,
	ОборотОстаткиВторая.Склад,
	ОборотОстаткиВторая.Период,
	ОборотОстаткиВторая.Регистратор,
	ОборотОстаткиВторая.СерияНоменклатуры,
	ОборотОстаткиВторая.Номенклатура.Артикул,
	ОборотОстаткиВторая.КоличествоПриход,
	ОборотОстаткиВторая.КоличествоПриходДалее
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОборотТовары.Номенклатура,
	ОборотТовары.СерияНоменклатуры,
	ОборотТовары.Регистратор,
	ОборотТовары.НомерСтроки,
	СУММА(ОборотТовары.КоличествоПриход) КАК КоличествоПриход
ПОМЕСТИТЬ ОборотНомер
ИЗ
	ОборотТовары КАК ОборотТовары

СГРУППИРОВАТЬ ПО
	ОборотТовары.Номенклатура,
	ОборотТовары.СерияНоменклатуры,
	ОборотТовары.Регистратор,
	ОборотТовары.НомерСтроки
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ИтогСерии.Номенклатура,
	ИтогСерии.СерияНоменклатуры,
	ИтогСерии.Остаток,
	ИтогСерии.Период,
	ИтогСерии.Регистратор,
	ИтогСерии.КоличествоПриход,
	ИтогСерии.Склад,
	ИтогСерии.ОстатокЗдесь,
	ИтогСерии.НоменклатураАртикул КАК НоменклатураАртикул,
	ОборотНомер.НомерСтроки,
	ОборотНомер.КоличествоПриход КАК КоЛВоВСтроке,
	ИтогСерии.КоличествоПриходДалее
ПОМЕСТИТЬ ПриходДалееСтроки
ИЗ
	ИтогСерии КАК ИтогСерии
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ОборотНомер КАК ОборотНомер
		ПО ИтогСерии.Номенклатура = ОборотНомер.Номенклатура
			И ИтогСерии.СерияНоменклатуры = ОборотНомер.СерияНоменклатуры
			И ИтогСерии.Регистратор = ОборотНомер.Регистратор
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПриходДалееСтроки.Номенклатура,
	ПриходДалееСтроки.СерияНоменклатуры,
	ПриходДалееСтроки.Остаток,
	ПриходДалееСтроки.Период,
	ПриходДалееСтроки.Регистратор,
	ПриходДалееСтроки.КоличествоПриход,
	ПриходДалееСтроки.Склад,
	ПриходДалееСтроки.ОстатокЗдесь,
	ПриходДалееСтроки.НоменклатураАртикул,
	ПриходДалееСтроки.НомерСтроки,
	ПриходДалееСтроки.КоличествоПриходДалее,
	ПриходДалееСтроки.КоЛВоВСтроке,
	СУММА(ПриходДалееСтроки1.КоЛВоВСтроке) КАК КоЛВоВСтрокеИтог
ПОМЕСТИТЬ ГруппаПриходСтроки
ИЗ
	ПриходДалееСтроки КАК ПриходДалееСтроки
		ЛЕВОЕ СОЕДИНЕНИЕ ПриходДалееСтроки КАК ПриходДалееСтроки1
		ПО ПриходДалееСтроки.Номенклатура = ПриходДалееСтроки1.Номенклатура
			И ПриходДалееСтроки.СерияНоменклатуры = ПриходДалееСтроки1.СерияНоменклатуры
			И ПриходДалееСтроки.Регистратор = ПриходДалееСтроки1.Регистратор
			И ПриходДалееСтроки.НомерСтроки > ПриходДалееСтроки1.НомерСтроки

СГРУППИРОВАТЬ ПО
	ПриходДалееСтроки.Номенклатура,
	ПриходДалееСтроки.СерияНоменклатуры,
	ПриходДалееСтроки.Период,
	ПриходДалееСтроки.Регистратор,
	ПриходДалееСтроки.Склад,
	ПриходДалееСтроки.НоменклатураАртикул,
	ПриходДалееСтроки.Остаток,
	ПриходДалееСтроки.КоличествоПриход,
	ПриходДалееСтроки.ОстатокЗдесь,
	ПриходДалееСтроки.НомерСтроки,
	ПриходДалееСтроки.КоличествоПриходДалее,
	ПриходДалееСтроки.КоЛВоВСтроке
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ГруппаПриходСтроки.Номенклатура,
	ГруппаПриходСтроки.СерияНоменклатуры,
	ГруппаПриходСтроки.Остаток,
	ГруппаПриходСтроки.Период,
	ГруппаПриходСтроки.Регистратор,
	ГруппаПриходСтроки.КоличествоПриход,
	ГруппаПриходСтроки.Склад,
	ГруппаПриходСтроки.ОстатокЗдесь,
	ГруппаПриходСтроки.НоменклатураАртикул,
	ГруппаПриходСтроки.НомерСтроки,
	ГруппаПриходСтроки.КоличествоПриходДалее,
	ГруппаПриходСтроки.КоЛВоВСтроке,
	ГруппаПриходСтроки.КоЛВоВСтрокеИтог,
	ВЫБОР
		КОГДА ГруппаПриходСтроки.ОстатокЗдесь - ЕСТЬNULL(ГруппаПриходСтроки.КоЛВоВСтрокеИтог, 0) <= 0
			ТОГДА 0
		ИНАЧЕ ВЫБОР
				КОГДА ГруппаПриходСтроки.ОстатокЗдесь - ЕСТЬNULL(ГруппаПриходСтроки.КоЛВоВСтрокеИтог, 0) <= ГруппаПриходСтроки.КоЛВоВСтроке
					ТОГДА ГруппаПриходСтроки.ОстатокЗдесь - ЕСТЬNULL(ГруппаПриходСтроки.КоЛВоВСтрокеИтог, 0)
				ИНАЧЕ ГруппаПриходСтроки.КоЛВоВСтроке
			КОНЕЦ
	КОНЕЦ КАК ОстатокПоСтроке
ПОМЕСТИТЬ ИтогГруппаСтрок
ИЗ
	ГруппаПриходСтроки КАК ГруппаПриходСтроки
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ИтогГруппаСтрок.Номенклатура,
	ИтогГруппаСтрок.СерияНоменклатуры,
	ИтогГруппаСтрок.Остаток,
	ИтогГруппаСтрок.Период,
	ИтогГруппаСтрок.Регистратор,
	ИтогГруппаСтрок.КоличествоПриход,
	ИтогГруппаСтрок.Склад,
	ИтогГруппаСтрок.ОстатокЗдесь,
	ИтогГруппаСтрок.НоменклатураАртикул,
	ИтогГруппаСтрок.НомерСтроки,
	ИтогГруппаСтрок.КоличествоПриходДалее,
	ИтогГруппаСтрок.КоЛВоВСтроке,
	ИтогГруппаСтрок.КоЛВоВСтрокеИтог,
	ИтогГруппаСтрок.ОстатокПоСтроке
ПОМЕСТИТЬ ПолныйИтог
ИЗ
	ИтогГруппаСтрок КАК ИтогГруппаСтрок
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПолныйИтог.Номенклатура,
	ПолныйИтог.СерияНоменклатуры,
	ПолныйИтог.Остаток,
	ПолныйИтог.Период,
	ПолныйИтог.Регистратор,
	ПолныйИтог.КоличествоПриход,
	ПолныйИтог.Склад,
	ПолныйИтог.ОстатокЗдесь,
	ПолныйИтог.НоменклатураАртикул,
	ПолныйИтог.НомерСтроки,
	ПолныйИтог.КоличествоПриходДалее,
	ПолныйИтог.КоЛВоВСтроке,
	ПолныйИтог.КоЛВоВСтрокеИтог,
	ПолныйИтог.ОстатокПоСтроке,
	ПоступлениеТоваровУслугТовары.Цена * ПоступлениеТоваровУслугТовары.Ссылка.КурсВзаиморасчетов * 1.18 КАК Цена,
	ПоступлениеТоваровУслугТовары.ЗаказПоставщику.Номер КАК ЗаказПоставщику,
	ПоступлениеТоваровУслугТовары.Ссылка.Контрагент,
	ПоступлениеТоваровУслугТовары.Ссылка КАК Поступление
ПОМЕСТИТЬ ОбщийИтог
ИЗ
	ПолныйИтог КАК ПолныйИтог
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
		ПО ПолныйИтог.Регистратор = ПоступлениеТоваровУслугТовары.Ссылка
			И ПолныйИтог.НомерСтроки = ПоступлениеТоваровУслугТовары.НомерСтроки
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОбщийИтог.Номенклатура,
	ОбщийИтог.СерияНоменклатуры.НомерГТД.Код КАК СерияНоменклатуры,
	ОбщийИтог.Остаток,
	ОбщийИтог.Период,
	ОбщийИтог.Регистратор,
	ОбщийИтог.КоличествоПриход,
	ОбщийИтог.Склад,
	ОбщийИтог.ОстатокЗдесь,
	ОбщийИтог.НоменклатураАртикул,
	ОбщийИтог.НомерСтроки,
	ОбщийИтог.КоличествоПриходДалее,
	ОбщийИтог.КоЛВоВСтроке,
	ОбщийИтог.КоЛВоВСтрокеИтог,
	ОбщийИтог.ОстатокПоСтроке,
	ОбщийИтог.Цена,
	ВЫБОР
		КОГДА СчетФактураПолученный.ДатаВходящегоДокумента ЕСТЬ NULL 
			ТОГДА ОбщийИтог.Поступление.ДатаВходящегоДокумента
		ИНАЧЕ СчетФактураПолученный.ДатаВходящегоДокумента
	КОНЕЦ КАК ДатаВхДокумента,
	ВЫБОР
		КОГДА СчетФактураПолученный.НомерВходящегоДокумента ЕСТЬ NULL 
			ТОГДА ОбщийИтог.Поступление.НомерВходящегоДокумента
		ИНАЧЕ СчетФактураПолученный.НомерВходящегоДокумента
	КОНЕЦ КАК НомерВхДокумента,
	ОбщийИтог.Контрагент,
	ОбщийИтог.Поступление,
	ВЫБОР
		КОГДА СчетФактураПолученный.Ссылка ЕСТЬ NULL 
			ТОГДА ВЫБОР
					КОГДА ОбщийИтог.Контрагент.РМС_КодВеб = 0
						ТОГДА ОбщийИтог.Контрагент.РМС_КодХанса
					ИНАЧЕ ОбщийИтог.Контрагент.РМС_КодВеб
				КОНЕЦ
		ИНАЧЕ ВЫБОР
				КОГДА СчетФактураПолученный.КаналСбыта.РМС_КодВеб = 0
					ТОГДА СчетФактураПолученный.КаналСбыта.РМС_КодХанса
				ИНАЧЕ СчетФактураПолученный.КаналСбыта.РМС_КодВеб
			КОНЕЦ
	КОНЕЦ КАК КодВеб,
	ОбщийИтог.ЗаказПоставщику,
	ОбщийИтог.Номенклатура.РМС_Производитель КАК Бренд,
	ОбщийИтог.СерияНоменклатуры.СтранаПроисхождения КАК Страна,
	ОбщийИтог.Поступление.Номер
ИЗ
	ОбщийИтог КАК ОбщийИтог
		ЛЕВОЕ СОЕДИНЕНИЕ Документ._Инвойс КАК СчетФактураПолученный
		ПО ОбщийИтог.Регистратор = СчетФактураПолученный.Поступление

 

 Спасибо за внимание, обоснованная критика приветствуется

 

UPD: Добавил временную таблицу группировки резервов т.к. при резервировании на разных складах в первичной таблице не группируется, видимо из за замены склада.

 

См. также

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

10000 руб.

02.09.2020    129548    700    390    

749

Как посмотреть итоговый запрос в отчете СКД

Запросы СКД Система компоновки данных Россия Бесплатно (free)

Часто при разработке отчетов в СКД возникает ситуация, когда не совсем понятно, почему отчет выводит не те данные, которые нужны, либо не выводит вовсе. Возникает потребность увидеть конечный запрос, который формирует СКД. Как это сделать, рассмотрим в этой статье.

15.05.2024    2708    implecs_team    4    

33

Пропорциональное распределение в запросе с использованием АвтоНомерЗаписи()

Запросы Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Часто поступают задачи по произвольному распределению общих сумм. После распределения иногда пропадают копейки. Суть решения добавить АвтоНомерЗаписи() в ВТ распределения, и далее используя функции МАКСИМУМ или МИНИМУМ можем положить разницу копеек в первую или последнюю строку знаменателя распределения.

11.04.2024    2609    andrey_sag    10    

32

Для чего используют конструкцию запроса "ГДЕ ЛОЖЬ" в СКД на примере конфигурации 1С:ERP

Запросы СКД Платформа 1С v8.3 Запросы Система компоновки данных 1С:ERP Управление предприятием 2 Бесплатно (free)

В типовых конфигурациях разработчики компании 1С иногда используют в отчетах, построенных на СКД, такую конструкцию, как "ГДЕ ЛОЖЬ". Такая конструкция говорит о том, что данные в запросе не будут получены совсем. Для чего же нужен тогда запрос?

13.02.2024    6295    KawaNoNeko    23    

26

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    2284    2    Yashazz    0    

31

Запрос 1С copilot

Инструментарий разработчика Запросы Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Бесплатно (free)

Пишем на человеческом языке, что нам надо, и получаем текст запроса на языке 1С. Используются большие языковые модели (LLM GPT) от OpenAI или Яндекс на выбор.

15.01.2024    7099    39    mkalimulin    32    

53

PrintWizard: поддержка представлений ЗУП в конструкторе

Инструментарий разработчика Запросы Платформа 1С v8.3 Бесплатно (free)

Одной из интересных задач, стоящих в процессе разработки, была поддержка механизма представлений в ЗУП. Но не просто возможность исполнения запросов с ними. Основная проблема была в том, чтобы с ними было удобно работать, а именно: создавать, модифицировать и отлаживать. Кратко о том, что в итоге получилось...

14.12.2023    2014    vandalsvq    7    

29

Консоль запросов УФ 8.3.2.24.12 (мод от Dr.Zombi)

Инструментарий разработчика Запросы Платформа 1С v8.3 Управляемые формы Запросы Россия Абонемент ($m)

Работа с запросом и СКД, Полная поддержка пакетных запросов, временных таблиц. Главное скорость отладки запроса и данных, а красота вторична.

1 стартмани

07.12.2023    3478    52    DrZombi    54    

21
Оставьте свое сообщение