Сверка таблиц при разработке через тестирование

Публикация № 553837

Разработка - Инструментарий разработчика

TDD тестирование разработка через тестирование xUnitFor1C

Данная статья про инструмент, который я использую уже продолжительное время, и который, по моему мнению, заслуживает внимания. Также опишу несколько примеров его применения.

Постановка задачи

Пусть есть некоторый алгоритм, результат которого можно представить в виде таблицы значений. Также имеем тест, который сравнивает результат алгоритма с таблицей эталоном. Если результат совпадает с ожидаемым, то никаких дополнительных действий не требуется. Но в случае отличия, необходим способ, позволяющий быстро найти расхождение двух таблиц. Можно конечно поставить точку останова в отладчике, но тогда обе таблицы придется сравнивать поочередно. Но это плохой способ.  Особенно это понимаешь, когда “покраснел” не один, а несколько тестов. Каждый раз переключаться в отладчик, и искать отличия, очень трудоемко.

Решение

Для решения понадобится алгоритм, который не просто проверяет равенство двух таблиц, но и выдает нам их различия. Суть этого алгоритма описана мной в одной из предыдущих публикаций. В двух словах: на вход сверочной процедуры подаются две таблицы, после сверки получается одна таблица с дополнительной колонкой, с помощью которой можно понять, какие строки совпадают в обеих таблицах, какие присутствуют только в первой, а какие только во второй. 
В случае, когда различий не найдено, никаких действий не выполняем. А если таблицы отличаются, то отображаем результат сверки на дополнительной форме. То есть прогоняем тесты как обычно. Если какие-то “покраснели”, то открываем дополнительную обработку, прогоняем нужный тест, и видим в открытой обработке различия, не переключаясь в конфигуратор.

На картинке представлен тестовый пример. На нем видно, что одна строка совпадает, а другая строка различается по колонке Продукты. Также добавлена служебная колонка __СВЕРКА__, по которой мы определяем наличие строки в эталоне и в результате. Код теста, приведенного на рисунке выглядит примерно так:

Процедура ТестДолжен_ПродемонстрироватьОтображениеРазличийДвухТаблиц() Экспорт
	
	ИмяМакета = "Пример1"; // по которому будут сгенерированы тестовые данные
	ТестовыеДанные = ТестовыеДанные(ИмяМакета); 

	План = ТестовыеДанные.ОжидаемыйРезультат;

	Факт = ТестовыеДанные
				.ПараметрыТеста
				.ПодопытныйДокумент
				.ПолучитьОбъект()
				.ПолучитьТаблицуИзОченьСложногоЗапроса(“какие-то параметры”);
	
	Помощники().ПроверитьРавенствоТаблиц(План, Факт, ИмяМакета);
	
КонецПроцедуры

Хочу обратить внимание, что сам тест не содержит никаких дополнительных действий. Результат сверки выдается из процедуры ПроверитьРавенствоТаблиц()

Пример 1. Проверка функции по заполнению табличной части подопытного объекта

Задача: в форме документа Закупка продуктов реализовать кнопку Заполнить, при нажатии на которую заполнять табличную часть Продукты остатками из регистра накопления Текущая потребность в товарах на дату документа. При этом необходимо брать только номенклатуру, которая является продуктом (МожноЕсть = Истина). Цену необходимо подтянуть из регистра сведений Цены номенклатуры на дату закупки (дату документа).

Тестовые данные я обычно сначала описываю на листке бумаги. В данном случае они будут выглядеть например, так

Добавили номенклатуру Гвоздь в регистр Текущая потребность, которая не должна попасть в результирующий запрос, т.к. не является продуктом. Номенклатуры Мясо нет в регистре цен, она должна попасть в результат с пустой ценой.

Создадим внешнюю обработку, в которой будем описывать тестовые сценарии. Назовем ее например так: Тесты_Документ_ЗакупкаПродуктов, и будем в нее помещать все тестовые случаи, связанные с нашим документом. Создадим в ней табличный макет ЗаполнениеТабличнойЧастиПродуктыИзПотребностей и перенесем в него данные из таблиц, описанных ранее.

Я стараюсь все параметры прописывать в макете, поэтому добавил структуру ПараметрыТеста с ключом ДатаЗакупки

Остатки в регистр ТекущаяПотребностьВТоварах можно добавить любым документом, я обычно использую в таком случае КорректировкаРегистров (или его аналог, в зависимости от конфигурации). 

Далее описываем тестовый случай. Именно в этот момент придумываем, как назовем функцию, которую будем вызывать, но которая пока еще не объявлена.

Процедура ТестДолжен_ЗаполнитьТабличнуюЧастьПродуктыПоПотребностям() Экспорт
	
	ИмяМакета = "ЗаполнениеТабличнойЧастиПродукты";
	ТестовыеДанные = ТестовыеДанные(ИмяМакета); 
	
	План = ТестовыеДанные.ОжидаемыйРезультат;
	
	Факт = Документы
			.ЗакупкаПродуктов
			.ПолучитьТабличнуюЧастьПродуктыПоПотребностямНаДатуЗакупки
				(
				ТестовыеДанные.ПараметрыТеста.ДатаЗакупки
				);
	
	Помощники().ПроверитьРавенствоТаблиц(План, Факт, ИмяМакета);
	
