Программное формирование существующих печатных форм

17.12.21

Разработка - Инструментарий разработчика

–

Получение списка печатных форм, формирование выбранной печатной формы и сохранение ее в файл.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование		SM	По подписке [?]	Купить один файл
Программное формирование существующих печатных форм .epf 8,97Kb 50	50	1 SM	Скачать	Купить за 1 850 руб.

В один прекрасный момент возникла задача контролировать комплектность печатных форм для документов реализации. При этом требовалось для разных случаев контролировать наличие разных печатных форм. Целиком задачу в рамках данной публикации рассматривать не будем, а рассмотрим следующие вопросы:

Получение списка печатных форм некоторого объекта
Программное получение заполненного табличного документа печатной формы
Сохранение табличного документа в формате pdf качестве присоединенного файла

Данный пример будем рассматривать в условиях наличия подсистем печати и внешних обработок БСП.

Для тестов использовалась конфигурация "1С:Комплексная автоматизация 2.4.13.278" с платформой 8.3.18.1289 (клиент-серверный вариант работы, тонкий клиент)

Получение списка печатных форм

Для получения объектов метаданных с командами печати будем использовать функцию УправлениеПечатью.ИсточникиКомандПечати:

Возвращаемое значение - Массив элементов типа ОбъектМетаданных.

Для получения списка печатных форм будем использовать функцию УправлениеПечатью.КомандыПечатиОбъекта:

Входящий параметр - ОбъектМетаданных (например, Метаданные.Документы.РеализацияТоваровУслуг)
Возвращаемое значение - ТаблицаЗначений с командами печати

Сразу оговоримся, будем получать следующие команды печати:

С заполненными менеджерами печати (комплекты печатных форм в этом случае в наш список не попадут)
Для внешних печатных форм получать будем команды с вариантом запуска ВызовСерверногоМетода

Итак, подготовим форму обработки:

ОбъектМетаданных - тип Строка (для хранение полного имени метаданных)
ПечатнаяФорма - тип Произвольный (для хранения свойств команды печати)
ОбъектСсылка - тип ЛюбаяСсылка (для выбора конкретного объекта базы данных)
У элементов формы ОбъектМетаданных и Печатная форма установим свойство Режим выбора из списка
У элемента формы ОбъектСсылка установим свойство ВыбиратьТип в значение Ложь

Далее добавим обработчик события формы ПриСозданииНаСервере, в котором заполним список выбора объектов метаданных с командами печати:

ПриСозданииНаСервере

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ИсточникиКомандПечати = УправлениеПечатью.ИсточникиКомандПечати();
	Для Каждого ТекОбъект Из ИсточникиКомандПечати Цикл
		Элементы.ОбъектМетаданных.СписокВыбора.Добавить(ТекОбъект.ПолноеИмя());
	КонецЦикла;
	
КонецПроцедуры

Для элемента формы ОбъектМетаданных добавим обработчик события ПриИзменении

ОбъектМетаданныхПриИзменении

&НаКлиенте
Процедура ОбъектМетаданныхПриИзменении(Элемент)
	ЗаполнитьСписокПечатныхФорм();
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьСписокПечатныхФорм()
	
	ИсточникКоманд 			= Метаданные.НайтиПоПолномуИмени(ОбъектМетаданных);
	ТаблицаКоманд 			= УправлениеПечатью.КомандыПечатиОбъекта(ИсточникКоманд);
	ВызовСерверногоМетода 	= Перечисления.СпособыВызоваДополнительныхОбработок.ВызовСерверногоМетода;
	Для Каждого КомандаПечати Из ТаблицаКоманд Цикл
		Если ПустаяСтрока(КомандаПечати.МенеджерПечати) Тогда
			Продолжить;
		КонецЕсли;
		Если КомандаПечати.ДополнительныеПараметры.Свойство("Ссылка") 
			И ЗначениеЗаполнено(КомандаПечати.ДополнительныеПараметры.Ссылка)
			И КомандаПечати.ДополнительныеПараметры.ВариантЗапуска <> ВызовСерверногоМетода Тогда
			Продолжить;
		КонецЕсли;
		ДанныеКоманды = Новый Структура("Представление, ВнешняяОбработка, МенеджерПечати, Идентификатор, ДополнительныеПараметры");
		ЗаполнитьЗначенияСвойств(ДанныеКоманды, КомандаПечати);
		Если КомандаПечати.ДополнительныеПараметры.Свойство("Ссылка") Тогда
			ДанныеКоманды.Вставить("ВнешняяОбработка", КомандаПечати.ДополнительныеПараметры.Ссылка);
		КонецЕсли;
		Элементы.ПечатнаяФорма.СписокВыбора.Добавить(ДанныеКоманды, КомандаПечати.Представление);
	КонецЦикла;
	
	Составляющие 							= СтрРазделить(ОбъектМетаданных, ".");
	Элементы.ОбъектСсылка.ОграничениеТипа 	= Новый ОписаниеТипов(Составляющие[0]+"Ссылка."+Составляющие[1]);
	
