Программное формирование существующих печатных форм

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ИсточникиКомандПечати = УправлениеПечатью.ИсточникиКомандПечати();
	Для Каждого ТекОбъект Из ИсточникиКомандПечати Цикл
		Элементы.ОбъектМетаданных.СписокВыбора.Добавить(ТекОбъект.ПолноеИмя());
	КонецЦикла;
	
КонецПроцедуры

&НаКлиенте
Процедура ОбъектМетаданныхПриИзменении(Элемент)
	ЗаполнитьСписокПечатныхФорм();
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьСписокПечатныхФорм()
	
	ИсточникКоманд 			= Метаданные.НайтиПоПолномуИмени(ОбъектМетаданных);
	ТаблицаКоманд 			= УправлениеПечатью.КомандыПечатиОбъекта(ИсточникКоманд);
	ВызовСерверногоМетода 	= Перечисления.СпособыВызоваДополнительныхОбработок.ВызовСерверногоМетода;
	Для Каждого КомандаПечати Из ТаблицаКоманд Цикл
		Если ПустаяСтрока(КомандаПечати.МенеджерПечати) Тогда
			Продолжить;
		КонецЕсли;
		Если КомандаПечати.ДополнительныеПараметры.Свойство("Ссылка") 
			И ЗначениеЗаполнено(КомандаПечати.ДополнительныеПараметры.Ссылка)
			И КомандаПечати.ДополнительныеПараметры.ВариантЗапуска <> ВызовСерверногоМетода Тогда
			Продолжить;
		КонецЕсли;
		ДанныеКоманды = Новый Структура("Представление, ВнешняяОбработка, МенеджерПечати, Идентификатор, ДополнительныеПараметры");
		ЗаполнитьЗначенияСвойств(ДанныеКоманды, КомандаПечати);
		Если КомандаПечати.ДополнительныеПараметры.Свойство("Ссылка") Тогда
			ДанныеКоманды.Вставить("ВнешняяОбработка", КомандаПечати.ДополнительныеПараметры.Ссылка);
		КонецЕсли;
		Элементы.ПечатнаяФорма.СписокВыбора.Добавить(ДанныеКоманды, КомандаПечати.Представление);
	КонецЦикла;
	
	Составляющие 							= СтрРазделить(ОбъектМетаданных, ".");
	Элементы.ОбъектСсылка.ОграничениеТипа 	= Новый ОписаниеТипов(Составляющие[0]+"Ссылка."+Составляющие[1]);
	
КонецПроцедуры

&НаКлиенте
Процедура Сформировать(Команда)
	СформироватьНаСервере();
КонецПроцедуры

&НаСервере
Процедура СформироватьНаСервере()
	
	ТабличныйДокумент.Очистить();
	
	Коллекция = УправлениеПечатью.ПодготовитьКоллекциюПечатныхФорм(ПечатнаяФорма.Идентификатор);
	Если Не ЗначениеЗаполнено(ПечатнаяФорма.ВнешняяОбработка) Тогда
		МодульПечати = ОбщегоНазначения.МенеджерОбъектаПоПолномуИмени(ПечатнаяФорма.МенеджерПечати);
	Иначе
		МодульПечати = ДополнительныеОтчетыИОбработки.ОбъектВнешнейОбработки(ПечатнаяФорма.ВнешняяОбработка);
		Если МодульПечати = Неопределено Тогда
			ВызватьИсключение "Не удалось подключить внешнюю печатную форму "+Строка(ПечатнаяФорма.ВнешняяОбработка);
		КонецЕсли;
	КонецЕсли;
	
	ПараметрыВывода = УправлениеПечатью.ПодготовитьСтруктуруПараметровВывода();
	МассивОбъектов = Новый Массив;
	МассивОбъектов.Добавить(ОбъектСсылка);
		
	Если Не ЗначениеЗаполнено(ПечатнаяФорма.ВнешняяОбработка) Тогда
		МодульПечати.Печать(МассивОбъектов, ПечатнаяФорма.ДополнительныеПараметры, Коллекция, Новый СписокЗначений, ПараметрыВывода);
	Иначе
		МодульПечати.Печать(МассивОбъектов, Коллекция, Новый СписокЗначений, ПараметрыВывода);
	КонецЕсли;
	
	ТабличныйДокумент = Коллекция[0].ТабличныйДокумент;	
	
КонецПроцедуры

&НаКлиенте
Процедура СохранитьВФайл(Команда)
	Оповещение 			= Новый ОписаниеОповещения("ВыборФайла_Завершение", ЭтотОбъект);
	Режим 				= РежимДиалогаВыбораФайла.ВыборКаталога;
	Диалог 				= Новый ДиалогВыбораФайла(Режим);
	Диалог.Заголовок 	= "Выберите каталог для сохранения";
	Диалог.Показать(Оповещение);
КонецПроцедуры

&НаКлиенте
Процедура ВыборФайла_Завершение(МассивФайлов, Контекст) Экспорт
	
	ОчиститьСообщения();
	Если МассивФайлов = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	ПолноеИмя = МассивФайлов[0]+ПечатнаяФорма.Представление+".pdf";
	
	Попытка
		ТабличныйДокумент.Записать(ПолноеИмя, ТипФайлаТабличногоДокумента.PDF);
		ОбщегоНазначенияКлиент.СообщитьПользователю("Файл успешно сохранен!");
	Исключение
		ОбщегоНазначенияКлиент.СообщитьПользователю("Не удалось записать файл: "+ОписаниеОшибки());
	КонецПопытки;
	
КонецПроцедуры

&НаКлиенте
Процедура СохранитьКакПрисоединенный(Команда)
	ОчиститьСообщения();
	СохранитьПрисоединенныйНаСервере();
КонецПроцедуры

&НаСервере
Процедура СохранитьПрисоединенныйНаСервере()
	
	Если Не Метаданные.ОпределяемыеТипы.ВладелецПрисоединенныхФайлов.Тип.СодержитТип(ТипЗнч(ОбъектСсылка)) Тогда
		ВызватьИсключение "Данный тип не позволяет хранить присоединенные файлы!";
	КонецЕсли;
	
	Поток = Новый ПотокВПамяти;
	ТабличныйДокумент.Записать(Поток, ТипФайлаТабличногоДокумента.PDF);
	Данные = Поток.ЗакрытьИПолучитьДвоичныеДанные();

	ПараметрыФайла = Новый Структура();
	ПараметрыФайла.Вставить("Автор", Пользователи.ТекущийПользователь());
	ПараметрыФайла.Вставить("ВладелецФайлов", ОбъектСсылка);
	ПараметрыФайла.Вставить("ИмяБезРасширения", ПечатнаяФорма.Представление);
	ПараметрыФайла.Вставить("РасширениеБезТочки", "pdf");
	ПараметрыФайла.Вставить("ВремяИзмененияУниверсальное");

	АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(Данные);
	Попытка
		РаботаСФайлами.ДобавитьФайл(ПараметрыФайла, АдресВоВременномХранилище);
		ОбщегоНазначения.СообщитьПользователю("Файл успешно добавлен!");
	Исключение
		ОбщегоНазначения.СообщитьПользователю("Не удалось добавить файл к "+Строка(ОбъектСсылка)+": "+ОписаниеОшибки());
	КонецПопытки;
	
КонецПроцедуры