При выполнении операции закрытия месяца "Распределение затрат и расчет себестоимости" произошла ошибка: Переполнение стека встроенного языка на сервере

10.02.22

Описание решения проблемы переполнения стека при выполнении операции закрытия месяца "Распределение затрат и расчет себестоимости" в 1С:ERP Управление предприятием, редакция 2.4.13.123.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование		По подписке [?]	Купить один файл
РассчитатьПартиюРекурсивно .bsl 29,76Kb 5	5	Скачать (1 SM)	Купить за 1 850 руб.

Столкнулись с проблемой, когда при распределении затрат и расчете себестоимости при закрытии месяца (1С:ERP Управление предприятием, редакция 2.4.13.123) получили ошибку "Переполнение стека встроенного языка на сервере". Мы воспользовались встроенным ограничителем (в настройках формы закрытия месяца) для рекурсивных функции и экспериментально выяснили, что для избежания этой ошибки значение по умолчанию 650 надо уменьшить до 430, тогда ошибка уходит, но и затраты полностью не распределяются. Проблема не решена.

Анализ работы алгоритма и данных, показал, что проблема не в циклических ссылках (в штатном алгоритме заложена проверка на циклические ссылки), а просто очень большой список документов для распределения, где-то порядка 1300+, а штатный алгоритм на каждый шаг для распределения вызывает рекурсивно сам себя и чтобы полностью распределить все затраты, понадобилась бы глубина рекурсии 1300+ соответственно.

Т.к. проблема была не в данных, а в самом алгоритме, было принято решение переписать рекурсию в итерацию, а переменные контекста хранить в массиве, размер которого уже ограничивается только доступной оперативной памятью компьютера, а не размером callstack.

Привожу получившийся результат:

Измененная функция РасчетСебестоимостиПрикладныеАлгоритмы.РассчитатьПартиюРекурсивно

