Заполнение выделенных строк таблицы

// Функция создает структуру описывающую поле таблицы (колонку).
// Эта структура используется для заполнения значений в выделеных строках таблицы.
//
// Параметры:
//  ПолеТаблицыФормы - ПолеФормы - получается из Объект.Таблица.ТекущийЭлемент.
//  ОбъектОбработки - Массив - получается из РеквизитФормыВЗначение("Объект").
//
// Возвращаемое значение:
//  Структура - содержит поля описания:
//    * ИмяТаблицы - Строка, имя таблицы объекта в метаданных
//    * ИмяПоля - Строка, имя реквизита таблицы в метаданных
//    * ТолькоПросмотр - Булево, содержит значение признака ТолькоПросмотр с формы
//    * ЗаголовокСиноним - Строка, либо заголовок элемента на форме, либо при его отсутствии синоним реквизита из метаданных.
//
// Пример:
//  ОписаниеТекущейКолонки = ОписаниеКолонкиТаблицыФормы(Объект.Таблица.ТекущийЭлемент, РеквизитФормыВЗначение("Объект"))
//
Функция ОписаниеКолонкиТаблицыФормы(ПолеТаблицыФормы, ОбъектОбработки) Экспорт
	
	ЧастиПутиКДанным = ЧастиПутиКДанным(ПолеТаблицыФормы);
	
	ОписаниеКолонки = ЧастиПутиКДанным;
	
	ОписаниеКолонки.Вставить("ТолькоПросмотр", ПолеТаблицыФормы.ТолькоПросмотр);
	
	МетаданныеОбъекта = ОбъектОбработки.Метаданные();
	
	Реквизит = МетаданныеОбъекта.ТабличныеЧасти[ЧастиПутиКДанным.ИмяТаблицы].Реквизиты[ЧастиПутиКДанным.ИмяПоля];
	
	Если ЗначениеЗаполнено(ПолеТаблицыФормы.Заголовок) Тогда
		ОписаниеКолонки.Вставить("ЗаголовокСиноним", ПолеТаблицыФормы.Заголовок);
	Иначе
		ОписаниеКолонки.Вставить("ЗаголовокСиноним", Реквизит.Синоним);
	КонецЕсли;
	
	ОписаниеТипаКолонки = Новый ОписаниеТипов(Реквизит.Тип.Типы());
	
	ОписаниеКолонки.Вставить("ОписаниеТипов", ОписаниеТипаКолонки);
	
	Возврат ОписаниеКолонки;
	
КонецФункции

Функция ЧастиПутиКДанным(ЭлементФормы)
	
	Массив = СтрРазделить(ЭлементФормы.ПутьКДанным, ".");
	
	Результат = Новый Структура;
	Результат.Вставить("ИмяТаблицы", Массив[1]);
	Результат.Вставить("ИмяПоля", Массив[2]);
	
	Возврат Результат;
	
КонецФункции

// Возвращает является ли описанная колонка только для просмотра
// и выдает сообщение пользователю при необходимости.
//
// Параметры:
//  ОписаниеКолонки - Структура - см. функцию РаботаСФормамиСервер.ОписаниеКолонкиТаблицыФормы()
//
// Возвращаемое значение:
//  Булево - значение свойства ТолькоПросмотр.
//
Функция КолонкаТолькоПросмотр(ОписаниеКолонки) Экспорт
    
    Если ОписаниеКолонки.ТолькоПросмотр Тогда 
        // СтандартныеПодсистемы.БазоваяФункциональность
        ТекстСообщения = СтрШаблон("Колонка ""%1"" только для чтения", ОписаниеКолонки.ЗаголовокСиноним);
        ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстСообщения);
        // Конец СтандартныеПодсистемы.БазоваяФункциональность
        Возврат Истина;
    Иначе
        Возврат Ложь;
    КонецЕсли;
    
КонецФункции

