Управляемое приложение. Внешняя обработка. Заполнение объекта
Разработка - Инструментарий разработчика
Файлы
ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.
Подписка PRO — скачивайте любые файлы со скидкой до 85% из Базы знаний
Оформите подписку на компанию для решения рабочих задач
Оформить подписку и скачать решение со скидкойВы можете заказать платную доработку или адаптацию этой разработки под вашу конфигурацию на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
Задача: В "1С:Управление торговлей 11" (релиз 11.06.7). В форме документа счет-фактура выданный аванс заполнить табличную часть Авансы на основании документа поступление безналичных денежных средств.
Условия:
1) Перед заполнением табличной части документа получить от пользователя подтверждение на это действие;
2) Обработку создания документа сделать внешней и подключаемой к форме документа счет-фактура на аванс выданный;
3) После заполнения табличной части не записывать документ, а разрешить пользователю продолжить редактирование изменной табличной части или самостоятельно записать документ.
Решение:
Пункты 1 и 2 не представляют особой сложности, но пункт 3 заставил меня задуматься и написать, по-моему мнению, топорный, но исправно действующий код.
Шаг 1.
Понятно, что от нас требуется создать внешнюю обработку вида "ЗаполнениеОбъекта" и подключить её в информационную базу.
Приведу код в модуле обработки:
Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = Новый Структура;
МассивНазначений = Новый Массив;
МассивНазначений.Добавить("Документ.СчетФактураВыданныйАванс");
ПараметрыРегистрации.Вставить("Вид", "ЗаполнениеОбъекта");
ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
ПараметрыРегистрации.Вставить("Наименование", "Заполнить документ");
ПараметрыРегистрации.Вставить("Версия", "1.0");
ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
ПараметрыРегистрации.Вставить("Информация", "Дополнительная обработка табличной части к документу счет-фактура выданный аванс");
ТаблицаКоманд = ПолучитьТаблицуКоманд();
ДобавитьКоманду(ТаблицаКоманд,
"Заполнить документ",
"Заполнить документ",
"ВызовКлиентскогоМетода",
Истина);
ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
Возврат ПараметрыРегистрации;
КонецФункции
Функция ПолучитьТаблицуКоманд()
Команды = Новый ТаблицаЗначений;
Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
Возврат Команды;
КонецФункции
Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
НоваяКоманда = ТаблицаКоманд.Добавить();
НоваяКоманда.Представление = Представление;
НоваяКоманда.Идентификатор = Идентификатор;
НоваяКоманда.Использование = Использование;
НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры
Так как нам придется работать с формами объектов, мы просто вынуждены использовать метод ВызовКлиентскогоМетода для вызова команды внешней обработки.
Напомню, при использовании ВызовСерверногоМетода с формами объектов работать не получится.
Подробнее о типовых принципах создания внешних подключаемых обработок и печатных форм вы можете почитать здесь.
Шаг 2.
Так как мы использовали ВызовКлиентскогоМетода, то обязательную процедуру, для внешней подключаемой обработки заполнения объектов, ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначенияМассив) Экспорт, необходимо выполнять &НаКлиенте в модуле формы обработки, а значит создадим любую форму обработки, пользователь её всеравно не увидит, и поместим внутрь модуля формы следующий код:
&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначенияМассив) Экспорт
//Спросим у пользователя разрешение на продолжение обработки
Режим = РежимДиалогаВопрос.ДаНет;
Текст = "Текущие данные документа будут заменены новыми без возможности восстановления.
|Продолжить?";
Ответ = Вопрос(Текст, Режим, 0);
Если Ответ = КодВозвратаДиалога.Да Тогда
//Если пользователь дал разрешение на продолжение, то начнем перебирать все
//документы, у которых мы планируем заполнить табличную часть
Для каждого Элемент из ОбъектыНазначенияМассив Цикл
//Зададим ключ поиска документа, из которого вызвана данная обработка,
//чтобы получить ссылку на редактирумый документ в удобном виде для
//функции ОткрытьФорму()
КлючПоиска = Новый Структура("Ключ", Элемент);
//Но нам не надо открывать новую форму (окно) для изменяемого документа, а
//Нам надо все изменения показать в уже открытых у клиента окнах
Окна = ПолучитьОкна();
Для каждого Окно из Окна Цикл
//Окно изменяемого документа будет точно не основным, а вспомогательным, поэтому
//сразу пропускаем основное окно, а далее идем на не очень хороший способ поиска открытого окна
//изменяемого документа. Мы просто переберем все окна, а в заголовке, которых будет встречаться
//Наименование, номер и дата нужного документа - будем изменять
Если НЕ Окно.Основное
И Найти(Окно.Заголовок, Элемент) Тогда
//Передадим ключ поиска (можно сказать ссылку на объект) и данные о найденном открытом окне
//в функцию ОткрытьФорму()
//Код находится в цикле на тот случай, если открытых окон изменяемого документа больше одного
Форма = ОткрытьФорму("Документ.СчетФактураВыданныйАванс.Форма.ФормаДокумента",КлючПоиска,,,Окно);
//Далее мы получаем объект только, что повторно открытой формы и помещаем её в переменную
//В объекте содержатся все реквизиты (элементы) формы
НовыйОбъект = Форма.Объект;
//Мы помещаем объект формы в переменную,
//так как должны передать её в процедуру на сервере,
//где нельзя изменять объект формы, зато можно править переменную содержащую его
ЗаполнитьОбъект(НовыйОбъект);
//После выполнения процедуры на сервере мы получаем изменную переменную НовыйОбъект,
//которую необходимо передать в уже полученную нами форму
КопироватьДанныеФормы(НовыйОбъект, Форма.Объект);
КонецЕсли;
КонецЦикла;
КонецЦикла;
КонецЕсли;
КонецПроцедуры
Ниже приведу код, который у вас может быть совершенно другим и делать какие-либо другие манипуляции с объектом формы:
&НаСервере
Функция ЗаполнитьОбъект(НовыйОбъект)
Если ТипЗнч(НовыйОбъект.ДокументОснование) = Тип("ДокументСсылка.ПоступлениеБезналичныхДенежныхСредств") Тогда
Если НовыйОбъект.ДокументОснование.РасшифровкаПлатежа.Количество() > 0 Тогда
НовыйОбъект.Авансы.Очистить();
КонецЕсли;
Для каждого СтрокаТЧ из НовыйОбъект.ДокументОснование.РасшифровкаПлатежа Цикл
НоваяСтрока = НовыйОбъект.Авансы.Добавить();
Если ЗначениеЗаполнено(СтрокаТЧ.СчетНаОплату) Тогда
НоваяСтрока.Содержание = "Предварительная оплата" + ФормированиеПечатныхФорм.СформироватьЗаголовокДокумента(СтрокаТЧ.СчетНаОплату, НСтр("ru=' по счету на оплату'"));
КонецЕсли;
НоваяСтрока.Сумма = СтрокаТЧ.Сумма;
НоваяСтрока.СтавкаНДС = Перечисления.СтавкиНДС.НДС18_118;
ТекПроцентНДС = ЦенообразованиеКлиентСервер.ПолучитьСтавкуНДСЧислом(НоваяСтрока.СтавкаНДС);
НоваяСтрока.СуммаНДС = ЦенообразованиеКлиентСервер.РассчитатьСуммуНДС(НоваяСтрока.Сумма, ТекПроцентНДС);
КонецЦикла;
КонецЕсли;
КонецФункции
Как можно заметить, представленное решение заполнения объекта из внешней подключаемой обработки с отображением изменений до записи объекта не является изящным, но другого способа мне найти не удалось. В Интернетах на эту тему тоже очень мало информации.
Поэтому если есть другое решение поставленной задачи, то обязательно сообщите о нем.
Вступайте в нашу телеграмм-группу Инфостарт
См. также
Разработка Инструментарий разработчика Групповая разработка (Git, хранилище) Разработчик Платные (руб)
Практический курс по работе с AI-агентами для разработчиков 1С уровня middle и senior, а также тимлидов команд: от постановки задач и передачи контекста до создания расширений, интеграций, MCP-инструментов, тестов и проверки готового решения.
50000 руб.
10.09.2026 14767 126 0
Инструментарий разработчика Чистка данных Свертка базы Инструменты администратора БД Системный администратор Разработчик Руководитель проекта 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Россия Платные (руб)
Инструмент представляет собой обработку для проведения свёртки или обрезки баз данных. Работает на ЛЮБЫХ конфигурациях (УТ, БП, ERP, УНФ, КА и т.д.). Поддерживаются серверные и файловые базы, управляемые и обычные формы, интерфейс 8.5. Может выполнять свертку одновременно в несколько потоков, а также без непосредственного участия пользователя. Решение в Реестре отечественного ПО.
24900 руб.
20.08.2024 84246 435 171
Инструментарий разработчика Роли и права Запросы СКД Разработчик Руководитель проекта 1С:Предприятие 8 Платные (руб)
Инструменты для разработчиков 1С 8.3 и 8.5: Infostart Toolkit. Автоматизация и ускорение разработки на управляемых формах. Легкость работы с 1С.
16500 руб.
02.09.2020 286906 1612 423
Инструментарий разработчика Разработка Администрирование веб-серверов Системный администратор Разработчик Аналитик Руководитель проекта 1С 8.3 Платные (руб)
Analyzer 1C сводит выгрузку 1С — основную конфигурацию и все расширения — в единый граф знаний. Любой запрос по связям за доли секунды, с пометками «Доб.» / «Заимств.» / «Переопределено». Новое в 2.0 — обновление поставки: сравнение и объединение версий деревом «как в Конфигураторе» с выгрузкой плана решений; поиск конфликтов из-за перехватов расширений и висячих ссылок; загрузка из бинарных .cf/.cfe; циклические зависимости. Плюс анализ влияния, запросы BSL, роли и RLS, граф вызовов. Минута на развёртывание через Docker без необходимости подключения к Интернет. Любая 1С:Предприятие 8.3+.
14000 руб.
17.04.2026 17455 65 62
Инструментарий разработчика Нейросети Платные (руб)
Первые попытки разработки на 1С с использованием больших языковых моделей (LLM) могут разочаровать. LLMки сильно галлюцинируют, потому что не знают устройства конфигураций 1С, не знают нюансов синтаксиса. Но если дать им подсказки с помощью MCP, то результат получается кардинально лучше. Далее в публикации: MCP для поиска по метаданным 1С, справке синтакс-помощника и проверки синтаксиса.
15250 руб.
25.08.2025 78135 148 41
Пакетная печать Печатные формы Инструментарий разработчика Разработчик 1С:Предприятие 8 Платные (руб)
Расширение для создания и редактирования печатных форм в системе 1С:Предприятие 8.3. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и прозрачность разработки, а также навести порядок в многообразии корпоративных печатных форм. Обновление версии от 21.04.26
22570 руб.
06.10.2023 44641 123 54
Разработка Инструментарий разработчика Разработчик Руководитель проекта 1С 8.3 Платные (руб)
Pilot 1C превращает задачу, поставленную обычными словами, в техническое задание, код на встроенном языке и сценарии проверки. Прежде чем что-то предложить, он сверяется с устройством вашей конфигурации через граф Analyzer 1C (приобретается отдельно, необязателен): существует ли объект, из чего он состоит, кто его вызывает, какие роли дают права, а также сверяется с данными использования функционала в вашем конкретном внедрении через Insight 1C (приобретается отдельно, необязателен). Чего найти не удалось – спрашивает, а не выдумывает. Готовый код проходит более полутора сотен проверок по справочнику языка и стандартам разработки, который приезжает вместе с продуктом. Модель – ваша: любой сервер, совместимый с программным интерфейсом OpenAI, в том числе локальный. Правки в конфигурацию Pilot вносит через плагин для EDT Effector 1C (включен в поставку, бесплатен), выдает вашему агенту через MCP, либо перечисляет в качестве пошаговых инструкций и их применяет разработчик вручную.
18300 руб.
11.09.2026 4163 5 0
Инструменты администратора БД Инструментарий разработчика Роли и права Разработчик 1С:Предприятие 8 1C:Бухгалтерия Россия Платные (руб)
Расширение позволяет без изменения кода конфигурации выполнять проверки при вводе данных, скрывать от пользователя недоступные ему данные, выполнять код в обработчиках. Не изменяет данные конфигурации, легко устанавливается практически на любую конфигурацию на управляемых формах.
17000 руб.
10.11.2023 28966 104 46
Разница такая, что в этой статье описана методика заполнения объекта (аналог из УПП 1.2 или УТ 10.3 - заполнение табличных частей), а в другой - описание создания связанных объектов или ввода на основании.
Статья полезная, сам думал, как бы это сделать пооптимальней.
(3) 1. Будь вежливее.
2. Цель моего предложения в (1) - автор ДОЛЖЕН расписать отличие одной обработки от другой, чтобы пользователь сайта, который не разбирается в этом (а ведь статья именно для таких пользователей! ), мог понять отличие и назначение каждой статьи.
Если ТЕБЕ эта моя цель непонятна/недоступна, это твои проблемы!
Уважаю тебя за твои работы, но здесь ты неправ.
ЗЫ На будущее - Не лезь и не обсуждай работу Модераторов.
Поясню:
1) Создание связанных объектов
2) Заполнение объекта
Задачи поставлены разные.
1) Создать документ счет-фактура выданный аванс на основании документа поступление безналичных денежных средств
2) В форме документа счет-фактура выданный аванс заполнить табличную часть Авансы
Частично одинаков код модуля обработок, он приведен на тот случай, если человек не делал до этого внешних обработок на управляемом приложении и читает публикацию по этой теме впервые.
Я мог конечно написать только суть и даже не публиковать обработку, но тогда по собственному опыту скажу, что были бы только вопросы и плевки в мою сторону, особенно у новичков.
А насчет
- это вполне может быть, здесь полно таких, вот я, к примеру. Поэтому Вам предложили только более понятно описать, о чем материал в статье, чтобы нам, "чайникам", было понятно. Удалять статьи никто не собирался.
И как какая тут последовательность надо вначале создать документ "счет-фактура выданный аванс" потом выбрать у него в основание "поступление безналичных денежных средств" а потом нажать заполнение?
Опа, нет ещё...
Короче, нифига не выходит с заполнением формы без сохранения данных в объекте: форма заполняется - но больше с ней ничего не сделать: «Ошибка блокировки объекта. Объект уже заблокирован». Пришлось в серверной процедуре записывать объект с помощью ДанныеФормыВЗначение... Пытался прикрутить к УТ 11.0.6.7 заполнение графы «Основание» в ПКО описанием документа-основания ПКО...
Кстати, а зачем обработка заполнения ТЧ счета-фактуры на аванс?
На мой взгляд правильней заполнять с/ф в обработке формирования с/ф на аванс.
Это лишь пример реализации интерактивного заполнения ТЧ. Можно было бы заполнять другую ТЧ, но суть решения не изменилась бы.
Хм, а если после выполнения обработки при любой попытке изменить реквизит или просто сохранить пишет «Ошибка блокировки объекта. Объект уже заблокирован <наименование сеанса>» ?
Верно подмечено. Разбираюсь в этой проблемой в данный момент.
Вопрос блокировок конечно очень обширный, поэтому я хотел бы для себя разобраться для начала в каком то одном частном вопросе. А именно как работает свойство БлокироватьДляИзменения у набора записей в 8.2 в управляемом режиме (SQL). Если для предыдущих версий платформы все достаточно понятно, так например:
Для 8.1 (Автоматический режим) ответы будут следующие:
1) Когда читаются данные, которые необходимо изменять в текущей транзакции необходимо в запросе указывать "ДЛЯИЗМЕНЕНИЯ"
2) Блокировка накладывается в момент выполнения запроса, диапазон блокируемых данных определяется условиями в запросе.
3) Блокируется запись, а так же чтение другими транзакциями, запросы которых используют директиву "ДЛЯИЗМЕНЕНИЯ"
Для 8.1 (Управляемый режим)
1) Когда читаются данные которые необходимо изменять в текущей транзакции нужно установить исключительную блокировку, когда необходимо просто обеспечить неизменность прочитанных данных - разделяемую.
2) Блокировка устанавливается явно, методом Заблокировать() блокируемые записи так же явно указываем в коде.
3) Разделяемая - запрещает запись, Исключительная - Чтение и запись
Для 8.2 (Управляемый режим) в принципе верно тоже что и для 8.1 (Управляемый),
но это если использовать старую методику - сначала контроль остатков, потом проведение.
Как действовать при новой методике, непонятно... ответ судя по всему кроется в понимании принципов работы этой самой "БлокироватьДляИзменения"
я так думаю нужно переделать в обработке каркас а именно это
Форма = ОткрытьФорму("Документ.СчетФактураВыданныйАванс.Форма.ФормаДокумента",КлючПоиска,,,Окно);
//Далее мы получаем объект только, что повторно открытой формы и помещаем её в переменную
//В объекте содержатся все реквизиты (элементы) формы
НовыйОбъект = Форма.Объект;
Незачет 1с. Собственно проблема в том, что в обработку не передается форма, из которой она открыта. Но автор нашел нужное окошко, молодец.
Форма = ОткрытьФорму("Документ.СчетФактураВыданныйАванс.Форма.ФормаДокумента",КлючПоиска,,,Окно);
А если этой обработкой нужно заполнять не один вид документов, а несколько? Надо чтобы данные вписывались в уже открытую форму объекта.
как попасть в этом случае в эту процедуру?
&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначенияМассив) Экспорти где брать значения для переменных?
Насторожила эта строчка:
Форма = ОткрытьФорму("Документ.СчетФактураВыданныйАванс.Форма.ФормаДокумента",КлючПоиска,,,Окно);
А если этой обработкой нужно заполнять не один вид документов, а несколько? Надо чтобы данные вписывались в уже открытую форму объекта.
Предоставьте выполнение этой задачи богу Шиве.
&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначенияМассив) Экспорт
СписокЭлементов.ЗагрузитьЗначения(ОбъектыНазначенияМассив);
ЭтаФорма.Открыть();
ПодключитьОбработчикОжидания("ПроцедураОбработкиОбъектов", 0.1, Истина);
КонецПроцедуры
&НаКлиенте
Процедура ПроцедураОбработкиОбъектов()
ЭтаФорма.Закрыть();
ОбъектыНазначенияМассив = СписокЭлементов.ВыгрузитьЗначения();
Окна = ПолучитьОкна();
Для Каждого Элемент из ОбъектыНазначенияМассив Цикл
Для Каждого Окно из Окна Цикл
Если НЕ Окно.Основное Тогда
Форма = Окно.ПолучитьСодержимое();
ОбъектФормы = Неопределено;
Попытка
ОбъектФормы = Форма.Объект;
Исключение
КонецПопытки;
Если ОбъектФормы <> Неопределено
И ОбъектФормы.Ссылка = Элемент Тогда
ОбъектФормы.Комментарий = формат(ТекущаяДата());
КонецЕсли;
КонецЕсли;
КонецЦикла;
КонецЦикла;
КонецПроцедуры
ПоказатьСписокЭлементов - в форму обработки добавлен реквизит типа "список значений".
И есть недостаток - ненадолго открывается форма обработки.
----
[ Всё, что далее написано, относится к получению формы через "Окно.ПолучитьСодержимое()", а не ОткрытьФорму(...) ]
И вообще, начал копать, почему же так происходит. Оказалось, что получив объект формы, и изменив данные у этого объекта, отображение данных на форме тоже меняется. Но затем, после завершения процедуры "ВыполнитьКоманду", закрывается окно списка обработок, управление передается в модуль команды. После чего из-за того что у команды стоит галочка "изменяет данные" данные формы обновляются (т.е. восстанавливаются) из ссылки.
Способ в (35) как раз обходит этот момент. Так как, после всего этого форма обработки у нас остается открытой, и вызывает подключенный обработчик. И при вызове его закрывается.
Примечательно, что у команды вызова печатных форм, такой галочки нет. И данные на форме должны оставаться такими, какими мы и хотим без всяких финтов ушами.
Не верю что это связано с обновлением УТ. Ваш код и в более ранних версиях УТ должен работать точно так же как и сейчас.
Достоверность (37) ставится под сомнение.
PS. Не нашел своего кода в вашей обработке (точнее, ключевой "фишки"). Так что вопрос не ко мне. Либо вопрос не так сформулирован.
"Не нашел своего кода в вашей обработке (точнее, ключевой "фишки")"
Если можно, то расшифруйте Вашу фразу. Хоть какая-то дополнительная информация.
"Не верю что это связано с обновлением УТ. Ваш код и в более ранних версиях УТ должен работать точно так же как и сейчас.
Достоверность (37) ставится под сомнение. "
Это же можно легко проверить. Вся инфомация доступна.
(37) salus,
По крайней мере в УТ 11.0.7.18 присутствует ошибка в конфигурации. И видимо, в следующих релизах её исправили.
В коих механизм из моего комментария вполне работает.
PS. По поводу нежелания разжевывать детально. У вас интерес денежный, у меня же интерес... просто интерес.
1. Перенаправить на открытие формы обработки
ДобавитьКоманду(ТаблицаКоманд,
"...",
"...",
"ОткрытиеФормы",
Истина,
"");
2. При создании формы обработки из параметров найти ссылку на вызывающий объект и сохранить куда-нибудь ссылку
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ЗагрузкаИзExel.ОбъектСсылка = Документы.УстановкаЦенНоменклатуры.ПустаяСсылка();
попытка
парам = ЭтаФорма.Параметры;
если парам.ОбъектыНазначения.Количество()>0 Тогда
ЗагрузкаИзExel.ОбъектСсылка = парам.ОбъектыНазначения[0];
КонецЕсли;
Исключение
КонецПопытки;
КонецПроцедуры
3. Заполнить форму документа интерактивно (либо если форма обработки не нужна в модуле ПриОткрытии)
&НаКлиенте
Процедура УстановитьЦены(Команда)
если ВСуществующийДокумент и ЗначениеЗаполнено(ЗагрузкаИзExel.ОбъектСсылка) тогда
ДокФорма = ПолучитьФорму("Документ.УстановкаЦенНоменклатуры.Форма.ФормаДокумента",новый Структура("Ключ", ЗагрузкаИзExel.ОбъектСсылка));
иначе
ДокФорма = ПолучитьФорму("Документ.УстановкаЦенНоменклатуры.Форма.ФормаДокумента");
ДокФорма.Объект.Дата = ТекущаяДата();
КонецЕсли;
ДокФорма.Объект.Комментарий = "Загрузка из файла "+ЭтаФорма.ЗагрузкаИзExel.ИмяФайла;
ДокФорма.Объект.Ответственный = Пользователи.ТекущийПользователь();
найденацена = ложь;
если ВСуществующийДокумент тогда
для каждого стр из ДокФорма.Объект.ВидыЦен цикл
если стр.ВидЦены = ЭтаФорма.ЗагрузкаИзExel.ВидЦены тогда
найденацена = истина;
Прервать;
КонецЕсли;
КонецЦикла;
КонецЕсли;
если не найденацена тогда
новстр = ДокФорма.Объект.ВидыЦен.Добавить();
новстр.ВидЦены = ЭтаФорма.ЗагрузкаИзExel.ВидЦены;
КонецЕсли;
для каждого стр из ЭтаФорма.ЗагрузкаИзExel.СписокРезультата цикл
если стр.НоменклатураСсылка<>ПустаяСсылкаСправочника("Номенклатура") Тогда
новстр = ДокФорма.Объект.Товары.Добавить();
новстр.Номенклатура = стр.НоменклатураСсылка;
новстр.Цена = стр.Цена;
новстр.ВидЦены = ЭтаФорма.ЗагрузкаИзExel.ВидЦены;
новстр.ЦенаИзмененаВручную = истина;
новстр.Характеристика = ВернутьХарактеристику(стр.Характеристика,стр.НоменклатураСсылка);
новстр.Упаковка = ВернутьУпаковку(стр.НоменклатураСсылка,стр.ЕдИзм);
КонецЕсли;
КонецЦикла;
ДокФорма.ПриСозданииНаСервере(Ложь, истина); // это чтобы форма этого заморочного документа правильно построилась
ДокФорма.Модифицированность = Истина;
ДокФорма.Открыть();
ЭтаФорма.Закрыть();
КонецПроцедуры
4. Не забыть в параметрах формы обработки создать параметр "ОбъектыНазначения"
Постоянно выдает вот такую ошибку:
{ОбщийМодуль.ДополнительныеОтчетыИОбработки.Модуль(201)}: Ошибка при вызове метода контекста (Подключить)
Возврат ВнешниеОбработки.Подключить(АдресВоВременномХранилище,, БезопасныйРежим);
по причине:
Ошибка подключения внешних метаданных
по причине:
Неправильный путь к файлу 'e1cib/tempstorage/49c11b29-ff5d-4612-aee4-7f8d785c2cda'
Я уже даже прописал
&НаСервере
Процедура ПриСозданииНаСервере()
Сообщить("ПриСозданииНаСервере");
1;
КонецПроцедуры
Т.е. модуль с ошибками - вообще никакой реакции. Скачал обработку, которая в статье - аналогично.
Что еще можно проверить?
&НаКлиенте
Процедура Подключаемый_ВыполнитьНазначаемуюКоманду(Команда)
Если НЕ ДополнительныеОтчетыИОбработкиКлиент.ВыполнитьНазначаемуюКомандуНаКлиенте(ЭтаФорма, Команда.Имя) Тогда
РезультатВыполнения = Неопределено;
ДополнительныеОтчетыИОбработкиВыполнитьНазначаемуюКомандуНаС ервере(Команда.Имя, РезультатВыполнения);
ДополнительныеОтчетыИОбработкиКлиент.ПоказатьРезультатВыполненияКоманды(ЭтаФорма, РезультатВыполнения);
КонецЕсли;
КонецПроцедуры
&НаСервере
Процедура ДополнительныеОтчетыИОбработкиВыполнитьНазначаемуюКомандуНаС ервере(ИмяЭлемента, РезультатВыполнения)
ДополнительныеОтчетыИОбработки.ВыполнитьНазначаемуюКомандуНаСервере(ЭтаФорма, ИмяЭлемента, РезультатВыполнения);
КонецПроцедуры Показатьи всё заработало.
// Обновить форму владельца
Если ТипЗнч(ВладелецФормы) = Тип("УправляемаяФорма") Тогда
Попытка
ВладелецФормы.Прочитать();
Исключение
КонецПопытки;
КонецЕсли;
Закомментировав выделенное всё заработало.
//Зададим ключ поиска документа, из которого вызвана данная обработка,
//чтобы получить ссылку на редактирумый документ в удобном виде для
//функции ОткрытьФорму()
КлючПоиска = Новый Структура("Ключ", Элемент);
//Но нам не надо открывать новую форму (окно) для изменяемого документа, а
//Нам надо все изменения показать в уже открытых у клиента окнах
Окна = ПолучитьОкна();
Для каждого Окно из Окна Цикл
//Окно изменяемого документа будет точно не основным, а вспомогательным, поэтому
//сразу пропускаем основное окно, а далее идем на не очень хороший способ поиска открытого окна
//изменяемого документа. Мы просто переберем все окна, а в заголовке, которых будет встречаться
//Наименование, номер и дата нужного документа - будем изменять
Если НЕ Окно.Основное
И Найти(Окно.Заголовок, Элемент) Тогда
//Передадим ключ поиска (можно сказать ссылку на объект) и данные о найденном открытом окне
//в функцию ОткрытьФорму()
//Код находится в цикле на тот случай, если открытых окон изменяемого документа больше одного
Форма = ОткрытьФорму("Документ.СчетФактураВыданныйАванс.Форма.ФормаДокумента",КлючПоиска,,,Окно);
//Далее мы получаем объект только, что повторно открытой формы и помещаем её в переменную
//В объекте содержатся все реквизиты (элементы) формы
НовыйОбъект = Форма.Объект;
//Мы помещаем объект формы в переменную,
//так как должны передать её в процедуру на сервере,
//где нельзя изменять объект формы, зато можно править переменную содержащую его
ЗаполнитьОбъект(НовыйОбъект);
//После выполнения процедуры на сервере мы получаем изменную переменную НовыйОбъект,
//которую необходимо передать в уже полученную нами форму
КопироватьДанныеФормы(НовыйОбъект, Форма.Объект);
КонецЕсли;
КонецЦикла;
Показатьна
Объект = ВладелецФормы.Объект;
ЗаполнитьОбъект(Объект);
Раньше действие было простое, а теперь занимает в 10 раз больше времени.
И я может не нашёл, но факт если у человека много табличных частей на форме все внешнии обработки их заполнения будут лежать в общей кучи через кнопку "Заполнить"
Представим, что у нас существует допустим 3-4 табличные части. Для каждой у нас есть своя внешняя обработка. Раньше пользователь видел под кнопокй заполнить кнопку для этой конкретной таблицы. Теперь же будет одна общая кнопка "Заполнить" и лишь по их названию можно понять, что и куда.
Я не говорю, что это сверх неудобно, просто чисто с точки удобства это ухудшение.
Кстати взять типой документ "Поступление товаров и услуг" у него 7 различных табличных части: Оборудование, ОбъектыСтроительства, Товары, Услуги, ВозвратнаяТара, ЗачетАвансов, АгентскиеУслуги.
Спасибо за всю информацию, которая помогла получить результат.
У меня обработка заполнения должна заполнять табличную часть документа "Заказ покупателя"
Обработка запускается из открытой формы существующего заказа это значит, что мне не нужно перебирать аргумент "ОбъектыНазначенияМассив" и я сразу беру первый элемент массива.
На форме обработки у меня расположена кнопка, по нажатию которой выполняется команда, к которой привязана процедура "ЗагрузитьЗаказ"
&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначенияМассив) Экспорт
// Ссылку на исходный документ сохраняю в реквизите обработки
Объект.СсылкаНаОбъект = ОбъектыНазначенияМассив[0];
Если НЕ ПустаяСсылка(Объект.СсылкаНаОбъект)Тогда
// Мне нужно поучить от пользователя некоторую информацию информацию
// для этого я открываю Форму внешней обработки заполнения объектов
ЭтаФорма.Открыть();
КонецЕсли;
КонецПроцедуры
&НаКлиенте
// Команда для кнопки формы внешней обработки
Процедура ЗагрузитьЗаказ(Команда)
// Закрываю форму внешней обработки
ЭтаФорма.Закрыть();
// Повторно открываю форму нужного объекта,
// в моём случае это Документ "Заказ клиента"
// Если форма уже открыта, то повторного открытия не происходит,
// но возвращается объект "Управляемая форма"
Параметр = Новый Структура("Ключ", Объект.СсылкаНаОбъект);
Форма = ОткрытьФорму("Документ.ЗаказКлиента.ФормаОбъекта",Параметр);
ОбъектФормы = Форма.Объект;
// Далее ваша функциональность
ОбъектФормы.Комментарий = формат(ТекущаяДата());
КонецПроцедуры
ПоказатьКонфигурация Розница 2.0, полугодовой давности.
Если это общеобразовательный пример, а не частный случай, то, возможно вариант ниже будет более понятным?
&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначения) Экспорт
Для каждого СсылкаНаОбъект Из ОбъектыНазначения Цикл
ФормаОбъекта = ПолучитьФорму(ПолучитьПолноеИмяДокумента(СсылкаНаОбъект)+".ФормаОбъекта", Новый Структура("Ключ", СсылкаНаОбъект));
ОбъектСсылки = ФормаОбъекта.Объект;
Запасы = ОбъектСсылки.Запасы;
НовСтр = Запасы.Добавить();
КонецЦикла;
КонецПроцедуры
&НаСервереБезКонтекста
Функция ПолучитьПолноеИмяДокумента(СсылкаНаОбъект)
Возврат СсылкаНаОбъект.Метаданные().ПолноеИмя();
КонецФункции
ПоказатьНо все-равно спасибо, навело на мысль сделать проще :)
Сейчас эта публикация не должна быть актуальна, так как она создавалась еще на первых релизах УТ 11. Когда БСП только появлялась, когда не хватало информации из общих источников.
(73) Поэтому спустя 3 года после публикации говорить, что это колхоз бессмысленно. На тот момент это была единственная известная мне публикация с необходимым решением. Сейчас можно книжку купить или в любой конфигурации на управляемых формах подсмотреть.
уТ 11.1.9.51 Пытаюсь по кнопке изменить колонку количество (в доп.реквизитах лежит число, его нужно кинуть в таблицу) Причем так же меняю цену - все делается как мне нужно! А количество - никак....
Это моя функция действия:
Процедура ЗаполнитьДокумент(ДокументОбъект)
ТЗ=ДокументОбъект.Товары.Выгрузить();
ДокументОбъект.Товары.Очистить();
ном=0;
кол= ДокументОбъект.ДополнительныеРеквизиты.Количество();
Пока ном < кол цикл
Если ДокументОбъект.ДополнительныеРеквизиты.Получить(ном).свойство.заголовок="Кол-во ЛИТРОВ" тогда
ТЗ[0].количество = ДокументОбъект.ДополнительныеРеквизиты[ном].значение;
КонецЕсли;
Если ДокументОбъект.ДополнительныеРеквизиты.Получить(ном).свойство.заголовок="Цена ЛИТРАЖ" тогда
ТЗ[0].цена = ДокументОбъект.ДополнительныеРеквизиты[ном].значение;
КонецЕсли;
ном=ном+1;
КонецЦикла;
ДокументОбъект.Товары.Загрузить(ТЗ);
Потом загружаю....
&НаКлиенте
Процедура Загрузить(Команда)
// Обновляем форму документа
ИмяДокумента = ПолучитьИмяМетаданныхДокумента(Объект.СсылкаНаДокумент);
Окна = ПолучитьОкна();
Для каждого Окно из Окна Цикл
Если НЕ Окно.Основное
И Найти(Окно.Заголовок, Объект.СсылкаНаДокумент) Тогда
ФормаДокумента = Окно.ПолучитьСодержимое();
Если Не ФормаДокумента = Неопределено Тогда
ФормаДокумента.Закрыть();
КонецЕсли;
ФормаДокумента = ОткрытьФорму("Документ."+ИмяДокумента+".Форма.ФормаДокумента",Новый Структура("Ключ", Объект.СсылкаНаДокумент),,,Окно);
НовыйОбъект = ФормаДокумента.Объект;
ЗаполнитьДокумент(НовыйОбъект);
КопироватьДанныеФормы(НовыйОбъект, ФормаДокумента.Объект);
ФормаДокумента.Объект.товары[0].количество=НовыйОбъект.товары[0].количество; //я уже и так пыталась
КонецЕсли;
КонецЦикла;
// Обновляем форму списка
ОповеститьОбИзменении(Тип("ДокументСсылка."+ИмяДокумента));
// Закрываем форму обработки
ЭтаФорма.Закрыть();
КонецПроцедуры
В итоге цена меняется, а количество прежнее..... :'(
Уже и отладчиком проходила вроде цифра из доп.реквизитов стоит... а в форме не обновляется... помогите.... я же делала по вашей методике
Причем в настройках Номенклатуры галочка с "упаковок номенклатуры" СНЯТА
Я может что пропустила... зачем тогда в табличной части реквизит "КОЛИЧЕСТВО"? если есть Реквизит "КоличествоУпаковок"
Парам = Новый Структура("Ключ", Объект.СсылкаНаОбъект); //это передали в форму заполнения
Форма = ПолучитьФорму("Документ.ОтчетКомитентуОПродажах.Форма.ФормаДокументаОПродажах",Парам); //окна не ищем, переполучаем уже открытое
Форма.ЭтотОбъект.Прочитать(); //обновляем нашу форму, перед этим сам объект-документ в базе уже заполнен и сохранен (записан, проведен)&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначенияМассив) Экспорт
типц = ПолучитьТипЦенДляВозвратов();
для каждого воз из ОбъектыНазначенияМассив цикл
Сообщить(""+ТипЗнч(воз)+" "+воз+" "+ТекущаяДата()); // тут нормально выходит сообщение
УстановитьСебестоимость(типц, воз);
КонецЦикла;
КонецПроцедуры
&Насервере
Функция УстановитьСебестоимость(типц, воз)
Сообщить(""+ТипЗнч(воз)+" "+воз); // тут тишина
сообщ = "";
объ = воз.ссылка.получитьобъект();
для каждого тов из объ.товары цикл
..............................................
КонецЦикла;
Попытка
объ.записать();
Исключение
сообщ = сообщ + "Не удалось записать документ " + воз.ссылка + " " + ОписаниеОшибки();
КонецПопытки;
Возврат сообщ;
КонецФункции
ПоказатьОбработка заполнения нормально подключилась. Кнопка "Заполнение" появилась. При нажатии на кнопку сообщение из процедуры ВыполнитьКоманду нормально выходит. А из функции УстановитьСебестоимость полная тишина, ни моих сообщений, ни сообщений об шибках, как будто в функции ни одной строчки кода.
Когда запустил обработку через меню "Файл - Открыть" и вручную вызвал процедуру ВыполнитьКоманду, всё отработало без замечаний.
&НаКлиенте
Процедура тест(Команда) //запускается кнопкой на форме
мас = новый Массив;
для каждого воз из элементы.список.ВыделенныеСтроки цикл
мас.Добавить(элементы.список.данныестроки(воз).Ссылка);
КонецЦикла;
ВыполнитьКоманду("",мас);
КонецПроцедуры
Показать1С:Предприятие 8.3 (8.3.5.1460)
1С:Предприятие 8. Общепит (3.0.33.19)
я пытаюсь создать заполнение Авизо по расчетам исходящее на основании Поступление товаров и услуг
использую вашу СведенияОВнешнейОбработке
ругается на
{ОбщийМодуль.ДополнительныеОтчетыИОбработкиКлиент.Модуль(505)}: Недостаточно фактических параметров
ФормаВнешнегоОбъекта.ВыполнитьКоманду(ПараметрыВызоваСервера.ИдентификаторКоманды, ПараметрыВызоваСервера.ОбъектыНазначения);
откуда эта ошибка идет из модуля объекта или модуля формы?
Запрос.Текст =
"ВЫБРАТЬ
| УстановкаСебестоимостиТовары.Номенклатура,
| МАКСИМУМ(УстановкаСебестоимостиТовары.Цена) КАК Цена
|ИЗ
| Документ.УстановкаСебестоимости.Товары КАК УстановкаСебестоимостиТовары
|ГДЕ
| УстановкаСебестоимостиТовары.Ссылка = &Ссылка
|
|СГРУППИРОВАТЬ ПО
| УстановкаСебестоимостиТовары.Номенклатура";
Запрос.УстановитьПараметр("Ссылка",Объект.СсылкаДок);
ОбДок = Объект.СсылкаДок.ПолучитьОбъект();
ОбДок.Товары.Загрузить(Запрос.Выполнить().Выгрузить());
ОбДок.Записать();
У формы обработки есть реквизит ВладелецФормы. Через него и можно редактировать все, что вашей душе угодно. Если конечно не запускать обработку из формы списка.
Если актуально - в результате у меня получился такой код(Задача была изменить цену на определенный коэффициент без записи документа для розницы 2.1.4):
////////////////////////////////////////////////////////////////////////////////
// Клиент - Программный интерфейс
&НаКлиенте
Процедура ВыполнитьКоманду(ИмяКоманды, ОбъектыНазначения) Экспорт
Открыть();
КонецПроцедуры
//////////////////////////////////////////////////////////// ////////////////////
// Клиент
&НаКлиенте
Процедура ИзменитьЦену(Команда)
// Вставить содержимое обработчика.
Если НЕ ЗначениеЗаполнено(Коэффициент) Тогда
Возврат;
КонецЕсли;
Для каждого Элемент из ОбъектыНазначения Цикл
НовыйОбъект = ВладелецФормы.Объект;
ЗаполнитьОбъект(НовыйОбъект);
КопироватьДанныеФормы(НовыйОбъект, ВладелецФормы.Объект);
ОбработкаТабличнойЧастиТоварыКлиентСервер.ОбновитьСуммыПодвала(ВладелецФормы.Объект.Товары, ВладелецФормы.Объект.ЦенаВключаетНДС, ВладелецФормы.СуммаВсего);
//ОбработкаТабличнойЧастиТоварыКлиент.ПриИзмененииРеквизитовВТЧКлиент(ТЧ, ТекущаяСтрока, СтруктураДействий, ВладелецФормы.КэшированныеЗначения);
ВладелецФормы.СуммаКОплате = ВладелецФормы.СуммаВсего - ВладелецФормы.СуммаОплачено - ВладелецФормы.СуммаВзаимозачет;
ВладелецФормы.РедактированиеТЧТовары = Истина;
ВладелецФормы.Модифицированность = Истина;
КонецЦикла;
Закрыть();
КонецПроцедуры
&НаСервере
Функция ЗаполнитьОбъект(Форма)
ТЧ = Форма.Товары;
Для Каждого Строка Из ТЧ Цикл
Строка.Цена = Строка.Цена * Коэффициент;
Строка.Сумма = Строка.Цена*Строка.Количество;
КонецЦикла;
Форма.СуммаДокумента = ТЧ.Итог("Сумма");
КонецФункции ПоказатьБыло бы круто если бы был пример вызова окна перед заполнением, в котором можно выбрать какие-нибудь параметры заполнения (например, другой документ).
1) в функции СведенияОВнешнейОбработке() ставишь "ОткрытиеФормы" вместо "ВызовКлиентскогоКетода"
2) кидаешь на форму нужные параметры и кнопку "заполнить" привязываешь к ней процедуру "ВыполнитьКоманду" (можешь назвать по своему)
и все.
P.S. очевидно команда Открыть() уже не нужна, сразу можно заполнять
//////////////////////////////////////////////////////////// ////////////////////
// ПРОГРАММНЫЙ ИНТЕРФЕЙС
#Область ПрограммныйИнтерфейс
// Возвращает сведения о внешней обработке.
Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("1.1");
ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиЗаполнениеОбъекта();
ПараметрыРегистрации.Версия = "1.3";
ПараметрыРегистрации.Назначение.Добавить("Справочник.Склады");
НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
НоваяКоманда.Представление = НСтр("ru = 'Заполнить наименование ""Склады"" не записывая объект (заполнение формы)'");
НоваяКоманда.Идентификатор = "ЗаполнитьНаименование";
НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыЗаполнениеФормы();
НоваяКоманда.ПоказыватьОповещение = Ложь;
НоваяКоманда.Скрыть = Истина;
Возврат ПараметрыРегистрации;
КонецФункции
// Интерфейс для выполнения команд обработки.
Процедура ВыполнитьКоманду(ИмяКоманды, ОбъектыНазначения, ПараметрыВыполнения) Экспорт
ПараметрыРегистрации = СведенияОВнешнейОбработке();
ПараметрыРегистрации.Команды.Колонки.Идентификатор.Имя = "ИмяКоманды";
ЭтаКоманда = ПараметрыРегистрации.Команды.Найти(ИмяКоманды, "ИмяКоманды");
Если ЭтаКоманда = Неопределено Тогда
ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'Команда ""%1"" не поддерживается обработкой ""%2""'"),
ИмяКоманды,
Метаданные().Представление()
);
КонецЕсли;
Если ИмяКоманды = "ЗаполнитьНаименование" Тогда
ЗаполнитьНаименование(ПараметрыВыполнения.ЭтаФорма, ПараметрыВыполнения.РезультатВыполнения);
КонецЕсли;
КонецПроцедуры
#КонецОбласти
//////////////////////////////////////////////////////////// ////////////////////
// СЛУЖЕБНЫЕ ПРОЦЕДУРЫ И ФУНКЦИИ
#Область СлужебныеПроцедурыИФункции
// Обработчик команды.
Процедура ЗаполнитьНаименование(Форма, РезультатВыполнения)
Форма.Объект.наименование = "111111111111111111111111111111111111111111111111111111";
Форма.Модифицированность = Истина;
СтандартныеПодсистемыКлиентСервер.ВывестиСообщение(
РезультатВыполнения,
НСтр("ru = 'Поле ""Наименование"" успешно заполнено'"),
"Объект.Наименование");
КонецПроцедуры
#КонецОбласти
ПоказатьПо существу нет никаких проблем с блокировками. Достаточно к табличной части обратиться через свойство ВладелецФормы. Делается это примерно так (демо):
&НаКлиенте
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначенияМассив) Экспорт
Для каждого ТекущаяСтрока из ВладелецФормы.Объект.Материалы Цикл
ТекущаяСтрока.Количество = 100 ;
Сообщить(ТекущаяСтрока.Количество) ;
КонецЦикла ;
КонецПроцедуры
ПоказатьТип значения свойства ВладелецФормы - УправляемаяФорма.
Все отлично отрабатывает. При этом у обработки должен быть Вид = ЗаполнениеОбъекта, а у Команды тип = ВызовКлиентскогоМетода.
Весь модуль объекта у меня выглядит так:
#Область РегистрацияОбработки
Функция СведенияОВнешнейОбработке() Экспорт
Назначения = Новый Массив ;
Назначения.Добавить("Документ.ОтражениеЗарплатыВУчете") ;
ПараметрыРегистрации = Новый Структура ;
ПараметрыРегистрации.Вставить("Вид","ЗаполнениеОбъекта");
ПараметрыРегистрации.Вставить("Назначение",Назначения);
ПараметрыРегистрации.Вставить("Наименование","Корректировка счетов учета, подразделений и видов платежей");
ПараметрыРегистрации.Вставить("Версия","1.0");
ПараметрыРегистрации.Вставить("Информация","Дополнительная обработка табличной части документа ""Зарплата (ЗУП 2.5, ЗиК 7.7)""");
ПараметрыРегистрации.Вставить("БезопасныйРежим",Истина);
Команды = ПолучитьТаблицуКоманд() ;
ДобавитьКоманду(Команды, "Скорректировать счета учета, подразделения и виды платежей","ИзменитьДокумент","ВызовКлиентскогоМетода",Ложь);
ПараметрыРегистрации.Вставить("Команды",Команды) ;
Возврат ПараметрыРегистрации;
КонецФункции
Функция ПолучитьТаблицуКоманд()
Команды = Новый ТаблицаЗначений ;
Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка")) ;
Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка")) ;
Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка")) ;
Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево")) ;
Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка")) ;
Возврат Команды ;
КонецФункции
Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
НоваяКоманда = ТаблицаКоманд.Добавить() ;
НоваяКоманда.Представление = Представление ;
НоваяКоманда.Идентификатор = Идентификатор ;
НоваяКоманда.Использование = Использование ;
НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение ;
НоваяКоманда.Модификатор = Модификатор ;
КонецПроцедуры
#КонецОбласти ПоказатьУ обработки должна быть создана Форма, на которой не нужно создавать никаких команд, объектов и элементов управления. В ней должна быть только Экспортная процедура ВыполнитьКоманду, текст команды см. выше.
Хочу отметить отдельно и заострить на этом внимание: Не смотря на то, что у добавляемой Команды (см. текст МодуляОбъектов) устанавливается тип ВызовКлиентскогоМетода, в модуле формы можно, при необходимости, создавать процедуры и функции, исполняемые на сервере и обращаться к ним из процедуры Выполнить(). Никаких ограничений я не обнаружил.
В ВыполнитьКоманду() вставил всего две строки
ЭтаФорма.РежимОткрытияОкна = РежимОткрытияОкнаФормы.БлокироватьОкноВладельца;
ЭтотОбъект.Открыть();
чтобы открылась форма обработки заполнения. А там уже -- полная свобода, и общение с заполняемой формой как Вы и сказали, через ВладелецФормы.Объект
Помогли.
ЭтаФорма.РежимОткрытияОкна = РежимОткрытияОкнаФормы.БлокироватьОкноВладельца;
ЭтотОбъект.Открыть();
после того как форма открылась, на ней поле "Коэффициент"- числовое и кнопка "Расчет" (и связанная с ней функция). Кнопка не срабатывает, нажимаем, но функция не выполняется.
Получилось, что вот этого оказалось достаточно:
ПараметрыФормы = Новый Структура("Ключ", ОбъектНазначения);
ТекФорма = ПолучитьФорму("Документ.ЗаказКлиента.Форма.ФормаДокумента", ПараметрыФормы);
ОбъектФормы = ТекФорма.Объект;
ОбновитьЦеныВДокументе(ОбъектФормы);
КопироватьДанныеФормы(ОбъектФормы, ТекФорма.Объект); ПоказатьНО, за подробное описание кода обработки - СПАСИБО, т.к. дало четкое понимание происходяещго процесса в мелких деталях.
Рабочий пример указанного кода можно посмотреть в коде обработки:
Рейтинг: 943
Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.
№ 84119
Создание 14.04.11 20:26
Обновление 05.07.20 14:16
Просмотры 221779
Загрузки 893
Рейтинг
332
Комментарии 105
Код открыт Не указано
Рубрики Инструментарий разработчика
Кому Разработчик
Тип файла Внешняя обработка (ert,epf)
Платформа 1С:Предприятие 8
Конфигурация 1С:Управление торговлей 11
Операционная система Не имеет значения
Страна Россия
Отрасль Не имеет значения
Налоги Не имеет значения
Вид учета Не имеет значения
Доступ к файлу Абонемент ($m)