Мы столкнулись с подобными задачами при разработке Кронос: WMS (интерфейс Такси, управляемые формы)- искать номенклатуру/МТР/товар по штрих-коду, при условии, что у одной номенклатуры может быть несколько штрих-кодов, а справочник порядка 700 000 позиций. Стандартный поиск не позволял реализовать подобное, его скорость нас не устроила.
Решений у этой задачки несколько, например, можно сначала найти нужную нам номенклатуру, а потом установить отбор динамического списка по ней или изменить текст запроса списка таким образом, чтобы он фильтровал список по нужным нам значениям. Дополнительно учтём, что пользователь хотел бы видеть на экране первым, что больше подходит под поиск, иными словами, добавим сортировку. Поэтому в итоге выбрали второй путь и сделали универсальный инструмент/механизм, который можно легко тиражировать в другие места конфигурации.
Итак, приступим.
Для начала немного изменим наш типовой запрос, добавив в него ПриоритетШаблона и раздел ГДЕ:
Добавим в настройках динамического списка порядок:
Далее, добавим наше поле Поиск, отключив стандартный поиск:
Добавляем процедуру по обработке ввода значения в поле Поиск:
&НаСервере
Процедура ПоискПриИзмененииСервер()
Если ПустаяСтрока(Поиск) Тогда
Элементы.Список.Отображение = ОтображениеТаблицы.ИерархическийСписок;
Иначе
Элементы.Список.Отображение = ОтображениеТаблицы.Список;
КонецЕсли;
_ДиалогСервер.УправлениеПоискомПоШаблону(Список, Поиск);
КонецПроцедуры
&НаКлиенте
Процедура ПоискПриИзменении(Элемент)
ПоискПриИзмененииСервер();
КонецПроцедуры
Как видно, если поле Поиск заполнено, то мы переключаем вид отображения с Иерархического списка на отображение таблиц Список, чтобы пользователю не делать это вручную.
Теперь переходим к написанию самой универсальной функции поиска через изменения текста запроса:
Процедура УправлениеПоискомПоШаблону(Список, СловоПоиска) экспорт
Получим метаданные основной таблицы списка:
МД = Метаданные.НайтиПоПолномуИмени(Список.ОсновнаяТаблица);
Если у нас поиск стандартный, только по полям, указанным в конфигураторе ВводПоСтроке, то массив
полей доступных для поиска получаем таким образом:
МассивПолей = СтрРазделить(МД.ВводПоСтроке, ",");
Если у нас что-то более сложное, или хочется какие-то метаданные обработать иначе:
Если МД=Метаданные.РегистрыСведений.ХХХХ Тогда
МассивПолей = Новый Массив();
МассивПолей.Добавить("Ячейка.Код");
МассивПолей.Добавить("Паллета.Код");
МассивПолей.Добавить("Родитель");
МассивПолей.Добавить("НомерПартии");
МассивПолей.Добавить("Маркировка");
КонецЕсли;
Далее, сформируем условие для раздела ГДЕ поиска по штрих-коду (номенклатуры или документа), например, таким образом:
ГДЕПоШтрихКоду = "";
Если НЕ Метаданные.Документы.Найти(МД.Имя)=Неопределено Тогда
МассивПолей.Добавить("Контрагент.Наименование");
МассивПолей.Добавить("СкладскаяОперация.Наименование");
ЭтоГруппа = " ";
ГДЕПоШтрихКоду = " ИЛИ Ссылка В(ВЫБРАТЬ ВЫБОР КОГДА Номенклатура=Значение(Справочник.Номенклатура.ПустаяСсылка) ТОГДА Объект ИНАЧЕ Номенклатура КОНЕЦ ИЗ РегистрСведений.лгШтрихКоды КАК РС ГДЕ РС.ШтрихКод=&СловоПоиска) ";
ТекстПометкаУдаления = " И ПометкаУдаления=Ложь ";
ИначеЕсли НЕ Метаданные.Справочники.Найти(МД.Имя)=Неопределено Тогда
ЭтоГруппа = " И (&ПоискПоШаблону=ЛОЖЬ ИЛИ (&ПоискПоШаблону=ИСТИНА И ЭтоГруппа=ЛОЖЬ)) ";
ГДЕПоШтрихКоду = " ИЛИ Ссылка В(ВЫБРАТЬ ВЫБОР КОГДА Номенклатура=Значение(Справочник.Номенклатура.ПустаяСсылка) ТОГДА Объект ИНАЧЕ Номенклатура КОНЕЦ ИЗ РегистрСведений.лгШтрихКоды КАК РС ГДЕ РС.ШтрихКод=&СловоПоиска) ";
ТекстПометкаУдаления = " И ПометкаУдаления=Ложь ";
КонецЕсли;
В конце сформируем полное условие ГДЕ и Приоритет для отображения пользователю:
Добавка = ""; ПриоритетШаблонаПоСлову = ""; ПриоритетШаблонаПоПодобию = "";
Для Каждого Поле Из МассивПолей Цикл
Если НЕ ЗначениеЗаполнено(Поле) Тогда
Продолжить;
КонецЕсли;
ПриоритетШаблонаПоСлову = ПриоритетШаблонаПоСлову + Добавка+ Поле + "=&СловоПоиска ";
ПриоритетШаблонаПоПодобию = ПриоритетШаблонаПоПодобию + Добавка + Поле + " ПОДОБНО &ШаблонПоиска СПЕЦСИМВОЛ ""~"" ";
Добавка = " ИЛИ ";
КонецЦикла;
Если ПустаяСтрока(ПриоритетШаблонаПоСлову) Тогда
Возврат;
КонецЕсли;
ПриоритетШаблона = "ВЫБОР
| КОГДА &ПоискПоШаблону=ИСТИНА И (" + ПриоритетШаблонаПоСлову +")"+ ТекстПометкаУдаления+" ТОГДА 10000
| КОГДА &ПоискПоШаблону=ИСТИНА И (" + ПриоритетШаблонаПоПодобию +")"+ ТекстПометкаУдаления+" ТОГДА 1000
|ИНАЧЕ 0 КОНЕЦ КАК ПриоритетШаблона";
ТекстГДЕПоискПоШаблону = " И (&ПоискПоШаблону=ЛОЖЬ
| ИЛИ " + ПриоритетШаблонаПоПодобию + ГДЕПоШтрихКоду+")" + ЭтоГруппа + ГДЕПериод;
Список.ТекстЗапроса = СтрЗаменить(Список.ТекстЗапроса, "0 КАК ПриоритетШаблона", ПриоритетШаблона);
Список.ТекстЗапроса = СтрЗаменить(Список.ТекстЗапроса, "//ТекстГДЕПоискПоШаблону", ТекстГДЕПоискПоШаблону);
В итоге мы получим текст запроса, который фильтрует на сервере данные по нужным нам условиям, с учётом ограничений нашей конфигурации или ее особенностей, а также заполнено поле для сортировки результатов.
Установим параметры нашего нового запроса:
ШаблонПоиска = СокрЛП(СловоПоиска);
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "~", "~~");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "%", "~%");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "_", "~_");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "[", "~[");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "-", "~-");
ШаблонПоиска = "%" + ШаблонПоиска + "%";
Если НЕ ПустаяСтрока(ГДЕПериод) Тогда
Список.Параметры.УстановитьЗначениеПараметра("ДатаНачала", ДатаНачала);
КонецЕсли;
Список.Параметры.УстановитьЗначениеПараметра("ШаблонПоиска", ШаблонПоиска);
Список.Параметры.УстановитьЗначениеПараметра("СловоПоиска", СловоПоиска);
Список.Параметры.УстановитьЗначениеПараметра("ПоискПоШаблону", НЕ ПустаяСтрока(СловоПоиска));
А также отключим пользовательскую сортировку, если такая им была включена, вернув к сортировке по умолчанию (заводским настройкам):
Если НЕ ПустаяСтрока(СловоПоиска) Тогда //отключим пользовательскую сортировку
Для Каждого Элемент Из Список.КомпоновщикНастроек.ПользовательскиеНастройки.Элементы Цикл
Если ТипЗнч(Элемент)=Тип("ПорядокКомпоновкиДанных") Тогда
Элемент.Элементы.Очистить();
Для Каждого Порядок Из Список.КомпоновщикНастроек.Настройки.Порядок.Элементы Цикл
НовыйПорядок = Элемент.Элементы.Добавить(Тип("ЭлементПорядкаКомпоновкиДанных"));
ЗаполнитьЗначенияСвойств(НовыйПорядок, Порядок);
КонецЦикла;
КонецЕсли;
КонецЦикла;
КонецЕсли;
Итак, вот какая функция получается в итоге наших действий:
Процедура УправлениеПоискомПоШаблону(Список, СловоПоиска) экспорт
Если ПустаяСтрока(Список.ОсновнаяТаблица) Тогда
Возврат;
КонецЕсли;
Если Найти(Список.ТекстЗапроса, "//ТекстГДЕПоискПоШаблону")>0 Тогда
МД = Метаданные.НайтиПоПолномуИмени(Список.ОсновнаяТаблица);
ГДЕПериод = "";
Если МД=Метаданные.РегистрыСведений.ХХХХ Тогда
МассивПолей = Новый Массив();
МассивПолей.Добавить("Ячейка.Код");
МассивПолей.Добавить("Паллета.Код");
МассивПолей.Добавить("Родитель");
МассивПолей.Добавить("НомерПартии");
МассивПолей.Добавить("Маркировка");
МассивПолей.Добавить("Спецификация");
Иначе
МассивПолей = СтрРазделить(МД.ВводПоСтроке, ",");
КонецЕсли;
ГДЕПоШтрихКоду = "";
Если НЕ Метаданные.Документы.Найти(МД.Имя)=Неопределено Тогда
МассивПолей.Добавить("Контрагент.Наименование");
МассивПолей.Добавить("СкладскаяОперация.Наименование");
ЭтоГруппа = " ";
ГДЕПоШтрихКоду = " ИЛИ Ссылка В(ВЫБРАТЬ ВЫБОР КОГДА Номенклатура=Значение(Справочник.Номенклатура.ПустаяСсылка) ТОГДА Объект ИНАЧЕ Номенклатура КОНЕЦ ИЗ РегистрСведений.лгШтрихКоды КАК РС ГДЕ РС.ШтрихКод=&СловоПоиска) ";
ТекстПометкаУдаления = " И ПометкаУдаления=Ложь ";
ИначеЕсли НЕ Метаданные.Справочники.Найти(МД.Имя)=Неопределено Тогда
ЭтоГруппа = " И (&ПоискПоШаблону=ЛОЖЬ ИЛИ (&ПоискПоШаблону=ИСТИНА И ЭтоГруппа=ЛОЖЬ)) ";
ГДЕПоШтрихКоду = " ИЛИ Ссылка В(ВЫБРАТЬ ВЫБОР КОГДА Номенклатура=Значение(Справочник.Номенклатура.ПустаяСсылка) ТОГДА Объект ИНАЧЕ Номенклатура КОНЕЦ ИЗ РегистрСведений.лгШтрихКоды КАК РС ГДЕ РС.ШтрихКод=&СловоПоиска) ";
ТекстПометкаУдаления = " И ПометкаУдаления=Ложь ";
КонецЕсли;
Добавка = ""; ПриоритетШаблонаПоСлову = ""; ПриоритетШаблонаПоПодобию = "";
Для Каждого Поле Из МассивПолей Цикл
Если НЕ ЗначениеЗаполнено(Поле) Тогда
Продолжить;
КонецЕсли;
ПриоритетШаблонаПоСлову = ПриоритетШаблонаПоСлову + Добавка+ Поле + "=&СловоПоиска ";
ПриоритетШаблонаПоПодобию = ПриоритетШаблонаПоПодобию + Добавка + Поле + " ПОДОБНО &ШаблонПоиска СПЕЦСИМВОЛ ""~"" ";
Добавка = " ИЛИ ";
КонецЦикла;
Если ПустаяСтрока(ПриоритетШаблонаПоСлову) Тогда
Возврат;
КонецЕсли;
ПриоритетШаблона = "ВЫБОР
| КОГДА &ПоискПоШаблону=ИСТИНА И (" + ПриоритетШаблонаПоСлову +")"+ ТекстПометкаУдаления+" ТОГДА 10000
| КОГДА &ПоискПоШаблону=ИСТИНА И (" + ПриоритетШаблонаПоПодобию +")"+ ТекстПометкаУдаления+" ТОГДА 1000
|ИНАЧЕ 0 КОНЕЦ КАК ПриоритетШаблона";
ТекстГДЕПоискПоШаблону = " И (&ПоискПоШаблону=ЛОЖЬ
| ИЛИ " + ПриоритетШаблонаПоПодобию + ГДЕПоШтрихКоду+")" + ЭтоГруппа + ГДЕПериод;
Список.ТекстЗапроса = СтрЗаменить(Список.ТекстЗапроса, "0 КАК ПриоритетШаблона", ПриоритетШаблона);
Список.ТекстЗапроса = СтрЗаменить(Список.ТекстЗапроса, "//ТекстГДЕПоискПоШаблону", ТекстГДЕПоискПоШаблону);
КонецЕсли;
ШаблонПоиска = СокрЛП(СловоПоиска);
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "~", "~~");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "%", "~%");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "_", "~_");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "[", "~[");
ШаблонПоиска = СтрЗаменить(ШаблонПоиска, "-", "~-");
ШаблонПоиска = "%" + ШаблонПоиска + "%";
Если НЕ ПустаяСтрока(ГДЕПериод) Тогда
Список.Параметры.УстановитьЗначениеПараметра("ДатаНачала", ДатаНачала);
КонецЕсли;
Список.Параметры.УстановитьЗначениеПараметра("ШаблонПоиска", ШаблонПоиска);
Список.Параметры.УстановитьЗначениеПараметра("СловоПоиска", СловоПоиска);
Список.Параметры.УстановитьЗначениеПараметра("ПоискПоШаблону", НЕ ПустаяСтрока(СловоПоиска));
Если НЕ ПустаяСтрока(СловоПоиска) Тогда //отключим пользовательскую сортировку
Для Каждого Элемент Из Список.КомпоновщикНастроек.ПользовательскиеНастройки.Элементы Цикл
Если ТипЗнч(Элемент)=Тип("ПорядокКомпоновкиДанных") Тогда
Элемент.Элементы.Очистить();
Для Каждого Порядок Из Список.КомпоновщикНастроек.Настройки.Порядок.Элементы Цикл
НовыйПорядок = Элемент.Элементы.Добавить(Тип("ЭлементПорядкаКомпоновкиДанных"));
ЗаполнитьЗначенияСвойств(НовыйПорядок, Порядок);
КонецЦикла;
КонецЕсли;
КонецЦикла;
КонецЕсли;
КонецПроцедуры
Таким образом, мы решили с Вами поставленную задачу - поиск работает быстро, сортирует для пользователя, ищем только по выбранным полям, а также по точному или неточному (по части строки) совпадению и главное его быстро и легко встроить в любой динамический список конфигурации.
Надеюсь, моя публикация была Вам полезна и сэкономит Ваше время, ссылка на все публикации SizovE, например, в публикации
Перенос отбора/периода при интерактивной смене варианта отчета/СКД в БСП 3.1 (1C ERP, УТ, БП, ...) мной было рассмотрено полезное улучшение стандартного механизма библиотеки стандартных подсистем.
Подписывайтесь на мой канал (наверху), будет много интересного бесплатного контента :)