КонецПроцедуры

Итак, нам понадобятся следующие параметры команд:

Представление - Строка - представление печатной формы
ВнешняяОбработка - СправочникСсылка.ДополнительныеОтчетыИОбработки - обработка с экспортной процедурой Печать (для внешних печатных форм)
МенеджерПечати - Строка - строковое представление менеджера печати
Идентификатор - Строка - идентификатор печатной формы, понадобится для формирования коллекции печатных форм
ДополнительныеПараметры - Структура - другие параметры, используемые при формировании печатных форм

Программное формирование печатной формы

Когда мы выбрали печатную форму и ссылку, для которой необходимо формировать печатную форму, перейдем непосредственно к формированию табличного документа.

Здесь у нас возможны 2 варианта печатных форм:

Печатная форма встроена в конфигурацию
Внешняя печатная форма

В соответствие с этим будут небольшие отличия формирования, но в любом случае их объединяет одно: в модуле менеджера печати должна содержаться экспортная процедура Печать.

Рассмотрим список параметров процедуры Печать для обоих случаев

Встроенная	Внешняя	Тип
МассивОбъектов	МассивОбъектов	Массив
ДополнительныеПараметры	-	Структура
Коллекция	Коллекция	ТаблицаЗначений
ОбъектыПечати	ОбъектыПечати	СписокЗначений
ПараметрыВывода	ПараметрыВывода	Структура

МассивОбъектов - содержит массив ссылок, для которых формируются печатные формы
ДополнительныеПараметры - дополнительные параметры формирования печатной формы (не используются для внешних печатных форм)
Коллекция - для формирования на сервере используем УправлениеПечатью.ПодготовитьКоллекциюПечатныхФорм, будет содержать сформированные табличные документы
ОбъектыПечати - для назначения соответствий областей табличного документа ссылкам
ПараметрыВывода - дополнительные параметры сформированных форм (выходной параметр); для инициализации используется функция УправлениеПечатью.ПодготовитьСтруктуруПараметровВывода

Собственно, единственное отличие в процедурах - это количество параметров: для встроенных печатных форм - 5, для внешних печатных форм - 4. Следование параметров процедуры Печать сохранена в таблице выше.

Второй нюанс - это получение модуля менеджера печати:

Для встроенных печатных форм используем функцию БСП ОбщегоНазначения.МенеджерОбъектаПоПолномуИмени
Для внешних печатных форм ДополнительныеОтчетыИОбработки.ОбъектВнешнейОбработки

Когда мы выяснили все нюансы формирования, перейдем к реализации. Добавим на нашу форму:

реквизит формы ТабличныйДокумент с типом ТабличныйДокумент; перенесем реквизит на форму
команду формы Сформировать и перенесем ее на форму

Для команды Сформировать добавим обработчик:

Сформировать

&НаКлиенте
Процедура Сформировать(Команда)
	СформироватьНаСервере();
КонецПроцедуры

&НаСервере
Процедура СформироватьНаСервере()
	
	ТабличныйДокумент.Очистить();
	
	Коллекция = УправлениеПечатью.ПодготовитьКоллекциюПечатныхФорм(ПечатнаяФорма.Идентификатор);
	Если Не ЗначениеЗаполнено(ПечатнаяФорма.ВнешняяОбработка) Тогда
		МодульПечати = ОбщегоНазначения.МенеджерОбъектаПоПолномуИмени(ПечатнаяФорма.МенеджерПечати);
	Иначе
		МодульПечати = ДополнительныеОтчетыИОбработки.ОбъектВнешнейОбработки(ПечатнаяФорма.ВнешняяОбработка);
		Если МодульПечати = Неопределено Тогда
			ВызватьИсключение "Не удалось подключить внешнюю печатную форму "+Строка(ПечатнаяФорма.ВнешняяОбработка);
		КонецЕсли;
	КонецЕсли;
	
	ПараметрыВывода = УправлениеПечатью.ПодготовитьСтруктуруПараметровВывода();
	МассивОбъектов = Новый Массив;
	МассивОбъектов.Добавить(ОбъектСсылка);
		
	Если Не ЗначениеЗаполнено(ПечатнаяФорма.ВнешняяОбработка) Тогда
		МодульПечати.Печать(МассивОбъектов, ПечатнаяФорма.ДополнительныеПараметры, Коллекция, Новый СписокЗначений, ПараметрыВывода);
	Иначе
		МодульПечати.Печать(МассивОбъектов, Коллекция, Новый СписокЗначений, ПараметрыВывода);
	КонецЕсли;
	
	ТабличныйДокумент = Коллекция[0].ТабличныйДокумент;	
	
