Скорость закачки с EXCEL при работе с большими файлами

// Функция читает лист их xls файла и загружает содержимое в таблицу значений
Функция ПолучитьТаблЗначИзЛистаXLS(ТаблЗнач = Неопределено, прИмяКолонки = "Колонка", ИмяФайла, прНомерЛистаExcel = Неопределено, ЛистЭксель = Неопределено, НомерПервойСтроки = 1, НомерПервойКолонки = 1, ВсегоСтрок = 0, ВсегоКолонок = 0) Экспорт

	Если ТаблЗнач = Неопределено Тогда
		ТаблЗнач =  Новый ТаблицаЗначений;
	КонецЕсли;

	
	Если ЛистЭксель = Неопределено Тогда
		Попытка
			Excel = Новый COMОбъект("Excel.Application");
		Исключение
			Сообщить("Не удалось подключиться к MS Excel");
			Возврат ТаблЗнач;
		КонецПопытки;
		Попытка
			Состояние("Обработка файла Microsoft Excel...");
			Excel.DisplayAlerts = 0;
			Excel.WorkBooks.Open(ИмяФайла);
		Исключение
			Сообщить("Не удалось прочитать файл (" + ОписаниеОшибки() + ")");
			Возврат ТаблЗнач;
		КонецПопытки;
		лпСписокЛистов = Новый СписокЗначений;
		Попытка
			Если прНомерЛистаExcel = Неопределено Тогда
				лпКоличествоЛистов = Excel.Sheets.Count;
				Если лпКоличествоЛистов = 0 Тогда
					Сообщить("Пусто");
					Возврат ТаблЗнач;
				КонецЕсли;
				Если лпКоличествоЛистов > 1 Тогда
					лпСписокВыбор = Новый СписокЗначений;
					лпСписокВыбор.Добавить("all", "Все листы");
					Для лпНомерЛиста = 1 По лпКоличествоЛистов Цикл
						лпЛист = Excel.Sheets(лпНомерЛиста);	
						лпСписокВыбор.Добавить(лпНомерЛиста, СокрЛП(лпЛист.Name));
					КонецЦикла;
					лпВыбор = лпСписокВыбор.ВыбратьЭлемент("Выбор листа");
					Если лпВыбор = Неопределено Тогда
						Сообщить("Не выбран лист!");
						Возврат ТаблЗнач;
					КонецЕсли;
					лпВыбран = лпВыбор.Значение;
					Если лпВыбран = "all" Тогда
						лпСписокЛистов = лпСписокВыбор.Скопировать();
					Иначе	
						лпСписокЛистов.Добавить(лпВыбран);
					КонецЕсли;
					//НомерЛистаExcel = ;	
				Иначе	
					//НомерЛистаExcel = лпКоличествоЛистов;
					лпСписокЛистов.Добавить(лпКоличествоЛистов);
				КонецЕсли;
			Иначе
				//НомерЛистаExcel = прНомерЛистаExcel;
				лпСписокЛистов.Добавить(прНомерЛистаExcel);
			КонецЕсли;
			
		Исключение
			Сообщить("Не удалось прочитать листы (" + ОписаниеОшибки() + ")");
			Возврат ТаблЗнач;
		КонецПопытки;
	КонецЕсли;
	
	лпСписокВозв = Новый СписокЗначений;
	
	Для каждого лпЭлемент Из лпСписокЛистов Цикл
		НомерЛистаExcel = лпЭлемент.Значение;
		Если НомерЛистаExcel = "all" Тогда
        	Продолжить;
		КонецЕсли;
		ТаблЗнач =  Новый ТаблицаЗначений;
		Попытка
			Состояние("Установка текущего листа...");
			ЛистЭксель = Excel.Sheets(НомерЛистаExcel);
		Исключение
			Сообщить("Не удалось установить текущий лист (" + ОписаниеОшибки() + ")");
			Возврат ТаблЗнач;
		КонецПопытки;
		
		//Range	= ЛистЭксель.UsedRange;
		Если ВсегоСтрок = 0 Тогда
			ВсегоСтрок = ЛистЭксель.Cells.SpecialCells(11).Row;
			//ВсегоСтрок = Range.Rows.Count;
		КонецЕсли;
		
		Если ВсегоКолонок = 0 Тогда
			ВсегоКолонок = ЛистЭксель.Cells.SpecialCells(11).Column;
			//ВсегоКолонок = Range.Columns.Count;  ЛистЭксель.UsedRange.Columns.Count
		КонецЕсли;
		
		Для Счетчик = 1 По ВсегоКолонок Цикл
			ТаблЗнач.Колонки.Добавить(прИмяКолонки+Счетчик, Новый ОписаниеТипов("Строка"));
		КонецЦикла;
		
		Для Счетчик = НомерПервойСтроки По ВсегоСтрок Цикл
			НоваяСтрока = ТаблЗнач.Добавить();
			Состояние("Запись пустых строк:" + Счетчик);
		КонецЦикла;
		
		Область = ЛистЭксель.Range(ЛистЭксель.Cells(НомерПервойСтроки,НомерПервойКолонки), ЛистЭксель.Cells(ВсегоСтрок,ВсегоКолонок));
		Данные = Область.Value.Выгрузить();
		
		Для Счетчик = 0 По ВсегоКолонок - 1 Цикл
			ТаблЗнач.ЗагрузитьКолонку(Данные[Счетчик], Счетчик);
			Состояние("Загружена колонка :" + Счетчик);
		КонецЦикла;	
		
		ЛистЭксель = Неопределено;
	
		лпСписокВозв.Добавить(ТаблЗнач, НомерЛистаExcel);	
		//Сообщить("Лист: " + СокрЛП(лпЭлемент.Представление) + " строк: " + СокрЛП(ТаблЗнач.Количество()));
		ВсегоСтрок = 0;
		ВсегоКолонок = 0;
	КонецЦикла;
	
    Excel.WorkBooks.Close();
    Excel = 0;

	Возврат лпСписокВозв;

КонецФункции