Функция ИнициализироватьКонтекст(ПараметрыРасчета, Данные, ИндексРасхода)
	Контекст = Новый Структура("Результат", Неопределено);
	Контекст.Вставить("ИндексРасхода", ИндексРасхода);

	СтатистикаРасчета = ПараметрыРасчета.РаспределениеПартий.СтатистикаРасчета[ПараметрыРасчета.РаспределениеПартий.СтатистикаРасчета.Количество() - 1];
	СтатистикаРасчета.КоличествоДанных = СтатистикаРасчета.КоличествоДанных + 1;
	
	Если НЕ НачалоЗамераРасчетаЦепочек(ПараметрыРасчета, Данные, ИндексРасхода) Тогда
		Контекст.Результат = ОкончаниеЗамераРасчетаЦепочек(ПараметрыРасчета, "ПереполнениеСтека");
		Возврат Контекст;
	КонецЕсли;
	
	ОписаниеДвижений = ПараметрыРасчета.РаспределениеПартий.ОписаниеДвижений;
	Контекст.Вставить("ОписаниеДвижений", ОписаниеДвижений);
	
	Контекст.Вставить("ЦепочкаРасхода", Данные.ЦепочкиДвижений[ИндексРасхода]);
	Если Контекст.ЦепочкаРасхода = Неопределено Тогда
		Контекст.Результат = ОкончаниеЗамераРасчетаЦепочек(ПараметрыРасчета, "НеТребуется");
		Возврат Контекст;
	КонецЕсли;
	
	Контекст.Вставить("Источники", Контекст.ЦепочкаРасхода.Источники);
	Если Контекст.Источники.Количество() = 0 Тогда
		Если ОписаниеДвижений.Свойство("УдалятьСтрокиБезИсточников") Тогда
			Контекст.Расход = Данные.Расходы[ИндексРасхода];
			Данные.Расходы.Удалить(ИндексРасхода);
			Данные.ЦепочкиДвижений.Удалить(ИндексРасхода);
			Данные.СтрокиРасходов.Удалить(Контекст.Расход);
			Данные.СтрокиЦепочек.Удалить(Контекст.ЦепочкаРасхода);
		КонецЕсли;

		Контекст.Результат = ОкончаниеЗамераРасчетаЦепочек(ПараметрыРасчета, "НетИсточников");
		Возврат Контекст;
	КонецЕсли;
	
	Если ИндексРасхода = Данные.ПройденныйПуть[ИндексРасхода] Тогда
		Контекст.Результат = ОкончаниеЗамераРасчетаЦепочек(ПараметрыРасчета, "Зацикливание");
		Возврат Контекст;
	КонецЕсли;
	
	ИндексСтроки = Данные.ИндексСтроки;
	Для Каждого ИндексПрихода Из Контекст.Источники Цикл
		Если ИндексПрихода > ИндексСтроки Тогда
			Контекст.Результат = ОкончаниеЗамераРасчетаЦепочек(ПараметрыРасчета, "НетДанных"); // еще нет всех строк для распределения
			Возврат Контекст;
		КонецЕсли;
	КонецЦикла;
	
	Данные.ПройденныйПуть.Вставить(ИндексРасхода, ИндексРасхода);
	
	Контекст.Вставить("НовыеПриходы", Неопределено);
	
	Расход = Данные.Расходы[ИндексРасхода];
	Контекст.Вставить("Расход", Расход);
	Контекст.Вставить("ЕстьСторно", ОписаниеДвижений.Свойство("ЕстьСторно"));
	Контекст.Вставить("ЭтоСторно", (Расход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Сторно
				ИЛИ Расход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.СторноВозвратНаДругойСклад
				ИЛИ Контекст.ЕстьСторно И Расход.Сторно));
	
	ТребуетсяСортировка = Ложь;
	Если Контекст.Источники.Количество() > 1 И ЗначениеЗаполнено(ОписаниеДвижений.ПоляСортировки) Тогда
		
		ЗначенияПолей = Новый Структура(ОписаниеДвижений.ПоляСортировки);
		ЗаполнитьЗначенияСвойств(ЗначенияПолей, Контекст.Расход);
		
		Для Каждого ПолеСортировки Из ЗначенияПолей Цикл
			Если ЗначениеЗаполнено(ПолеСортировки.Значение) Тогда
				ТребуетсяСортировка = Истина;
				Прервать;
			КонецЕсли;
		КонецЦикла;
		
	КонецЕсли;
	
	Если ТребуетсяСортировка Тогда
		СортироватьИсточникиПоФИФО_ЛИФО(Контекст.Источники, ОписаниеДвижений.ПолеПорядка, Данные.Приходы, Данные.Расходы, Контекст.ЭтоСторно);
		СортироватьИсточникиПоЗначениямПолей(Контекст.Источники, ЗначенияПолей, Данные.Приходы, Данные.Расходы, Контекст.Расход.Регистратор, Контекст.ЭтоСторно);
	КонецЕсли;
	
	Контекст.Вставить("Счетчик", 0);
	Контекст.Вставить("ВГраница", Контекст.Источники.ВГраница());
	
	ИнвертироватьПоказатели(Расход, ОписаниеДвижений.Показатели, Контекст.ЭтоСторно);
	
	Контекст.Вставить("УменьшатьБазисРасхода", ОписаниеДвижений.Свойство("УменьшатьБазис"));
	Контекст.Вставить("БазисРасходаДоРасчета", Расход[ОписаниеДвижений.БазисРасхода]);
	Контекст.Вставить("ТекущийБазисРасхода", Контекст.БазисРасходаДоРасчета);
	Контекст.Вставить("ИсточникиКУдалению", Новый Массив);
	Контекст.Вставить("ИндексИсточника", Неопределено);
	// 0 - начало цикла до рекурсивного вызова, 
	// 1 - сразу после завершения рекурсии
	// 2 - оставшаяся часть цикла
	Контекст.Вставить("Шаг", 0);
	
	Возврат Контекст;
КонецФункции

