Тестирование: пример из семи шагов создания Unit-теста для платформы 1С.

Администрирование - Системное

В этой статье мы расскажем, как создать Unit-тест. Опишем как это сделать с использованием Фреймворка xUnitFor1C. Рассмотрим пример максимально приближенный к боевому, покажем процесс отладки теста, поделимся советами и приложим несколько обработок-примеров. Вы сможете убедиться, что создание тестов на самом деле это относительно быстрый и простой процесс.

Окружение для теста – конфигурация: ЕРП 2 (демо база версия 2.2.4.59, 2.2.3.231, 2.1.3.195)/УТ 11 (демо база 11.3.3.205); Фреймворк xUnitFor1C, внешние обработки (см. приложения) .

Задача теста - проверить корректность работы функции «СкладыСервер.ПереоформитьРасходныеОрдера»; с пользовательской стороны - это проверка кнопки «оформить расходные ордера по заказам» рабочего места «управление отгрузкой» (см. рис. ниже).

Условие проверки -  при «имитации» нажатия кнопки «оформить ордера» должен будет сформироваться документ «Расходный ордер на товары» и табличная часть этого документа должна будет соответствовать  некоторой эталонной таблице значений.

рабочее место отгрузка товаров со склада

Шаг 1. Определяемся с данными для теста. 

1.1 НСИ: склад будет ордерный и существующий в демо базе «Магазин «Продукты»», организация «Торговый дом «Комплексный»», контрагента создадим нового «ООО Ромашка», также создадим новое типовое соглашение и договор контрагента (можно подобрать существующие).

1.2 Документы: нам нужно будет создать только два документа «Заказ клиента» (отгружать его будем в кредит) и «Расходный ордер на товары».

1.3 Дополнительно: можно создать документы поступления, это поможет решить проблему отсутствия/нехватки товара – «Поступление товаров и услуг» и «Приходный ордер на товары» (не обязательно).

 

Шаг 2. Создаем «эталонную» цепочку. В большинстве случаев рекомендуем создавать документы, а НСИ использовать существующую.

2.1 Создаем контрагента, партнера, типовое соглашение и договор контрагента.

2.2 Оформляем заказ, ставим его в отгрузку.

2.3 Создаем расходный ордер и снимаем его с проведения. Это будет наш эталонный документ для сравнения.

 

Шаг 3. Создаем макет данных, с помощью плагина «СериализаторMXL».

вариант «а» - быстрый
3.1 Открываем обработку в предприятии и остаемся на вкладке «Метаданные».

3.2 Устанавливаем в свойствах генерации макета флажки: «Выгружать ссылку», «Связь по ГУИД», «Обмен Данными», «выгружать с документом его движения», «Уровень выгрузки зависимых» в значение «2».

3.3 Указываем документ «Заказ клиента» и «Расходный ордер на товары» в дереве метаданных  или жмем кнопку «Структура подчиненности».

В форме указываем тип данных «Заказ клиента» и находим наш документ, далее добавляем в корзину и передаем в основную форму (см. рис. ниже).

Для удобства работы можно скрыть не выбранные элементы дерева метаданных с помощью кнопки «Только выбранные» .

3.4 Создаем и сохраняем макет (в обработке плагине «СериализаторMXL» кнопки «Создать макет данных» и «Сохранить макет в файл»).
3.5 Поверяем макет на другой «копии базы», т.е. убеждаемся, что мы выбрали все необходимые данные и не будет ошибки при подгрузке данных.(в обработке плагине «СериализаторMXL» для этого есть кнопки команды «Загрузить макет из файла» и «Протестировать загрузку макета»)

вариант «б» - только то что нужно
3.1 Открываем обработку в предприятии и остаемся на вкладке «Метаданные».

3.2 Устанавливаем в свойствах генерации макета флажки: «Выгружать ссылку», «Связь по ГУИД», «Обмен Данными». Также в дереве подчинённости снимем флажки «Выгружать при необходимости».

3.3 Жмем кнопку «Структура подчиненности» (особенности работы были описаны выше).

3.4 С помощью кнопки «Проставить отбор подчинённых ссылок»   из текущей строки документа в быстром режиме подбираем справочники, которые хотели выгрузить – это контрагент, договор контрагента и еще рекомендуем добавить справочники вида «ключи аналитик» (принцип работы аналогичен кнопке структура подчиненности).

3.5 Выбираем все движения регистров через кнопку «установить отборы для регистров» для документа «Заказ клиента» (для этого позиционируем необходимую строку документа и жмем кнопку отборов для регистров).

3.6 Сохраним настройки дерева в файл. Это позволит довольно быстро восстановить настройки макета для повторного сохранения.

3.7 Создаем и сохраняем макет.

3.8 Проверяем макет на другой «копии базы», т.е. убеждаемся, что мы выбрали все необходимые данные, в противном случае добавляем недостающую информацию в выгрузку.

 

Шаг 4. Подготовка обработки для создания юнит теста. 

 4.1 Берем шаблон обработки для серверного теста.

 4.2 Открываем в конфигураторе и переименовываем шаблонные функции на созвучное нам имя теста (в модуле обработки и в модуле управляемой формы) как «ПроверитьФункциюОформленияРасходныхОрдеров».

4.3 Вставляем в обработку наш макет с начальными данными и называем его как «МакетДанных» (выгрузка см. шаг 3).

4.4 Сохраняемся.

 

Шаг 5. Создаем код теста. Ниже приведены логические пункты, на которые мы советуем разбить исходный код теста.

5.1 Подготавливаем данные для выполнения проверки функции.

5.2 Формируем параметры для функции.

5.3 Выполняем функцию.