КонецПроцедуры

В модуле менеджера документа создаем эту функцию

Функция ПолучитьТабличнуюЧастьПродуктыПоПотребностямНаДатуЗакупки(ДатаЗакупки) Экспорт
	
	Возврат Новый ТаблицаЗначений;

КонецФункции

Запускаем тест, и убеждаемся, что он падает. При этом наблюдаем такую картину

Далее заполняем нашу функцию бизнес-логикой, добиваясь, чтобы тест стал “зеленым“.

После этого добавляем кнопку на форму, организуем вызов описанной нами функции из обработчика нажатия на эту кнопку, проверяем один раз интерактивно, что не падает критическая ошибка. 

В случае появления новых бизнес-требований, дополняем тестовый пример, или добавляем еще один тестовый случай.

Пример 2. Проверка нескольких связанных таблиц

Задача: реализовать заполнение документа Заявка на перевозку товаров при вводе на основании документа Закупка продуктов. Реквизит Склад заполнять из параметров сеанса текущего пользователя. Маршрут в шапке вычислять по сочетанию складов документа основания и заполняемого документа. Табличную часть Номенклатура заполнять из табличной части Продукты документа основания. Дополнительно заполнять табличную часть Точки маршрута из выбранного маршрута в шапке.

Создадим еще одну внешнюю обработку Тесты_Документ_ЗаявкаНаПеревозкуТоваров. (Мне удобнее группировать тесты по видам документов в большинстве случаев) 

Добавим в ней табличный макет ВводНаОсновании_ЗакупкаПродуктов. Опишем ожидаемый результат в виде структуры таблиц. Ключи структуры: Шапка, тчНоменклатура, тчТочкиМаршрута

Опишем тест

Процедура ТестДолжен_ЗаполнитьЗаданиеНаПеревозкуНаОснованииЗакупкиПродуктов() Экспорт
	
	
	ИмяМакета = "ВводНаОснованииЗакупкиПродуктов";
	ТестовыеДанные = ТестовыеДанные(ИмяМакета); 
	
	План = ТестовыеДанные.ОжидаемыйРезультат;
	
	ПодопытныйДокумент = Документы.ЗаданиеНаПеревозкуТоваров.СоздатьДокумент();
	ПодопытныйДокумент.Заполнить(
							ТестовыеДанные.ПараметрыТеста.ДокументОснование
							);
							
	Факт = Новый Структура;
	
	Шапка = План.Шапка.Скопировать();
	Шапка.Очистить();
	ЗаполнитьЗначенияСвойств(Шапка.Добавить(), ПодопытныйДокумент);
	Факт.Вставить("Шапка", Шапка);
	
	Факт.Вставить("тчНоменклатура", ПодопытныйДокумент.Номенклатура.Выгрузить());
	Факт.Вставить("тчТочкиМаршрута", ПодопытныйДокумент.ТочкиМаршрута.Выгрузить());
	
	Помощники().ПроверитьРавенствоНаборовТаблиц(План, Факт);
	
КонецПроцедуры

Запустим тест на выполнение и убедимся, что он падает

Далее опишем требуемые требуемые данные в макете, а в модуле документа реализуем процедуру ОбработкаЗаполнения().

Пример 3. Тестирование заполнения движений типовых документов

Задача: реализовать проведение документа Сборка комплектов. По табличной части Составляющие выполнять расход по регистру Остатки товаров. По табличной части Комплекты выполнять приход на склад собранных комплектов. Если в шапке документа заполнен реквизит Покупатель, то выполнять сразу расход комплектов со склада.

Имеем два тестовых случая: Сборка на склад и Сборка для клиента

Создадим внешнюю обработку Тесты_Документ_СборкаКомплектов. Создадим макет Движения_ОстаткиТоваров

Опишем тестовый случай

Процедура ТестДолжен_ПроверитьДвижения_ОстаткиТоваров() Экспорт
	
	ИмяМакета = "Движения_ОстаткиТоваров";
	ТестовыеДанные = ТестовыеДанные(ИмяМакета); 
	
	План = ТестовыеДанные.ОжидаемыйРезультат;
	
	
	Факт = Помощники()
		.ПолучитьТаблицуДвиженийДляМассиваТиповыхДокументов(
				ТестовыеДанные
					.ПараметрыТеста
					.ВыгрузитьКолонку("Ссылка"),
				"ОстаткиТоваров"
				);
				
	Помощники().ПроверитьРавенствоТаблиц(План, Факт, "Движения ОстаткиТоваров");
	
КонецПроцедуры


Далее запустим тест и убедимся, что он падает именно на различии таблиц. Реализуем проведение. 

  

Резюме к примерам

В примере 1 более подробно описаны все шаги от постановки задачи до написания тестового сценария

В примере 2 рассмотрен случай, когда результатом теста является не одна, а несколько таблиц

В примере 3 приведена процедура, часто используемая на практике: тестирование проведения типового документа по конкретному регистру. Также рассмотрен пример объединения двух похожих тестовых случаев в один сценарий

 

Основные служебные процедуры, упомянутые в тексте

Сами сверочные процедуры выглядят так:

Процедура ПроверитьРавенствоТаблиц(Таблица1, Таблица2, Сообщение = "", ПроверяемыеКолонки = Неопределено, ИсключаемыеКолонки = Неопределено) Экспорт
	
	СводнаяТаблица = Таблица1.Скопировать(, ПроверяемыеКолонки);
	Если ЗначениеЗаполнено(ИсключаемыеКолонки) Тогда
		МассивИмен = РазложитьСтрокуВМассивПодстрок(ИсключаемыеКолонки, ",");
		Для Каждого ИмяКолонки Из МассивИмен Цикл
			Если НЕ СводнаяТаблица.Колонки.Найти(ИмяКолонки) = Неопределено Тогда
				СводнаяТаблица.Колонки.Удалить(ИмяКолонки);
			КонецЕсли;
		КонецЦикла;
	КонецЕсли;
	
	ИменаКолонокГруппировки = "";
	Для каждого Колонка из СводнаяТаблица.Колонки Цикл
		ИменаКолонокГруппировки = ИменаКолонокГруппировки + нрег(Колонка.Имя) + ",";
	КонецЦикла;
	ИменаКолонокГруппировки = Лев(ИменаКолонокГруппировки, СтрДлина(ИменаКолонокГруппировки)-1);
	
	ИмяКолонкиСуммирования = "___СВЕРКА___";
	СводнаяТаблица.Колонки.Вставить(0,ИмяКолонкиСуммирования, Новый ОписаниеТипов("Число"));
	СводнаяТаблица.ЗаполнитьЗначения(-1, ИмяКолонкиСуммирования);
	
	Для каждого Строка из Таблица2 Цикл
		НоваяСтрока = СводнаяТаблица.Добавить();
		ЗаполнитьЗначенияСвойств(НоваяСтрока, Строка);
		НоваяСтрока[ИмяКолонкиСуммирования] = 1;
	КонецЦикла;
	
	СводнаяТаблица.Свернуть(ИменаКолонокГруппировки, ИмяКолонкиСуммирования);
	Отбор = Новый Структура(ИмяКолонкиСуммирования, 0);
	Если СводнаяТаблица.НайтиСтроки(Отбор).Количество() = СводнаяТаблица.Количество() Тогда
		Возврат;
	КонецЕсли;
	
	СводнаяТаблицаХранилище = Новый ХранилищеЗначения(СводнаяТаблица);
	#Если Клиент Тогда
	Оповестить("РазличияВТаблицах", СводнаяТаблицаХранилище, Сообщение);
	#КонецЕсли
	
	ВызватьИсключение "Таблицы различны: " + Сообщение;
КонецПроцедуры

Процедура ПроверитьРавенствоНаборовТаблиц(СтруктураПлан, СтруктураФакт) Экспорт
	
	ТекстОшибок = "";
	Для Каждого КлючИЗначение Из СтруктураПлан Цикл
		
		Ключ = КлючИЗначение.Ключ;
		
		План = СтруктураПлан[Ключ];
		Факт = СтруктураФакт[Ключ];
		
		Попытка
			ПроверитьРавенствоТаблиц(План, Факт, Ключ);
		Исключение
			ТекстОшибок = "Ошибка при сверке таблицы "+Ключ+": " + ОписаниеОшибки() + Символы.ПС;
		КонецПопытки;
		
	КонецЦикла;
	
	Если НЕ ТекстОшибок = "" Тогда
		ВызватьИсключение ТекстОшибок;
	КонецЕсли;
	
КонецПроцедуры

Обращаю внимание, что я использую метод Оповестить(), т.к. разрабатываю на файловой базе в толстом клиенте. В случае с серверной базой можно модифицировать общую схему, и помещать результат сверки во временное хранилище или хранилище общих настроек, а в обработке по выводу различий - считывать ее и отображать. Однако такую схему я не реализовывал, т.к. пока не было такой необходимости.

Приведу тексты еще нескольких служебных процедур, упомянутых в описанных тестах


Функция Помощники()
	Возврат Плагин("ПомощникиТестирования");
КонецФункции

Функция ТестовыеДанные(ИмяМакета)
	
	Макет = ПолучитьМакет(ИмяМакета);
	Возврат Плагин("ГенераторДанных").СоздатьДанныеПоТабличномуДокументу(Макет);
	
КонецФункции

Функция Плагин(ИмяПлагина)
	
	КаталогПлагинов = "X:\";
	Возврат ВнешниеОбработки.Создать(КаталогПлагинов + ИмяПлагина + ".epf", Ложь);

КонецФункции


Материалы

В приведенных выше примерах упоминались следующие интернет ресурсы

  1. Фреймворк xUnitFor1C. Если вы раньше им не пользовались, установка описана в инструкции на гитхабе. Менее правильный, но более простой способ - скачать zip архив, распаковать, и запустить из 1С обработку xddTestRunner.epf. Обращу особое внимание, что скачивать нужно ветку master.
  2. Универсальный способ сравнения таблиц
  3. Методика постановки задачи для быстрого перекладывания ее на тесты
  4. Генератор данных
  5. Проведение в третьем примере выполняется по шаблону, приведенному в статье Несколько шаблонов для доработки типовых конфигураций


Файлы