Функция ЗавершитьКонтекст(ПараметрыРасчета, Данные, Контекст)
	Расход = Контекст.Расход;
	УменьшатьБазисРасхода = Контекст.УменьшатьБазисРасхода;
	ОписаниеДвижений = Контекст.ОписаниеДвижений;
	БазисРасходаДоРасчета = Контекст.БазисРасходаДоРасчета;
	ТекущийБазисРасхода = Контекст.ТекущийБазисРасхода;
	НовыеПриходы = Контекст.НовыеПриходы;
	ИсточникиКУдалению = Контекст.ИсточникиКУдалению;
	Источники = Контекст.Источники;
	ЦепочкаРасхода = Контекст.ЦепочкаРасхода;
	ЭтоСторно = Контекст.ЭтоСторно;
	ИндексРасхода = Контекст.ИндексРасхода;

	Если УменьшатьБазисРасхода Тогда
		Расход[ОписаниеДвижений.БазисРасхода] = ТекущийБазисРасхода;
	КонецЕсли;
	
	Если ОписаниеДвижений.Свойство("ПоляГруппировки")
	 И НовыеПриходы <> Неопределено
	 И НовыеПриходы.Количество() > 0 Тогда
		
		НовыеПриходы.Свернуть(ОписаниеДвижений.ПоляГруппировки, ОписаниеДвижений.ПоляСуммирования);
		
		Если Данные.Приходы[ИндексРасхода] = Неопределено Тогда
			Данные.Приходы.Вставить(ИндексРасхода, Новый Массив);
		КонецЕсли;
		
		Для Каждого Строка Из НовыеПриходы Цикл
			НовыйПриход = Данные.СтрокиПриходов.Добавить();
			ЗаполнитьЗначенияСвойств(НовыйПриход, Строка);
			Если НовыйПриход[ОписаниеДвижений.БазисРасхода] = 0 Тогда
				НовыйПриход[ОписаниеДвижений.БазисРасхода] = БазисРасходаДоРасчета;
			КонецЕсли;
			Данные.Приходы[ИндексРасхода].Добавить(НовыйПриход);
		КонецЦикла;
		
		Контекст.НовыеПриходы = Неопределено;
		
	КонецЕсли;
	
	Если ИсточникиКУдалению.Количество() > 0 Тогда
		Для Каждого ИндексИсточника Из ИсточникиКУдалению Цикл
			ИндексВМассиве = Источники.Найти(ИндексИсточника);
			Если ИндексВМассиве <> Неопределено Тогда
				Источники.Удалить(ИндексВМассиве);
			КонецЕсли;
		КонецЦикла;
		Данные.ЦепочкиДвижений[ИндексРасхода].Источники = Источники;
	КонецЕсли;
	
	Если (Расход[ОписаниеДвижений.БазисРасхода] > 0
	 ИЛИ Расход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходыБезПартии И Расход.Знаменатель > 0)
	 И (Источники.Количество() > 0 ИЛИ НЕ ОписаниеДвижений.Свойство("УдалятьСтрокиБезИсточников")) Тогда
		
		ИнвертироватьПоказатели(Расход, ОписаниеДвижений.Показатели, ЭтоСторно);
		
	Иначе
		
		Данные.Расходы.Удалить(ИндексРасхода);
		Данные.ЦепочкиДвижений.Удалить(ИндексРасхода);
		Данные.СтрокиРасходов.Удалить(Расход);
		Данные.СтрокиЦепочек.Удалить(ЦепочкаРасхода);
		
	КонецЕсли;

	Контекст.Результат = ОкончаниеЗамераРасчетаЦепочек(ПараметрыРасчета, "Выполнено");
	Возврат Контекст;
КонецФункции