5.4 Обрабатываем результат. Если документы создались, то выполняем сравнение табличных частей эталонных документов (из макета) и документов, созданных при выполнении процедуры. Сравнивать рекомендуем, только значимые колонки (нет смысла сравнивать внутренние ключи и т.п.).

    Код функции проверки:

    ////////////////////////////////////////////////////////////////
    // I получение данных из макета
    
    // 1.1 из макета
    МакетДанные = ПолучитьМакет("МакетДанные");
    СозданныеДанные = СериализаторMXL.СоздатьДанныеПоТабличномуДокументу(МакетДанные);
    
    Склад = СозданныеДанные.ЗаказКлиента.Склад;
    Получатель = СозданныеДанные.РОМАШКАООО_Партнер;
    ЗаказКлиента = СозданныеДанные.ЗаказКлиента;
    РасходныйОрдерНаТовары_Эталон = СозданныеДанные.РасходныйОрдерНаТовары;
    РасходныйОрдерНаТовары_Битый = СозданныеДанные.РасходныйОрдерНаТовары_Битый;
    
    // 1.2 готовим входные параметры для функции
    СтруктураПараметровСозданияРасходныхОрдеров = СкладыСервер.ПараметрыПереоформленияРасходныхОрдеров();
    СтруктураПараметровСозданияРасходныхОрдеров.Склад = Склад;    
    СтруктураПараметровСозданияРасходныхОрдеров.РаспоряженияНаОтгрузку = новый Массив;
    СтруктураПараметровСозданияРасходныхОрдеров.РаспоряженияНаОтгрузку.Добавить(ЗаказКлиента);   
    СтруктураПараметровСозданияРасходныхОрдеров.Получатель = Получатель;
    
    
    ////////////////////////////////////////////////////////////////
    // II вызов проверяемой функции
    
    СтруктураОтвета = СкладыСервер.ПереоформитьРасходныеОрдера(СтруктураПараметровСозданияРасходныхОрдеров);    
    
    
    ////////////////////////////////////////////////////////////////
    // III обработка и проверка результата
    
    // 3.1 Внутренняя ошибка
    БазовыеУтверждения.ПроверитьЛожь(СтруктураОтвета.ЕстьОшибка,"Внутренняя ошибка при создании расходных ордеров");
    БазовыеУтверждения.ПроверитьНеРавенство(СтруктураОтвета.ОформленныеОрдера.Количество(),0,"Внутренняя ошибка. Не удалось создать ордера");
    
    // 3.2 Сравним с эталоном
    // выгружаем только проверяемые колонки, некоторые необходимо проигнорировать
    СтрокаНужныхКолонок="Номенклатура,Характеристика,Назначение,Серия,Упаковка,
    |КоличествоУпаковок,Количество";
    
    УтвержденияПроверкаТаблиц.ПроверитьРавенствоТаблиц(РасходныйОрдерНаТовары_Эталон.ОтгружаемыеТовары.Выгрузить(,СтрокаНужныхКолонок),
        СтруктураОтвета.ОформленныеОрдера[0].РасходныйОрдер.ОтгружаемыеТовары.Выгрузить(,СтрокаНужныхКолонок));

         
Шаг 6. Проводим отладку теста. Сразу может заработать только простейший пример из разряда «2+3=5» (без этой функциональности первоначально юнит тесты у нас не поехали). 
6.1 Отключаем у пользователя защиту от опасных действий, в противном случае будут проблемы с загрузкой плагинов и менеджера юнит тестов.
6.2 Открываем обработку в предприятии на тестовой базе.
6.3 Указываем требуемые серверные пути (у нас на сервере разработки расшаренный каталог GIT, где находится все что необходимо).
6.4 Ставим точки останова и отлаживаем. 

Обработка теста

Шаг 7. Завершение. Все готово! Помещаем тест в рабочую папку/хранилище GIT, настраиваем задания для выполнения тестов.

 

Бонусы! 
А) Мы добавили обработку пример. В обработке примера две функции - правильная и битая (приводящая к ошибке для демонстрации). Кроме правильного эталонного расходного ордера есть еще «битый», при котором сработает наша проверка на равенство таблиц. В результате его выполнения мы увидим текст сообщения об ошибке – не совпадают табличные части в таких-то позициях (см. рис. ниже).
 Пример сообщения об ошибке для юнит теста
Б) В приложениях есть шаблон обработки с встроенным блоком для отладки и двумя примерами заготовками (загрузка данных из макета и выполнение простой функции).

 

Советы:
1. Запускать тесты удобно через Jenkins, TeamCity, а еще можно через Windows Task Manager.
2. Смотреть тесты красиво позволяет свободный фреймворк Allure.
3. Для удобства создания данных для тестов мы внесли некоторые изменения в плагин «СериализаторMXL», что оптимизировало процесс работы с ним: добавили возможность сохранения дерева настроек, загрузку макета, отбор документов по структуре подчиненности и пакетное формирование движений для выбранных документов, кое-что поправили еще; (в рамках нашего процесса). Есть в приложении, но также можно использовать стандартный плагин фреймворка.
4. Работайте с GIT - это позволит использовать тесты и инструменты работы с ними в командной разработке.
5. Рекомендуем прогонять тесты не только при сборке релиза, но и на ночном билде, а также на базах разработчиков.
6. Актуальную версию, весь необходимый набор плагинов и многое другое Вы можете скачать со странички проекта xUnitFor1C на github.

Скачать файлы

Наименование Файл Версия Размер
Обработка - UnitТест оформление расходного ордера на товары
.epf 18,27Kb
20.08.17
2
.epf 18,27Kb 2 Скачать
Плагин СериализаторXML*
.epf 129,85Kb
30.08.17
1
.epf 129,85Kb 1 Скачать
Шаблон обработки с режимом отладки для серверного теста
.epf 11,49Kb
20.08.17
3
.epf 11,49Kb 3 Скачать

См. также

Комментарии
1. Артур Аюханов (artbear) 882 29.08.17 14:41 Сейчас в теме
Плюс за использование нашего фреймворка xUnitFor1C.
4. Владимир Крючков (ivanov660) 409 29.08.17 16:16 Сейчас в теме
(1) Других "достойных" фреймворков для юнит-тестов мы не нашли :-)
8. Решитко Дмитрий (grumagargler) 322 29.08.17 19:59 Сейчас в теме
(4) Спасибо за статью по теме тестирования! Почему "достойных" у вас в кавычках? :-)
Вы пробовали сценарное тестирование или тестер? Подобные примеры на мой взгляд не менее элегантно решаются и там. Интересно ваше мнение, почему другие системы не вошли в список достойных.
9. Виталий Попов (Сурикат) 152 29.08.17 21:46 Сейчас в теме
(8)
ых" у вас в кавычках? :-)
Вы пробовали сценарное тестирование или тестер? Подобные примеры на мой взгляд не менее элегантно решаются и там. Интересно ваше мнение, почему другие системы не вошли в список достойных.


