Здравствуйте.
Если Вы спросите на форуме: "А как программно добавить свою кнопку на форму в какую-либо типовую конфигурацию", то получите 2 типа ответов:
1. Это сто раз обсуждалось, гугли!
2. Это есть в синтаксис-помощнике. Ищи!
3. Код вида:
//Добавляем новую кнопку
МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, Родитель);
МояКнопка.Вид = ВидКнопкиФормы.ОбычнаяКнопка;
МояКнопка.ИмяКоманды = ИмяКоманды;
Так как эта статья для новичков, то предполагаем, что спрашивающий — это новичок, и у него возникнет много вопросов вида:
- А что такое ТипЭлемента? И кто его родил, раз есть Родитель? Я хочу всего лишь кнопку, которая называется «МояКнопка». Вот в имя это и должен написать, а зачем все остальное не понятно.
- А почему кнопка имеет какой-то вид? И почему он обычный? А разве бывает необычный?
- Что за команда? Я хочу просто кнопку! Я не хочу командовать!
- А куда этот код вставлять?
Где-то на 3-5 вопросе форумчане вернутся к 1 и 2 типу ответов.
Давайте вместе разбираться в этом вопросе.
Разберем строку: МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, Родитель);
МояКнопка — это временная переменная, в которой будет определен добавляемый элемент. Название может быть любым (конечно кроме названий, которые уже зарезервированы системой). Название ни на что не влияет и нигде не отображается — пишите что хотите! Кнопка — это элемент формы (как надпись, как декорация, как картинка, как поле ввода...), поэтому далее я буду называть ее новый элемент или просто «элемент», чтобы Вы понимали, что все это может относиться не только к кнопке, но и вообще к любым элементам формы.
Так вот, после того как элемент будет определен (то есть, по сути, появится на форме), эта переменная будет уже не нужна и в ней можно будет определять уже другой элемент (кнопку, поле, картинку...).
Отступление: Так как у переменной мы не объявляли тип, то ее дальше можно использовать не только для описания элементов формы, но и вообще для чего угодно! Допустим, хранить в ней сумму документа.
ЭтаФорма.Элементы.Добавить — это функция которая называется Добавить. Все что стоит перед названием, по сути, есть путь, куда следует добавлять новый элемент. То есть, новый элемент мы добавляем в элементы формы. По сути, добавлять мы будем элемент в массив, который называется «Элементы». Этот массив есть у каждой формы и его название неизменно (всегда пишем «Элементы»). А добавлять будем на эту же форму, в которой выполняется код — «ЭтаФорма».
Отступление: Так как мы будем вставлять новый элемент в туже форму, в которой находится код, то «ЭтаФорма» можно не указывать.
Имя — Это имя кнопки. Оно должно быть уникальным для данной формы. То есть, если на форме уже есть элемент, который называется «Кнопка1», то мы должны дать иное имя, например, «Кнопка2». Имя кнопки, в большинстве случаев визуально не отображается, но это в большинстве! Поэтому, в отличие от переменной «МояКнопка», имя лучше давать осмысленное.
Имя можно задать явно и через переменную:
МояКнопка = ЭтаФорма.Элементы.Добавить("Кнопка1", ТипЭлемента, Родитель);
или
Имя = "Кнопка1";
МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, Родитель);
ТипЭлемента — тут все просто. Для кнопки всегда КнопкаФормы, Для группы — ГруппаФормы и т.д. (об этом будет ниже). Задать можно также 2 способами. Оптимальный:
МояКнопка = ЭтаФорма.Элементы.Добавить("Кнопка1", Тип("КнопкаФормы"), Родитель);
Родитель — место на форме. Если информация до слова Добавить определяет форму, где будет расположен новый элемент, то Родитель — место на форме. Функция «Добавить» всегда добавляет элемент в конец Родителя. Примеры:
МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, ЭтаФорма); //добавление в самый конец (низ) формы.
МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, ЭтаФорма.Элементы.МБХ5); //Добавление в конец группы на форме, которая называется «МБХ5».
Важное отступление: Группа может включаться в группу, но все равно останется элементы формы, а не станет элементом группы, в которую включена. И путь у вложенной группы будет: ЭтаФорма.Элементы.ВложеннаяГруппа.
МояКнопка = ЭтаФорма.Элементы.Добавить("Кнопка1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.ВложеннаяГруппа );
Разберем строку: МояКнопка.Вид = ВидКнопкиФормы.ОбычнаяКнопка;
Да у элемента формы есть вид. Только у одних кнопок их 4:
-Гиперссылка
-ГиперссылкаКоманднойПанели
-КнопкаКоманднойПанели
-ОбычнаяКнопка
Из названия понятно, что кнопка может выглядеть как кнопка и как гиперссылка (синенькая надпись). Кроме того, если кнопка находится в Командной панели, то и вид принимает соответствующий.
Разберем строку: МояКнопка.ИмяКоманды = ИмяКоманды;
Здесь очень важное отступление.
Кнопка без команды бесполезна, а потому, по умолчанию, на форме кнопка БЕЗ привязанной к ней КОМАНДЫ НЕ ОТОБРАЖАЕТСЯ.
Убедитесь в этом сами, бросив в конфигураторе на форму кнопку без команды.
Поэтому наш код нужно добавить следующими строками:
МояКнопка.ИмяКоманды = "Команда1";
//использумем переменную МояКнопка уже для добавления команды
МояКнопка = ЭтаФорма.Команды.Добавить("Команда1"); //Имя должно быть уникальным
МояКнопка.Действие = "ДействиеКоманда1";//Имя процедуры, которая будет выполняться при нажатии на добавляемую кнопку, несколько команд могут выполнять одно и тоже действие, а потому не уникально
МояКнопка.Заголовок = "Запуск действия"; //надпись на кнопке. Видна пользователю. Системе безразлична, а потому может не заполняться.
Перейдем от теоретической к практической части.
Задача, не снимая с поддержки типовую конфигурацию, программно добавить на форму документа свою кнопку, по нажатию которой сообщается «Привет, Мир!».
Важное отступление: Рисование кнопки программно позволит избежать ситуации, когда после обновления кардинально поменялась форма документа, в результате которой расширение не сможет нарисовать необходимый элемент и выпадет в ошибку. При программном добавлении элемента на форму, ошибка может возникнуть только в том случае, когда удалили саму форму (которую, кстати, также можно программно нарисовать и тогда ошибки не будет) . Даже если разработчик оставит форму полностью пустой, все равно добавить новый элемент на нее не составит труда.
Однако!!! Это подходит только для добавления в начало или конец формы. Если требуется элемент запихать внутрь Родителя, то этот метод надежностью ничем не будет отличаться от рисования элементов вручную. Разработчик переименовав или удалив Родителя нарушит логику программы в обоих случаях. И даже , если Родителя указывать по номеру в массиве элементов формы, то это спасет только от переименования, если же разработчик решит удалить некоторые элементы с формы, то нумерация элементов поменяется и в ряде случаев приведет к ошибке.
В любом случае, этот метод чуть более надежный. Хотя и требует больше внимания от программиста, так как система в случае ручного рисования элементов предупредит об изменениях, а в случае программного — нет.
Возьмем документ "ПоступлениеТоваровУслуг" бухгалтерии предприятия 3.0
Дабы не снимать типовую конфигурацию с поддержки воспользуемся расширением конфигурации.
Открываем конфигуратор.
Конфигурация - Расширения конфигурации. Добавить. Обзываем как хотим. Снимаем все галочки, кроме «Активно».
В основной конфигурации ищем документ поступление товаров и услуг. Раскрываем. Переходим к формам документа. Ищем «ФормаСписка». Через нажатие правой кнопки мыши на ней и выбора «Добавить в расширение» отправляем на доработку в расширение.
Все! Основная конфигурация нам больше не нужна. Далее все действия производим в расширении.
Открываем форму документа "ПоступлениеТоваровУслуг" (она у нас одна, так как переносили мы только одну - нужную).
Ищем событие формы ПриСозданииНаСервере нажимаем открыть. Так как никаких процедур при создании на сервере у нас еще нет, то система нам предлагает создать такую. Нам следует выбрать когда будет выполняться наш код. До или После кода который уже написан фирмой 1С. Наименее деструктивным методом обычно является После, что система наим и предлагает выбрать. Соглашаемся.
Отступление: вот мы и вернулись к вопросу куда вставлять код. Глупо конечно же жать одну кнопку, чтобы рисовалась другая. Нет, мы хотим чтобы кнопка рисовалась автоматически при открытии формы. А при открытии формы происходит 2 события: это создание формы и непосредственно ее открытие. Так как нам нужна серверная процедура, а серверной является создание, то приоритетным выбором будет событие ПриСозданииНаСервере.
Открывается модуль формы с единственной процедурой, в которой мы и должны прописать код новой кнопки.
Но прежде чем начать писать код, нам надо определиться, куда же будем вставлять кнопку, а также ее вид.
Все случаи рассматривать не будем. Но частные разберем:
1. Обычная кнопка в конце формы.
2. Обычная кнопка в начале формы.
3. Гиперссылка в начале формы.
4. Добавление нескольких кнопок в группу, которая находится в начале формы.
5. Выпадающая кнопка (подменю) в начале формы.
6. Выпадающая кнопка в Родителе.
Случай № 1.
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Кнопку в конце Родителя (формы)
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВКонце", Тип("КнопкаФормы"), ЭтаФорма);
НоваяКнопка.ИмяКоманды = "Команда1";
Отступление: Выше говорилось, что имена должны быть уникальными и нам очень повезло, что на форме нет имени Команда1. Лучше всего добавлять префиксы к именам, например, Расш1_, но это Вы выполните в качестве домашнего задания.
Случай всем хорош, кроме неудобного расположения кнопки. Поэтому переходим ко второму.
Случай № 2.
Как же нам рисовать кнопку в начале, если функция Добавить, рисует в конце? А никак! Для это существует другая функция: Вставить. Функции полностью идентичные, то есть результат будет одинаков если написать следующее:
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Кнопку в конце Родителя (формы)
НоваяКнопка = ЭтаФорма.Элементы.Вставить("КнопкаВКонце", Тип("КнопкаФормы"), ЭтаФорма);
НоваяКнопка.ИмяКоманды = "Команда1";
Однако у функции Вставить, есть параметр Элемент — это элемент, который уже существует на форме и который будет якорем для нашего. Но мы не знаем какие элементы уже существуют на форме. Но знаем, что они в массиве, а у каждого элемента массива есть индекс и у первого он равен 0. А потому изменим наш код так:
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Кнопку перед указанным
НоваяКнопка = ЭтаФорма.Элементы.Вставить("КнопкаВНачале", Тип("КнопкаФормы"), ЭтаФорма, ЭтаФорма.ПодчиненныеЭлементы[0]);
НоваяКнопка.ИмяКоманды = "Команда1";
Случай № 3.
Превратим кнопку в гиперссылку. Для этого нужно добавить всего одну строку — вид кнопки.
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем гиперссылку перед указанным
НоваяКнопка = ЭтаФорма.Элементы.Вставить("КнопкаВНачале", Тип("КнопкаФормы"), ЭтаФорма, ЭтаФорма.ПодчиненныеЭлементы[0]);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка.Вид = ВидКнопкиФормы.Гиперссылка;
Случай № 4.
Без группировки элементы располагаются друг под другом. Если же мы хотим расположить их в ряд, то придется добавить на форму группу.
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Группу
НоваяГруппа = ЭтаФорма.Элементы.Вставить("Группа1", Тип("ГруппаФормы"), ЭтаФорма, Этаформа.ПодчиненныеЭлементы[0]);
НоваяГруппа.Вид = ВидГруппыФормы.ОбычнаяГруппа;
//Создаем Кнопки
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа1);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа1);
НоваяКнопка.ИмяКоманды = "Команда1";
Заметьте, что хоть кнопки и одинаковы, хоть и выполняют одну и туже команду, но имена у них разные. К тому же, нам опять повезло, что на форме нет группы с именем «Группа1».
Случай № 5.
Все сводится к тому, что требуется создать группу с видом КоманднаяПанель, в нее вставить еще одну группу с видом подменю, у вот в подменю уже пихать кнопки.
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Группы
НоваяГруппа = ЭтаФорма.Элементы.Вставить("Группа1", Тип("ГруппаФормы"), ЭтаФорма, Этаформа.ПодчиненныеЭлементы[0]);
НоваяГруппа.Вид = ВидГруппыФормы.КоманднаяПанель;
НоваяГруппа = ЭтаФорма.Элементы.Добавить("Группа2", Тип("ГруппаФормы"), ЭтаФорма.Элементы.Группа1);
НоваяГруппа.Вид = ВидГруппыФормы.Подменю;
НоваяГруппа.Заголовок = "Выпадающая";
//Создаем Кнопки
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа2);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа2);
НоваяКнопка.ИмяКоманды = "Команда1";
Случай № 6.
Ищем на форме группу вида КоманднаяПанель. Можно программно через перебор всех элементов. Я же просто знаю, что в типовых формах почти всегда есть группа с названием ГруппаКоманднаяПанель, вид которой КоманднаяПанель. Так как это стандарт, воспользуемся этим.
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем группу, которая будет подменю для типовой
НоваяГруппа = ЭтаФорма.Элементы.Добавить("Подменю1", Тип("ГруппаФормы"), ЭтаФорма.Элементы.ГруппаКоманднаяПанель);
НоваяГруппа.Вид = ВидГруппыФормы.Подменю;
НоваяГруппа.Заголовок = "Выпадающая";
//Создаем Кнопки
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
НоваяКнопка.ИмяКоманды = "Команда1";
Но тут следует быть осторожным. Фирма 1С всегда может поменять имя группы или вообще удалить ее. Помните об этом.
Ну и самое главное - сама процедура приветствующая мир:
&НаСервере
Процедура Кнопки_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем группу, которая будет подменю для типовой
НоваяГруппа = ЭтаФорма.Элементы.Добавить("Подменю1", Тип("ГруппаФормы"), ЭтаФорма.Элементы.ГруппаКоманднаяПанель);
НоваяГруппа.Вид = ВидГруппыФормы.Подменю;
НоваяГруппа.Заголовок = "Выпадающая";
//Создаем Кнопки
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
НоваяКнопка.ИмяКоманды = "Команда1";
КонецПроцедуры
&НаКлиенте
Процедура ВыполнитьКоманду(Команда)
Сообщить("Привет, Мир!");
КонецПроцедуры
Делал статью как напоминалку для себя и в помощь другим, так что критика принимается, статья редактируется и дополняется.
