Сервисы интеграции без Шины и интеграции

13.03.24

Пример использования «Сервисов интеграции» без подключения к Шине и без обменов.

Скачать файл

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование		Бесплатно
Расширение для статьи "Сервисы интеграции без Шины и интеграции" .cfe 10,51Kb ver:1.0.0 77	77	Скачать бесплатно
Обработка для статьи "Сервисы интеграции без Шины и интеграции" .epf 8,83Kb ver:1.0.0 78	78	Скачать бесплатно

Статья создана для того, чтобы развеять миф: «Сервисы интеграции» — это только коннектор для Шины.

Покажу пример с «ПоказатьОповещениеПользователя», в этом примере не будет Шины от слова совсем.

У меня была не самая свежая БСП 3.1.6.118, на ней и буду демонстрировать, но вообще не принципиально.

В БСП есть расширение «_ДемоПустоеРасширение», в нем создал «Сервис интеграции» и Канал «_ОповещенияПользователей» для отправки:

В БСП есть форма текущие дела, добавим ее в расширение «_ДемоПустоеРасширение»:

Добавим обработчик события формы ПриОткрытии (После): _ДемоПустоеРасширениеПриОткрытииПосле

Добавим на форму код:

&НаКлиенте
Перем СтруктураПользователяФормы; 
                                                                                           
&НаКлиенте
Процедура _ДемоПустоеРасширениеПриОткрытииПосле(Отказ) 
	СтруктураПользователяФормы = ПолучитьСтруктуруПользователя();
	// установил срабатывание раз в 15 секунд
	ПодключитьОбработчикОжидания("ПолучитьСообщенияДляОповещения", 15, Ложь);
КонецПроцедуры

&НаСервере
Функция ПолучитьСтруктуруПользователя()
	
	ВключенПривилегированныйРежим = Ложь;
	Если Не ПривилегированныйРежим() Тогда  
		ВключенПривилегированныйРежим = Истина;
		УстановитьПривилегированныйРежим(ВключенПривилегированныйРежим);
	КонецЕсли;	

	ТекПользовательФормы = ПользователиИнформационнойБазы.ТекущийПользователь(); 
	СтруктураПользователяФормы = Новый Структура("Имя,Идентификатор",
		ТекПользовательФормы.Имя, 
		Строка(ТекПользовательФормы.УникальныйИдентификатор));
		
	Если ВключенПривилегированныйРежим Тогда 
		ВключенПривилегированныйРежим = Ложь;
		УстановитьПривилегированныйРежим(ВключенПривилегированныйРежим);	
	КонецЕсли;
	
	Возврат СтруктураПользователяФормы;
	
КонецФункции	

&НаКлиенте
Процедура ПолучитьСообщенияДляОповещения()
	
	МассивСообщений = ПолучитьСообщения("_ДляОповещения", "_ОповещенияПользователей", СтруктураПользователяФормы);
	Если МассивСообщений.Количество() > 0 Тогда	
		Для Каждого ТекСообщение Из МассивСообщений Цикл 
			
			Если Не ТекСообщение.Свойство("Сообщение") Тогда 
								
				Продолжить;
				
			КонецЕсли;	
				
			Если ТекСообщение.Свойство("НавигационнаяСсылка") Тогда	 
				
				ПоказатьОповещениеПользователя(ТекСообщение.Сообщение
					,ТекСообщение.НавигационнаяСсылка
					,?(ТекСообщение.Свойство("Отправитель"),ТекСообщение.Отправитель,""),
					,СтатусОповещенияПользователя.Важное
					,ТекСообщение.Идентификатор);
				
			Иначе
				
				ПоказатьОповещениеПользователя(ТекСообщение.Сообщение,
					,?(ТекСообщение.Свойство("Отправитель"),ТекСообщение.Отправитель,""),
					,СтатусОповещенияПользователя.Важное
					,ТекСообщение.Идентификатор);
			КонецЕсли;	
				

		КонецЦикла;

       	Если МассивСообщений.Количество() > 0 Тогда 
		
			ОчиститьВсеСообщенияНаСервере("_ДляОповещения", "_ОповещенияПользователей", МассивСообщений);
			
		КонецЕсли;
  
	КонецЕсли;
	