Я присоединюсь к высказыванию выше.
Если я хочу использовать TDD для тестирование кода на сервере, то сценарное тестирование подходит плохо. Очень много времени тратиться на прогон теста + в вашей конфигурации метод "Создать" необходимо делать.
А в xUnit можно набросать тест на проведение документа мин за 10.

Минус xUnit, что поведение форм тестировать неудобно. Хочется без открытия самой формы, чтобы все процедуры ПриОткрытии, ПриСозданииНаСервере отработали и там уже проверять свои.

Это сделать можно, но тогда методы форм нужно писать как процедуры с передачей в них Формы или добавлять какие-то специальные методы для тестирования, что неочень хорошо при работе в типовых конфигурациях.

Клиентские методы общих модулей тестировать одно удовольствие
12. Решитко Дмитрий (grumagargler) 322 30.08.17 00:14 Сейчас в теме
(9)
Я присоединюсь к высказыванию выше.
Если я хочу использовать TDD для тестирование кода на сервере, то сценарное тестирование подходит плохо

Смотрите, в статье речь не идет о TDD. Кроме этого, генетически, TDD не самая простая технология для разработки от тестирования бизнес-приложений с тесным взаимодействием с базой данных. Несомненно, всё поддается эволюции и часть гибридных подходов упрощает жизнь, но я готов дискутировать на счет скорости!

Накидать код обработки по-быстрячку для проверки проведения документа, это ведь вершина айсберга. В сценарном тесте, абсолютно точно также можно открыть существующий документ, нажать кнопку проведения и посмотреть движения, и это будет ничуть не медленней.

А вот когда дело заходит о всей инфраструктуре, вот здесь и начинается всё самое интересное, о чем даже в книгах стесняются писать. Да просто давайте затронем вопрос - подготовка начальных данных, их понимание, хранение и эволюция для вашего юнит-теста и развивающегося функционала. Как вы это делаете для своих тестов, вручную, выгрузками в макеты? Ведь вам чтобы проверить хотя бы расходную накладную (например), нужно приход какой-то иметь, товары, счета учета и т.д. И вот вы бережно создаете эти данные, информация о подготовке которых существует только в сериализованном в макете виде и у вас в голове. Возможно, кто-то даже базу для каждого теста отдельно хранит...и всё умирает потом с каким-нибудь очередным изменением конфигурации, которое простым изменением регистра сведений, сделает не уникальными ваши записи, или субконто плана счетов вылазят и начинают дублироваться, и всё это в итоге приводит к невозможности простого обновление конфигурации ваших подопытных баз, не говоря о макетах, данных в них, и всей той утерянной информации по их подготовке, и представим, что вы не один разработчик решения. И лишь вскользь упомяну о парадоксе, когда тесты вроде как развязывают руки в плане рефакторинга, но при этом связывают ноги из-за падения тестов по причинам инфраструктурных вопросов, а не ошибок как таковых.

И даже если с этим всем всё в порядке, сценарное тестирование, на мой взгляд дает больше возможностей в плане тестирования как такового (вопрос не в том, какой подход лучше, а в какой имеет смысл больше инвестировать времени). Например, буквально недавно разрабатывал кастомный журнал документов, где обновление, удаления/проведения и т.д. нужно делать кодом вручную. И вот сценарий: вводится через такой журнал документ, изменяется в нем сумма, документ сохраняется и закрывается, нужно проверить, что в журнале, колонка сумма соответствует сумме документа. Разработку я веду через тестирование, поэтому у меня нет заготовленных данных и готового функционала для проверки. Сумму документа и новую сумму я в общем случае не знаю, я всё это создаю на лету сценарным тестом. Открываю журнал, ищу документ, не нашел - ввожу, нашел - запоминаю сумму в журнале, открываю документ, увеличиваю на доллар сумму, записываю, закрываю, проверяю сумму в журнале с расчетной. И так я запускал этот тест пока поведение не пришло к ожидаемому. Я не уверен, что обработкой на сервере вы сделаете тот же тест, не говоря о времени, которое экономится на итерациях Открыть журнал / Ввести документ / Запомнить сумму и т.д.
oleynik.dv; Dementor; tsukanov; tormozit; Armando; ivanov660; BabySG; +7 Ответить
14. Владислав Мороз (vlad.frost) 172 30.08.17 08:16 Сейчас в теме
(12)
сценарное тестирование, на мой взгляд дает больше возможностей в плане тестирования как такового

Я так понимаю, речь о типовой конфигурации "Сценарное тестирование"? Она умеет работать в составе какой-либо CI-системы сборки? Gitlab, Jenkins, TeamCity вот это вот всё? Поддерживает ли она запуск из командной строки?
xUnitFor1C всё это умеет, есличо.
pumbaE; artbear; +2 Ответить
26. Решитко Дмитрий (grumagargler) 322 30.08.17 17:21 Сейчас в теме
(14)
Я так понимаю, речь о типовой конфигурации "Сценарное тестирование"?

- нет, речь технологии тестирования

Она умеет работать в составе какой-либо CI-системы сборки? Gitlab, Jenkins, TeamCity вот это вот всё? Поддерживает ли она запуск из командной строки?
xUnitFor1C всё это умеет, есличо.

это всё здорово, вопрос лишь в том - насколько это ценно без возможности быстро создавать и управлять тестами как таковыми.
17. Виталий Попов (Сурикат) 152 30.08.17 09:21 Сейчас в теме
(12)

На мой взгляд мы с вами дискутируем о том, что покрывать тестами. Вы покрываете тестами конечный функционал. Я пытаюсь покрывать тестами не конечный функционал, а более мелкие блоки.

В идеале нужно совмещать оба подхода.

Может в скором времени и к вашему подходу приду =)

