Пришел в компанию тот день, когда мы начали использовать давальческую схему переработки материалов, в частности документ "Отчет переработчика", и выгружать это все добро в БП. Если с первым проблем не возникло, то по второму пункту столкнулись с проблемой. Открыв документ в БП, обнаружили, что табличная часть "Услуги" не переносится.
Так выглядит документ в УНФ:
Такой результат ожидает в БП:
Для решения данной проблемы предлагаю следующие ходы на стороне УНФ:
- Убедимся, что универсальный формат поддерживает передачу данной табличной части, для этого найдем наш документ в xdto-пакете EnterpriseData
Здесь мы видим, что формат поддерживает все необходимые реквизиты табличной части "Услуги"
2. Проанализировать код модуля "МенеджерОбменаЧерезУниверсальныйФормат"
Для решения таких моментов настоятельно рекомендую, особенно кто только начинает работать с доработкой универсального формата обмена, загрузить типовые настройки правил конвертации в КД 3.0. Это можно сделать по инструкции из стартового помощника в КД 3.0, также написано уже немало статей по этому поводу.
В КД 3.0 весь модуль "МенеджерОбменаЧерезУниверсальныйФормат" будет структурирован, по документам, объектам, свойствам и вам горазде легче будет понимать логику, чем просто смотреть бесконечный, однотипный код самого модуля.
В КД 3.0 быстро нахожу необходимый документ
Внутри правила конвертации находим нашу табличную часть, и видим, что для всех реквизитов табличной части используется алгоритм конвертации, это означает, что вся логика по формированию вынесена в событие "ПриОтправке".
Логику этой процедуры мы можем найти тут же, на вкладке "Обработчики событий", а также название процедуры для поиска в модуле
Анализируя код процедуры, находим код, который отвечает за заполнение нашей ТЧ
Теперь нам надо найти функцию, которая определяет "РасширенныеДанныеИБ"
РасширенныеДанныеИБ = ДанныеДокументаОтчетПереработчика(ДанныеИБ);
В Данной функции находится текст запроса, который собирает данные документа, вот мы и приблизились к корню проблемы.
В данной функции таблица услуг получается вторым пакетом из запроса, если мы взглянем на сам запрос пакета, то увидим, что он берет данные из реквизитов документа, получение данных из ТЧ "Услуги" не поддерживается в принципе. Проблема найдена, остается последний шаг.
3. Исправить Текст запроса получения данных документа.
Директивой "ИзменениеИКонтроль" заимствую функцию "ДанныеДокументаОтчетПереработчика", переопределяю текст запроса, чтоб данные брались из табличной части документа.
Здесь приведу весь текст доработанного модуля
&ИзменениеИКонтроль("ДанныеДокументаОтчетПереработчика")
Функция ОД_ДанныеДокументаОтчетПереработчика(ДанныеИБ)
Результат = Новый Структура;
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ОтчетПереработчикаПродукция.Номенклатура,
| ОтчетПереработчикаПродукция.Характеристика,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаПродукция.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ВЫРАЗИТЬ(ОтчетПереработчикаПродукция.Количество * ОтчетПереработчикаПродукция.ЕдиницаИзмерения.Коэффициент КАК ЧИСЛО(15, 3))
| ИНАЧЕ ОтчетПереработчикаПродукция.Количество
| КОНЕЦ КАК Количество,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаПродукция.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ОтчетПереработчикаПродукция.Номенклатура.ЕдиницаИзмерения
| ИНАЧЕ ОтчетПереработчикаПродукция.ЕдиницаИзмерения
| КОНЕЦ КАК ЕдиницаИзмерения,
| ОтчетПереработчикаПродукция.Спецификация
|ИЗ
| Документ.ОтчетПереработчика.Продукция КАК ОтчетПереработчикаПродукция
|ГДЕ
| ОтчетПереработчикаПродукция.Ссылка = &Ссылка
| И ОтчетПереработчикаПродукция.Номенклатура <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
| И ОтчетПереработчикаПродукция.Количество > 0
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ОтчетПереработчика.Расход КАК Номенклатура,
| ОтчетПереработчика.Сумма,
| ОтчетПереработчика.СтавкаНДС,
| ОтчетПереработчика.СуммаНДС,
| 1 КАК Количество,
| ОтчетПереработчика.Сумма КАК Цена,
| ОтчетПереработчика.Расход.НаименованиеПолное КАК Содержание
|ИЗ
| Документ.ОтчетПереработчика КАК ОтчетПереработчика
|ГДЕ
| ОтчетПереработчика.Ссылка = &Ссылка
| И ОтчетПереработчика.Расход <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
| И ОтчетПереработчика.Сумма > 0
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ОтчетПереработчикаЗапасы.Номенклатура,
| ОтчетПереработчикаЗапасы.Характеристика,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаЗапасы.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ВЫРАЗИТЬ(ОтчетПереработчикаЗапасы.Количество * ОтчетПереработчикаЗапасы.ЕдиницаИзмерения.Коэффициент КАК ЧИСЛО(15, 3))
| ИНАЧЕ ОтчетПереработчикаЗапасы.Количество
| КОНЕЦ КАК Количество,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаЗапасы.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ОтчетПереработчикаЗапасы.Номенклатура.ЕдиницаИзмерения
| ИНАЧЕ ОтчетПереработчикаЗапасы.ЕдиницаИзмерения
| КОНЕЦ КАК ЕдиницаИзмерения,
| ОтчетПереработчикаЗапасы.Спецификация,
| ВЫБОР
| КОГДА ОтчетПереработчикаЗапасы.Партия <> ЗНАЧЕНИЕ(Справочник.ПартииНоменклатуры.ПустаяСсылка)
| И ОтчетПереработчикаЗапасы.Партия.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыПартий.ТоварыНаКомиссии)
| ТОГДА ВЫРАЗИТЬ(""КомиссионныеТовары"" КАК СТРОКА(18))
| ИНАЧЕ ВЫРАЗИТЬ(""СобственныеТовары"" КАК СТРОКА(18))
| КОНЕЦ КАК ТипЗапасов,
| ПОДСТРОКА(ОтчетПереработчикаЗапасы.НомерГТД.Код, 1, 30) КАК НомерГТД,
| ОтчетПереработчикаЗапасы.СтранаПроисхождения КАК СтранаПроисхождения
|ИЗ
| Документ.ОтчетПереработчика.Запасы КАК ОтчетПереработчикаЗапасы
|ГДЕ
| ОтчетПереработчикаЗапасы.Ссылка = &Ссылка
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ОтчетПереработчикаПредоплата.Документ КАК Документ,
| ОтчетПереработчикаПредоплата.СуммаРасчетов КАК Сумма
|ИЗ
| Документ.ОтчетПереработчика.Предоплата КАК ОтчетПереработчикаПредоплата
|ГДЕ
| ОтчетПереработчикаПредоплата.Ссылка = &Ссылка";
#Вставка
Запрос.Текст = ПолучитьТекстЗапросаУслугиСУчетомРасширения();
#КонецВставки
Запрос.УстановитьПараметр("Ссылка", ДанныеИБ.Ссылка);
РезультатыЗапроса = Запрос.ВыполнитьПакет();
ТаблицаПродукция = РезультатыЗапроса[0].Выгрузить();
Результат.Вставить("Продукция", ТаблицаПродукция);
ТаблицаУслуги = РезультатыЗапроса[1].Выгрузить();
ЗаполнитьСтавкиНДС_Отправка(ТаблицаУслуги);
Результат.Вставить("Услуги", ТаблицаУслуги);
ТаблицаМатериалы = РезультатыЗапроса[2].Выгрузить();
ЗаполнитьНомераГТДСтраныПроисхождения_Отправка(ТаблицаМатериалы, ДанныеИБ.Ссылка);
Результат.Вставить("Материалы", ТаблицаМатериалы);
ПогашениеЗадолженности = Новый ТаблицаЗначений;
ПогашениеЗадолженности.Колонки.Добавить("ДокументРасчетов");
ПогашениеЗадолженности.Колонки.Добавить("Сумма");
ВыборкаРасчеты = РезультатыЗапроса[3].Выбрать();
Пока ВыборкаРасчеты.Следующий() Цикл
ДокументРасчетов = Новый Структура("Значение, ИмяПКО", ВыборкаРасчеты.Документ, ИмяПКОДляДокумента(ВыборкаРасчеты.Документ));
Если Не ЗначениеЗаполнено(ДокументРасчетов.Значение)
ИЛИ Не ЗначениеЗаполнено(ДокументРасчетов.ИмяПКО) Тогда
Продолжить;
КонецЕсли;
СтрокаРасчеты = ПогашениеЗадолженности.Добавить();
СтрокаРасчеты.ДокументРасчетов = ДокументРасчетов;
СтрокаРасчеты.Сумма = ВыборкаРасчеты.Сумма;
КонецЦикла;
Результат.Вставить("ПогашениеЗадолженности", ПогашениеЗадолженности);
Возврат Результат;
КонецФункции
Функция ПолучитьТекстЗапросаУслугиСУчетомРасширения()
ТекстЗапроса = "ВЫБРАТЬ
| ОтчетПереработчикаПродукция.Номенклатура КАК Номенклатура,
| ОтчетПереработчикаПродукция.Характеристика КАК Характеристика,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаПродукция.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ВЫРАЗИТЬ(ОтчетПереработчикаПродукция.Количество * ОтчетПереработчикаПродукция.ЕдиницаИзмерения.Коэффициент КАК ЧИСЛО(15, 3))
| ИНАЧЕ ОтчетПереработчикаПродукция.Количество
| КОНЕЦ КАК Количество,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаПродукция.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ОтчетПереработчикаПродукция.Номенклатура.ЕдиницаИзмерения
| ИНАЧЕ ОтчетПереработчикаПродукция.ЕдиницаИзмерения
| КОНЕЦ КАК ЕдиницаИзмерения,
| ОтчетПереработчикаПродукция.Спецификация КАК Спецификация
|ИЗ
| Документ.ОтчетПереработчика.Продукция КАК ОтчетПереработчикаПродукция
|ГДЕ
| ОтчетПереработчикаПродукция.Ссылка = &Ссылка
| И ОтчетПереработчикаПродукция.Номенклатура <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
| И ОтчетПереработчикаПродукция.Количество > 0
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ОтчетПереработчикаРасходы.Расход КАК Номенклатура,
| ОтчетПереработчикаРасходы.Сумма КАК Сумма,
| ОтчетПереработчикаРасходы.СтавкаНДС КАК СтавкаНДС,
| ОтчетПереработчикаРасходы.СуммаНДС КАК СуммаНДС,
| ОтчетПереработчикаРасходы.ОД_Количество КАК Количество,
| ОтчетПереработчикаРасходы.ОД_Цена КАК Цена,
| ОтчетПереработчикаРасходы.Расход.НаименованиеПолное КАК Содержание
|ИЗ
| Документ.ОтчетПереработчика.Расходы КАК ОтчетПереработчикаРасходы
|ГДЕ
| ОтчетПереработчикаРасходы.Ссылка = &Ссылка
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ОтчетПереработчикаЗапасы.Номенклатура КАК Номенклатура,
| ОтчетПереработчикаЗапасы.Характеристика КАК Характеристика,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаЗапасы.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ВЫРАЗИТЬ(ОтчетПереработчикаЗапасы.Количество * ОтчетПереработчикаЗапасы.ЕдиницаИзмерения.Коэффициент КАК ЧИСЛО(15, 3))
| ИНАЧЕ ОтчетПереработчикаЗапасы.Количество
| КОНЕЦ КАК Количество,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(ОтчетПереработчикаЗапасы.ЕдиницаИзмерения) = ТИП(Справочник.ЕдиницыИзмерения)
| ТОГДА ОтчетПереработчикаЗапасы.Номенклатура.ЕдиницаИзмерения
| ИНАЧЕ ОтчетПереработчикаЗапасы.ЕдиницаИзмерения
| КОНЕЦ КАК ЕдиницаИзмерения,
| ОтчетПереработчикаЗапасы.Спецификация КАК Спецификация,
| ВЫБОР
| КОГДА ОтчетПереработчикаЗапасы.Партия <> ЗНАЧЕНИЕ(Справочник.ПартииНоменклатуры.ПустаяСсылка)
| И ОтчетПереработчикаЗапасы.Партия.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыПартий.ТоварыНаКомиссии)
| ТОГДА ВЫРАЗИТЬ(""КомиссионныеТовары"" КАК СТРОКА(18))
| ИНАЧЕ ВЫРАЗИТЬ(""СобственныеТовары"" КАК СТРОКА(18))
| КОНЕЦ КАК ТипЗапасов,
| ПОДСТРОКА(ОтчетПереработчикаЗапасы.НомерГТД.Код, 1, 30) КАК НомерГТД,
| ОтчетПереработчикаЗапасы.СтранаПроисхождения КАК СтранаПроисхождения
|ИЗ
| Документ.ОтчетПереработчика.Запасы КАК ОтчетПереработчикаЗапасы
|ГДЕ
| ОтчетПереработчикаЗапасы.Ссылка = &Ссылка
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ОтчетПереработчикаПредоплата.Документ КАК Документ,
| ОтчетПереработчикаПредоплата.СуммаРасчетов КАК Сумма
|ИЗ
| Документ.ОтчетПереработчика.Предоплата КАК ОтчетПереработчикаПредоплата
|ГДЕ
| ОтчетПереработчикаПредоплата.Ссылка = &Ссылка";
Возврат ТекстЗапроса;
КонецФункции // ПолучитьТекстЗапросаУслугиСУчетомРасширения()
На стороне БП доработки не требуются, в этом один из основных плюсов универсального формата, главное поддержать сам формат.
Тестировалось на версии УНФ 1.6.24.107.
Платформа 8.3.18.1334.