КонецПроцедуры

&НаСервереБезКонтекста
Функция ПолучитьСообщения(Сервис, Канал, ПользовательФормы) 
	
    Отбор = Новый Структура;
    Отбор.Вставить("КодПолучателя", ПользовательФормы.Идентификатор);
	
	ПараметрыОтбора = Новый Соответствие;
	ПараметрыОтбора.Вставить("ТипСообщения", "Оповещение");  
	
	СообщенияСервиса = СервисыИнтеграции[Сервис][Канал].ВыбратьСообщения(Отбор);
	
	МассивСообщений = Новый Массив;
	Для Каждого текСообщение Из СообщенияСервиса Цикл 
		
		СткруктураСообщения = Новый Структура;	
		СткруктураСообщения.Вставить("Идентификатор", текСообщение.Идентификатор);
		
		РазмерСообщения = текСообщение.Параметры.Получить("РазмерСообщения");
		
		Если РазмерСообщения <> Неопределено Тогда
			РазмерБуфера = Число(РазмерСообщения); 
		Иначе
			РазмерБуфера = 1024;    
		КонецЕсли;

		// Читаем тело сообщения++         
		Если РазмерБуфера = 0 Тогда 
				
			ВходящееСообщение = "";
				
		Иначе
				
			Тело  = Новый БуферДвоичныхДанных(0);
			Буфер = Новый БуферДвоичныхДанных(РазмерБуфера);
			Поток = текСообщение.ПолучитьТелоКакПоток();	
				
			Пока Истина Цикл
					
				Прочитано = Поток.Прочитать(Буфер, 0, РазмерБуфера);
					
				Если Прочитано > 0 Тогда
						
					Тело = Тело.Соединить(Буфер);  
						
				КонецЕсли;   
					
				Если Прочитано < РазмерБуфера Тогда
						
					Прервать; 
						
		 		КонецЕсли; 
					
			КонецЦикла; 
				
			ВходящееСообщение = ПолучитьСтрокуИзБуфераДвоичныхДанных(Тело);   
				
		КонецЕсли;
		
		Если Не ПустаяСтрока(ВходящееСообщение) Тогда 
			
			РезультатJS = ЧтениеДанныхИзJSON(ВходящееСообщение);
			
			Если РезультатJS.Отработал Тогда 
				
				ТелоРезультат = РезультатJS.Результат;
				 
				СткруктураСообщения.Вставить("Сообщение", ТелоРезультат.Сообщение);	
				СткруктураСообщения.Вставить("НавигационнаяСсылка", 
					ТелоРезультат.НавигационнаяСсылка);
				СткруктураСообщения.Вставить("Отправитель", ТелоРезультат.Отправитель);
				
			КонецЕсли;	
			
		КонецЕсли;
		
		
		МассивСообщений.Добавить(СткруктураСообщения);
		
	КонецЦикла;
	
	Возврат МассивСообщений;
	
КонецФункции

&НаСервереБезКонтекста
Процедура ОчиститьВсеСообщенияНаСервере(Сервис, Канал, МассивСообщений = Неопределено)  
	
	Если ЗначениеЗаполнено(МассивСообщений) Тогда 
		Для Каждого ИдентификаторСообщения Из МассивСообщений Цикл 
			СервисыИнтеграции[Сервис][Канал].УдалитьСообщения(ИдентификаторСообщения);	
		КонецЦикла;	
	КонецЕсли;
	
КонецПроцедуры   