(13)

Спасибо за пример!
19. Артур Аюханов (artbear) 882 30.08.17 11:02 Сейчас в теме
(12) В очередной раз многовато текста, попробую ответить.

Большое лукавство говорить о TDD, юнит-тестах и отдельно о сценарном тестировании, которое используется в различных продуктах.
Сценарное тестирование по своей сути набор последовательных действий, которые идут в сторону одной цели.
Такое тестирование есть в xUnitFor1C, не нужно об этом забывать.
Так называмое "сценарное тестирование" это не только кнопконажималка :)

вообще считается, что тесты, завязанные на интерфейс (что как раз и реализовано в автотестировании 8.3), являются самой хрупкой частью по сравнению с остальными видами тестов

А еще есть т.н. сценарное тестирование в нашем же продукте vanessa-behavior - человеческий язык сценариев, отличное переиспользование шагов, большая библиотека шагов, автогенерация инструкций, поддержка автотестирования 1С 8.3 (кнопконажималка и прочее) и многое другое.

и xUnitFor1C и vanessa-behavior отлично и очень давно работают с различными билд-серверами - Jenkins, TeamCity, MS TFS/MS Team Services, Bamboo и т.п.
Получают красивую отчетность по тестированию, в т.ч. и учет трендов по тестам.

Да, подготовка и поддержание инфраструктуры самое сложное.
У нас (Серебряной Пули) 2 базовые рекомендации по подготовке тестовой базы, которые мы предлагаем на обучении различных команд - пустая база или минимальная эталонная база (условно-константные данные (константы, справочники, ПВХ, регистры сведений и т.п.)

но для этого у нас есть различные помощники.
Например, наш генератор данных/сериализатор из xUnitFor1C как раз и разработан с целью минимизации последствий по обновлению структуры метаданных, в отличие от других средств сериализации - конвертация данных или универсальный обмен xml и т.п.
подробнее об этом я напишу в ответе на (18), .вопрос 1.

При использовании так называемого "сценарного тестирования", которое заключается в интерактивном создании необходимых данных через "кнопконажималку" автотестирования 1С 8.3, также возможны проблемы при обновлении. например, исчезновение полей в формах, перенос полей в разные закладки и т.п. и т.д.
Из опыта - проблем в кнопконажималке совсем не мало, падает в самых различных местах :(
27. Решитко Дмитрий (grumagargler) 322 30.08.17 18:42 Сейчас в теме
(19)
В очередной раз многовато текста, попробую ответить.

Спасибо.

Большое лукавство говорить о TDD, юнит-тестах и отдельно о сценарном тестировании, которое используется в различных продуктах.

Прочел много раз и не понял суть претензии. Мы же о тестировании и говорим, да и вообще, речь была о подаче материала в статье, а не возможностях продуктов.

А еще есть т.н. сценарное тестирование в нашем же продукте vanessa-behavior - человеческий язык сценариев, отличное переиспользование шагов, большая библиотека шагов, автогенерация инструкций, поддержка автотестирования 1С 8.3 (кнопконажималка и прочее) и многое другое.

и xUnitFor1C и vanessa-behavior отлично и очень давно работают с различными билд-серверами - Jenkins, TeamCity, MS TFS/MS Team Services, Bamboo и т.п.
Получают красивую отчетность по тестированию, в т.ч. и учет трендов по тестам.

Моя толерантность дает течь: лучше много текста по сути дела, чем реклама.

Например, наш генератор данных/сериализатор из xUnitFor1C как раз и разработан с целью минимизации последствий по обновлению структуры метаданных, в отличие от других средств сериализации - конвертация данных или универсальный обмен xml и т.п.

Забыт на мой взгляд самый правильный подход - подготовка данных кодом сценария.

При использовании так называемого "сценарного тестирования", которое заключается в интерактивном создании необходимых данных через "кнопконажималку" автотестирования 1С 8.3, также возможны проблемы при обновлении. например, исчезновение полей в формах, перенос полей в разные закладки и т.п. и т.д.
Из опыта - проблем в кнопконажималке совсем не мало, падает в самых различных местах :(

Изменение пользовательского интерфейса - это реакция на изменение функционала, в подавляющем большинстве случаев. Поэтому тесты "до сценарных" упадут еще раньше, и заготовленные связанные данные в макетах, не имеющие связи со сценарием - также вероятность переделать не ради теста, а ради работы инфраструктуры - высока.

Теперь о лукавстве. Ванесса пропагандирует BDD подход, однако вы не будете отрицать, что в вашем продукте, в подавляющем большинстве все сценарии пишутся программистами, что несколько противоречит самой идее, и о чем свидетельствует недавние изменения и брожения умов самих адептов по поводу добавления в язык циклов и условий. Если постоянно приходиться держать себя в колготках, убеждая, что всё это бравое дело, значит что-то не так с подходом. Языки программирования для того и придумали, чтобы делать много малым, и программисты не должны сами себе писать абзацы текстов на другом языке, когда в тоже самое время, они это могут лаконично выразить кодом. В BDD на их совести техническая часть сценария. И к слову, во многих историях успеха, внедрение BDD до отдела разработки даже не всегда доходит.
Буду резок, но большим лукавством я считаю скрытие или недостаточное внимание инфраструктурным вопросам и сложности тестов, заменяя это рекламой красивых отчетов, западных терминов и автоинструкций.

Давайте по существу. Вот у меня есть задача, нужно разработать табель учета рабочего времени. Нужно проверить расчеты всех видов часов в табеле, резерв времени, использование резерва и т.д. Нужно учесть, например, что период в табеле не указывается датой, а пролистывается стрелками. У каждого сотрудника может быть свой период табелирования, неделя/две/месяц. Таким образом, нужно учитывать, чтобы проверяемый тестом день отсутствия не попал на выходной, а рабочий не попал в праздник и так далее. Также, нужно определить сколько рабочих дней в периоде, чтобы сверить с расчетами. Да, можно использовать гарантированный месяц, где четко известны все эти данные, но как вы без условий и циклов открутите период назад, на нужный нам месяц? Вот было бы интересно посмотреть, что может предложить в этом плане ванесса в сравнении с тестером, например. Добавим сюда начальные данные, такие как клиент, проект, график работы, прием на работу, учтем, что это не один тест в природе, а таких будет много, где сотрудник будет уволен в течении отчетного периода или переведен на другой график работы. Что делать, когда появится тест, меняющий график, добавляющий праздник или меняющий тип проекта (всё случайно или намеренно), как и кто и будет ли вообще контролировать очередность тестов? Заготовка макетов для каждого такого случая просто не выглядит реальной, особенно в свете меняющейся конфигурации.
1ceo_2015; Dementor; BabySG; tsukanov; +4 Ответить
28. Артур Аюханов (artbear) 882 30.08.17 19:23 Сейчас в теме
(27)
В очередной раз многовато текста, попробую ответить.


Спасибо.


Да, извини, я и сам не удержался :(
Я хотел отвечать небольшими кусками текста, но не справился с этой задачей :)
13. Владислав Мороз (vlad.frost) 172 30.08.17 08:05 Сейчас в теме
(9)
Минус xUnit, что поведение форм тестировать неудобно.


Поведение форм тестируйте с помощью платформенного "Автоматизированного тестирования". В xUnitFor1C для этого есть плагин ТестКлиент

Пример использования:

&НаКлиенте
Перем КонтекстЯдра;
&НаКлиенте
Перем Утверждения;

&НаКлиенте
Процедура Инициализация(КонтекстЯдраПараметр) Экспорт
	КонтекстЯдра = КонтекстЯдраПараметр;
	Утверждения = КонтекстЯдра.Плагин("БазовыеУтверждения");
КонецПроцедуры

&НаКлиенте
Процедура ЗаполнитьНаборТестов(НаборТестов) Экспорт
	НаборТестов.Добавить("Тест_СозданиеВалютыУНФ");
КонецПроцедуры

&НаКлиенте
Процедура Тест_СозданиеВалютыУНФ() Экспорт
	
	ТестКлиент = КонтекстЯдра.Плагин("ТестКлиенты").ТестКлиентПоУмолчанию();
	
	ВключитьНесколькоВалют(ТестКлиент);
	
	ОсновноеОкно = ОсновноеОкно(ТестКлиент);
	ОсновноеОкно.ВыполнитьКоманду("e1cib/command/Справочник.Валюты.Команда.Создать");
	ФормаНоваяВалюта = ТестКлиент.НайтиОбъект(Тип("ТестируемаяФорма"), "Валюта (создание)");
	
	ПолеСимвольноеПредставление = ФормаНоваяВалюта.НайтиОбъект(Тип("ТестируемоеПолеФормы"), "Символьное представление");
	Утверждения.ПроверитьТип(ПолеСимвольноеПредставление, Тип("ТестируемоеПолеФормы"), "Не найдено поле ""Символьное представление""");
	
КонецПроцедуры

&НаКлиенте
Процедура ВключитьНесколькоВалют(ТестКлиент)
	
	ОсновноеОкно = ОсновноеОкно(ТестКлиент);
	ОсновноеОкно.ВыполнитьКоманду("e1cib/command/ОбщаяКоманда.БольшеВозможностейДеньги");
	ФормаБольшеВозможностей = ТестКлиент.НайтиОбъект(Тип("ТестируемаяФорма"), "Больше возможностей: настройка программы");
	ПолеНесколькоВалют = ФормаБольшеВозможностей.НайтиОбъект(Тип("ТестируемоеПолеФормы"), "Несколько валют");
	Если ПолеНесколькоВалют.ПолучитьПредставлениеДанных() = "Нет" Тогда
		ПолеНесколькоВалют.УстановитьОтметку();
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Функция ОсновноеОкно(ТестКлиент)
	КлиентсткиеОкнаТестируемогоПриложения = ТестКлиент.ПолучитьПодчиненныеОбъекты();
	Для Каждого ТекОкно Из КлиентсткиеОкнаТестируемогоПриложения Цикл
		Если ТекОкно.Основное Тогда
			Возврат ТекОкно;
			Прервать;
		КонецЕсли;
	КонецЦикла;
КонецФункции
Показать
10. Владимир Крючков (ivanov660) 409 29.08.17 22:01 Сейчас в теме
(8) 1. Речь идет про юнит-тесты, а не про сценарные тесты - это "немного" разные вещи.
2. Конфигурация "Сценарное-тестирование" и "Тестер"не подошли нам (Мы решили написать свой "велосипед" для создания сценарных тестов для платформы 1С, про него мы расскажем позже).
11. Решитко Дмитрий (grumagargler) 322 29.08.17 23:19 Сейчас в теме
(10)
Речь идет про юнит-тесты, а не про сценарные тесты - это "немного" разные вещи.

Возможно, тогда ваш пример в статье выбран неудачно. Вы описываете вполне четкий сценарий, только его проверку делаете кодом на сервере, а не кодом сценария. То есть разница тут только техническая, код в обработке на сервере или на клиенте в сценарии, не делает из первого Unit тестирование или TDD, а второе не означает сразу BDD. Поэтому в теории - да, это разные подходы, но в вашем примере - это не так.

Позвольте мне обрушить на вас еще немного критики: ваш пример не удовлетворяет строгости unit-теста, и некоторым его базовым принципам. Также, в нем мало общего с TDD (впрочем, вы это и не декларировали). Заготовка данных идет вручную, она не описана кодом и в шаблоне уже будет потеряна. Нужны две базы, нужны НСИ которые фактически, только в "уме", что произойдет, если поменяются условия теста или изменится структура метаданных, и помножить это на две три сотни тестов - я не вижу как практически можно будет эффективно следить за всем этим хозяйством.

2. Конфигурация "Сценарное-тестирование" и "Тестер"не подошли нам (Мы решили написать свой "велосипед" для создания сценарных тестов для платформы 1С, про него мы расскажем позже).

как сделали в свое время и мы, будет интересно посмотреть на ваш подход!
15. Тимур Багаутдинов (Timur_Bagautdinov) 30.08.17 08:29 Сейчас в теме
(10)
1. Речь идет про юнит-тесты, а не про сценарные тесты - это "немного" разные вещи.


Как раз таки в примере и не видно юнит-теста. Согласен с коллегой выше, что здесь пример сценарного теста.
16. Владимир Крючков (ivanov660) 409 30.08.17 09:00 Сейчас в теме
(15) 1. В статье идет речь о юнит-тесте и проверке функции "СкладыСервер.ПереоформитьРасходныеОрдера".
2. Все что описано в шагах 1,2 - это подготовка и создание данных для проведения юнит-теста.
(Мы внесли эти шаги для того чтобы желающие могли повторить последовательность действий от начала до завершения теста)
3. Конечно же можно написать сценарный тест для проверки задачи переоформления складских ордеров.

возможно ввела в заблуждение фраза "при имитации нажатия кнопки «оформить ордера» должен будет сформироваться документ «Расходный ордер на товары»". Под имитацией я подразумеваю вызвать функцию "СкладыСервер.ПереоформитьРасходныеОрдера".
2. Артур Аюханов (artbear) 882 29.08.17 14:43 Сейчас в теме
Пожалуйста, поделитесь доработанной версией "СериализаторMXL", он общедоступный для всех.
я добавлю его в проект xUnitFor1C на github
3. Владимир Крючков (ivanov660) 409 29.08.17 16:14 Сейчас в теме
(2) К статье прикрепить бесплатно система не дает, скидываю в комментах
Прикрепленные файлы:
СериализаторMXL.epf
Lo1jke; vlad.frost; Сурикат; artbear; +4 Ответить
5. Артур Аюханов (artbear) 882 29.08.17 16:35 Сейчас в теме
(3) Спасибо.

мы внесли некоторые изменения в плагин «СериализаторMXL», что оптимизировало процесс работы с ним: добавили возможность сохранения дерева настроек, загрузку макета, отбор документов по структуре подчиненности и пакетное формирование движений для выбранных документов, кое-что поправили еще; (в рамках нашего процесса).


Есть более расширенное описание изменений плагина, чем в статье?
Если да, поделись. Можно в личку.
7. Владимир Крючков (ivanov660) 409 29.08.17 17:46 Сейчас в теме
6. Артур Аюханов (artbear) 882 29.08.17 16:45 Сейчас в теме
18. Alex Ko (AlexKo84) 30.08.17 10:35 Сейчас в теме
Добрый день.
Пользовался при разработки xUnitFor1C. Понравилось.
Однако есть вопросы, может Вы сможете подсказать.
1. Допустим делаю документ, выгрузил в шаблон макет а потом изменились его реквизиты(метаданные) выходит мне надо заново делать шаблон или пытаться править макет вручную. Это не удобно. Есть ли способ лучше?
2. Допустим я тестирую некий функционал который пишет свои результаты в базу, далее мне надо тестить функционал который зависим от предыдущего и тд, те один зависит от другого. Сейчас я просто вызываю из одного теста другой. Насколько это правильно? Если я буду делать шаблоны и не вызывая "предыдущий функционал" сразу вносить данные в базу для работы текущего тестирования то при изменениях мне придется много менять а это очень неудобно.
3. Есть ли какой то способ/рекомендация как организовывать тесты ведь если их много и они тестят функции зависимые от др и при этом прогружают данные из макета(СериализаторMXL) то по прошествии времени не особо помнишь что для чего.
20. Артур Аюханов (artbear) 882 30.08.17 11:11 Сейчас в теме
(18) Спасибо за хорошую оценку нашего открытого и бесплатного продукта xUnitFor1C.
Отвечаю по пунктам:
1. Изменение метаданных - сложный этап.
Но при создании генератора данных в xUnitFor1C мы как раз постарались помочь решить эту проблему.

После изменения метаданных есть несколько способов реагирования.
1.1 ничего не делать :) , т.к. вполне может быть, что добавлен не столь значащий реквизит документ и документ, созданный из макета, все равно будет находиться в консистентом состоянии
1.2 если все-таки добавлен значащий реквизит, можно выбрать один из 2х способов ниже.
1.3 заново сделать шаблон документа. это может быть трудно - например. нет подходящего документа, или на документ много завязано других ссылок

1.4 подредактировать макет вручную !
на самом деле это не так сложно.
+ Структура макета довольно простая и специально сделана для повышения человекочитаемости и человеко-редактируемости. Табличный документ рулит :)
+ Генератор специально не загружает/не выгружает, а пропускает поля, значения которых не отличается от полей пустого документа.
+ например, значение Ложь для реквизита с типом Булево не будет выгружено или пустая ссылка для ссылочного типа не будет выгружена.
+ в итоге в макете остаются только значащие поля, в отличие от, например, универсальной выгрузки xml, которая очень зависима от изменения метаданных
+ можно просто добавить несколько полей в макет документа - добавить имя поля, его значение. в большинстве случае этого хватает.
21. Артур Аюханов (artbear) 882 30.08.17 11:16 Сейчас в теме
(18) По вопросу № 2
Здесь нет простого решения, все зависит от конкретных особенностей.
Базовые рекомендации
+ либо используйте сценарии, т.е. из одного теста вызывайте другой
+ это возможно разными средствами xUnitFor1C -
+ например, ручной вызов теста из другого теста
+ либо используйте сценарный тест в самом xUnitFor1C - смотрите wiki продукта
+ либо можно развязать эти тесты от взаимного использовании и использовать только данные
+ сгенерируйте макет от первого теста и используйте его во втором.
+ тесты будут независимы, их будет легко проверять и разбирать в случае падения одного из тестов.

Напоминаю, что если тест/сценарий падает, то это возможно по 3-м причинам:
+ изменилось поведение системы (например, программист поменял код)
+ изменился тест
+ изменились данные

и бывает далеко не просто понять, в чем же проблема падения теста, и нужно принимать все меры к упрощению подобного анализа.
25. Артур Аюханов (artbear) 882 30.08.17 11:33 Сейчас в теме
(18) По вопросу 3
> Есть ли какой то способ/рекомендация как организовывать тесты ведь если их много и они тестят функции зависимые от др и при этом прогружают данные из макета(СериализаторMXL) то по прошествии времени не особо помнишь что для чего.

Есть разные варианты, как всегда :)
+ Можно делить по блокам функционала - один каталог на верхнем уровне соответствует одному блоку
+ Можно делить по метаданным - один каталог на верхнем уровне соответствует одному метаданному
+ можно совмещать эти подходы
+ например, создание НСИ - отдельный каталог
+ создание документов - другой каталог
+ блоки функциональности - третий каталог
22. Владимир Крючков (ivanov660) 409 30.08.17 11:18 Сейчас в теме
1. Актуализировать данные в случае изменений влияющий на проведение теста придется делать - это накладные расходы.
К примеру, можно снизить затраты на обновление, если использовать при загрузке макетов "обмен данными" = истина, тогда новые реквизиты просто будут проигнорированы. В рамках примера, когда мы пробовали тестировать его на некоторых версиях конфигурации ЕРП, то для совместимости мы удалили несколько реквизитов документа "заказ клиента" из макета, которые не влияют на решение задачи.
2. Все зависит от методологического подхода к решению задачи тестирования: делать много тестов, использовать один источник данных для всех тестов, использовать демо базу, использовать лицо, которое следит за актуализацией и др. Это большая и серьезная тема.
3. Удобнее всего использовать какую-либо систему учета тестов с описаниями и возможно ссылками на систему баг-трекинга.

