Быстрое определение интервалов в запросе

01.10.15

Разработка - Запросы

В статье описывается новый метод определения интервалов между данными различных записей в запросе. В отличие от общеизвестного метода, время работы предлагаемого метода зависит от объема данных ЛИНЕЙНО. Это обеспечивает ему значительный выигрыш по быстродействию на больших объемах данных.
В качестве иллюстрации возможностей метода приведен отчет, показывающий гистограмму распределения времени между продажами.

Скачать файлы

Наименование Файл Версия Размер
Отчет "Гистограмма интервалов между продажами" для УТ10.3
.erf 11,30Kb
39
.erf 8.2 11,30Kb 39 Скачать

Суть задачи определения интервалов состоит в том, что есть таблица, содержащая множество дат, дат со временем или просто чисел. Требуется построить по этой таблице интервалы, на которые исходные даты (числа) разбивают временную (числовую) ось.

 Дата                      НачалоИнтервала  КонецИнтервала 
t1   t1 t2
t2   t2 t3
t3 ------> t3 t4
...   ... ...
tn   tn-1 tn


К примеру, есть даты установки цен. По ним можно определить интервалы постоянства цен в виде: начало действия цены - начало действия следующей цены. Чтобы в результате определить, например, среднюю по времени цену. Или, к примеру, есть дата и время документов отгрузки. Тогда можно определить величины промежутков времени между отгрузками: определить, к примеру, минимальный или максимальный интервал между отгрузками одного товара или одному контрагенту, построить гистограмму распределения времени между отгрузками. 

Судя по обсуждению "В каких задачах может потребоваться определять интервалы", такого рода задачи встречается на практике достаточно часто.

Общеизвестным методом решения этой задачи в запросе является запрос следующего вида:

ВЫБРАТЬ
    Слева.Дата КАК НачалоИнтервала,
    МИНИМУМ(Справа.Дата) КАК КонецИнтервала
ИЗ 
    Даты КАК Слева 
    ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Справа
        ПО Слева.Дата < Справа.Дата
СГРУППИРОВАТЬ ПО 
    Слева.Дата

В большинстве случаев этого достаточно. Однако когда число элементов в исходной таблице становится достаточно большим, время выполнения запроса существенно возрастает. Это связано с квадратичным характером зависимости времени работы запроса от объема исходной таблицы: для каждой записи при расчете агрегатной функции МИНИМУМ просматривается в среднем половина других записей!

Идея, лежайшая в основе данного метода, ранее была использована при ускорении расчета нарастающего итога в запросе, описанном в статье Баттерфляй - метод быстрого расчета нарастающего итога в запросе . Однако в данном случае запрос получился более простым и универсальным.

В основе метода лежит поразрядная сортировка, а его схема имеет много общего с олимпийской системой соревнований (методом плей-офф). В каждом туре группируются записи, отличающиеся (при вычитании единицы) младшим разрядом номера: 1-2, 3-4, 5-6, 7-8 и так далее. В каждой паре определяется (и далее попадает в результирующую выборку) промежуток: интервал от верхней границы младшего элемента до нижней границы верхнего. А также определяется новая общая нижняя и верхняя граница. В следующем туре пара получает номер, полученный отбрасыванием младшего разряда номеров элементов пары. И так до финала. Промежуток определяется только тогда, когда в группировке есть оба элемента, иначе из пары в следующий тур выходит единственный элемент с теми же границами.

Вышесказанное иллюстрируется схемой одной группировки (матча):

СхемаГруппировки

и общей схемой группировок:

Общая схема группировок

Для тридцати двух туров и интервалов, измеряемых секундами, запрос имеет вид:

ВЫБРАТЬ
	РАЗНОСТЬДАТ(ДАТАВРЕМЯ(1980, 1, 1), Дано.НачалоИнтервала, СЕКУНДА) + 1 КАК НомерПары,
	Дано.НачалоИнтервала КАК НижняяГраница,
	Дано.НачалоИнтервала КАК ВерхняяГраница
ПОМЕСТИТЬ Тур0
ИЗ
	&Интервалы КАК Дано
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур0.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур0.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур0.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур0.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур0.НижняяГраница) КАК КонецИнтервала
ПОМЕСТИТЬ Тур1
ИЗ
	Тур0 КАК Тур0

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур0.НомерПары / 2 КАК ЧИСЛО(10, 0))
;
...
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур31.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур31.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур31.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур31.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур31.НижняяГраница) КАК КонецИнтервала
ПОМЕСТИТЬ Финал
ИЗ
	Тур31 КАК Тур31

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур31.НомерПары / 2 КАК ЧИСЛО(10, 0))
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Тур1.НачалоИнтервала,
	Тур1.КонецИнтервала
ИЗ
	Тур1 КАК Тур1
ГДЕ
	Тур1.НачалоИнтервала < Тур1.КонецИнтервала

ОБЪЕДИНИТЬ
...
ВЫБРАТЬ
	Финал.НачалоИнтервала,
	Финал.КонецИнтервала
ИЗ
	Финал КАК Финал
ГДЕ
	Финал.НачалоИнтервала < Финал.КонецИнтервала

Тридцать два тура выбрано потому, что этого будет достаточно, чтобы охватить период с 1 января 1980-го до 2 февраля 2116 года (для интервалов, измеряемых секундами). Задание числа туров с большим запасом позволяет использовать всегда один и тот же текст запроса, а не формировать его динамически в зависимости от реально анализируемого промежутка времени. При этом избыточные запросы на быстродействии никак не сказываются, поскольку в лишних турах будет участвовать только один элемент.

Кажется удивительным, что такая громоздкая конструкция из тридцати трех запросов может побеждать по времени исходный запрос. Объяснением этому является тот факт, что в каждом следующем туре число участников сокращается вдвое (плюсы плей-офф). Следовательно, число матчей будет равно числу участников минус один! То есть число операций в данной схеме будет пропорциональным числу исходных записей, а не квадрату этого числа. Чем и объясняется быстродействие метода.