// Функция Десериализует строку JSON в формат данных 1С
//
// Параметры:
//  СтрокаJSON - Строка - JSON
// 
// Возвращаемое значение:
//  Результат - Структура
//  	Отработал - Булево - Выполнено или нет
//  	ТекстОшибки - Строка - Текст ошибки если функция отработала с ошибкой
//  	Результат - ЛюбоеЗначение - Данные в формате 1С
//
&НаСервереБезКонтекста
Функция ЧтениеДанныхИзJSON(СтрокаJSON) Экспорт
	
	Результат = Новый Структура("Отработал, ТекстОшибки", Истина, "");
						
	Попытка
		ЧтениеJSON 				= Новый ЧтениеJSON;
		ЧтениеJSON.УстановитьСтроку(СтрокаJSON);
		Результат.Вставить("Результат",ПрочитатьJSON(ЧтениеJSON));
	Исключение
		Результат.Отработал 	= Ложь;
		Результат.ТекстОшибки 	= ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
	КонецПопытки;
	
	Возврат Результат;
	
КонецФункции

Пояснение по коду:

В обработчике события «ПриОткрытии» считываем параметры текущего пользователя и запускаем обработчик ожидания раз в 15 секунд. Параметры пользователя нам нужны для поиска сообщений, адресованных только ему.
В обработчике считываем сообщения и выводим в цикле их содержание используя функционал «ПоказатьОповещениеПользователя».
После вывода оповещения удаляем сообщения.

Расширение приложено к данной статье «_ДемоПустоеРасширение.cfe»

Активируем «Сервис интеграции» воспользовавшись типовой обработкой или обработкой «Настройка сервисов интеграции».

Никакие параметры не заполняем, так как мы к Шине не цепляемся.

Для примера я создал обработку, которую приложил к данной статье «СоздатьСообщениеДляОповещения.epf»

Код обработки:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Метаданные.СервисыИнтеграции.Количество() > 0 Тогда 
		Для Каждого СервисИнтеграции Из Метаданные.СервисыИнтеграции Цикл 
			
			Элементы.Сервис.СписокВыбора.Добавить(СервисИнтеграции.Имя,СервисИнтеграции.Имя);
			
		КонецЦикла;	
		
		Если Элементы.Сервис.СписокВыбора.Количество() > 0 Тогда 
			
			Сервис = Элементы.Сервис.СписокВыбора[0];
			
	        СервисПриИзмененииНаСервере();
							
		КонецЕсли;	
	КонецЕсли;  
	
	// Для получения списка пользователей нужны административные права++
	ВключенПривилегированныйРежим = Ложь;
	Если Не ПривилегированныйРежим() Тогда  
		ВключенПривилегированныйРежим = Истина;
		УстановитьПривилегированныйРежим(ВключенПривилегированныйРежим);
	КонецЕсли;	
	
	ТекПользовательФормы = ПользователиИнформационнойБазы.ТекущийПользователь(); 
	ИмяОтпраителя = ТекПользовательФормы.Имя;
	ИдентификаторОтправителя = Строка(ТекПользовательФормы.УникальныйИдентификатор);		
	
	ВыборкаПользователей = ПользователиИнформационнойБазы.ПолучитьПользователей(); // Получаем список пользователей   
 	Для Каждого ЭлементМассива Из ВыборкаПользователей Цикл 	
		
		Элементы.Получатель.СписокВыбора.Добавить(Строка(ЭлементМассива.УникальныйИдентификатор), ЭлементМассива.Имя);

	КонецЦикла; 
	
	Если ВключенПривилегированныйРежим Тогда 
		ВключенПривилегированныйРежим = Ложь;
		УстановитьПривилегированныйРежим(ВключенПривилегированныйРежим);	
	КонецЕсли;
	// Для получения списка пользователей нужны административные права--

КонецПроцедуры

&НаКлиенте
Процедура СервисПриИзменении(Элемент)
	
	СервисПриИзмененииНаСервере();
	