Думаю, что чуть позже мы расскажем про наше видение данной ситуации. И в рамках этого вопроса/тематики я планирую выступить на конференции инфостарта.
23. Артур Аюханов (artbear) 882 30.08.17 11:18 Сейчас в теме
Кстати, я уже несколько лет перестал употреблять юнит-тесты в применении к тестированию в 1С, а использую просто тесты или сценарные или приемочные тесты.
В 1С мало юнит-тестов, т.к. тесты чаще всего завязаны на БД.

поэтому лукавство говорить, что в xUnitFor1C, дескать,.юнит-тесты, а вот у нас сценарные тесты, как говорят некоторые коллеги :)
24. Артур Аюханов (artbear) 882 30.08.17 11:27 Сейчас в теме
А еще есть т.н. сценарное тестирование в нашем же продукте vanessa-behavior - человеческий язык сценариев, отличное переиспользование шагов, большая библиотека шагов, автогенерация инструкций, поддержка автотестирования 1С 8.3 (кнопконажималка и прочее) и многое другое.

и xUnitFor1C и vanessa-behavior отлично и очень давно работают с различными билд-серверами - Jenkins, TeamCity, MS TFS/MS Team Services, Bamboo и т.п.
Получают красивую отчетность по тестированию, в т.ч. и учет трендов по тестам.