Сказанное подтверждается результатами испытаний, приведенными на Фиг.2 (для файлового варианта) и Фиг.3 (для MSSQL).

График быстродействия для файловой ИБ

График быстродействия для SQL

Из графиков следует, что предлагаемый метод превосходит традиционный, начиная примерно с 250 записей в файловом варианте и с 1500 записей в варианте SQL. Следовательно, например, средний курс валюты за год в файловом варианте уже будет выгоднее считать предлагаемым методом.

Но вообще-то это запрос не "на каждый день". Только для действительно больших объемов данных и случаев, когда результат требуется для дальнейшего использования в запросе. Иначе проще использовать внезапросную технику (например, СКД).   

Определенной проблемой данного метода является "разреженность" данных, когда интервалы достаточно велики. Тогда в первых турах будет много "холостых" встреч без соперника, что приведет к небольшому замедлению метода при сохранении в целом линейной зависимости. У этой зависимости всего лишь немного увеличится коэффициент. 

Также следует сказать, что данное решение предназначено пока только для случаев тэта-соединений таблицы с самой собой. Внешне похожая на данную задача "множественных срезов последних" предлагаемым способом не решается, хотя также имеет определенные проблемы с быстродействием и перспективы его повышения данным методом на больших объемах данных. Для распространения описанного подхода на этот случай требуются определенные усложнения, о которых, возможно, будет рассказано позже. 

В качестве примера использования предлагаемого метода к статье прилагается отчет на основе СКД, который строит гистограмму интервалов между продажами в разрезе организаций со всеми возможными отборами. Отчет построен на обычных формах для конфигурации "Управление торговлей 10.3". Используется оборотный регистр "Продажи". Благодаря применяемому методу достигается высокая скорость построения отчета на любых объемах данных.

в запросе интервал

См. также

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

13000 руб.

02.09.2020    119908    656    389    

701

Для чего используют конструкцию запроса "ГДЕ ЛОЖЬ" в СКД на примере конфигурации 1С:ERP

Запросы СКД Платформа 1С v8.3 Запросы Система компоновки данных 1С:ERP Управление предприятием 2 Бесплатно (free)

В типовых конфигурациях разработчики компании 1С иногда используют в отчетах, построенных на СКД, такую конструкцию, как "ГДЕ ЛОЖЬ". Такая конструкция говорит о том, что данные в запросе не будут получены совсем. Для чего же нужен тогда запрос?

13.02.2024    5618    KawaNoNeko    23    

23

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    1964    2    Yashazz    0    

29

Запрос 1С copilot

Инструментарий разработчика Запросы Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Пишем на человеческом языке, что нам надо, и получаем текст запроса на языке 1С. Используются большие языковые модели (LLM GPT) от OpenAI или Яндекс на выбор.

5 стартмани

15.01.2024    6089    29    mkalimulin    23    

48

PrintWizard: поддержка представлений ЗУП в конструкторе

Инструментарий разработчика Запросы Платформа 1С v8.3 Бесплатно (free)

Одной из интересных задач, стоящих в процессе разработки, была поддержка механизма представлений в ЗУП. Но не просто возможность исполнения запросов с ними. Основная проблема была в том, чтобы с ними было удобно работать, а именно: создавать, модифицировать и отлаживать. Кратко о том, что в итоге получилось...

14.12.2023    1714    vandalsvq    7    

28

Объектная модель запроса "Схема запроса" 2

Запросы Платформа 1С v8.3 Запросы Конфигурации 1cv8 Бесплатно (free)

Далеко уже не новый тип данных "Схема запроса". Статья о том, как использовать его "попроще". Примеры создания текста запроса с нуля и изменение имеющегося запроса.

06.12.2023    5282    user1923546    26    

43

Начните уже использовать хранилище запросов

HighLoad оптимизация Запросы

Очень немногие из тех, кто занимается поддержкой MS SQL, работают с хранилищем запросов. А ведь хранилище запросов – это очень удобный, мощный и, главное, бесплатный инструмент, позволяющий быстро найти и локализовать проблему производительности и потребления ресурсов запросами. В статье расскажем о том, как использовать хранилище запросов в MS SQL и какие плюсы и минусы у него есть.

11.10.2023    15954    skovpin_sa    14    

97
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. spezc 781 01.10.15 07:07 Сейчас в теме
Спасибо за статью, интересно.
2. Evil Beaver 8100 01.10.15 12:40 Сейчас в теме
Вот люблю я статьи маэстро! Они делают меня лучше
Kinestetik; Aletar; troubleshooter; uncle_Vasya; dddxddd; +5 Ответить
3. Поручик 4670 01.10.15 14:08 Сейчас в теме
Определить автора можно по заголовку, даже не заглядывая на страницу.
manlak; Kinestetik; uncle_Vasya; dddxddd; wowik; Nuobu; igormiro; veretennikoff; ffgnebel; hotey; frying; herfis; vladir; Irwin; nbeliaev; powerpc; Xershi; infostart user; kuzyara; 1cmax; wolfsoft; zaxarovsky; artbear; DrAku1a; so-quest; HiKS; CSiER; Йожкин Кот; rtnm; Evil Beaver; +30 Ответить
4. amiralnar 9 02.10.15 08:46 Сейчас в теме
Бесподобно!
BlizD; wowik; Makushimo; +3 Ответить
5. 1cmax 152 07.10.15 08:47 Сейчас в теме
Предполагаю, что у автора фундаментальное мат. образование, мало таких в мире 1с
6. ildarovich 7846 07.10.15 10:30 Сейчас в теме
(5) 1cmax, нет, образование у меня техническое
7. _also 484 20.10.15 16:40 Сейчас в теме
Ничего не понял, но, на всякий случай, плюсанул )))))
Vinzor; adamst; korppinen; +3 1 Ответить
8. qwinter 671 27.10.15 14:48 Сейчас в теме
А банальный обход этой таблицы в цикле решает эту задачу медленнее?

