Дополнительные cведения для групп номенклатуры

_Подключаемый()

Процедура ДС_ЗаполнитьНаборыСвойствОбъекта(Объект, ТипСсылки, НаборыСвойств, СтандартнаяОбработка, КлючНазначения) Экспорт
	
	//++ НЕ ГОСИС
	Если ТипСсылки = Тип("СправочникСсылка.Партнеры") Тогда
		
		СписокСвойств = ПолучитьНаборыСвойствДляПартнеров(Объект.Клиент, Объект.Конкурент, Объект.Поставщик, Объект.ПрочиеОтношения);
	
	// +++
	//ИначеЕсли ТипСсылки = Тип("СправочникСсылка.Номенклатура") И НЕ Объект.ЭтоГруппа Тогда
	ИначеЕсли ТипСсылки = Тип("СправочникСсылка.Номенклатура") Тогда
	// ---

		СписокСвойств = ДС_ПолучитьНаборыСвойствДляНоменклатуры(Объект);
		
	ИначеЕсли ТипСсылки = Тип("СправочникСсылка.ХарактеристикиНоменклатуры") Тогда
		
		СписокСвойств = ПолучитьНаборыСвойствДляХарактеристикНоменклатуры(Объект);
		
	ИначеЕсли ТипСсылки = Тип("СправочникСсылка.СерииНоменклатуры") Тогда
		
		СписокСвойств = ПолучитьНаборыСвойствДляСерииНоменклатуры(Объект);
		
	//++ НЕ УТ
//	ИначеЕсли ТипСсылки = Тип("СправочникСсылка.ОбъектыЭксплуатации") Тогда
		
	//	СписокСвойств = ПолучитьНаборыСвойствДляОбъектаЭксплуатации(Объект);
		
	//-- НЕ УТ
	Иначе
		
		Возврат;
		
	КонецЕсли;
	
	Для Каждого ЭлементСписка Из СписокСвойств Цикл
		
		СтрокаНабора = НаборыСвойств.Добавить();
		
		СтрокаНабора.Набор 	   = ЭлементСписка.Значение;
		СтрокаНабора.Заголовок = ЭлементСписка.Представление;
		
	КонецЦикла;
	
	//-- НЕ ГОСИС
	
КонецПроцедуры

// Устарела. Будет удалена в следующей редакции БСП.
// 
// Теперь вместо указания имени реквизита, содержащего вид владельца свойств,
// например, ВидНоменклатуры типа СправочникСсылка.ВидыНоменклатуры,
// у которого должен быть реквизит НаборСвойств типа
// СправочникСсылка.НаборыДополнительныхРеквизитовИСведений
// следует заполнить набор свойств для объекта СправочникСсылка.Номенклатура
// в процедуре ЗаполнитьНаборыСвойствОбъекта, как и в случае нескольких
// наборов свойств. Отличие лишь в том, что набор будет получен из реквизита
// объекта вида владельца самостоятельно, что позволяет использовать несколько
// разных реквизитов с удобными именами для разных типов объектов у которых
// один вид объектов. Например, Справочник.Проекты это вид владельца свойств
// у Справочник.Ошибки и Справочник.Задачи, для которых в справочнике Проекты
// будут реквизиты НаборСвойствОшибок, НаборСвойствЗадач.
//
Функция ПолучитьИмяРеквизитаВидаОбъекта(Ссылка) Экспорт
	
	Если ТипЗнч(Ссылка) = Тип("СправочникСсылка.Номенклатура") Тогда
		Возврат "ВидНоменклатуры";
	КонецЕсли;
	
	Возврат "";
	
КонецФункции

////////////////////////////////////////////////////////////­////////////////////
// ФУНКЦИИ ДЛЯ РАБОТЫ СО СПРАВОЧНИКОМ ПАРТНЕРЫ