Кстати, я очень рекомендую посмотреть на vanessa-behavior.

человеческий язык сильно упрощает жизнь.

30 секунд рекламы :)
А еще лучше воспользоваться нашим курсом, чей логотип светится сейчас справа - Разработка по промышленным стандартам.
старт потока 11 сентября!

научитесь продуктивно и качественно работать в 1С.
29. Артур Аюханов (artbear) 882 30.08.17 19:41 Сейчас в теме
большим лукавством я считаю скрытие или недостаточное внимание инфраструктурным вопросам и сложности тестов, заменяя это рекламой красивых отчетов, западных терминов и автоинструкций.

Зачем нам лукавить, все, кто с нами работает, знает нашу открытость, доступность и желание делиться знаниями.
Например, мы указанные вопросы активно исследуем и решаем в рамках наших платных имплементаций инженерных практик для различных команд, а очень часто и вообще бесплатно раздаем :)

Заготовка макетов для каждого такого случая просто не выглядит реальной, особенно в свете меняющейся конфигурации.

Ванесса и т.н. "заготовка макета" это все-таки разные вещи, не нужно их смешивать.
БДД - это методика.

А т.н. "заготовка макета" - это один из инструментов, который можно использовать.
Разные инструменты подходят для разных задач. Можно использовать подготовка макетов данных, можно использовать программное создание данных, можно использовать интерфейсное создание данных.
Использовать макеты - это одна из рекомендаций, необязательно ей следовать.