9. ildarovich 7846 27.10.15 15:20 Сейчас в теме
(8) qwinter, думаю, что
банальный обход этой таблицы в цикле
вне запроса решает эту задачу быстрее. Даже с учетом необходимости сортировки. СКД или оконные функции в других СУБД тоже могут помочь. Однако, если интервалы нужны в самом запросе для последующей обработки, то выгоднее использовать этот подход.
10. qwinter 671 27.10.15 21:37 Сейчас в теме
(9) запрос конечно веселый)) 900 строчек)))
11. Sevg 16 29.10.15 10:54 Сейчас в теме
Хороший новый способ взгляда на проблему.
12. ildarovich 7846 01.12.15 12:53 Сейчас в теме
Кажется, нашел еще одно важное применение данного алгоритма. Это поиск пропущенных номеров! Задача актуальна, если судить по дискуссии в Интересная задачка для решения на SQL (Найти в диапазоне номеров пропуск).
Приведенный в статье алгоритм позволит найти все пропуски как интервалы между номерами, которые больше, чем 1. И сделает это быстро!
Это если стоит задача найти все пропуски. Если нужно найти только первый, то данный алгоритм будет не нужен. Подойдет запрос с условием
ГДЕ Номер + 1 НЕ В (ВЫБРАТЬ * ИЗ МножествоНомеров)
Но в нем тоже могут быть подводные камни, связанные с возможным использованием NESTED LOOP для этой проверки. Это можно обойти через прием с группировкой.
13. kint 18 06.01.16 13:33 Сейчас в теме
В свое время пришлось разбираться с интервалами.
Стандартные задачи поиска свободных мест размещения, подбора интервалов оказания услуг, графики, расписания и т.п.
Оставлю здесь ссылку на свои заметки,- возможно, кому-то пригодится.
Самое вкусное (алгоритмы свертки и соединения), правда, там осталось за кадром (руки не дошли). Но основные понятия даны.

Дмитрий Малюгин
CratosX; Kinestetik; Gesperid; ildarovich; +4 Ответить
14. ildarovich 7846 06.01.16 16:11 Сейчас в теме
(13) kint, большое спасибо, интересно
18. Gesperid 2 14.03.17 14:19 Сейчас в теме
(13) Круто. Не могли бы, Вы, накидать источников (литературы, ссылок)? Особенно интересно по темам в разделе "К описанию" :)
15. BlizD 1023 06.07.16 17:30 Сейчас в теме
Добрый день.

Спасибо, за такой удивительный запрос.
Ощущается магия какая-то.

Применил данный метод на поиск свободных штрихкодов.

Тридцать два тура выбрано потому, что этого будет достаточно, чтобы охватить период с 1 января 1980-го до 2 февраля 2116 года (для интервалов, измеряемых секундами).

Правильно понимаю, что 32 тура позволяет искать до того, пока разница секунд не будет больше 4294512000?
Т.е. в моем случае пока штрихкоды от 0 до 4294512000?

Сформулирую по другому вопрос:

если ищу свободные штрихкоды в интервале
от 210000000000
до 210001000000
это 1 миллион штрихкодов, будет ли достаточно 32 туров?
16. ildarovich 7846 06.07.16 19:59 Сейчас в теме
(15) BlizD, все правильно, 32 тура это 4 294 967 296 секунд - больше четырех миллиардов.
А для миллиона штрих-кодов будет достаточно 20-ти туров, так как 2^20 = 1 048 576 > 1 000 000.
В принципе, если штрих-код у вас в базе, то это, скорее всего, строка. Поэтому для поиска пропущенных штрих-кодов можно воспользоваться отчетом из статьи Поиск пропусков в нумерации документов запросом, заменив в запросе выборку номеров документов на выборку штрих-кодов. В отчете из той статьи сразу решается задача преобразования строки в число в запросе. Для 12-ти значного штрих-кода понадобится 40 туров.
17. BlizD 1023 06.07.16 22:42 Сейчас в теме
(16)
Спасибо, значит все правильно сделал.
Да, штрих-код у нас это строка и преобразование в число делал из той статьи , что указали:D
Ищу в заданном интервале, поэтому остановлюсь на 32 турах.
42. PerlAmutor 129 04.07.22 06:53 Сейчас в теме
(16) А как можно эффективно решить следующую задачу? Есть диапазоны кодов номенклатуры в виде 10000-20000, 30000-40000 заданные числами. При создании номенклатуры надо найти первый свободный код в заданном диапазоне и присвоить. Коды соответственно хранятся в базе в виде строки, плюс среди номенклатуры попадаются коды с текстом типа "дубль123".
Наша текущая реализация достаточно медленная и приводит к замедлению создания номенклатуры. Сейчас она создается около 1 секунды, что довольно медленно. Общее количество элементов в справочнике около 1 млн.
19. emir99 4 20.08.17 07:37 Сейчас в теме
Мне надо узнать длительность каждого действия. Отрезков может быть несколько десятков тысяч поэтому выбрал этот алгоритм, но меня отчего-то результат не верный.
Прикрепленные файлы:
20. ildarovich 7846 20.08.17 11:30 Сейчас в теме
(19) Если отчет на СКД, попробуйте в последний запрос добавить в принципе ненужные поля НижняяГраница, ВерхняяГраница. СКД может исключать эти поля из промежуточных запросов, что приводит к таким казусам.
21. emir99 4 20.08.17 11:37 Сейчас в теме
Нет, не на СКД - пока только запрос.
22. ildarovich 7846 20.08.17 12:08 Сейчас в теме
(21) Ну тогда используемый текст запроса пришлите. Там точно все каскады? Многоточие не забыли запросами заменить? И исходную таблицу, которая в (19), если можно.
23. emir99 4 21.08.17 08:03 Сейчас в теме
Вот весь запрос (я посчитал, что 22-ух хватит на каждую секунду на месяц):