КонецПроцедуры
&НаСервере
Процедура СервисПриИзмененииНаСервере()
	
	Если Элементы.Канал.СписокВыбора.Количество() > 0 Тогда
		
		Элементы.Канал.СписокВыбора.Очистить();
		
	КонецЕсли;
	
	текСервис = Метаданные.СервисыИнтеграции.Найти(Сервис);
			
	Если текСервис <> Неопределено Тогда 
				
		КаналаСервисаИнтеграцииОтправка = Метаданные.СвойстваОбъектов.НаправлениеСообщенияКаналаСервисаИнтеграции.Отправка;
		Для Каждого текКаналСервиса Из текСервис.КаналыСервисаИнтеграции Цикл 
					
			Если текКаналСервиса.НаправлениеСообщения = КаналаСервисаИнтеграцииОтправка Тогда 
						
				Элементы.Канал.СписокВыбора.Добавить(текКаналСервиса.Имя, текКаналСервиса.Имя);				
						
			КонецЕсли;
					
		КонецЦикла;
				
		Если Элементы.Канал.СписокВыбора.Количество() > 0 Тогда 
					
			Канал = Элементы.Канал.СписокВыбора[0];
					
		КонецЕсли;
				
	КонецЕсли;
			
КонецПроцедуры


&НаКлиенте
Процедура ОтправитьСообщение(Команда)
	ОтправитьСообщениеНаСервере();
КонецПроцедуры
&НаСервере
Процедура ОтправитьСообщениеНаСервере()
	
	// храним сообщение 60 дней
	ДатаУстаревания = ТекущаяДатаСеанса() + 60 * 86400;
	
	СообщениеСервиса = СервисыИнтеграции[Сервис].СоздатьСообщение(ДатаУстаревания);
	
	// вставляем идентификаторы
	СообщениеСервиса.КодПолучателя = Получатель;
	СообщениеСервиса.КодОтправителя = ИдентификаторОтправителя;
	
	СтруктураТела = Новый Структура("Сообщение, НавигационнаяСсылка, Отправитель", 
		Сообщение, ТекстоваяСсылка, ИмяОтпраителя);
	
	// передавать будем в формате json
	РезультатJS = ЗаписатьДанныеВJSON(, СтруктураТела);
	
	ТекстСообщения = ?(РезультатJS.Отработал, РезультатJS.Результат, ""); 
	
	Тело = СообщениеСервиса.ПолучитьТелоКакПоток();
	Буфер = ПолучитьБуферДвоичныхДанныхИзСтроки(ТекстСообщения);
	Тело.Записать(Буфер, 0, Буфер.Размер);
	Тело.Закрыть();

	// размер тела
	СообщениеСервиса.Параметры.Вставить("РазмерСообщения", Буфер.Размер);
	// тип сообщения, для выборки
	СообщениеСервиса.Параметры.Вставить("ТипСообщения", "Оповещение");
	
	СервисыИнтеграции[Сервис][Канал].ОтправитьСообщение(СообщениеСервиса);
	
КонецПроцедуры


// Функция возвращает чаще всего используемые ПараметрыЗаписиJSON (JSONWriterSettings)
// 
// Возвращаемое значение:
//  Результат - Структура - Стандартное заполнение
//
Функция СтандартныеПараметрыJSON() Экспорт
	
	Результат = Новый Структура;
	Результат.Вставить("ПереносСтрок",			ПереносСтрокJSON.Нет);
	Результат.Вставить("СимволОтступа",			" ");
	Результат.Вставить("ИспользоватьДвойныеКавычки",	Истина);
	Результат.Вставить("ЭкранированиеСимволов",		ЭкранированиеСимволовJSON.Нет);
	Результат.Вставить("ЭкранироватьАмперсанд",		Ложь);
	Результат.Вставить("ЭкранироватьОдинарныеКавычки",	Ложь);
	Результат.Вставить("ЭкранироватьРазделителиСтрок",	Ложь);
	Результат.Вставить("ЭкранироватьУгловыеСкобки",		Ложь);
	Результат.Вставить("ЭкранироватьСлеш",			Ложь);	
	
	Возврат Результат;		
	
КонецФункции

