Возникла задача (и, как показал поиск, не у меня одного) формирования печатных форм в формате pdf для отправки клиентам. Причем процесс этот должен был происходить практически полностью автоматически - в один-два клика. То, что я нашел на эту тему в сети меня не устроило по тем или иным причинам, поэтому пришлось писать свое. Первое с чем я столкнулся - это достаточно скудное количество информации на эту тему, очень мало примеров. Несколько дней разбирался сам, теперь решил поделиться опытом с вами. Америку, я конечно не открыл, но пару интересных решений в процессе написания родилось - возможно кому-то пригодится и сэкономит время.
Публикацию я решил оформить в виде статьи, поскольку написанная мной обработка имеет несколько прикладной характер и заточена под конкретную конфигурацию. Так что поделюсь с вами кодом, и постараюсь прокомментировать его максимально подробно.
Итак, сначала немного предыстории. Изучив вопрос, я остановил свой выбор на бесплатных виртуальных принтерах BullZip PDF Printer и PDFCreator, которые позволяют на выходе получать файлы pdf, а также файлы различных графических форматов. Обе утилиты имеют возможность автосохранения файлов без лишних вопросов пользователю. В принципе, для полуавтоматического создания печатных форм в электронном виде, этого достаточно. Мы можем написать в коде
ТабДок.ИмяПринтера = "PDFCreator"; //"BullZip PDF Printer";
ТабДок.Напечатать();
и в каталогах, указанных в настройках автосохранения, появятся нужные файлы. Но, во-первых, пользователь может что-нибудь в настройках изменить, во-вторых, принтер вообще может оказаться переименован или удален чьими-нибудь шаловливыми ручонками (то есть нам нужно как-то контролировать имя и вообще наличие виртуального принтера в системе), в-третьих, придется настроить автосохранение для каждого пользователя (если принтер не сетевой), в-четвертых, проблематично добиться вменяемого имени файла с помощью настроек. Да и вообще, мы же все хотим делать автоматически, а так пользователю придется самому создать письмо, указать адрес клиента, прикрепить нужные вложения - вероятность ошибки возрастает, ну и лениво конечно. Приходим к выводу, что нужно юзать COM-объект, самому устанавливать необходимые настройки и выполнять нужные действия, чтобы не взрывать потом мозг ни себе, ни пользователю.
Изначально имелось пожелание сохранять файлы в графическом формате, скажем jpeg или png. PDFCreator, по-моему мнению, обладает более гибкими возможностями, но, к сожалению, он не умеет разбивать изображения на страницы, поэтому при сохранении печатных форм в виде картинок, можно наблюдать только первую страницу документа. BullZip же такую функцию имеет, поэтому я начал работать с ним. Но вот его COM-интерфейс оказался довольно скудным, да и плюс ко всему, настройки свои утилита хранит в ini-файле. Соответственно тратится время на их чтение и запись, если мы хотим (а мы хотим!) в них что-то менять. Вобщем, чтобы не извращаться и не придумывать всякую ерунду, было принято решение сохранять печатные формы в pdf и использовать для этих целей PDFCreator. Полностью конечно "ерунды" избежать не удалось, но в целом задача была решена.
Собственно дальше код моей функции для формирования файлов с подробными комментариями в проблемных местах. Функция выдрана из модуля обработки с минимальными изменениями, поэтому имеет "узкие" места в виде привязки к конфигурации и конкретному виду документов. Но общий смысл понятен и при необходимости код легко может быть преобразован для конкретной задачи.
upd 14.04.2011
Сегодня понадобилось переписать обработку, сделав ее более универсальной. Теперь в главную функцию передается массив готовых табличных документов для конвертации в pdf. Для передачи имен файлов используется свойство табличного документа "ИспользуемоеИмяФайла", которое необходимо заполнить программно до вызова функции конвертации.
upd 03.05.2011
Выявил неявный баг. У табличного документа есть свойство "ИмяПараметровПечати". Оно отвечает за сохранение параметров печати, установленных пользователем, и их восстановление при следующем показе табличного документа. Так вот, если это свойство используется в конфигурации (а в типовых оно, как правило, используется), то при печати в pdf в указанных параметрах будет сохранен наш виртуальный pdf-принтер, и, если в следующий раз табличный документ будет печататься обычным способом, то 1С восстановит именно этот принтер для печати по-умолчанию (не путать с принтером по-умолчанию в Windows). Чтобы этого избежать, после формирования наших файлов, вернем табличному документу его старое имя принтера.
// Функция формирует файлы для отправки по электронной почте с помощью виртуального принтера PDFCreator,
// Возвращаемое значение: тип "Массив" - массив сформированных файлов pdf
// Параметры: ТабличныеДокументы - тип "Массив", массив табличных документов для конвертации
// Путь - тип "Строка", путь к каталогу, в котором будут создаваться конечные файлы pdf
//
Функция PDFCreator_СформироватьФайлыДляОтправки(ТабличныеДокументы, Путь) Экспорт
// Тут все ясно: пробуем создать COM-объект, получилось - хорошо, нет - на нет, как говорится, и суда нет
Попытка
УтилитаПечати = Новый COMОбъект("PDFCreator.clsPDFCreator");
Исключение
Сообщить("Не установлен драйвер принтера PDFCreator!", СтатусСообщения.Важное);
Возврат Неопределено;
КонецПопытки;
Состояние("Настройка виртуального принтера ...");
// Получим виртуальные принтеры, установленные в системе, если нет ни одного - создадим новый, если есть - будем использовать первый попавшийся
ПринтерыPDF = УтилитаПечати.cGetPDFCreatorPrinters();
Если ПринтерыPDF.Count() = 0 Тогда
УтилитаПечати.cAddPDFCreatorPrinter("PDFCreator");
ПринтерыPDF = УтилитаПечати.cGetPDFCreatorPrinters();
КонецЕсли;
ИмяПринтераPDF = ПринтерыPDF.Item(1);
// Запустим утилиту, в области уведомлений появится соответствующий значок очереди печати
УтилитаПечати.cStart();
// PDFCreator позволяет создавать несколько профилей с настройками - это очень удобно: мы не будем менять настройки по умолчанию, а создадим отдельный профиль для печати из 1С и будем его использовать. То есть для "ручной" печати пользователь может настроить принтер как ему вздумается.
// Проверим, существует ли профиль для печати документов из 1С, если нет - создадим
Если Не УтилитаПечати.cProfileExists("Печать 1С") Тогда
УтилитаПечати.cAddProfile("Печать 1С", УтилитаПечати.cStandardOptions);
КонецЕсли;
// Поскольку теоретически пользователь может изменить настройки и нашего профиля, а некоторые из них для нас критичны, будем записывать их принудительно каждый раз. Это настройки автосохранения, остальные - пусть меняет, если надо.
// Запишем настройки профиля, которые не должны меняться
НастройкиПоУмолчанию = УтилитаПечати.cReadOptions("Печать 1С");
НастройкиПоУмолчанию.UseAutosave = 1;
НастройкиПоУмолчанию.UseAutosaveDirectory = 1;
НастройкиПоУмолчанию.UseCreationDateNow = 1;
НастройкиПоУмолчанию.AutosaveDirectory = Путь;
// Подробно на каждой опции останавливаться не буду, думаю и так понятно. Поясню только принципиальный момент, на котором строится дальнейшая логика работы функции.
// Я долго пытался добиться более менее вменяемого и при этом уникального имени файла стандартными настройками - это оказалось довольно проблематично. В итоге я пришел к такой схеме: в качестве имени файла автосохранения используем предопределенную настройку Title - заголовок нашего документа. Поскольку табличный документ мы создаем программно, средствами 1С изменить его не удастся (есть лишь возможность задать его при выводе на экран, указав в качестве первого параметра метода Показать()). Соответственно, используя такую настройку, мы всегда будем получать файл вида "Табличный документ.pdf". Что ж, значит, придется переименовать его после. Если бы мы печатали один файл, можно было задать его имя сразу в настройках, но мы-то хотим печатать много и сразу, а в этом случае опции просто не будут успевать сохраняться. Короче говоря, экспериментальным путем я пришел именно к такому варианту.
НастройкиПоУмолчанию.AutosaveFileName = "Title"; // Здесь Title должно быть в угловых скобках, но редактор HTML воспринимает это как тег и сбивает разметку
НастройкиПоУмолчанию.AutosaveFormat = 0; // 0 = PDF, 1 = PNG, 2 = JPEG, 3 = BMP, 4 = PCX, 5 = TIFF, 6 = PS, 7 = EPS, 8 = TXT, 9 = PDF/A-1b, 10 = PDF/X, 11 = PSD, 12 = PCL, 13 = RAW
НастройкиПоУмолчанию.AutosaveStartStandardProgram = 0;
УтилитаПечати.cSaveOptions(НастройкиПоУмолчанию, "Печать 1С");
Состояние("Создание файлов ...");
// Делаем наши настройки текущими. Возможно как-то можно сделать активным конкретный профиль программно, но мне это не удалось, а так - заработало и ладно. По сути здесь мы подменяем настройки по умолчанию своими.
УтилитаПечати.cOptionsProfile = "Печать 1С"; // эта строка, по-моему, не работает, но так "красивше" =)
УтилитаПечати.cOptions = НастройкиПоУмолчанию;
// Собственно, начинаем штамповать наши файлы
МассивФайлов = Новый Массив;
Для Индекс = 0 По ТабличныеДокументы.Количество() - 1 Цикл
// Получаем табличный документ по индексу из массива. Цикл Для ... По ... используем для того, чтобы иметь возможность сразу получать индекс элемента из счетчика без применения метода Найти().
ТабДок = ТабличныеДокументы[Индекс];
// Запоминаем старое имя принтера, т.к. при использовании параметров печати, они будут сохраняться с нашим pdf-принтером
СтароеИмяПринтера = ТабДок.ИмяПринтера;
// Далее уже знакомый нам кусок кода. Все настройки сделаны - можем смело печатать.
ТабДок.ИмяПринтера = ИмяПринтераPDF;
ТабДок.Напечатать();
// Здесь одна особенность, которую я победил не очень хорошим способом. Помните, что у нас все файлы называются "Табличный документ.pdf"? Это нас не устраивает - надо переименовать, но поскольку принтер работает не мгновенно, необходимо сначала дождаться, пока файл сформируется и запишется на диск. Так что запускаем цикл и ждем пока файл появится. Да, грузится проц, но что поделать - это ненадолго.
// На случай, если что-то пойдет не так, ставим ограничение в 30 секунд, по истечении которых цикл прерываем принудительно
ФайлСформирован = Истина;
ФайлPDF = Новый Файл(Путь + "Табличный документ.pdf");
Порог = ТекущаяДата() + 30;
Пока Не ФайлPDF.Существует() И ФайлСформирован Цикл
ОбработкаПрерыванияПользователя();
Если ТекущаяДата() >= Порог Тогда
ФайлСформирован = Ложь;
КонецЕсли;
КонецЦикла;
// Наш файл уже существует, но еще не записан - ждем еще, но не более 30 секунд
Порог = ТекущаяДата() + 30;
Пока ФайлPDF.Размер() = 0 И ФайлСформирован Цикл
ОбработкаПрерыванияПользователя();
Если ТекущаяДата() >= Порог Тогда
ФайлСформирован = Ложь;
КонецЕсли;
КонецЦикла;
// Произошла исключительная ситуация - файл не был создан в течение длительного времени
Если Не ФайлСформирован Тогда
Сообщить("Ожидание отклика завершено. Файл не создан!", СтатусСообщения.Важное);
Попытка
УтилитаПечати.cClose();
Исключение
Сообщить("Нормальное завершение процесса печати невозможно!", СтатусСообщения.ОченьВажное);
КонецПопытки;
УтилитаПечати = Неопределено;
НастройкиПоУмолчанию = Неопределено;
Состояние();
Возврат Неопределено;
КонецЕсли;
// Вот теперь переименуем его. Используем свойство табличного документа "ИспользуемоеИмяФайла" (должно быть заполнено программно до вызова процедуры, предполагается, что имя файла указано без расширения), либо, если оно не заполнено, просто порядковый номер элемента.
НовоеПолноеИмя = Путь + ?(ЗначениеЗаполнено(ТабДок.ИспользуемоеИмяФайла), ТабДок.ИспользуемоеИмяФайла, "Табличный документ " + Строка(Индекс + 1)) + ".pdf";
ПереместитьФайл(ФайлPDF.ПолноеИмя, НовоеПолноеИмя) ;
// Добавим в массив вложений, который вернет в итоге наша функция
ФайлPDF = Новый Файл(НовоеПолноеИмя);
МассивФайлов.Добавить(ФайлPDF);
// Возвращаем старое имя принтера, чтобы не менялись параметры печати по-умолчанию
ТабДок.ИмяПринтера = СтароеИмяПринтера;
КонецЦикла;
// Закрываем утилиту - иконка в трее пропала. Что примечательно, закрывать раньше времени очередь печати нельзя, а то пропадут все задания, но так как мы с нетерпением ждем появления каждого файла и в этот момент уже дождались, то тут все ок.
УтилитаПечати.cClose();
УтилитаПечати = Неопределено;
НастройкиПоУмолчанию = Неопределено;
Состояние();
Возврат МассивФайлов;
Конецфункции
Ну а дальше уже дело техники, что с этими файлами делать... Я, например, использую встроенный в УТ почтовый клиент, создаю новое письмо, заполняю адрес из контактной информации контрагента, добавляю туда вложения и открываю письмо пользователю для просмотра и принятия решения об отправке, а pdf-ки с диска удаляю.
Естественно, мой код не претендует на истину в последней инстанции - может где и коряво получилось, но вобщем-то он работает и свою задачу выполняет. Более элегантного решения я во всяком случае не нашел. Принимаю конструктивную критику и предложения
upd 08.10.2010
Создал аналогичную функцию с использованием внешней компоненты Yoksel. Код проще и прозрачнее, файлы формируются намного быстрее, нет заморочек с искусственными задержками времени, но печатная форма добавляется в документ картинкой, причем не очень хорошего качества, плюс требуется создание временного файла на диске для последующей конвертации.
// Функция формирует файлы для отправки по электронной почте с помощью внешней компоненты Yoksel.dll
//
Функция Йоксель_СформироватьФайлыДляОтправки(ТабличныеДокументы, Путь)
Попытка
ЗагрузитьВнешнююКомпоненту(КаталогПрограммы() + "Yoksel.dll");
Йоксель = ПолучитьCOMОбъект("","Йоксель");
КонвертерPDF = Йоксель.СоздатьГрафическийКонвертерPDF();
Исключение
Предупреждение("Не удалось загрузить внешнюю компоненту Yoksel! Сообщите администратору системы!", 20);
Возврат Неопределено;
КонецПопытки;
МассивФайлов = Новый Массив;
Состояние("Создание файлов ...");
Для Индекс = 0 По ТабличныеДокументы.Количество() - 1 Цикл
// Получаем табличный документ
ТабДок = ТабличныеДокументы[Индекс];
// Формируем временный файл xls
ИмяФайлаБезРасширения = ?(ЗначениеЗаполнено(ТабДок.ИспользуемоеИмяФайла), ТабДок.ИспользуемоеИмяФайла, "Табличный документ " + Строка(Индекс + 1));
ТабДок.Записать(Путь + ИмяФайлаБезРасширения + ".xls", ТипФайлаТабличногоДокумента.XLS97);
// Конвертируем временный файл в формат pdf
Попытка
Таб = Йоксель.СоздатьТабличныйДокумент();
Таб.Открыть(Путь + ИмяФайлаБезРасширения + ".xls", "2");
КонвертерPDF.Документ = Таб;
КонвертерPDF.КоличествоБитНаПиксел = 24; //1, 4, 8, 24
КонвертерPDF.ПолеСлева = 1134; // в твипах (1 твип = 1/567 см)
КонвертерPDF.ЗаписатьВФайл(Путь + ИмяФайлаБезРасширения + ".pdf");
Исключение
УдалитьФайлы(Путь + ИмяФайлаБезРасширения + ".xls");
Сообщить(ОписаниеОшибки(), СтатусСообщения.Важное);
Возврат Неопределено;
КонецПопытки;
// Удаляем временный файл xls
УдалитьФайлы(Путь + ИмяФайлаБезРасширения + ".xls");
// Добавляем в массив вложений
ФайлPDF = Новый Файл(Путь + ИмяФайлаБезРасширения + ".pdf");
МассивФайлов.Добавить(ФайлPDF);
КонецЦикла;
Йоксель = Неопределено;
Состояние();
Возврат МассивФайлов;
КонецФункции