Прикладываю демонстрационную базу, в которой реализованы описанные примеры с “зелеными” тестами. Все тесты, а также инструменты тестирования - встроены в конфигурацию для удобства. На практике они все хранятся в виде внешних обработок. В конфигурацию не встроен браузер тестирования xUnitFor1C его нужно скачивать отдельно. Демонстрационная база создана на платформе 8.3 в режиме совместимости с 8.2.13


Обработка Отображение различий при сверке таблиц встроена в демонстрационную конфигурацию, но я дополнительно выкладываю ее отдельным файлом.

Скачать файлы

Наименование Файл Версия Размер
Демонстрационная база с примерами

.dt 122,71Kb
09.10.16
6
.dt 122,71Kb 6 Скачать
Обработка Отображение различий при сверке таблиц

.epf 10,67Kb
09.10.16
5
.epf 10,67Kb 5 Скачать

Специальные предложения

Оставьте свое сообщение

См. также

Установка предопределенных элементов: просмотр, исправление и поиск ошибок (задвоенных и отсутствующих) Промо

Инструментарий разработчика Универсальные обработки v8 1cv8.cf Абонемент ($m)

Простая обработка для просмотра и установки значений предопределенных элементов. Позволяет заменить значение предопределенного элемента с одного элемента справочника на другой, удалить предопределенный элемент (снять пометку предопределенности), установить пометку переопределенного элемента. Проверяет предопределенные данные на наличие задвоений и отсутствующих. Работает со справочниками, планами счетов, планами видов характеристик, планами видов расчетов.

2 стартмани

06.10.2014    149265    1986    ekaruk    165    

Вам нравятся запросы в 1С?

Практика программирования Разработка v8 v8::Запросы 1cv8.cf Абонемент ($m)

Речь не только о том, что простейший запрос с "легальным" оформлением растянется на пол-экрана, речь еще обо всем, что нужно написать "в нагрузку" к тексту запроса. Все эти "Новый Запрос", "УстановитьПараметр" и последующие пляски с обработкой результата... Пора с этим заканчивать!

1 стартмани

03.07.2019    19682    4    m-rv    86    

Модель объекта

Инструментарий разработчика v8 Абонемент ($m)

Подсистема позволяет описать модель данных объекта, где описана зависимость между реквизитами, и затем использовать эту модель в разных сценариях работы с объектом. Версия платформы: 8.3.6 и выше. С небольшими доработками будет работать на 8.2.

1 стартмани

30.06.2019    12188    0    vadim1980    5    

Конструктор мобильного клиента Simple WMS Client: способ создать полноценный ТСД без мобильной разработки. Теперь новая версия - Simple UI (обновлено 14.11.2019)

Инструментарий разработчика Сканер штрих-кода Терминал сбора данных Мобильная разработка Оптовая торговля Производство готовой продукции (работ, услуг) Розничная торговля Учет ОС и НМА Учет ТМЦ Оптовая торговля Производство готовой продукции (работ, услуг) Розничная торговля Учет ОС и НМА Учет ТМЦ v8 v8::Mobile БУ УУ Абонемент ($m)

Simple WMS Client – это визуальный конструктор мобильного клиента для терминала сбора данных(ТСД) или обычного телефона на Android. Приложение работает в онлайн режиме через интернет или WI-FI, постоянно общаясь с базой посредством http-запросов (вариант для 1С-клиента общается с 1С напрямую как обычный клиент). Можно создавать любые конфигурации мобильного клиента с помощью конструктора и обработчиков на языке 1С (НЕ мобильная платформа). Вся логика приложения и интеграции содержится в обработчиках на стороне 1С. Это очень простой способ создать и развернуть клиентскую часть для WMS системы или для любой другой конфигурации 1С (УТ, УПП, ERP, самописной) с минимумом программирования. Например, можно добавить в учетную систему адресное хранение, учет оборудования и любые другие задачи. Приложение умеет работать не только со штрих-кодами, но и с распознаванием голоса от Google. Это бесплатная и открытая система, не требующая обучения, с возможностью быстро получить результат.

5 стартмани

09.01.2019    43563    247    informa1555    232    

Навигатор по конфигурации базы 1С 8.3 Промо

Инструментарий разработчика Универсальные обработки v8 v8::УФ 1cv8.cf Россия Абонемент ($m)

Универсальная внешняя обработка для просмотра метаданных конфигураций баз 1С 8.3. Отображает свойства и реквизиты объектов конфигурации, их количество, основные права доступа и т.д. Отображаемые характеристики объектов: свойства, реквизиты, стандартные рекизиты, реквизиты табличных частей, предопределенные данные, регистраторы для регистров, движения для документов, команды, чужие команды, подписки на события, подсистемы. Отображает структуру хранения объектов базы данных, для регистров доступен сервис "Управление итогами". Платформа 8.3, управляемые формы. Версия 1.1.0.69 от 09.09.2020

3 стартмани

28.10.2018    33091    293    ROL32    69    

Отправка электронной почты с помощью локального почтового клиента из 1С, развернутой под удаленным рабочим столом

Печатные формы документов Универсальные функции Email v8 КА1 БП2.0 УТ10 УПП1 Абонемент ($m)