// Функция переводит данные в формат JSON
//
// Параметры:
//  ВходящиеПараметры	 - Структура - Параметры формирование JSON
//  ВходныеДанные		 - ЛюбоеЗначение - Данные которые нужно перевести в JSON
// 
// Возвращаемое значение:
//  Результат - Структура
//  	Отработал - Булево - Выполнено или нет
//  	ТекстОшибки - Строка - Текст ошибки если функция отработала с ошибкой
//  	Результат - Строка - JSON
//
Функция ЗаписатьДанныеВJSON(ВходящиеПараметры = Неопределено, ВходныеДанные = "") Экспорт
	
	Результат = Новый Структура("Отработал, ТекстОшибки", Истина, "");
	
	Если ВходящиеПараметры = Неопределено Тогда 
		ВходящиеПараметры = СтандартныеПараметрыJSON(); 	
	КонецЕсли;	
	
	ПараметрыJSON	= Новый ПараметрыЗаписиJSON(ВходящиеПараметры.ПереносСтрок,
			ВходящиеПараметры.СимволОтступа,
			ВходящиеПараметры.ИспользоватьДвойныеКавычки,
			ВходящиеПараметры.ЭкранированиеСимволов,
			ВходящиеПараметры.ЭкранироватьУгловыеСкобки,
			ВходящиеПараметры.ЭкранироватьРазделителиСтрок,
			ВходящиеПараметры.ЭкранироватьАмперсанд,
			ВходящиеПараметры.ЭкранироватьОдинарныеКавычки,
			ВходящиеПараметры.ЭкранироватьСлеш);
	
	
	Попытка
		ЗаписьJSON			= Новый ЗаписьJSON;
		ЗаписьJSON.ПроверятьСтруктуру 	= Истина;
		ЗаписьJSON.УстановитьСтроку(ПараметрыJSON);	
		ЗаписатьJSON(ЗаписьJSON, ВходныеДанные);
		Результат.Вставить("Результат",	ЗаписьJSON.Закрыть());
	Исключение
		Результат.Отработал 	= Ложь;
		Результат.ТекстОшибки 	= ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
	КонецПопытки;
	
	Возврат Результат;
	
КонецФункции

Пояснение по коду:

1 В обработчике события «ПриСозданииНаСервере» добавляем список сервисов и каналов.

Считываем Имя и Идентификатор текущего пользователя, для поля ИмяОтправителя.

Считываем Имя и Идентификаторы всех пользователей, для поля Пользователь.

Идентификатор будет служить для идентификации получателя и отправителя.

2 В создаваемых сообщениях устанавливаем дату устаревания 60 дней после текущей даты.

3 Тело сообщения — это структура в формате JSON, в которую сохраняем текст сообщения, имя автора и навигационную ссылку на объект (необязательно).

Открываем два окна под Руководителем и Администратором.

От Руководителя шлем сообщение Администратору, затем после того, как Администратор его прочитает, отправим сообщение руководителю:

Заключение:

Вот таким незамысловатым способом мы использовали новый механизм «Сервисы интеграции». Как вы видите, этот механизм может решать не только интеграционные задачи.

Я считаю, что механизм неплохой и перспективный, если вы его еще не трогали, присмотритесь к нему.

На этом статью завершаю.

Всем желаю профессионального роста и интересных задач!

Полезные ссылки:

Поинтегрируем: нужна ли Шина вам? – Статья, с которой начался цикл статей по интеграции.

Три инструмента для сервисов интеграции – Бесплатные инструменты по работе с сервисами интеграции.

PAPI-tools – Проект на GitHub содержащий исходники обработок, которые будут первоначально выкладываться в данном проекте, а в будущем перетекать в подсистему PAPI (релиз подсистемы запланирован на 19.05.2024)

Поинтегрируем: сервисы интеграции – новый стандарт или просто коннектор? – Статья описывает механизм «Сервисы интеграции» изнутри и снаружи

1С История данных Регистры сведений Интеграция Архитектура Сервисы интеграции Планы обмена Сообщения сервисов интеграции PAPI-tools PAPI GitHub

+80 –

См. также

Про файловые потоки: работа с любыми данными и в любом количестве

Механизмы платформы 1С Программист Стажер Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Эта небольшая статья - некоторого рода шпаргалка по файловым потокам: как и зачем с ними работать, какие преимущества это дает.

23.06.2024 7409 bayselonarrend 19

154

Поинтегрируем: сервисы интеграции – новый стандарт или просто коннектор?

Перенос данных 1C Администрирование СУБД Механизмы платформы 1С Системный администратор Программист Стажер Платформа 1С v8.3 Бесплатно (free)