Функция РассчитатьПартиюРекурсивно(ПараметрыРасчета, Данные, ИндексРасходаНачальный)

	Стэк = Новый Массив();

	НовыйКонтекст = ИнициализироватьКонтекст(ПараметрыРасчета, Данные, ИндексРасходаНачальный);
	Если НовыйКонтекст.Результат <> Неопределено Тогда
		Возврат НовыйКонтекст.Результат;
	КонецЕсли;

	Стэк.Добавить(НовыйКонтекст);
	РезультатРасчета = НовыйКонтекст;
	Пока Стэк.Количество() > 0 Цикл
		Контекст = Стэк[Стэк.ВГраница()];
		ИндексРасхода = Контекст.ИндексРасхода;
		
		Если Контекст.Шаг = 0 Тогда
			Если Контекст.Счетчик > Контекст.ВГраница Тогда
				РезультатРасчета = ЗавершитьКонтекст(ПараметрыРасчета, Данные, Контекст);
				Стэк.Удалить(Стэк.ВГраница());
				Продолжить;
			КонецЕсли;
			
			Контекст.ИндексИсточника = Контекст.Источники[?(Контекст.ЭтоСторно, Контекст.ВГраница - Контекст.Счетчик, Контекст.Счетчик)];
			Контекст.Счетчик = Контекст.Счетчик + 1;

			Контекст.Вставить("МассивПриходов", Данные.Приходы[Контекст.ИндексИсточника]);
			Если Контекст.МассивПриходов = Неопределено Тогда
				
				Если Данные.Расходы[Контекст.ИндексИсточника] = Неопределено Тогда
					Контекст.ИсточникиКУдалению.Добавить(Контекст.ИндексИсточника);
					Продолжить;
				КонецЕсли;
				
				Источник = Данные.Расходы[Контекст.ИндексИсточника];
				Если НЕ Источник.РасчетЗавершен Тогда
					Контекст.Шаг = 1;
					
					НовыйКонтекст = ИнициализироватьКонтекст(ПараметрыРасчета, Данные, Контекст.ИндексИсточника);
					Если НовыйКонтекст.Результат = Неопределено Тогда
						Стэк.Добавить(НовыйКонтекст);
						Продолжить;
					КонецЕсли;
				Иначе
					Контекст.Вставить("МассивПриходов", Данные.Приходы[Контекст.ИндексИсточника]);
					Если Контекст.МассивПриходов = Неопределено Тогда
						Продолжить;
					КонецЕсли;
				КонецЕсли;
				
			КонецЕсли;
		КонецЕсли;

		Если Контекст.Шаг = 1 Тогда
			Контекст.ВГраница = Контекст.Источники.ВГраница();
			Если Данные.Расходы[ИндексРасхода] = Неопределено Тогда
				Контекст.Результат = ОкончаниеЗамераРасчетаЦепочек(ПараметрыРасчета, "НеТребуется");
				РезультатРасчета = Контекст;
				Стэк.Удалить(Стэк.ВГраница());
				Продолжить;
			КонецЕсли;
			Контекст.МассивПриходов = Данные.Приходы[Контекст.ИндексИсточника];
			Если Контекст.МассивПриходов = Неопределено Тогда
				Контекст.Шаг = 0;
				Продолжить;
			КонецЕсли;
		КонецЕсли;

		Контекст.Шаг = 0;
		ЭтоСторно = Контекст.ЭтоСторно;
		ЕстьСторно = Контекст.ЕстьСторно;
		ОписаниеДвижений = Контекст.ОписаниеДвижений;
		БазисРасходаДоРасчета = Контекст.БазисРасходаДоРасчета;
		ТекущийБазисРасхода = Контекст.ТекущийБазисРасхода;
		УменьшатьБазисРасхода = Контекст.УменьшатьБазисРасхода;
		Расход = Контекст.Расход;
		ИндексИсточника = Контекст.ИндексИсточника;
		МассивПриходов = Контекст.МассивПриходов;
		ЦепочкаРасхода = Контекст.ЦепочкаРасхода;

		Если ЭтоСторно Тогда
			СортироватьПриходыПоЛИФО(ОписаниеДвижений.ПолеПорядка, Контекст.МассивПриходов);
		КонецЕсли;
		
		ПриходыКУдалению = Новый Массив;
		
		КоличествоДвижений = ПараметрыРасчета.РаспределениеПартий.РасчетныеПартии.Количество();
		УменьшениеБазисаРасхода = 0;

		Для Каждого Приход Из МассивПриходов Цикл
			
			Если УменьшатьБазисРасхода Тогда
				
				Если Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходы
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходыБезПартии
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходыСПартией
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходыРегл
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходыУпр
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.КорректировкаПриобретенияПрошлогоПериода
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ОтклонениеВСтоимости
				 ИЛИ (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Прошлое
				 	И ЗначениеЗаполнено(Приход.Номенклатура))
				 ИЛИ (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Сторно
				 	И ЗначениеЗаполнено(Приход.Номенклатура)
				 	И ОписаниеДвижений.Контекст <> "ПодготовкаДанныхДляУчетаНДСиУСН")
				 ИЛИ (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ОстатокСгруппированный
				 	И ЗначениеЗаполнено(Приход.Номенклатура))
				 ИЛИ (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ПартияСгруппированная
				 	И ЗначениеЗаполнено(Приход.Номенклатура))
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Партия
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Остаток Тогда
					
					Если ОписаниеДвижений.Контекст = "ПодготовкаДанныхДляУчетаНДСиУСН"
					 И (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ОстатокСгруппированный
					 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ПартияСгруппированная) Тогда
						Расход[ОписаниеДвижений.БазисРасхода] = ТекущийБазисРасхода;
						Если Приход.Количество <> 0 Тогда // данные о партии товара (не доп. расходы)
							УменьшениеБазисаРасхода = Мин(ТекущийБазисРасхода, Приход[ОписаниеДвижений.БазисРасхода]);
						// Могут быть только доп расходы по товарам. У таких записей нет количества.
						ИначеЕсли УменьшениеБазисаРасхода = 0 Тогда
							УменьшениеБазисаРасхода = ТекущийБазисРасхода;
						КонецЕсли;
					Иначе
						
						Расход[ОписаниеДвижений.БазисРасхода] = БазисРасходаДоРасчета;
					КонецЕсли;
					
				ИначеЕсли ОписаниеДвижений.Контекст = "ПодготовкаДанныхДляУчетаНДСиУСН"
				 И (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Партия
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Выпуск
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.СписанияНаВыпуск
				 ИЛИ (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Потребление
				 	И Расход.ТипЗаписи <> Перечисления.ТипыЗаписейПартий.Сторно
				 	И Расход.ТипЗаписи <> Перечисления.ТипыЗаписейПартий.СторноВозвратНаДругойСклад)
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ПотреблениеАвто
				 ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ПотреблениеПроизводство) Тогда
					
					Расход[ОписаниеДвижений.БазисРасхода] = БазисРасходаДоРасчета;
					
				ИначеЕсли ОписаниеДвижений.Контекст <> "ПодготовкаДанныхДляУчетаНДСиУСН"
				 И (Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.СписанияНаВыпуск
				 	ИЛИ Приход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.СписанияНаВыпускПостатейные) Тогда
					
					Расход[ОписаниеДвижений.БазисРасхода] = БазисРасходаДоРасчета;
					
				Иначе
					
					УменьшениеБазисаРасхода = Мин(ТекущийБазисРасхода, Приход[ОписаниеДвижений.БазисРасхода]);
					Расход[ОписаниеДвижений.БазисРасхода] = ТекущийБазисРасхода;
					
				КонецЕсли;
				
				Если Расход[ОписаниеДвижений.БазисРасхода] <= 0 Тогда
					Продолжить;
				КонецЕсли;
				
			КонецЕсли;
			
			РасчетнаяПартия = ДобавитьИЗаполнитьРасчетнуюПартию(ПараметрыРасчета, Расход, Приход, ЭтоСторно);
			
			Если Приход[ОписаниеДвижений.БазисПрихода] <= 0 Тогда
				ПриходыКУдалению.Добавить(Приход);
			КонецЕсли;
			
			Если РасчетнаяПартия.РасчетЗавершен Тогда
				Если ЦепочкаРасхода.Приемники.Количество() > 0 Тогда
					Если ОписаниеДвижений.Свойство("ПоляГруппировки") Тогда
						
						Если Контекст.НовыеПриходы = Неопределено Тогда
							Контекст.НовыеПриходы = Данные.СтрокиПриходов.СкопироватьКолонки();
						КонецЕсли;
						НовыйПриход = Контекст.НовыеПриходы.Добавить();
						ЗаполнитьЗначенияСвойств(НовыйПриход, РасчетнаяПартия);
						ИнвертироватьПоказатели(НовыйПриход, ОписаниеДвижений.Показатели,
							НовыйПриход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Сторно
							ИЛИ НовыйПриход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.СторноВозвратНаДругойСклад
							ИЛИ ЕстьСторно И НовыйПриход.Сторно);
						
					Иначе
						
						НовыйПриход = Данные.СтрокиПриходов.Добавить();
						ЗаполнитьЗначенияСвойств(НовыйПриход, РасчетнаяПартия);
						ИнвертироватьПоказатели(НовыйПриход, ОписаниеДвижений.Показатели,
							НовыйПриход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.Сторно
							ИЛИ НовыйПриход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.СторноВозвратНаДругойСклад
							ИЛИ ЕстьСторно И НовыйПриход.Сторно);
						
						Если Данные.Приходы[ИндексРасхода] = Неопределено Тогда
							Данные.Приходы.Вставить(ИндексРасхода, Новый Массив);
						КонецЕсли;
						
						Данные.Приходы[ИндексРасхода].Добавить(НовыйПриход);
						
					КонецЕсли;
				КонецЕсли;
			Иначе
				УдалитьРасчетнуюПартию(ПараметрыРасчета, РасчетнаяПартия);
			КонецЕсли;
			
			РасчетнаяПартия = Неопределено;
			
			Если НЕ УменьшатьБазисРасхода И Расход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходыБезПартии Тогда
				Если Расход.Знаменатель <= 0 Тогда
					Прервать;
				КонецЕсли;
			ИначеЕсли НЕ УменьшатьБазисРасхода И Расход[ОписаниеДвижений.БазисРасхода] <= 0 Тогда
				Прервать;
			КонецЕсли;
			
		КонецЦикла;
		
		Если УменьшатьБазисРасхода
		 И КоличествоДвижений <> ПараметрыРасчета.РаспределениеПартий.РасчетныеПартии.Количество()
		 И УменьшениеБазисаРасхода <> 0 Тогда
			ТекущийБазисРасхода = ТекущийБазисРасхода - УменьшениеБазисаРасхода;
			Контекст.ТекущийБазисРасхода = ТекущийБазисРасхода;
		КонецЕсли;

		Для Каждого Приход Из ПриходыКУдалению Цикл
			Индекс = МассивПриходов.Найти(Приход);
			Если Индекс <> Неопределено Тогда
				МассивПриходов.Удалить(Индекс);
			КонецЕсли;
			Данные.СтрокиПриходов.Удалить(Приход);
		КонецЦикла;
		
		Если МассивПриходов.Количество() = 0 Тогда
			
			Данные.Приходы.Удалить(ИндексИсточника);
			
			Если Данные.Расходы[ИндексИсточника] = Неопределено Тогда
				ЦепочкаПрихода = Данные.ЦепочкиДвижений[ИндексИсточника];
				Если ЦепочкаПрихода <> Неопределено Тогда
					Данные.ЦепочкиДвижений.Удалить(ИндексИсточника);
					Данные.СтрокиЦепочек.Удалить(ЦепочкаПрихода);
				КонецЕсли;
			КонецЕсли;
			
		ИначеЕсли ПриходыКУдалению.Количество() > 0 Тогда
			Данные.Приходы.Вставить(ИндексИсточника, МассивПриходов);
		КонецЕсли;
		
		Если НЕ УменьшатьБазисРасхода И Расход.ТипЗаписи = Перечисления.ТипыЗаписейПартий.ДопРасходыБезПартии Тогда
			Если Расход.Знаменатель <= 0 Тогда
				РезультатРасчета = ЗавершитьКонтекст(ПараметрыРасчета, Данные, Контекст);
				Стэк.Удалить(Стэк.ВГраница());

				Продолжить;
			КонецЕсли;
		ИначеЕсли НЕ УменьшатьБазисРасхода И Расход[ОписаниеДвижений.БазисРасхода] <= 0 Тогда
			РезультатРасчета = ЗавершитьКонтекст(ПараметрыРасчета, Данные, Контекст);
			Стэк.Удалить(Стэк.ВГраница());
		
			Продолжить;
		КонецЕсли;

	КонецЦикла;

	Возврат РезультатРасчета.Результат;