КонецПроцедуры

Сохранение печатной формы

В качестве небольшого бонуса рассмотрим, как сохранить нашу печатную форму:

В файл на клиентский ПК
В качестве присоединенного файла

Добавим на форму 2 команды и соответствующие им кнопки:

СохранитьВФайл

&НаКлиенте
Процедура СохранитьВФайл(Команда)
	Оповещение 			= Новый ОписаниеОповещения("ВыборФайла_Завершение", ЭтотОбъект);
	Режим 				= РежимДиалогаВыбораФайла.ВыборКаталога;
	Диалог 				= Новый ДиалогВыбораФайла(Режим);
	Диалог.Заголовок 	= "Выберите каталог для сохранения";
	Диалог.Показать(Оповещение);
КонецПроцедуры

&НаКлиенте
Процедура ВыборФайла_Завершение(МассивФайлов, Контекст) Экспорт
	
	ОчиститьСообщения();
	Если МассивФайлов = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	ПолноеИмя = МассивФайлов[0]+ПечатнаяФорма.Представление+".pdf";
	
	Попытка
		ТабличныйДокумент.Записать(ПолноеИмя, ТипФайлаТабличногоДокумента.PDF);
		ОбщегоНазначенияКлиент.СообщитьПользователю("Файл успешно сохранен!");
	Исключение
		ОбщегоНазначенияКлиент.СообщитьПользователю("Не удалось записать файл: "+ОписаниеОшибки());
	КонецПопытки;
	
КонецПроцедуры

СохранитьКакПрисоединенный

&НаКлиенте
Процедура СохранитьКакПрисоединенный(Команда)
	ОчиститьСообщения();
	СохранитьПрисоединенныйНаСервере();
КонецПроцедуры

&НаСервере
Процедура СохранитьПрисоединенныйНаСервере()
	
	Если Не Метаданные.ОпределяемыеТипы.ВладелецПрисоединенныхФайлов.Тип.СодержитТип(ТипЗнч(ОбъектСсылка)) Тогда
		ВызватьИсключение "Данный тип не позволяет хранить присоединенные файлы!";
	КонецЕсли;
	
	Поток = Новый ПотокВПамяти;
	ТабличныйДокумент.Записать(Поток, ТипФайлаТабличногоДокумента.PDF);
	Данные = Поток.ЗакрытьИПолучитьДвоичныеДанные();

	ПараметрыФайла = Новый Структура();
	ПараметрыФайла.Вставить("Автор", Пользователи.ТекущийПользователь());
	ПараметрыФайла.Вставить("ВладелецФайлов", ОбъектСсылка);
	ПараметрыФайла.Вставить("ИмяБезРасширения", ПечатнаяФорма.Представление);
	ПараметрыФайла.Вставить("РасширениеБезТочки", "pdf");
	ПараметрыФайла.Вставить("ВремяИзмененияУниверсальное");

	АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(Данные);
	Попытка
		РаботаСФайлами.ДобавитьФайл(ПараметрыФайла, АдресВоВременномХранилище);
		ОбщегоНазначения.СообщитьПользователю("Файл успешно добавлен!");
	Исключение
		ОбщегоНазначения.СообщитьПользователю("Не удалось добавить файл к "+Строка(ОбъектСсылка)+": "+ОписаниеОшибки());
	КонецПопытки;
	
КонецПроцедуры

В списке файлов публикации вы сможете найти готовую демонстрационную форму, которую можете добавить в справочник внешних обработок. Не забудьте поставить плюсик)

ПФ ВПФ печатная форма БСП печать pdf присоединенный файл

–

См. также

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Программист Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

10000 руб.

02.09.2020 141506 777 391

804

Infostart PrintWizard - создание и редактирование печатных форм в 1С 8.3

Пакетная печать Печатные формы Инструментарий разработчика Программист Платформа 1С v8.3 Запросы 1С:Зарплата и кадры бюджетного учреждения 1С:Конвертация данных 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Платные (руб)