В платформе 8.3.17 появился замечательный механизм «Сервисы интеграции». Многие считают, что это просто коннектор 1С:Шины. Так ли это?

11.03.2024 14271 dsdred 64

Как готовить и есть массивы

Механизмы платформы 1С Программист Стажер Платформа 1С v8.3 Бесплатно (free)

Все мы используем массивы в своем коде. Это один из первых объектов, который дают ученикам при прохождении обучения программированию. Но умеем ли мы ими пользоваться? В этой статье я хочу показать все методы массива, а также некоторые фишки в работе с массивами.

24.01.2024 17622 YA_418728146 26

Планы обмена VS История данных

Перенос данных 1C Механизмы платформы 1С Системный администратор Программист Стажер Платформа 1С v8.3 Бесплатно (free)

Вы все еще регистрируете изменения только на Планах обмена и Регистрах сведений?

11.12.2023 11208 dsdred 44

130

1С-ная магия

Механизмы платформы 1С Программист Бесплатно (free)

Язык программирования 1С содержит много нюансов и особенностей, которые могут приводить к неожиданным для разработчика результатам. Сталкиваясь с ними, программист начинает лучше понимать логику платформы, а значит, быстрее выявлять ошибки и видеть потенциальные узкие места своего кода там, где позже можно было бы ещё долго медитировать с отладчиком в поисках источника проблемы. Мы рассмотрим разные примеры поведения кода 1С. Разберём результаты выполнения и ответим на вопросы «Почему?», «Как же так?» и «Зачем нам это знать?».

06.10.2023 23747 SeiOkami 48

135

Дефрагментация и реиндексация после перехода на платформу 8.3.22

Механизмы платформы 1С Системный администратор Платформа 1С v8.3 Бесплатно (free)

Начиная с версии платформы 8.3.22 1С снимает стандартные блокировки БД на уровне страниц. Делаем рабочий скрипт, как раньше.

14.09.2023 18812 human_new 27

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Программист Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023 14723 YA_418728146 7

166

Внешние компоненты Native API на языке Rust - Просто!

Механизмы платформы 1С Программист Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Внешние компоненты для 1С можно разработывать очень просто, пользуясь всеми преимуществами языка Rust - от безопасности и кроссплатформенности до удобного менеджера библиотек.

20.08.2023 8371 sebekerga 55

104

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. user-z99999 71 13.03.24 09:28 Сейчас в теме

Почему так хорошо и доходчиво пишите, в чём секрет?

2. dsdred 3593 13.03.24 09:29 Сейчас в теме

(1) Секрета нет.
Трое детей и большой опыт работы с людьми ))

3. anosin 29 13.03.24 09:48 Сейчас в теме

на 8.3.19.x будет работать?

4. dsdred 3593 13.03.24 09:49 Сейчас в теме

(3) Да, должно работать начиная с 8.3.17

5. starik-2005 3087 13.03.24 10:54 Сейчас в теме

А правильно я понял, что это внутри одной базы оповещения? Вот смысл имеет, когда базы разные, а внутри одной базы можно и регистром/справочником/документом/... обойтись, ну или системой взаимодействия, хотя она вроде как тоже межбазовой может быть.
ЗЫ: Ну и хорошим лайфхаком межбазового взаимодействия триггер скульный является, который из таблицы источника в таблицу приемника перекинет данные о сообщении. О нем Вы, кстати, писали. А без шины это все - нарушение лицензионного соглашения, ну и работать будет до очередного изменения структуры таблиц.

6. dsdred 3593 13.03.24 11:57 Сейчас в теме

(5)

А правильно я понял, что это внутри одной базы оповещения?

Все верно. Просто решил показать, что механизм живой и без интеграции.

Вот смысл имеет, когда базы разные, а внутри одной базы можно и регистром/справочником/документом/... обойтись, ну или системой взаимодействия, хотя она вроде как тоже межбазовой может быть.

1 Система взаимодействия это еще одна инсталляция с БД, либо облака. Она имеет более богатый функционал и предназначена глобально для других вещей.