КонецФункции

После применения измененного алгоритма затраты распределились и себестоимость рассчиталась. Ограничение на количество шагов из алгоритма удалять не стал, поэтому ограничение в настройках выставили в 2000.

Для использования этого алгоритма, надо просто заменить исходную процедуру РасчетСебестоимостиПрикладныеАлгоритмы.РассчитатьПартиюРекурсивно на указанный выше код и увеличить ограничение на количество вызовов в настройках закрытия месяца.

На этом все. Надеюсь, это будет полезно еще кому-нибудь.

Переполнение стека расчет себестоимости

+9 –

См. также

Анализ расхождений выручки НДС и Налога на прибыль в декларациях 1С:БП 3.0 ПРОФ и КОРП, КА 2.4/2.5 ЕRP2.4/2.5

Анализ учета Закрытие периода Бухгалтер Платформа 1С v8.3 Бухгалтерский учет 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Комплексная автоматизация 2.х Россия Бухгалтерский учет Налоговый учет Налог на прибыль НДС Платные (руб)

Каждый бухгалтер не раз сталкивался с требованием от налоговой инспекции пояснить расхождения в показателях декларации по Налогу на прибыль («Доходы от реализации» + «Внереализационные доходы») и налоговой базой по НДС за год. Являются ли ошибкой подобные расхождения? Как пояснить налоговой их причину? Отчет «Анализ расхождений выручки НДС и Налога на прибыль в декларациях» для 1С (БП 3.0 ПРОФ и КОРП, КА 2, ЕRP) поможет найти все расхождения.