Решение для интерактивной (нажал-отредактировал) отправки электронных писем и печатных форм через почтовый клиент (Thunderbird, Outlook) находящийся на локальном компьютере, из конфигурации 1С, развернутой под удаленным рабочим столом (RDP, remote-app). Подходит также для локального развертывания 1С. Представлен пример быстрой интеграции с конфигурациями "Управление торговлей 10.3", "Управление производственным предприятием 1.3", "Комплексная автоматизация 1.1", "Бухгалтерия предприятия 2.0".

1 стартмани

21.09.2018    23723    16    stvorl    0    

Работа с публикациями "Инфостарт"

Практика программирования О сообществе WEB v8 УУ Абонемент ($m)

Работа с рублевыми публикациями на сайте "Инфостарт": ведение клиентов, заказов, обновление файлов публикации, рассылка обновлений.

1 стартмани

13.09.2018    21072    13    RocKeR_13    16    

Позиционирование в помещении с помощью нейросети по сигналу Wi-Fi. Интерактивная карта склада в 1С с показом позиции

Инструментарий разработчика Практика программирования v8 Абонемент ($m)

Данная публикация содержит в себе редактор и интерактивную карту склада или иного помещения, на которой в реальном времени отображается позиция устройства, координаты которого вычисляются по уровням сигнала нескольких роутеров Wi-Fi. В статье и приложенным к ней разработкам предлагаются инструменты и методика для реализации вычисления точной геопозиции внутри помещений с помощью нейронной сети. Конфигурация написана на релизе 1С:Предприятие 8.3.12.1412, клиентское приложение имеет минимальный уровень совместимости SDK -16.

5 стартмани

09.08.2018    27311    26    informa1555    26    

[Расширение] Контроль отрицательных остатков по регистру бухгалтерии при проведении Промо

Универсальные функции Инструментарий разработчика Учет ТМЦ Учет ТМЦ v8 1cv8.cf Россия БУ Абонемент ($m)

Расширение позволяет без изменений конфигурации проверять остатки по регистру бухгалтерии при проведении каждого документа и запрещает проведение при появлении отрицательных остатков после проведения.

1 стартмани

17.08.2015    46604    156    ekaruk    32    

Работа с данными выбора

Практика программирования Работа с интерфейсом v8 Россия Абонемент ($m)

В управляемом интерфейсе заложена мощная возможность описывать связи реквизитов формы через параметры. Установка параметров связей позволяет ограничить выбор данных так, чтобы целостность данных была обеспечена на этапе ввода. Однако без дополнительного программирования задать можно только самые простые связи. Такие условия связи, как зависимость от реквизита через точку или зависимость через дополнительное отношение, заданное в регистре сведений - уже задать без программирования не получится.

1 стартмани

17.07.2018    45143    17    kalyaka    16    

ВСТАВИТЬ В Справочник.Номенклатура (Код, Наименование) ЗНАЧЕНИЯ ("001", "Новый товар")

Практика программирования v8 v8::Запросы 1cv8.cf Абонемент ($m)

Вас не обманывают ваши глаза, это запрос на изменение данных! И это работает без прямого доступа к БД, регистрации и смс.

1 стартмани

01.06.2018    29777    86    m-rv    57    

Регистры правил [Расширение]

Инструментарий разработчика Информационная безопасность v8 v8::Права УТ11 Абонемент ($m)

Регистры правил - права доступа, запрет редактирования, автоподстановка реквизитов и т.д.

10 стартмани

15.03.2018    17471    9    33lab    1    

Faster - многофункциональный ускоритель работы программиста 1С и других языков программирования Промо

Инструментарий разработчика v8 1cv8.cf Россия Абонемент ($m)

Программа Faster 9.4 позволяет ускорить процесс работы программиста (работает в любом текстовом редакторе). Подсказка при вводе текста на основе ранее введенного текста и настроенных шаблонов. Программа Faster позволяет делится кодом с другими программистами в два клика или передать ссылку через QR Код. Исправление введенных фраз двойным Shift (с помощью speller.yandex). Переводчик текста. Переворачивает текст случайно набранный на другой раскладке. Полезная утилита для тех, кто печатает много однотипного текста, кодирует в среде Windows на разных языках программирования. Через некоторое время работы с программой у вас соберется своя база часто используемых словосочетаний и кусков кода. Настройка любых шорткатов под себя с помощью скриптов. Никаких установок и лицензий, все бесплатно.

1 стартмани

24.05.2012    77416    212    moolex    147    

Заполняем по шаблону (по умолчанию)

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

Простой в подключении, универсальный и достаточно удобный механизм заполнения реквизитов произвольных документов/справочников значениями по умолчанию. Реализован в расширении, но может быть и непосредственно включен практически в любую конфигурацию на управляемых формах простым копированием одной формы и двух команд. Весь код в статье.

1 стартмани

08.02.2018    27513    19    mvxyz    17    

Печатная форма, сделанная как расширение конфигурации для БП 3.0. Новые возможности БСП

Практика программирования Универсальные печатные формы v8 БП3.0 Абонемент ($m)

Печатные формы на внешних обработках скоро канут в лету. На смену им приходят ПФ, реализованные в виде расширений конфигурации. Не нашел на сайте примеров таких расширений. Привожу пример подобного расширения для БП 3.0.

1 стартмани

06.12.2017    26388    50    kwazi    6    

Программное формирование форматированной строки в стиле html+inline CSS