2 Обойтись Регистром, справочником, документом можно, но есть ряд нюансов.
Может выйти вариант когда под каждый вид оповещений начнут плодится все новые и новые сущности.

В сервисах интеграции, в сообщении есть свойство "Параметр", в который можно добавлять сколько угодно ключей для выборки. Например добавить ключ "ТипОповещение" и т.д.
Соответственно мы получаем очень гибкий механизм. Добавив один канал на него можем вешать разные оповещалки без доработок.

ЗЫ: Ну и хорошим лайфхаком межбазового взаимодействия триггер скульный является, который из таблицы источника в таблицу приемника перекинет данные о сообщении. О нем Вы, кстати, писали. А без шины это все - нарушение лицензионного соглашения, ну и работать будет до очередного изменения структуры таблиц.

Все верно.
Моя цель была как можно подробнее донести информацию по механизму, но когда писал статью во мне проснулся инженер который все время мне говорил: а давай еще вот это попробуем!
В итоге вышло как вышло ))

7. John_d 5891 13.03.24 12:32 Сейчас в теме

(0) Все хорошо, но на практике не применимо. Никто не будет слать сообщения другим пользователям средствами 1С платформы. Проще написать письмо в outlook и вставить в него скриншот.

9. dsdred 3593 13.03.24 12:40 Сейчас в теме

(7)+ я показал лишь один пример.
По сути Сервисы интеграции это ящик с сообщениями а куда и как их отправлять это уже второй вопрос.
Можно хоть в почту, хоть в телегу слать.

8. dsdred 3593 13.03.24 12:39 Сейчас в теме

(7) Вот вам пример из жизни:
В том году на моего коллегу упала задача.
Если в справочнике Номенклатура меняются определенные реквизиты необходимо сделать оповещение через колокольчик группу ответственных лиц.

Как бы вы решили эту задачу?

10. John_d 5891 13.03.24 12:43 Сейчас в теме

(8) Согласен, как оповещение о событии рабочий вариант.

11. starik-2005 3087 13.03.24 13:12 Сейчас в теме

(8)

Как бы вы решили эту задачу?

Неоднократно решал через механизм оповещений из еще старой БСП. Для этого там регистр был и общая форма, а обработчик ожидания использовался системный. Сейчас, кстати, он тоже есть. И в этот колокольчик, как я понял, Вы с помощью него и добавляете.

12. dsdred 3593 13.03.24 13:14 Сейчас в теме

(11) Дак и я так раньше решал. Еще через систему взаимодействия решал.
А теперь появился способ без БСП и без Системы взаимодействия.

ПоказатьОповещениеПользователя(ТекСообщение.Сообщение
,ТекСообщение.НавигационнаяСсылка
,?(ТекСообщение.Свойство("Отправитель"),ТекСообщение.Отправитель,""),
,СтатусОповещенияПользователя.Важное
,ТекСообщение.Идентификатор);

В колокольчик попадает из-за СтатусОповещенияПользователя.Важное

13. starik-2005 3087 13.03.24 13:15 Сейчас в теме

(12)

без БСП и без Системы взаимодействия

Через регистр было бы меньше кода.

14. dsdred 3593 13.03.24 13:17 Сейчас в теме

(13)Это потому, что в БСП уже готовый код универсальный есть, а так по коду не больше.
Даже меньше.

15. d4rkmesa 21.03.24 11:27 Сейчас в теме

Спасибо, курьезная фича. На ИТС "обратный случай" расписали - использование шины без сервисов интеграции:
https://its.1c.ru/db/metod8dev/content/6012/hdoc

16. dsdred 3593 21.03.24 11:43 Сейчас в теме

(15)В пункте "2.2. Доработки в информационной базе "Бухгалтерии предприятия"" присутствуют Сервисы интеграции.
А вообще я видел интересный пример когда из JS отправляли в 1с Канал Шины.

Вообще в шине можно просто файлы перекладывать, можно из кафки в кролик пересылать и т.д. Собственно там 1с конфигурация необязательна, так как 1с Элемент это таже конфигурация 1с только написана заново ))