Коллеги, которые проходили у нас обучение, юзают разные способы.
Например, кто-то юзает универсальный обмен данными XML, кто-то юзает даже конвертацию данных, многие кнопкнонажималкой создают, а также пользуются подготовкой через макеты.

Скажи, чем подготовка макетов данных отличается от программного или интерфейсного создания данных в разрезе тобой же указанных разнообразия данных?
ИМХО разница не слишком большая, у всех есть и плюсы и минусы, которые играют роль в конкретных сценариях.

По своему опыту скажу - когда слишком большое разнообразие данных, становится очень не очень удобно или вообще неудобно собирать данные из кирпичиков, чаще проще проще представить единый набор данных для нескольких сценариев.
31. Решитко Дмитрий (grumagargler) 322 30.08.17 20:10 Сейчас в теме
(29)
Скажи, чем подготовка макетов данных отличается от программного или интерфейсного создания данных в разрезе тобой же указанных разнообразия данных?


Я здесь вижу несколько существенных плюсов.

1. Понимание данных.
- Программно: есть понимание какие данные важны и какова их глубина. Например, если мне для тестирования нужен клиент, и я в тесте его создаю, то я вижу, как я его создаю, я вижу, что передаю только имя контрагента. А валюта, договор, идентификационный код и другое - не передаются, а значит, для теста не важны.
- В макете: плоская таблица с выгруженными данными, является ли этот набор минимальным для создания объекта или это всё нужно для теста - не очевидно.

2. Низкая связность.
- Программно: создавая данные через сценарий, я задаю только то, что требуется, всю остальную работу по формированию сопуствующих данных выполняют обработчики _клиентских_ и серверных событий создаваемого объекта. Мне чтобы создать товар, нужно просто передать наименование, единицу измерения, полное наименование, какие-то записи в регистры уже сделает приложение. Вывод тут такой: при изменении структуры метаданных, мне не нужно думать о том, что я не использую, мне всё равно как там хранится тип товара, признак услуги это перечисление или галка и его вообще удалили.
- Макет: просто выгруженные данные, плоские, при несоответствии какого-то реквизита по типу или наличию как таковому - проблемы.