ВЫБРАТЬ
	ЗН.arte_ПараметрАвтографа,
	ВЫРАЗИТЬ(ЗН.Значение КАК ЧИСЛО(15, 6)) КАК РОТ1,
	0 КАК РОТ2,
	0 КАК MOVE,
	ЗН.Дата КАК ДатаОКР
ПОМЕСТИТЬ МАТ
ИЗ
	РегистрСведений.arte_ЗначенияВАвтографе КАК ЗН
ГДЕ
	ЗН.уатТС = &уатТС
	И ЗН.arte_ПараметрАвтографа = &Рот1
	И ЗН.Дата МЕЖДУ &Д1 И &Д2
	И ЕСТЬNULL(ЗН.Значение, 0) <> 0

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ЗН.arte_ПараметрАвтографа,
	0,
	ВЫРАЗИТЬ(ЗН.Значение КАК ЧИСЛО(15, 6)),
	0,
	ЗН.Дата
ИЗ
	РегистрСведений.arte_ЗначенияВАвтографе КАК ЗН
ГДЕ
	ЗН.уатТС = &уатТС
	И ЗН.arte_ПараметрАвтографа = &Рот2
	И ЗН.Дата МЕЖДУ &Д1 И &Д2
	И ЕСТЬNULL(ЗН.Значение, 0) <> 0

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ЗН.arte_ПараметрАвтографа,
	0,
	0,
	ВЫБОР
		КОГДА ВЫРАЗИТЬ(ЗН.Значение КАК БУЛЕВО)
			ТОГДА 1
		ИНАЧЕ 0
	КОНЕЦ,
	ЗН.Дата
ИЗ
	РегистрСведений.arte_ЗначенияВАвтографе КАК ЗН
ГДЕ
	ЗН.уатТС = &уатТС
	И ЗН.arte_ПараметрАвтографа = &MOVE
	И ЗН.Дата МЕЖДУ &Д1 И &Д2
	И ЗН.Значение ЕСТЬ НЕ NULL 
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	РАЗНОСТЬДАТ(ДАТАВРЕМЯ(1980, 1, 1), МАТ.ДатаОКР, СЕКУНДА) + 1 КАК НомерПары,
	МАТ.ДатаОКР КАК НижняяГраница,
	МАТ.ДатаОКР КАК ВерхняяГраница,
	ВЫБОР
		КОГДА СУММА(МАТ.РОТ1) > 0 И СУММА(МАТ.MOVE) > 0 ТОГДА "Движение"
		КОГДА СУММА(МАТ.РОТ1) > 0 И СУММА(МАТ.MOVE) = 0 ТОГДА "ХХШ"
		КОГДА СУММА(МАТ.РОТ2) > 0 ТОГДА "РаботаВО"
		ИНАЧЕ "Пусто"
	КОНЕЦ КАК Действие
ПОМЕСТИТЬ Тур0
ИЗ
	МАТ КАК МАТ

СГРУППИРОВАТЬ ПО
	МАТ.ДатаОКР
;

////////////////////////////////////////////////////////////­//////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур0.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур0.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур0.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур0.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур0.НижняяГраница) КАК КонецИнтервала,
	Тур0.Действие
ПОМЕСТИТЬ Тур1
ИЗ
	Тур0 КАК Тур0

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур0.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур0.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур1.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур1.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур1.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур1.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур1.НижняяГраница) КАК КонецИнтервала,
	Тур1.Действие
ПОМЕСТИТЬ Тур2
ИЗ
	Тур1 КАК Тур1

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур1.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур1.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур2.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур2.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур2.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур2.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур2.НижняяГраница) КАК КонецИнтервала,
	Тур2.Действие
ПОМЕСТИТЬ Тур3
ИЗ
	Тур2 КАК Тур2

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур2.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур2.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур3.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур3.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур3.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур3.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур3.НижняяГраница) КАК КонецИнтервала,
	Тур3.Действие
ПОМЕСТИТЬ Тур4
ИЗ
	Тур3 КАК Тур3

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур3.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур3.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур4.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур4.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур4.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур4.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур4.НижняяГраница) КАК КонецИнтервала,
	Тур4.Действие
ПОМЕСТИТЬ Тур5
ИЗ
	Тур4 КАК Тур4

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур4.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур4.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур5.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур5.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур5.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур5.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур5.НижняяГраница) КАК КонецИнтервала,
	Тур5.Действие
ПОМЕСТИТЬ Тур6
ИЗ
	Тур5 КАК Тур5

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур5.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур5.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур6.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур6.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур6.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур6.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур6.НижняяГраница) КАК КонецИнтервала,
	Тур6.Действие
ПОМЕСТИТЬ Тур7
ИЗ
	Тур6 КАК Тур6

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур6.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур6.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур7.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур7.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур7.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур7.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур7.НижняяГраница) КАК КонецИнтервала,
	Тур7.Действие
ПОМЕСТИТЬ Тур8
ИЗ
	Тур7 КАК Тур7

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур7.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур7.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур8.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур8.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур8.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур8.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур8.НижняяГраница) КАК КонецИнтервала,
	Тур8.Действие
ПОМЕСТИТЬ Тур9
ИЗ
	Тур8 КАК Тур8

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур8.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур8.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур9.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур9.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур9.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур9.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур9.НижняяГраница) КАК КонецИнтервала,
	Тур9.Действие