Работа с интерфейсом Инструментарий разработчика v8 1cv8.cf Абонемент ($m)

Если вам приходилось работать с форматированными строками программно, то вы знаете, какая это боль. Данное решение облегчает программное формирование таких строк.

1 стартмани

18.11.2017    30971    33    bonv    10    

Консоль запросов + ТЗ как параметры Промо

Консоль запросов v8 1cv8.cf Украина Абонемент ($m)

Стандартная консоль запросов, с добавленной возможностью использования описания/заполнения/использования таблиц значений как параметров. Совместима с настройками базовой консоли. Упрощает отладку запросов, использующих временные таблицы.

2 стартмани

12.11.2010    34805    61    Kashemir    24    

Расширения конфигураций 1С: учимся перехватывать методы

Практика программирования v8 v8::УФ 1cv8.cf Абонемент ($m)

В этой статье я на примерах разберу некоторые механизмы расширений конфигураций 1С. А именно «перехваты» методов модуля объекта и «перехваты» событий формы и элементов формы. Данная статья написана с учебными целями, чтобы показать, как при помощи расширений конфигурации можно делать такие доработки, ради которых раньше приходилось снимать конфигурацию с поддержки.

1 стартмани

30.05.2017    125750    13    signum2009    48    

Набор подсистем "Умные таблицы"

Инструментарий разработчика v8 Беларусь Россия Казахстан Абонемент ($m)

Данный набор подсистем – прикладная библиотека, призванная помочь программисту 1С быстрее решать ряд типовых задач бизнес-логики, таких как: ведение статусов объектов, отправка почтовых сообщений в определенное время, ведение произвольных таблиц с возможностью редактирования, сохранения и группировки, ориентированные на расчет бюджетных таблиц (план продаж, ретробонусы B2C, проценты по договорам B2B и договорные условия по КАМ), расчет коммерческой политики для бюджетных таблиц, исполнение произвольных алгоритмов с хранением кода в информационной базе, определение рабочих баз, хранение файлов во внешних СУБД (Postgre SQL, MS SQL и MongoDB) и выполнение произвольного кода после изменений ссылочного объекта вне транзакции изменения.

1 стартмани

22.05.2017    32625    96    Silenser    34    

Конструктор-тестер http запросов в 1С

WEB Инструментарий разработчика v8 1cv8.cf Россия Абонемент ($m)

Данная обработка позволяет в несколько кликов конструировать http запросы на языке 1С и просматривать результаты их выполнения.

3 стартмани

19.08.2016    41735    295    hlopik    17    

[x1c.ru] 1CDBin: Работа с файлами *.1CD на низком уровне средствами языка 1С с возможностью чтения таблиц (поддерживается формат 8.3.8.0) Промо

Тестирование и исправление Инструментарий разработчика v8 1cv8.cf Абонемент ($m)

Обработка позволяет просматривать файловые базы 1CD на низком уровне средствами встроенного языка. Реализована часть функциональности Tool_1CD, но на языке 1С Предприятия. Показываются таблицы, параметры таблиц, поля таблиц, записи таблиц, значения полей BLOB, есть 16-ричный просмотр страниц базы и консоль кода. Можно использовать для изучения структуры файлов 1CD, просмотра баз 1CD для выявления повреждений, создания своих обработок для выгрузки данных без открытия исследуемой базы в 1С:Предприятии.

1 стартмани

07.10.2014    52163    209    GusevNA    75    

1С: Предприятие + корпоративный чат, как наладить оперативные уведомления за 10 минут

Практика программирования v8 Абонемент ($m)

Как сделать автоматические уведомления о разных событиях из 1С в корпоративный чат MyChat для сотрудников компании

1 стартмани

14.08.2016    47393    36    Demanoidos    60    

Подсистема обмена данными с порталом ИМНС по электронным счетам-фактурам (автоматический обмен)

Внешние источники данных WEB Инструментарий разработчика v8 1cv8.cf Беларусь БУ НДС Абонемент ($m)

Подсистема включает документы и обработки для автоматического обмена данными с порталом ИМНС через web-сервис. Присутствует возможность заполнения данными типовых операций за период, учёта входящих документов, учёта произвольных исходящих документов. Приложены обработки для запуска задания планировщика на автоматический обмен данными.

1 стартмани

28.07.2016    33192    19    c1nil    4    

Навигатор по структуре и данным баз 1С 8

Инструментарий разработчика v8 v8::УФ 1cv8.cf Абонемент ($m)

Просмотр структуры и данных информационных баз 1С:Предприятие 8.2, 8.3. Состав, типы объектов, табличных частей, движений. Размер, структура хранения объекта. Для администраторов и разработчиков. Версия 1 - на обычных формах, версия 2 - на управляемых.

1 стартмани

11.07.2016    28555    127    o.nikolaev    17    

Разбираемся со структурой правил конвертации данных Промо

Инструментарий разработчика v8 КД Абонемент ($m)

При переносе данных между различающимися данными частенько приходится смотреть в правила. И часто, чтобы выяснить, к примеру, каким документом формируются остатки по конкретному ПВД, нужно заглядывать в него и искать, какое ПКО в нем вызывается. А может вызываться и алгоритм, в котором вызывается ПКО ;-) А если правил много? Чтобы не мучить себя утомительными поисками, предлагаю воспользоваться этой обработкой.