10200 руб.

21.10.2017 90285 351 173

313

Ускоренное проведение документов в 1С (x4), устранение ошибок 60/62 счетов и зачет авансов (Бухгалтерия 3.0)

Закрытие периода Инструменты администратора БД Корректировка данных Бухгалтер Пользователь Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)

Расширение «Оперативное проведение» в 4 раза уменьшает время проведения документов и закрытия месяца. Является комплексным решением проблем 62 и 60 счетов. Оптимизирует проведение при включенной функциональной опции «Раздельный учет НДС». Используется в более 10 организациях уже 2 года. Совместимо с конфигурацией Бухгалтерия 3.0 (+КОРП).

14400 руб.

29.04.2020 35262 113 152

Помощник закрытия месяца

Закрытие периода Бухгалтер Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Управленческий учет Платные (руб)

В современных конфигурациях УТ 11, КА 2, ERP 2 и их аналогах присутствует механизм закрытия периода. Но при ошибках учета закрыть период корректно становится практически невозможно! Давайте попробуем разобраться, как можно устранить ошибки и закрыть корректно месяц!

28000 руб.

20.03.2018 76634 280 76

305

Книга доходов и расходов (КУДИР) и кассовая книга для 1С 8.х любой конфигурации для предприятий на УСН, ПСН, ЕСХН