3. Лучшее покрытие.
- Программно: создавая объект он создается также, как его бы создавал пользователь, что ценно для тестирования
- Макет: загружается в особом режиме, с каким-нибудь ОбменДанными.Загрузка = истина, или не дай бог в транзакции

4. Понимание теста в целом.
- Программно: кроме того, что я вижу какие данные создаются, я вижу еще и как это происходит. Очередность, что за чем. Это дает возможность другим программистам понять мой сценарий и воспроизвести его у себя, в своих условиях
- Макет: не так очевидно, если что-то пошло не так, непонятно, это потому что какой-то реквизит конфликтует или действительно в моем функционале имеет место ошибка
kuntashov; BabySG; tsukanov; +3 Ответить
32. Решитко Дмитрий (grumagargler) 322 30.08.17 20:22 Сейчас в теме
(29)
Ванесса и т.н. "заготовка макета" это все-таки разные вещи, не нужно их смешивать.
БДД - это методика.

А т.н. "заготовка макета" - это один из инструментов, который можно использовать.
Разные инструменты подходят для разных задач. Можно использовать подготовка макетов данных, можно использовать программное создание данных, можно использовать интерфейсное создание данных.
Использовать макеты - это одна из рекомендаций, необязательно ей следовать.

Стараюсь не смешивать. Стратегически, у всех предлагаемых способов подготовки данных (из тех, что мне были доступны для прочтения) я вижу один фундаментальный изъян - статичность. Данные живут отдельно от приложения и не эволюционируют с ним. А уже как их там загружать, через макет, конвертацию данных или еще как - неважно. Ну например, используете вы конвертацию и выгружаете каждый раз данные из якобы живой базы. Но сами данные там устаревают, ведь их никто не "передергивает" в связи с изменениями функционала, реквизиты которые стали обязательными для заполнения, какие-то другие связанные данные. Я уже молчу о том, что правила конвертации менять тоже времени стоит, а если идет разработка нового функционала, где у программиста часть реквизитов есть, как версионировать правила? Это же очень тяжело организовать коллективную работу при таком подходе, возможно, да, но эффективность...
А в тестере, вы просто в коде сценария пишите если МояВерсия () тогда....и вся бригада прогеров спокойно работает с одним сценарием создания объекта
30. Артур Аюханов (artbear) 882 30.08.17 19:47 Сейчас в теме
Условия и циклы в тестах и тестовых сценариях вредны.

в тестах должно быть отражение реальной системы :)

1 Если есть некое условие, значит, это не один тестовый сценарий, а несколько.
А раз несколько сценариев у системы, значит, и тестовых сценариев должно быть несколько.
Значит, нужно в тестовой системе нужно зафиксировать эти разные тестовые сценарии

2 если внутри тест.сценария есть условие/цикл, как определить, какой из вариантов условия/цикла выполнялся, а какой нет?
ведь если какой-то не выполнился, значит, проверки этого поведения не было сделано и тестирование задачу проверки поведения системы выполнило только частично :(
33. Решитко Дмитрий (grumagargler) 322 30.08.17 20:47 Сейчас в теме
(30)
1 Если есть некое условие, значит, это не один тестовый сценарий, а несколько.
А раз несколько сценариев у системы, значит, и тестовых сценариев должно быть несколько.
Значит, нужно в тестовой системе нужно зафиксировать эти разные тестовые сценарии

Совершенно верно, и я дополню: условий не должно быть в проверяемом сценарии, но это не значит, что условий не должно быть и в инструменте их создания. Например, начальные данные - это тоже условия прохождения теста, и разница лишь в том, что ты их создаешь руками, а не кодом, вот и всё.
34. Татьяна Лустина (Silverbulleters) 151 31.08.17 10:58 Сейчас в теме
(33) заполнение начальных данных - это часть сценария поведения системы, даже для ERP ... а вы его сознательно пропускаете
new_user; +1 Ответить
35. Решитко Дмитрий (grumagargler) 322 31.08.17 19:58 Сейчас в теме
(34) Я к сожалению не понял эту реплику, особенно по части ERP. Разверните мысль.
36. Сергей Старых (tormozit) 4487 01.09.17 07:12 Сейчас в теме
Вопросы по удобствам. В разделах модуля 1.1 и 3.*, как я понял, контекстной подсказки через точку никак не получится сделать или все таки можно что то придумать?
37. Владимир Крючков (ivanov660) 409 01.09.17 12:25 Сейчас в теме
(36) Если я правильно понял суть вопроса, то сомневаюсь что в общем случае получится дописать как-то плагин(ы), чтобы минимизировать код.
38. Артур Аюханов (artbear) 882 01.09.17 13:44 Сейчас в теме
(36) Сергей, разверни свой вопрос, я его практически не понял :(
1 - Данные для теста
3 - макет данных, верно?
39. Сергей Старых (tormozit) 4487 01.09.17 14:42 Сейчас в теме
(38) В публикации есть "Код функции проверки" и в нем есть разделы модуля. Я спрашивал про удобство набора такого кода. Например будет ли подсказка после точки для "БазовыеУтверждения"?
40. Артур Аюханов (artbear) 882 01.09.17 15:20 Сейчас в теме
(39) Нет, подсказки не будет, т.к. это внешний модуль - модуль внешней обработки :(

Не вижу в этом особой проблемы, т.к. при определенном количестве набора подобных методов они вводятся довольно просто.

Например, для "старых" утверждений пишем Проверить и добавляем нужную проверку - ПроверитьРавенство, ПроверитьТип и т.п.

Некоторые пользуются шаблонами с автоподстановкой, я редко такими шаблонами пользуюсь

для "новых красивых/текучих" утверждений также все просто
шаблон Ожидаем.Что(Значение, ТекстОшибки).Это().Равно(2) или .ЭтоНе().Равно(1) и т.п.

тут можно пользоваться одним шаблоном.
Оставьте свое сообщение