1 стартмани

14.10.2011    22250    29    Meta    17    

Хранение файлов в томах на диске (для УПП 1.3)

Практика программирования v8 УПП1 Абонемент ($m)

Доработка типовой УПП 1.3 в плане хранения присоединенных файлов вне базы данных

2 стартмани

05.06.2016    56058    8    wowik    32    

Остатки на каждый день в запросе

Практика программирования Учет ТМЦ Учет ТМЦ v8 1cv8.cf УУ Абонемент ($m)

Запрос формирует остатки товаров на каждый день в пределах выбранного периода.

1 стартмани

26.04.2016    56575    19    arakelyan    18    

Консоль запросов "Запросник" для управляемых форм с подсветкой синтаксиса

Консоль запросов v8 1cv8.cf Абонемент ($m)

Вот уже много лет я использую замечательный инструмент для работы с запросами - Запросник. Однако, с переходом на управляемые формы для его использования пришлось запускать базы в устаревшем толстом клиенте, да еще и разрешать в свойствах конфигурации использование обычных форм. В 2014 году появился запросник на управляемых формах, который, к сожалению, оказался несовершенен из за ограничений платформы. Самое неприятное из них - отсутствие подсветки синтаксиса. Мне кажется, что я нашел решение этой проблемы.

1 стартмани

19.04.2016    37128    256    1С_Мастер    42    

Выполнение JavaScript кода из 1С в объекте Поле HTML Документа (HTML 5) и вызов события в 1С ПриНажатии

Практика программирования v8 1cv8.cf Россия Абонемент ($m)

Пример выполнения JS кода из 1С в Поле HTML Документа под управляемыми формами, с удобным получением результата в 1С(С помощью вызова привязанного события ПриНажатии к элементу ПолеHTMLДокумента)

1 стартмани

22.03.2016    79055    155    igo1    54    

Количество дней недели (понедельников/вторников/...) в заданном диапазоне одним запросом

Практика программирования v8 Абонемент ($m)

При реализации периодического авто-заполнения маршрутных листов по графику (недельному) необходимо было просчитать стоимость всего периода, с условием выездов только по определенным дням. Заморачиваться с обходом результата не хотелось. Пришлось написать "Небольшой" запрос.

1 стартмани

03.03.2016    17741    1    Alexander.Shvets    5    

Простые радости жизни программиста 1С: выбор типа значения

Работа с интерфейсом Практика программирования v8 1cv8.cf Абонемент ($m)

Предлагаемая в работе обработка включает обычную и управляемую формы, которые максимально точно реализуют функциональность системного диалога выбора типа в толстом клиенте обычное приложение (включая оформление диалога). Эти формы имеют дополнительные интерфейсные удобства и могут быть использованы в качестве альтернативных диалогов выбора типа.

1 стартмани

17.02.2016    48911    50    yuraos    17    

Яндекс.Деньги "Благотворительность"

Инструментарий разработчика Практика программирования v8 1cv8.cf Абонемент ($m)

Яндекс.Деньги теперь в 1С. Форма для приема благотворительных взносов. Форму легко сделать и вставить на любую страницу сайта или блога. Платежи будут приходить на ваш кошелек. На форме есть три способа платежа: из кошелька, с банковской карты, с баланса мобильного.

1 стартмани

16.02.2016    22713    8    Tatitutu    5    

Генерация QR-кода программная и интерактивная (код открыт, управляемая форма, обычное и управляемое приложение, API)

Универсальные функции Универсальные обработки v8 v8::УФ 1cv8.cf Абонемент ($m)

Обработку можно быстро и легко интегрировать в любую конфигурацию с и без БСП (Библиотека Стандартных Подсистем).

3 стартмани

04.02.2016    47315    173    TuneSoft    30    

Мастер рассылки e-mail 2.2 для управляемых форм

Практика программирования Email v8 v8::УФ ERP2 БП3.0 УТ11 Абонемент ($m)

Для пользователей: переделанный из старый разработки под 8.2 с использованием библиотеки Мастер рассылки e-mail 2.2 (ERP, УТ, БП) (Только управляемые формы), который теперь может запускаться под любой версией платформы с разрешенными или запрещенными модальными/синхронными вызовами в конфигурации. Также удобный выбор e-mail и их владельцев с помощью отбора динамического списка по любым критериям и галочки исключения.

1 стартмани

29.12.2015    36525    19    milkers    4    

Нечеткий поиск одним запросом

Практика программирования v8 1cv8.cf Абонемент ($m)

Использование механизма полнотекстового поиска в 1С не всегда оправдано, т.к. построение индекса и поддержание его в актуальном состоянии может значительно нагружать систему. Предлагаемая реализация нечеткого поиска методом N-грамм выполняется одним запросом, что позволяет производить поиск в любой таблице и не требует предварительного построения индекса.

1 стартмани

28.12.2015    26944    69    vasvl123    9    

Передача больших пакетов через веб-сервисы

Практика программирования Администрирование данных 1С Внешние источники данных v8 Абонемент ($m)

Реализация механизма передачи больших пакетов через веб-сервисы. С его помощью передать файл размером в несколько гигабайт не составит проблем.

1 стартмани