Закрытие периода Оптовая торговля Розничная торговля Кассовые операции Учет доходов и расходов Бухгалтер Платформа 1С v8.3 Бухгалтерский учет 1C:Бухгалтерия 1С:Комплексная автоматизация 1.х 1С:Управление торговлей 10 1С:Розница 2 1С:Управление производственным предприятием 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:CRM ПРОФ, КОРП 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 1С:ERP. Управление холдингом Розничная и сетевая торговля (FMCG) Оптовая торговля, дистрибуция, логистика Гостиничный бизнес Пищевая промышленность Россия Бухгалтерский учет Бюджетный учет Налоговый учет ЕНВД ЕСХН ИП, ПБОЮЛ, КФХ Налог на прибыль НДС УСН ПСН (патентная система налогообложения) Платные (руб)

Внешняя обработка для ведения в электронной форме КУДиР в 1С - книги учёта доходов и расходов для предприятий на УСН, ПСН, ЕСХН. Заполнение раздела 1 - "доходы и расходы" из журнала документов вашей ИБ (любой конфигурации 1С:Предприятие 8). Формирование отчета Кассовая книга КО-4 по данным раздела 1.

6990 руб.

15.03.2016 118744 301 158

285

Помощник исправления развернутого сальдо по видам запасов и ГТД

Закрытие периода Бухгалтер Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Бухгалтерский учет Платные (руб)

Обработка позволяет исправить развернутое сальдо по видам запасов, которое осталось после штатной обработки перепроведения документов. Подходит для конфигураций: УТ 11, КА 2, ERP

2400 руб.

15.07.2017 64391 157 49

154

Заполнение КУДиР (книги учета доходов и расходов) в 1С

Закрытие периода Мастера заполнения Бухгалтер Платформа 1С v8.3 Управляемые формы 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление производственным предприятием 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Комплексная автоматизация 2.х Бухгалтерский учет Налоговый учет УСН Платные (руб)