Функция ПолучитьНаборыСвойствДляПартнеров(Клиент, Конкурент, Поставщик, ПрочиеОтношения) Экспорт
	
	Наборы = Новый СписокЗначений;
	
	Наборы.Добавить(Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_Партнеры_Общие, НСтр("ru='Общие для всех партнеров';uk='Загальні для всіх партнерів'"));
	
	Если Клиент Тогда
		Наборы.Добавить(Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_Партнеры_Клиенты,    НСтр("ru='Для клиентов';uk='Для клієнтів'"));
	КонецЕсли;
	
	Если Конкурент Тогда
		Наборы.Добавить(Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_Партнеры_Конкуренты, НСтр("ru='Для конкурентов';uk='Для конкурентів'"));
	КонецЕсли;
	
	Если Поставщик Тогда
		Наборы.Добавить(Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_Партнеры_Поставщики, НСтр("ru='Для поставщиков';uk='Для постачальників'"));
	КонецЕсли;
	
	Если ПрочиеОтношения Тогда
		Наборы.Добавить(Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_Партнеры_Прочие,     НСтр("ru='Для прочих';uk='Для інших'"));
	КонецЕсли;
	
	Возврат Наборы;
	
КонецФункции // ПолучитьНаборыСвойствДляПартнеров()

////////////////////////////////////////////////////////////­////////////////////
// ФУНКЦИИ ДЛЯ РАБОТЫ СО СПРАВОЧНИКОМ НОМЕНКЛАТУРЫ

Функция ДС_ПолучитьНаборыСвойствДляНоменклатуры(Объект) Экспорт
	
	Наборы = Новый СписокЗначений;
	//++ НЕ ГОСИС
	НаборСвойств = Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_Номенклатура_Общие;
	Наборы.Добавить(НаборСвойств, НСтр("ru = 'Общие свойства'"));
	
	// +++
	Если НЕ Объект.ЭтоГруппа Тогда
	// ---
		НаборСвойств = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Объект.ВидНоменклатуры, "НаборСвойств");
		Наборы.Добавить(НаборСвойств, НСтр("ru = 'Свойства для вида номенклатуры'"));
	// +++	
	КонецЕсли;
	// ---
	
	//-- НЕ ГОСИС
	Возврат Наборы;

	
КонецФункции


Функция ПолучитьНаборыСвойствДляХарактеристикНоменклатуры(Объект) Экспорт
	
	Наборы = Новый СписокЗначений;
	
	НаборСвойств = Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_ХарактеристикиНоменклатуры_Общие;
	Наборы.Добавить(НаборСвойств, НСтр("ru='Общие свойства характеристик';uk='Загальні властивості характеристик'"));
	
	Если ТипЗнч(Объект.Владелец) = Тип("СправочникСсылка.ВидыНоменклатуры") Тогда
		
		НаборСвойств = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Объект.Владелец, "НаборСвойствХарактеристик");
		Наборы.Добавить(НаборСвойств, НСтр("ru='Свойства характеристик для вида номенклатуры';uk='Властивості характеристик для виду номенклатури'"));
		
	ИначеЕсли ТипЗнч(Объект.Владелец) = Тип("СправочникСсылка.Номенклатура") Тогда
		
		Запрос = Новый Запрос;
		Запрос.Текст = 
		"ВЫБРАТЬ
		|	Номенклатура.ВидНоменклатуры КАК ВидНоменклатуры
		|ИЗ
		|	Справочник.Номенклатура КАК Номенклатура
		|ГДЕ
		|	Номенклатура.Ссылка = &Ссылка";
		
		Запрос.УстановитьПараметр("Ссылка", Объект.Владелец);
		
		Выборка = Запрос.Выполнить().Выбрать();
		Если Выборка.Следующий() Тогда
			НаборСвойств = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Выборка.ВидНоменклатуры, "НаборСвойствХарактеристик");
			Наборы.Добавить(НаборСвойств, НСтр("ru='Свойства характеристик для номенклатуры';uk='Властивості характеристик для номенклатури'"));
		КонецЕсли;
		
	КонецЕсли;
	
	Возврат Наборы;
	
КонецФункции // ПолучитьНаборыСвойствДляХарактеристикНоменклатуры()

Функция ПолучитьНаборыСвойствДляСерииНоменклатуры(Объект) Экспорт
	
	Наборы = Новый СписокЗначений;
	
	НаборСвойств = Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник_СерииНоменклатуры_Общие;
	Наборы.Добавить(НаборСвойств, НСтр("ru='Общие свойства';uk='Загальні властивості'"));
	
	НаборСвойств = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Объект.ВидНоменклатуры, "НаборСвойствСерий");
	Наборы.Добавить(НаборСвойств, НСтр("ru='Свойства для шаблона серий номенклатуры';uk='Властивості шаблону серій номенклатури'"));
	
	Возврат Наборы;
	
КонецФункции // ПолучитьНаборыСвойствДляНоменклатуры()

#КонецОбласти