Сюрприз от регистра накопления "Зарплата к выплате". ЗУП 3.1

	конМесяца = КонецМесяца(НаДату);
	Запрос = Новый Запрос;
	// 1. Выбрать сотрудников по которым было движение в РН.ВзаиморасчетыССотрудникамии и оборот = 0, а остаток в РН.ЗарплатаКВыплате не равен 0 на конец анализируемого месяца
	Запрос.Текст = "ВЫБРАТЬ
	               |	ВзаиморасчетыССотрудникамиОбороты.Сотрудник КАК Сотрудник,
	               |	ВзаиморасчетыССотрудникамиОбороты.СуммаВзаиморасчетовПриход КАК СуммаВзаиморасчетовПриход,
	               |	ВзаиморасчетыССотрудникамиОбороты.СуммаВзаиморасчетовРасход КАК СуммаВзаиморасчетовРасход,
	               |	ЕСТЬNULL(ЗарплатаКВыплатеОстатки.СуммаКВыплатеОстаток, 0) КАК СуммаКВыплатеОстаток
	               |ПОМЕСТИТЬ втИтог
	               |ИЗ
	               |	РегистрНакопления.ВзаиморасчетыССотрудниками.Обороты(&НачПериода, &КонПериода, , Организация = &Организация) КАК ВзаиморасчетыССотрудникамиОбороты
	               |		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ЗарплатаКВыплате.Остатки(&КонПериода, Организация = &Организация) КАК ЗарплатаКВыплатеОстатки
	               |		ПО ВзаиморасчетыССотрудникамиОбороты.Сотрудник = ЗарплатаКВыплатеОстатки.Сотрудник
	               |ГДЕ
	               |	ВзаиморасчетыССотрудникамиОбороты.СуммаВзаиморасчетовОборот = 0
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	втИтог.Сотрудник КАК Сотрудник,
	               |	втИтог.СуммаВзаиморасчетовПриход КАК СуммаВзаиморасчетовПриход,
	               |	втИтог.СуммаВзаиморасчетовРасход КАК СуммаВзаиморасчетовРасход,
	               |	втИтог.СуммаКВыплатеОстаток КАК СуммаКВыплатеОстаток
	               |ИЗ
	               |	втИтог КАК втИтог
	               |ГДЕ
	               |	втИтог.СуммаКВыплатеОстаток <> 0";
	Запрос.УстановитьПараметр("Организация",Организация);
	Запрос.УстановитьПараметр("НачПериода",НаДату);
	Запрос.УстановитьПараметр("КонПериода",конМесяца);
	врмТбл = Запрос.Выполнить().Выгрузить();

	// 2. по полученным сотрудникам выбрать записи из РН.ЗарплатаКВыплате у который сумма к выплате <> 0
	Запрос.Текст = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
	               |	ЗарплатаКВыплатеОстатки.Сотрудник КАК Сотрудник,
	               |	ЗарплатаКВыплатеОстатки.ФизическоеЛицо КАК ФизическоеЛицо,
	               |	ЗарплатаКВыплатеОстатки.Подразделение КАК Подразделение,
	               |	ЗарплатаКВыплатеОстатки.ПериодВзаиморасчетов КАК ПериодВзаиморасчетов,
	               |	ЗарплатаКВыплатеОстатки.СтатьяФинансирования КАК СтатьяФинансирования,
	               |	ЗарплатаКВыплатеОстатки.СтатьяРасходов КАК СтатьяРасходов,
	               |	ЗарплатаКВыплатеОстатки.ВидДоходаИсполнительногоПроизводства КАК ВидДоходаИсполнительногоПроизводства,
	               |	ЗарплатаКВыплатеОстатки.ДокументОснование КАК ДокументОснование,
	               |	СУММА(ЗарплатаКВыплатеОстатки.СуммаКВыплате) КАК СуммаКВыплате
	               |ПОМЕСТИТЬ втИтог
	               |ИЗ
	               |	(ВЫБРАТЬ
	               |		ЗарплатаКВыплатеОстатки.Сотрудник КАК Сотрудник,
	               |		ЗарплатаКВыплатеОстатки.ФизическоеЛицо КАК ФизическоеЛицо,
	               |		ЗарплатаКВыплатеОстатки.Подразделение КАК Подразделение,
	               |		ЗарплатаКВыплатеОстатки.ПериодВзаиморасчетов КАК ПериодВзаиморасчетов,
	               |		ЗарплатаКВыплатеОстатки.СтатьяФинансирования КАК СтатьяФинансирования,
	               |		ЗарплатаКВыплатеОстатки.СтатьяРасходов КАК СтатьяРасходов,
	               |		ЗарплатаКВыплатеОстатки.ВидДоходаИсполнительногоПроизводства КАК ВидДоходаИсполнительногоПроизводства,
	               |		ЗарплатаКВыплатеОстатки.ДокументОснование КАК ДокументОснование,
	               |		ЗарплатаКВыплатеОстатки.СуммаКВыплатеОстаток КАК СуммаКВыплате
	               |	ИЗ
	               |		РегистрНакопления.ЗарплатаКВыплате.Остатки(
	               |				,
	               |				ПериодВзаиморасчетов < &ПериодВзаиморасчетов
	               |					И Сотрудник В (&Сотрудник)) КАК ЗарплатаКВыплатеОстатки
	               |	
	               |	ОБЪЕДИНИТЬ ВСЕ
	               |	
	               |	ВЫБРАТЬ
	               |		ЗарплатаКВыплате.Сотрудник,
	               |		ЗарплатаКВыплате.ФизическоеЛицо,
	               |		ЗарплатаКВыплате.Подразделение,
	               |		ЗарплатаКВыплате.ПериодВзаиморасчетов,
	               |		ЗарплатаКВыплате.СтатьяФинансирования,
	               |		ЗарплатаКВыплате.СтатьяРасходов,
	               |		ЗарплатаКВыплате.ВидДоходаИсполнительногоПроизводства,
	               |		ЗарплатаКВыплате.ДокументОснование,
	               |		ВЫБОР
	               |			КОГДА ЗарплатаКВыплате.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
	               |				ТОГДА -ЗарплатаКВыплате.СуммаКВыплате
	               |			ИНАЧЕ ЗарплатаКВыплате.СуммаКВыплате
	               |		КОНЕЦ
	               |	ИЗ
	               |		РегистрНакопления.ЗарплатаКВыплате КАК ЗарплатаКВыплате
	               |	ГДЕ
	               |		ЗарплатаКВыплате.ПериодВзаиморасчетов <= &ПериодВзаиморасчетов
	               |		И ЗарплатаКВыплате.Сотрудник В(&Сотрудник)) КАК ЗарплатаКВыплатеОстатки
	               |
	               |СГРУППИРОВАТЬ ПО
	               |	ЗарплатаКВыплатеОстатки.Сотрудник,
	               |	ЗарплатаКВыплатеОстатки.ФизическоеЛицо,
	               |	ЗарплатаКВыплатеОстатки.Подразделение,
	               |	ЗарплатаКВыплатеОстатки.ПериодВзаиморасчетов,
	               |	ЗарплатаКВыплатеОстатки.СтатьяФинансирования,
	               |	ЗарплатаКВыплатеОстатки.СтатьяРасходов,
	               |	ЗарплатаКВыплатеОстатки.ВидДоходаИсполнительногоПроизводства,
	               |	ЗарплатаКВыплатеОстатки.ДокументОснование
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	втИтог.Сотрудник КАК Сотрудник,
	               |	втИтог.ФизическоеЛицо КАК ФизическоеЛицо,
	               |	втИтог.Подразделение КАК Подразделение,
	               |	втИтог.ПериодВзаиморасчетов КАК ПериодВзаиморасчетов,
	               |	втИтог.СтатьяФинансирования КАК СтатьяФинансирования,
	               |	втИтог.СтатьяРасходов КАК СтатьяРасходов,
	               |	втИтог.ВидДоходаИсполнительногоПроизводства КАК ВидДоходаИсполнительногоПроизводства,
	               |	втИтог.ДокументОснование КАК ДокументОснование,
	               |	-втИтог.СуммаКВыплате КАК СуммаКВыплате
	               |ИЗ
	               |	втИтог КАК втИтог
	               |ГДЕ
	               |	втИтог.СуммаКВыплате <> 0";
	Запрос.УстановитьПараметр("ПериодВзаиморасчетов",НаДату);
	Запрос.УстановитьПараметр("Сотрудник",врмТбл.ВыгрузитьКолонку("Сотрудник"));    

	// 3. По выбранным записям выполнить "сторно записи"
	Выборка = Запрос.Выполнить().Выбрать();
	Если Выборка.Количество() > 0 Тогда  
		ДатаДок = конМесяца + 1;
		начМесяца = ДатаДок;
		мДок = ПолучитьДокПереносаДанных(Организация,"Остатки",ДатаДок,"__Обнуление остатков по сотрудникам","ЗарплатаКВыплате");
		
		НЗ = РегистрыНакопления.ЗарплатаКВыплате.СоздатьНаборЗаписей();
		НЗ.Отбор.Регистратор.Установить(мДок.ссылка);
		НЗ.Прочитать();
		НЗ.Очистить();
		Пока Выборка.Следующий() Цикл
			новЗапись = НЗ.Добавить();
			ЗаполнитьЗначенияСвойств(новЗапись,Выборка);
			новЗапись.ВидДвижения = ВидДвиженияНакопления.Приход;
			новЗапись.Регистратор = мДок.Ссылка;
			новЗапись.Период = начМесяца;  
			новЗапись.Организация = Организация;
			новЗапись.ПериодВзаиморасчетов = начМесяца;
		КонецЦикла;
	    НЗ.Записать();
	КонецЕсли;