ПОМЕСТИТЬ Тур10
ИЗ
	Тур9 КАК Тур9

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур9.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур9.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур10.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур10.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур10.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур10.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур10.НижняяГраница) КАК КонецИнтервала,
	Тур10.Действие
ПОМЕСТИТЬ Тур11
ИЗ
	Тур10 КАК Тур10

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур10.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур10.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур11.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур11.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур11.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур11.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур11.НижняяГраница) КАК КонецИнтервала,
	Тур11.Действие
ПОМЕСТИТЬ Тур12
ИЗ
	Тур11 КАК Тур11

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур11.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур11.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур12.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур12.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур12.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур12.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур12.НижняяГраница) КАК КонецИнтервала,
	Тур12.Действие
ПОМЕСТИТЬ Тур13
ИЗ
	Тур12 КАК Тур12

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур12.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур12.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур13.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур13.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур13.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур13.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур13.НижняяГраница) КАК КонецИнтервала,
	Тур13.Действие
ПОМЕСТИТЬ Тур14
ИЗ
	Тур13 КАК Тур13

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур13.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур13.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур14.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур14.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур14.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур14.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур14.НижняяГраница) КАК КонецИнтервала,
	Тур14.Действие
ПОМЕСТИТЬ Тур15
ИЗ
	Тур14 КАК Тур14

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур14.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур14.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур15.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур15.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур15.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур15.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур15.НижняяГраница) КАК КонецИнтервала,
	Тур15.Действие
ПОМЕСТИТЬ Тур16
ИЗ
	Тур15 КАК Тур15

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур15.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур15.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур16.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур16.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур16.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур16.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур16.НижняяГраница) КАК КонецИнтервала,
	Тур16.Действие
ПОМЕСТИТЬ Тур17
ИЗ
	Тур16 КАК Тур16

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур16.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур16.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур17.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур17.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур17.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур17.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур17.НижняяГраница) КАК КонецИнтервала,
	Тур17.Действие
ПОМЕСТИТЬ Тур18
ИЗ
	Тур17 КАК Тур17

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур17.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур17.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур18.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур18.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур18.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур18.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур18.НижняяГраница) КАК КонецИнтервала,
	Тур18.Действие
ПОМЕСТИТЬ Тур19
ИЗ
	Тур18 КАК Тур18

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур18.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур18.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур19.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур19.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур19.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур19.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур19.НижняяГраница) КАК КонецИнтервала,
	Тур19.Действие
ПОМЕСТИТЬ Тур20
ИЗ
	Тур19 КАК Тур19

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур19.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур19.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур20.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур20.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур20.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур20.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур20.НижняяГраница) КАК КонецИнтервала,
	Тур20.Действие
ПОМЕСТИТЬ Тур21
ИЗ
	Тур20 КАК Тур20

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур20.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур20.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур21.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур21.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур21.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур21.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур21.НижняяГраница) КАК КонецИнтервала,
	Тур21.Действие
ПОМЕСТИТЬ Тур22
ИЗ
	Тур21 КАК Тур21

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур21.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур21.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	ВЫРАЗИТЬ(Тур22.НомерПары / 2 КАК ЧИСЛО(10, 0)) КАК НомерПары,
	МИНИМУМ(Тур22.НижняяГраница) КАК НижняяГраница,
	МАКСИМУМ(Тур22.ВерхняяГраница) КАК ВерхняяГраница,
	МИНИМУМ(Тур22.ВерхняяГраница) КАК НачалоИнтервала,
	МАКСИМУМ(Тур22.НижняяГраница) КАК КонецИнтервала,
	Тур22.Действие
ПОМЕСТИТЬ Финал
ИЗ
	Тур22 КАК Тур22

СГРУППИРОВАТЬ ПО
	ВЫРАЗИТЬ(Тур22.НомерПары / 2 КАК ЧИСЛО(10, 0)),
	Тур22.Действие
;

////////////////////////////////////////////////////////////­////////////////////
ВЫБРАТЬ
	Тур1.НачалоИнтервала,
	Тур1.КонецИнтервала,
	Тур1.Действие
//ПОМЕСТИТЬ Интервалы
ИЗ
	Тур1 КАК Тур1
ГДЕ
	Тур1.НачалоИнтервала < Тур1.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур2.НачалоИнтервала,
	Тур2.КонецИнтервала,
	Тур2.Действие
ИЗ
	Тур2 КАК Тур2
ГДЕ
	Тур2.НачалоИнтервала < Тур2.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур3.НачалоИнтервала,
	Тур3.КонецИнтервала,
	Тур3.Действие
ИЗ
	Тур3 КАК Тур3
ГДЕ
	Тур3.НачалоИнтервала < Тур3.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур4.НачалоИнтервала,
	Тур4.КонецИнтервала,
	Тур4.Действие
ИЗ
	Тур4 КАК Тур4
ГДЕ
	Тур4.НачалоИнтервала < Тур4.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур5.НачалоИнтервала,
	Тур5.КонецИнтервала,
	Тур5.Действие
ИЗ
	Тур5 КАК Тур5
ГДЕ
	Тур5.НачалоИнтервала < Тур5.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур6.НачалоИнтервала,
	Тур6.КонецИнтервала,
	Тур6.Действие
ИЗ
	Тур6 КАК Тур6
ГДЕ
	Тур6.НачалоИнтервала < Тур6.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур7.НачалоИнтервала,
	Тур7.КонецИнтервала,
	Тур7.Действие
ИЗ
	Тур7 КАК Тур7