// Вызывает форму выбора значения и прописывает выбранное значение во все выделенные строки таблицы
//
// Параметры:
//  ОписаниеКолонки - Структура - описание колонки на форме. 
//                                См. РаботаСФормамиСервер.ОписаниеКолонкиТаблицыФормы()
//  Форма - УправляемаяФорма - форма на которой расположена таблица.
//
Процедура ЗаполнитьЗначенияВВыделенныхСтроках(Знач ОписаниеКолонки, Форма) Экспорт
    
    ДополнительныеПараметры = ОписаниеКолонки;
    ДополнительныеПараметры.Вставить("Форма", Форма);
    
    ОписаниеОповещенияОЗавершении = Новый ОписаниеОповещения("ЗаполнитьЗначенияВВыделенныхСтрокахЗавершение", ЭтотОбъект, ДополнительныеПараметры);
    
    ПоказатьВыборЗначения(ОписаниеОповещенияОЗавершении, , , ОписаниеКолонки.ОписаниеТипов);
    
КонецПроцедуры

// Показывает форму выбора произвольного значения
//
// Параметры:
//  ОписаниеОповещенияОЗавершении - ОписаниеОповещения - Содержит описание процедуры, которая будет вызвана после 
//                                                       закрытия окна выбора значения со следующими параметрами:
//     - СтруктураРезультата - Структура, Неопределено - Неопределено, если пользователь отказался от выбора,
//                                                       или структура со значением:
//        * Значение - Произвольный - выбранное значение.
//     - ДополнительныеПараметры - Произвольный - значение, которое было указано при создании объекта. 
//  Значение - Произвольный - будет использовано в качестве начального значения в окне ввода.
//                            Пока не используется.
//  Подсказка - Строка - Текст заголовка окна выбора. Может использоваться в качестве подсказки пользователю. 
//                       Пока не используется.
//  ОписаниеТипов - ОписаниеТипов - описание типов, из которых допустимо выбирать.
//
Процедура ПоказатьВыборЗначения(ОписаниеОповещенияОЗавершении, Значение = Неопределено, Подсказка = "", ОписаниеТипов = Неопределено) Экспорт
    
    П = Новый Структура("ОписаниеТипаЗначения", ОписаниеТипов);
    
    ОткрытьФорму("ОбщаяФорма.ВыборПроизвольногоЗначения", П, ,
        , , ,
        ОписаниеОповещенияОЗавершении);
    
КонецПроцедуры
    
#Область ОбработчикиОповещения

Процедура ЗаполнитьЗначенияВВыделенныхСтрокахЗавершение(СтруктураРезультата, ДополнительныеПараметры) Экспорт
    
    Если СтруктураРезультата = Неопределено Тогда // значение заполнения не было выбрано
        Возврат;
    КонецЕсли;
    
    ВыделенныеСтроки = ДополнительныеПараметры.Форма.Элементы[ДополнительныеПараметры.ИмяТаблицы].ВыделенныеСтроки;
    ДанныеФормыКоллекция = ДополнительныеПараметры.Форма.Объект[ДополнительныеПараметры.ИмяТаблицы];
    
    Для каждого ИндектификаторВыделеннойСтроки Из ВыделенныеСтроки Цикл
        
        ЭлементКоллекции = ДанныеФормыКоллекция.НайтиПоИдентификатору(ИндектификаторВыделеннойСтроки);
        
        ЭлементКоллекции[ДополнительныеПараметры.ИмяПоля] = СтруктураРезультата.Значение;
        
    КонецЦикла;
    
КонецПроцедуры

#КонецОбласти

реквизит Значение типа Произвольный 

Модуль формы:

////////////////////////////////////////////////////////////////////////////////
// Форма предназначена для выбора значения произвольного (заданного) типа
//
// Параметры формы и их назначение:
// - ОписаниеТипаЗначения - описание типа нужного значения
// 
////////////////////////////////////////////////////////////////////////////////

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Элементы.Значение.ОграничениеТипа = Параметры.ОписаниеТипаЗначения;
	
КонецПроцедуры

&НаКлиенте
Процедура ПодтвердитьВыбор(Команда)
	
	ПараметрЗакрытия = Новый Структура("Значение", Значение);
	ЭтаФорма.Закрыть(ПараметрЗакрытия);
	
КонецПроцедуры

&НаКлиенте
Процедура ОтменитьВыбор(Команда)
	ЭтаФорма.Закрыть(Неопределено);
КонецПроцедуры

// Если в вашей конфигурации нет БСП, то напишите хотя бы такую

 Процедура СообщитьПользователю(ТекстСообщенияПользователю) Экспорт
    
    Сообщение = Новый СообщениеПользователю;
    Сообщение.Текст = ТекстСообщенияПользователю;
    Сообщение.Сообщить();
    
КонецПроцедуры