При формировании КУДиР при УСН часто возникает множество вопросов и проблем, к.т.: 1. Как выполняется заполнение книги учета доходов и расходов 2. Неправильно формируется книга учета доходов и расходов в 1С а). Доходы / расходы не попадают в КУДиР; б). Доходы / расходы попадают, но не принимаются к учету и многие другие ошибки. При правильном учёте, книга формируется корректно, но идеальный учет это скорее фантастика, для реальных случаев можно использовать специальный инструмент. Обработка предназначена для заполнения КУДиР. Версия для актуальных конфигураций на управляемых формах поддерживает один механизм заполнения - от бухгалтерской проводки. Старый метод автоматизации штатного заполнения присутствует в отдельной версии для обычных форм.

5880 руб.

12.03.2014 134560 81 97

108

УТ 11. Автоматическое перемещение товаров между складами и организациями

Закрытие периода Оптовая торговля Розничная торговля Логистика, склад и ТМЦ Бухгалтер Пользователь Платформа 1С v8.3 Оперативный учет 1С:Управление торговлей 11 Управленческий учет Платные (руб)

Менеджер забывает перемещать товар между складами, а в УТ отключен контроль остатков ? Бухгалтер готов застрелиться при закрытии месяца и выравнивании отрицательных остатков по складам и фирмам ? Используй автоматическое перемещение товаров между складами и организациями для 1С УТ 11.

5000 руб.

30.05.2019 29852 33 10

Автоматическое закрытие месяца в 1С:УНФ (закрытие периода)

Закрытие периода Бухгалтер Пользователь Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Управление нашей фирмой 3.0 Россия Управленческий учет Платные (руб)

Закрытие месяца в конфигурации 1С:Управлении нашей фирмой — это очень важная задача, которую необходимо выполнять на постоянной основе. Однако, как зачастую бывает, важные и регулярные задачи могут быть упущены из виду. В связи с этим, нами было разработано решение для автоматического закрытия месяца в 1С:УНФ для оптимизации данного процесса.

3600 руб.

30.09.2022 8555 21 0

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. SkorikA 83 23.01.23 16:31 Сейчас в теме

1С:ERP релиз 2.5.8.378 столкнулся с такой же проблемой.
(shsa) не подскажете, данный вариант решения все еще актуален? Я понимаю что код из статьи уже нет, но сам вариант решения с уходом от рекурсии в сторону итераций?

2. anna_kr 02.03.23 10:14 Сейчас в теме

(1) Добрый день! удалось вам решить проблему на релизе 2.5.8.378?

3. SkorikA 83 03.03.23 04:58 Сейчас в теме

(2) Добрый день! Проблема решилась. В моём случае она была в исходных данных. Решал иначе: сначала уменьшил максимальную длину цепочки - для того чтобы при расчете корректно фиксировалась ошибка ("превышена максимальная длина цепочки..", а не переполнение стека с прекращением расчета). На ошибке ставил точку остановки и уже смотрел на какой аналитике/цепочке вызывалась ошибка. С этой информацией уже анализировал данные.

Далее локализовал источник ошибки и исправил ситуацию: в течении месяца отгружали возвратную тару в минус, а в конце месяца просто оприходовали её чтобы этот минус закрыть (и ведь даже не подумали что как-то странно поступают..), в итоге сделали "фиктивный оборот" который программа не понимала.

В моём случае бы хватило уменьшения ограничителя (все остальное корректно посчиталось), но долг требовал разобрать ситуацию полностью:)

4. insurgut 208 23.01.24 09:06 Сейчас в теме

(3)

Далее локализовал источник ошибки и исправил ситуацию

Подскажите, очень похожая ситуация на вашу, тоже с возвратной тарой. А каким образом исправили ситуацию? Оприходование просто перенесли на начало месяца или какие-то другие манипуляции проводили (например подгоняли даты возвратов к датам реализаций, чтобы минуса не было в следующей реализации). Несколько дней уже бьюсь, номенклатуру - вижу, вроде исправил уже минуса. А зацикливание всё равно происходит. Может какие-то дополнительно манипуляции произвести необходимо или куда внимательнее посмотреть?