Инструмент, позволяющий абсолютно по-новому взглянуть на процесс разработки печатных форм. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и "прозрачность" разработки, а также навести порядок в многообразии корпоративных печатных форм.

18000 руб.

06.10.2023 11762 31 6

OneDebugger - инструмент для отладки кода в 1С без использования конфигуратора

Инструментарий разработчика Программист Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Инструмент для написания и отладки кода в режиме «1С:Предприятие». Представляет собой консоль кода с возможностью пошаговой отладки, просмотра значений переменных любых типов, использования процедур и функций, просмотра стека вызовов, вычисления произвольных выражений на встроенном языке в контексте точки останова, синтаксического контроля и остановки по ошибке. В консоли используется удобный редактор кода с подсветкой, контекстной подсказкой, возможностью вызова конструкторов запроса и форматной строки.

5400 руб.

17.05.2024 14443 36 29

Infostart DataFormWizard: Управление данными и формами в 1С 8.3

Инструменты администратора БД Инструментарий разработчика Роли и права Программист Платформа 1С v8.3 Конфигурации 1cv8 Россия Платные (руб)

Расширение позволяет без изменения кода конфигурации выполнять проверки при вводе данных, скрывать от пользователя недоступные ему данные, выполнять код в обработчиках. Не изменяет данные конфигурации, легко устанавливается практически на любую конфигурацию на управляемых формах.

10000 руб.

10.11.2023 7406 27 4

SALE! %

PowerTools: Инструменты администратора 1С 8.3

Инструментарий разработчика Инструменты администратора БД Системный администратор Программист Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Россия Платные (руб)

Универсальный инструмент программиста для администрирования конфигураций. Сборник наиболее часто используемых обработок под единым интерфейсом.

~~3600~~ 2880 руб.

14.01.2013 182215 1105 0

876

Многопоточность в 1С. Универсальный «Менеджер потоков» 2.1

Инструментарий разработчика Программист Платформа 1С v8.3 Конфигурации 1cv8 Россия Платные (руб)

Восстановление партий или взаиморасчетов, расчет зарплаты, пакетное формирование документов или отчетов - теперь все это стало доступнее. * Есть желание повысить скорость работы медленных алгоритмов! Но... * Нет времени думать о реализации многопоточности? * о запуске и остановке потоков? * о поддержании потоков в рабочем состоянии? * о передаче данных в потоки и как получить ответ из потока? * об организации последовательности? Тогда ЭТО - то что надо!!!

5000 руб.

07.02.2018 101261 243 97

304

Обработка для 1С: выполнение произвольного кода или запроса с параметрами через Web-сервис (замена COM-подключений)

Инструментарий разработчика Перенос данных 1C Программист Платформа 1С v8.3 Платные (руб)

В процессе работы в 1С часто возникает потребность получить данные из другой базы. Обычно это делается через COM-соединение, и время выполнения запроса при этом оставляет желать лучшего. В данной публикации представлено универсальное решение для 1С, позволяющее практически моментально выполнить произвольный код или запрос с параметрами в другой информационной базе через Web-сервис.

2400 руб.

24.09.2019 24580 17 15

[ЕХТ] Фреймворк для Расширений 1С

Инструментарий разработчика Программист Платформа 1С v8.3 Управляемые формы Платные (руб)

"Фреймворк для Расширений 1С" это универсальное и многофункциональное решение, упрощающее разработку и поддержку создаваемых Расширений. Поставляется в виде комплекта из нескольких Расширений с открытым исходным кодом. Работает в любых Конфигурациях в режиме Управляемого приложения с режимом совместимости 8.3.12 и выше без необходимости внесения изменений в Конфигурацию.

3000 руб.

27.08.2019 19535 7 8

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. RustIG 1721 17.12.21 09:13 Сейчас в теме

интересненько...

2. МимохожийОднако 142 21.12.21 08:12 Сейчас в теме

Было бы интересно получить вывод печатных форм в общую форму печати документов

3. RocKeR_13 1345 21.12.21 08:35 Сейчас в теме

(2) Есть такое - сам давно пользуюсь)

4. user1823913 02.11.22 07:21 Сейчас в теме

&НаСервере
Процедура СформироватьНаСервере()
....

Коллекция = УправлениеПечатью.ПодготовитьКоллекциюПечатныхФорм(ПечатнаяФорма.Идентификатор);

ПодготовитьКоллекциюПечатныхФорм () - не экспортная процедура, вызвать её не возможно.