ГДЕ
	Тур7.НачалоИнтервала < Тур7.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур8.НачалоИнтервала,
	Тур8.КонецИнтервала,
	Тур8.Действие
ИЗ
	Тур8 КАК Тур8
ГДЕ
	Тур8.НачалоИнтервала < Тур8.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур9.НачалоИнтервала,
	Тур9.КонецИнтервала,
	Тур9.Действие
ИЗ
	Тур9 КАК Тур9
ГДЕ
	Тур9.НачалоИнтервала < Тур9.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур10.НачалоИнтервала,
	Тур10.КонецИнтервала,
	Тур10.Действие
ИЗ
	Тур10 КАК Тур10
ГДЕ
	Тур10.НачалоИнтервала < Тур10.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур11.НачалоИнтервала,
	Тур11.КонецИнтервала,
	Тур11.Действие
ИЗ
	Тур11 КАК Тур11
ГДЕ
	Тур11.НачалоИнтервала < Тур11.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур12.НачалоИнтервала,
	Тур12.КонецИнтервала,
	Тур12.Действие
ИЗ
	Тур12 КАК Тур12
ГДЕ
	Тур12.НачалоИнтервала < Тур12.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур13.НачалоИнтервала,
	Тур13.КонецИнтервала,
	Тур13.Действие
ИЗ
	Тур13 КАК Тур13
ГДЕ
	Тур13.НачалоИнтервала < Тур13.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур14.НачалоИнтервала,
	Тур14.КонецИнтервала,
	Тур14.Действие
ИЗ
	Тур14 КАК Тур14
ГДЕ
	Тур14.НачалоИнтервала < Тур14.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур15.НачалоИнтервала,
	Тур15.КонецИнтервала,
	Тур15.Действие
ИЗ
	Тур15 КАК Тур15
ГДЕ
	Тур15.НачалоИнтервала < Тур15.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур16.НачалоИнтервала,
	Тур16.КонецИнтервала,
	Тур16.Действие
ИЗ
	Тур16 КАК Тур16
ГДЕ
	Тур16.НачалоИнтервала < Тур16.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур17.НачалоИнтервала,
	Тур17.КонецИнтервала,
	Тур17.Действие
ИЗ
	Тур17 КАК Тур17
ГДЕ
	Тур17.НачалоИнтервала < Тур17.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур18.НачалоИнтервала,
	Тур18.КонецИнтервала,
	Тур18.Действие
ИЗ
	Тур18 КАК Тур18
ГДЕ
	Тур18.НачалоИнтервала < Тур18.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур19.НачалоИнтервала,
	Тур19.КонецИнтервала,
	Тур19.Действие
ИЗ
	Тур19 КАК Тур19
ГДЕ
	Тур19.НачалоИнтервала < Тур19.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур20.НачалоИнтервала,
	Тур20.КонецИнтервала,
	Тур20.Действие
ИЗ
	Тур20 КАК Тур20
ГДЕ
	Тур20.НачалоИнтервала < Тур20.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур21.НачалоИнтервала,
	Тур21.КонецИнтервала,
	Тур21.Действие
ИЗ
	Тур21 КАК Тур21
ГДЕ
	Тур21.НачалоИнтервала < Тур21.КонецИнтервала

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	Тур22.НачалоИнтервала,
	Тур22.КонецИнтервала,
	Тур22.Действие
ИЗ
	Тур22 КАК Тур22
ГДЕ
	Тур22.НачалоИнтервала < Тур22.КонецИнтервала
;
Показать
Прикрепленные файлы:
25. ildarovich 7846 21.08.17 09:55 Сейчас в теме
(23) Формально все верно, запрос вроде бы такой, какой нужно, но теперь непонятно, в чем вы видите ошибку в (19).
Судя по запросу, определяются интервалы между отметками времени, соответствующими одинаковым действиям.
В (19) четыре отметки, отмеченные "Пусто" и четыре отметки "ХХШ".
С моей точки зрения, в линейке "Пусто" верно определены три интервала:
5:01 - 6:02 - 6:13 - 7:02,
а в линейке ХХШ определены три интервала:
6:11 - 7:13 - 7:26 - 8:02.
Возможно, задача была в том (тут требуется догадываться, поскольку содержательная сторона в вопросе, к сожалению, опущена), чтобы найти интервалы между ближайшими отметками времени без учета действий, а затем пометить интервалы действиями, соответствующими его первой точке.
Но тогда нужно во всех запросах группировку по действиям убрать, чтобы найти элементарные интервалы, а уже потом маркировать интервалы действиями.
24. emir99 4 21.08.17 09:45 Сейчас в теме
Может быть эта задача так не решается? Может надо по-другому делать? Мне кажется перебором по ТЗ будет медленно - мне надо три таких набора разобрать
26. ildarovich 7846 21.08.17 10:01 Сейчас в теме
(24) Думаю, решается. Решение нужно всего лишь немного подправить, вы на верном пути.
27. emir99 4 21.08.17 10:38 Сейчас в теме
Мне бы хотелось получить следующее:
Прикрепленные файлы:
28. emir99 4 21.08.17 10:43 Сейчас в теме
Это данные с датчиков в автомобиле - двигатель работает/не работает, машина - движется/стоит. Соответственно надо посчитать, сколько времени ехала, сколько стояла со включенным двигателем. Плюс разные другие датчики - уровни топлива в разных баках, работа второго двигателя. Проблема в том, что разные наборы датчиков посылают сигналы в разное время. По-началу я группировал всё до минуты, собирал всё в одну таблицу и её обходил. Но на нескольких сутках округление даёт, в таком случае, большую погрешность. Если не объединять до минут, то надо делать три таких запроса, три обхода - будет долго.
29. ildarovich 7846 21.08.17 11:32 Сейчас в теме
(28) Теперь более-менее понятно.
Тогда действительно метод не вполне подходящий (одного его недостаточно).
Он предназначен для поиска интервалов между событиями, а вам еще нужно будет найти: в какие интервалы постоянства значений наборов датчиков входит этот интервал.
То есть соединить полученную таблицу интервалов с таблицей каждого набора датчиков по условию Tдатчика <= НачалоИнтервала, найти максимум Tдатчика с группировкой по индексу интервала, а затем соединить полученный максимум с таблицами, чтобы определить состояние набора датчиков.
Это задача множественного среза последних.
Проблемой будет поиск максимума для каждого минимального интервала.
Это в целом затратная операция, так как ее трудоемкость NхM/2, где N - количество минимальных интервалов, а М - число значений в таблице значений наборов датчиков.
Тут есть пара довольно головоломных подходов.
Один на основе https://infostart.ru/public/201526/, второй попроще - упрощенная версия https://infostart.ru/public/551583/ (пока в черновиках).
Но прежде чем их применять, нужно замерить время решения через ТЗ.
Если оно будет удовлетворительным, ломать голову не стоит.
30. boln 1040 21.08.17 13:12 Сейчас в теме
(0)
Общеизвестным методом решения этой задачи в запросе является запрос следующего вида:

ВЫБРАТЬ
Слева.Дата КАК НачалоИнтервала,
МИНИМУМ(Справа.Дата) КАК КонецИнтервала
ИЗ
Даты КАК Слева
ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Справа
ПО Слева.Дата < Справа.Дата
СГРУППИРОВАТЬ ПО
Слева.Дата
Угу, так и делаем. Но такой запрос чреват ошибкой, если вдруг попадутся два смежных интервала (конец одного равен началу другого).
31. ildarovich 7846 21.08.17 13:46 Сейчас в теме
(30) Этого замечания я не понял.
Суть задачи определения интервалов состоит в том, что есть таблица, содержащая множество дат, дат со временем или просто чисел. Требуется построить по этой таблице интервалы, на которые исходные даты (числа) разбивают временную (числовую) ось
То есть если в исходной таблице есть отметки времени 5:01; 6:02; 6:13; 7:02, то должны получиться интервалы:[5:01, 6:02], [6:02, 6:13], [6:13, 7:02]. Задача, в которой интервалы имеют нулевую длину (когда отметки повторяются), не рассматривается, поскольку, как минимум, требует доопределения (еще одного поля для упорядочивания). Можно считать, что отметки времени выбираются запросом ВЫБРАТЬ РАЗЛИЧНЫЕ, что исключает их дублирование.
32. boln 1040 21.08.17 14:21 Сейчас в теме
(31) А, я невнимательно посмотрел запрос. У меня другая таблица: два поля - Начало и Конец. У Вас одно поле - Дата. И задача у меня немного другая: я определяю запросом промежутки между интервалами. Моя ошибка, извиняюсь.
33. Tolpinski 65 10.10.17 09:02 Сейчас в теме
Спрошу тут, задача похожая.
Исходная таблица c пропущенным интервалом, таких может быть несколько.
t1-t2
t2-t3
t4-t5

Как запросом добавить пропущенные интервалы?
Задача из ЗУП, когда на период задано что-то плановое, а внутри идут временные перемещения. Промежутки между временными нужно заполнить основным.
34. ildarovich 7846 10.10.17 10:39 Сейчас в теме
(33) Тут требуется уточнение. Если отрезки не пересекаются, то все просто. Для определения пропусков нужно соединить таблицу интервалов саму с собой примерно так:
ВЫБРАТЬ
	ДОБАВИТЬКДАТЕ(МАКСИМУМ(Слева.До), ДЕНЬ, 1) КАК От,
	ДОБАВИТЬКДАТЕ(Интервалы.От, ДЕНЬ, -1) КАК До
ИЗ
	Интервалы КАК Интервалы
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Интервалы КАК Слева
		ПО (Слева.До < Интервалы.От)
СГРУППИРОВАТЬ ПО
	Интервалы.От
ИМЕЮЩИЕ
	ДОБАВИТЬКДАТЕ(МАКСИМУМ(Слева.До), ДЕНЬ, 1) < Интервалы.От
Показать
Еще можно пронумеровать все крайние точки интервалов подряд и соединить соседние четные с нечетными. Так делают в SQL, где есть функция RowNumber(). Задача называется Gaps and Islands Problem.

Если интервалы в исходной таблице могут пересекаться, то тут два пути:
Первый: Соединить таблицу с производственным календарем, чтобы определить дни, не входящий ни в один интервал, а затем сгруппировать соседние дни, чтобы получить сами интервалы. По принципу задачи 14 из Минимализмы.
Второй: посчитать нарастающий итог, где начало интервала делает +1, а конец -1. Тогда пропуски будут соответствовать интервалам, где нарастающий итог нулевой.

Все эти решения годятся для случаев, где интервалов до тысячи. Если их больше, то, чтобы не столкнуться с квадратичным ростом времени выполнения запросов, требуется применять специальные методы типа описанного в этой статье и в статье Баттерфляй - метод быстрого расчета нарастающего итога в запросе.
Tolpinski; +1 Ответить
35. adva 45 12.05.18 07:48 Сейчас в теме
Есть ли какое-нибудь математическое "решение", у следующей задачи:
Дано:

в телесистему (виалон) можно сделать запрос по одному/нескольким объектам, но строго за один интервал;

в системе 1С у объектов интервалы по большому счету разные (дата выезда и убытия по ПЛ);
количество запросов в телесистему лимитировано;

ответ из телесистемы можно получить либо в целом за интервал, либо он разбит на подинтервалы произвольным образом неодинаково по объектам (работает / не работает двигатель, двигается авто / стоит). Подинтервалы при этом соприкасаются