06.12.2015    55759    47    YPermitin    19    

Автоматическая подстановка уничтожений временных таблиц в текст запроса

Универсальные функции v8 1cv8.cf Абонемент ($m)

Функция, которая сама подставляет в текст запроса "УНИЧТОЖИТЬ" в местах последнего использования ВТ.

1 стартмани

14.11.2015    19954    0    SeiOkami    3    

Интерфейс сопоставления объектов для обмена (для типового регистра СоответствиеОбъектовДляОбмена)

Инструментарий разработчика Универсальные обработки Перенос данных из 1C8 в 1C8 v8 КА1 БП2.0 ЗУП2.5 УТ10 УПП1 Абонемент ($m)

Вы внедряете обмен данными между двумя типовыми или основанными на типовых БД и вам необходим инструмент, чтобы сопоставить между собой справочники этих конфигураций? Вы хотите навести порядок в обмене данными, потому что вам надоело вылавливать дублирующиеся объекты? Вам очень хочется перепоручить сопоставление объектов обменивающихся баз пользователям, но нет подходящего и понятного пользователям интерфейса? Тогда вам нужна именно эта обработка!

4 стартмани

11.11.2015    38929    134    catsam    8    

Exec - Выполнение кода, консоль запросов и не только!

Консоль запросов v8 1cv8.cf Абонемент ($m)

Незаменимый инструмент администратора БД и программиста: Выполняйте произвольный код из режима 1С Предприятие; сохраняйте/загружайте часто используемые скрипты; выполняйте запросы с замером производительности запроса в целом и каждой из временных таблиц в частности, а также с просмотром содержимого временных таблиц; произвольным образом изменяйте любые объекты БД, редактируя даже не вынесенные на формы реквизиты и записывая изменения в режиме "ОбменДанными.Загрузка = Истина"; легко узнавайте ИД объектов БД; выполняйте прямые запросы к SQL с замером производительности и не только!

5 стартмани

10.11.2015    40577    75    catsam    11    

Быстрое определение интервалов в запросе

Практика программирования v8 Абонемент ($m)

В статье описывается новый метод определения интервалов между данными различных записей в запросе. В отличие от общеизвестного метода, время работы предлагаемого метода зависит от объема данных ЛИНЕЙНО. Это обеспечивает ему значительный выигрыш по быстродействию на больших объемах данных. В качестве иллюстрации возможностей метода приведен отчет, показывающий гистограмму распределения времени между продажами.

1 стартмани

01.10.2015    50590    35    ildarovich    41    

Полезные приемы при работе с Excel из 1С (Версия 3.1)

Практика программирования Разработка внешних компонент Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Программисту 1С часто приходится работать с таблицами Excel из 1С. Я постарался собрать небольшой FAQ и набор функций для работы с файлами Excel. Надеюсь, кому-то будет полезна данная статья.

1 стартмани

22.09.2015    193918    441    Zerocl    66    

Code First и Linq to EF на примере 1С версии 7.7 и 8.3 часть I

Практика программирования v8 Абонемент ($m)

Данный проект является чисто исследовательским примером использования Code First и Linq to EF на примере 1С версии 7.7. Так как сам я программист 1С, то мне всегда было интересно, как можно перенести модель объектов 1С на компилируемые языки, и использовать мощь Linq to EF. С появлением Code First давно хотел прикрутить, но все как-то руки не доходили, и вот, наконец ..

1 стартмани

28.08.2015    22479    3    Serginio    2    

Работа с push сервисами только средствами 1С 8.2

Сервисные утилиты Инструментарий разработчика Универсальные обработки v8 Абонемент ($m)

Обработка для настройки, тестирования и использования с предустановками для 3-х сервисов. Текст модуля для внедрения в конфигурацию или другие обработки. Уведомления на телефон, компьютер, браузер.

1 стартмани

18.08.2015    30411    43    anig99    1    

Универсальная учетная система с конструктором документов и справочников в режиме 1С: Предприятие

Инструментарий разработчика Практика программирования v8 1cv8.cf УУ Абонемент ($m)

Заголовок статьи звучит фантастично, но это не шутка. Занимаясь внедрениями, я часто сталкивался с ситуацией, когда надо было к типовой конфе приделать простенький модуль учета чего-нибудь, не специфичного для самой конфы. Например в УТ учет материалов в эксплуатации. Модуль обычно состоял из пары справочников (2-3), 3-х документов и регистра или пары регистров. Однажды подобные пристройки понадобились одновременно на 3 проектах. Скучно делать одинаковую работу, и я подумал, а что, если сделать универсальный инструмент, в котором пользователь сам сможет нарисовать себе справочники, реквизиты к ним, документы и движения. Т.е. конструктор полноценных документов в пользовательском режиме. Это оказалось не так сложно - все дело в подходящей архитектуре данных.

1 стартмани

29.07.2015    31315    88    informa1555    41    

Конвертация данных. Найдется все! И еще немного...

Поиск данных Инструментарий разработчика v8 КД Абонемент ($m)

Каждый разработчик, применяющий конфигурацию «1С:Конвертация данных», когда-нибудь обязательно сталкивается с проблемой поиска данных в правилах обмена и (или) регистрации данных.

2 стартмани

25.06.2015    27906    32    tomvlad    7