Необходимо как-то минимизировать количество запросов в телесистему, и при этом минимизировать запись в системе 1С
36. ildarovich 7846 14.05.18 10:52 Сейчас в теме
Задача кажется интересной, нужной, сложной, но данных для выбора способа решения недостаточно.
Нужно знать структуру полей таблицы, возвращаемой по запросу из Виалон, метод определения стоимости запроса (стоимость определяется или числом запросов, числом строк в запросе, числом объектов и прочее), а также структуру регистра для хранения полученных данных в 1С.
37. adva 45 14.05.18 13:16 Сейчас в теме
В 1С предполагает примерно такая структура (упрощенно), РС: измерения - ИдОбъекта (строка), ДатаУбыт, ДатаПриб (даты со временем), ВидКэша (по сути вид таблицы из виалон), ресурсы - моточасы, пробег, время, начальное и конечное положение (строка) и другие числовые.

Тут еще думаю добавить измерение Сутки (чтобы можно было наборы писать посуточно), в итоге записей по объекту может быть 4-100 за сутки.

Сколько объектов может быть запрошено в запросе максимально, пока не знаю, но ограничения точно есть, и их полно: если за 5 минут запрос не выполняется, он прерывается, поэтому например за час данные можно получить сразу по всем объектам, а за сутки, уже надо снижать количество объектов (пробовал запрашивать по 100 объектам, за сутки выдавало результат). Передать в запрос тоже можно ограниченное число объектов для запроса, но как уже отметил, максимальное значение не знаю. Строк возвращается всегда разное количество, ответ (json) разбит на 4 таблицы, в 2х из них есть несоприкасающиеся интервалы, а в двух других, просто определенные моменты времени (даты заправок, и т.п.).

Из ограничений еще такое важное (ограничения указаны на сайте виалона, не знаю, можно ли тут ссылки приводить): по одному пользователю можно запросить за 5 минут не более 200 запросов (вроде как это по всем сессиям пользователя, и, не совсем понял, ранее у них не было указано, что это запросы определенного типа, а сейчас уточнено, что report/exec_report . Этот момент пока не тестировал, но в целом, на один такой запрос, приходится 6-7 других

Объектов может быть порядка 1200-1500 (может и больше, но у меня в имеющихся тестовых базах примерно столько)

Если этой информации недостаточно, то к сожалению, на текущей момент другой не владею
38. adva 45 14.05.18 13:33 Сейчас в теме
Как предполагал решить задачу сам: сначала загрузить за сутки по группам объектов (скажем по 100 штук), а затем, если, границы интервала по объекту "попадают" в загруженные подинтервалы, то эти подинтервалы разделить исходя из нужных границ.

В принципе такую реализацию сейчас и буду доделывать, но первая версия показала, что выполняется это очень долго (порядка 10 часов), с учетом ночных "перегрузок" сервера 1С неприемлемо, задача, сократить хотя бы до 5 часов.

Думаю тут выигрыш дадут запись наборами за сутки, и сейчас у меня разбивка поинтервалов идет по каждой из "таблиц" виалона (т.е. 2 таблицы на 2 границы - до 4х запросов в виалон), это сокращу строго на 1 запрос. В принципе если смогу сократить до 5 часов загрузку, то задача решена, и наверное переделывать не буду.

Пробовал еще такую версию: разбивал сутки на подпериоды по всем границам ПЛ и запрашивал сразу по всем объектам, но в итоге загрузка также была в пределах 10 часов, и обеспечить "посуточную" загрузку оказалось сложно, в случае ошибки при загрузке (или не успел придумать вариант). Тут наверное как то надо было разделять с учетом ИД объектов для каждой границы, но я не сообразил, как
39. adva 45 15.05.18 09:27 Сейчас в теме
Сергей, спасибо за участие.

В итоге выяснил, что самый большой проигрыш почти половина времени уходила на разбор "самописными" процедурами JSON. Переделал на платформенное, и еще некоторые моменты поправил, в итоге добился 3х часов.

Но если все же будет объяснения, как решать такие задачи "математически", было бы очень интересно, или хотя бы намек, что это за тип задачи, чтобы самому попытаться разобраться.
40. adva 45 15.05.18 09:31 Сейчас в теме
А еще хотел бы узнать, есть ли какая-то возможность "сгруппировать" в запросе по интервалам ? Не по периодам, а именно, что интервалы в записях:
1 Дата1, Дата2
2 Дата1, Дата3
3 Дата1, Дата3

В итоге записи 2 и 3 - это "группа интервалов"
41. XelOla 17 29.10.18 22:44 Сейчас в теме
потуплю...)
можете помочь с простым скд ?
надо отобрать реализации группируя их по 15 мин, условно начиная с 9:00:00?
43. PerlAmutor 129 06.09.22 06:13 Сейчас в теме
(0) "В большинстве случаев этого достаточно. Однако когда число элементов в исходной таблице становится достаточно большим, время выполнения запроса существенно возрастает. Это связано с квадратичным характером зависимости времени работы запроса от объема исходной таблицы: для каждой записи при расчете агрегатной функции МИНИМУМ просматривается в среднем половина других записей!"

В моем случае 5000 строк в таблице хватило для того, чтобы завесить запрос на MSSQL сервере. Ждал двое суток, "живой план запроса" не обновлялся. Нагрузки на сервер 0, вводов/выводов никаких. Т.е. запрос полностью завис и ничего не делал. Пришлось применять KILL.
44. makaron24 15.03.23 12:25 Сейчас в теме
Сможете помочь с решением задачи:
Есть установка действия цен с датой начало и окончания, периоды могут пересекаться и накладываться друг на друга. Нужно запросом собрать в какой из периодов действовала цена. Для наглядности прикрепил файл.
Прикрепленные файлы:
45. makaron24 16.03.23 06:22 Сейчас в теме
Оставьте свое сообщение