Новичок новичку: как добавить программно кнопку на форму путем расширения

13.05.21

Разработка - Механизмы платформы 1С

Рассказываю очень простым языком, как добавить программно кнопку в типовую конфигурацию. Сам новичок в этом деле и рассказываю на "новичковом" языке.

Здравствуйте.

Если Вы спросите на форуме: "А как программно добавить свою кнопку на форму в какую-либо типовую конфигурацию", то получите 2 типа ответов:

1. Это сто раз обсуждалось, гугли!

2. Это есть в синтаксис-помощнике. Ищи!

3. Код вида:

    //Добавляем новую кнопку
    МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, Родитель);
    МояКнопка.Вид = ВидКнопкиФормы.ОбычнаяКнопка;
    МояКнопка.ИмяКоманды = ИмяКоманды;

Так как эта статья для новичков, то предполагаем, что спрашивающий — это новичок, и у него возникнет много вопросов вида:

- А что такое ТипЭлемента? И кто его родил, раз есть Родитель? Я хочу всего лишь кнопку, которая называется «МояКнопка». Вот в имя это и должен написать, а зачем все остальное не понятно.

- А почему кнопка имеет какой-то вид? И почему он обычный? А разве бывает необычный?

- Что за команда? Я хочу просто кнопку! Я не хочу командовать!

- А куда этот код вставлять?

Где-то на 3-5 вопросе форумчане вернутся к 1 и 2 типу ответов.

Давайте вместе разбираться в этом вопросе.

Разберем строку: МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, Родитель);

МояКнопка — это временная переменная, в которой будет определен добавляемый элемент. Название может быть любым (конечно кроме названий, которые уже зарезервированы системой). Название ни на что не влияет и нигде не отображается — пишите что хотите! Кнопка — это элемент формы (как надпись, как декорация, как картинка, как поле ввода...), поэтому далее я буду называть ее новый элемент или просто «элемент», чтобы Вы понимали, что все это может относиться не только к кнопке, но и вообще к любым элементам формы.

Так вот, после того как элемент будет определен (то есть, по сути, появится на форме), эта переменная будет уже не нужна и в ней можно будет определять уже другой элемент (кнопку, поле, картинку...).

Отступление: Так как у переменной мы не объявляли тип, то ее дальше можно использовать не только для описания элементов формы, но и вообще для чего угодно! Допустим, хранить в ней сумму документа.

ЭтаФорма.Элементы.Добавить — это функция которая называется Добавить. Все что стоит перед названием, по сути, есть путь, куда следует добавлять новый элемент. То есть, новый элемент мы добавляем в элементы формы. По сути, добавлять мы будем элемент в массив, который называется «Элементы». Этот массив есть у каждой формы и его название неизменно (всегда пишем «Элементы»). А добавлять будем на эту же форму, в которой выполняется код — «ЭтаФорма».

Отступление: Так как мы будем вставлять новый элемент в туже форму, в которой находится код, то «ЭтаФорма» можно не указывать.

Имя — Это имя кнопки. Оно должно быть уникальным для данной формы. То есть, если на форме уже есть элемент, который называется «Кнопка1», то мы должны дать иное имя, например, «Кнопка2». Имя кнопки, в большинстве случаев визуально не отображается, но это в большинстве! Поэтому, в отличие от переменной «МояКнопка», имя лучше давать осмысленное.

Имя можно задать явно и через переменную:

МояКнопка = ЭтаФорма.Элементы.Добавить("Кнопка1", ТипЭлемента, Родитель);

или

Имя = "Кнопка1";

МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, Родитель);

 

ТипЭлемента — тут все просто. Для кнопки всегда КнопкаФормы, Для группы — ГруппаФормы и т.д. (об этом будет ниже). Задать можно также 2 способами. Оптимальный:

МояКнопка = ЭтаФорма.Элементы.Добавить("Кнопка1", Тип("КнопкаФормы"), Родитель);

Родитель — место на форме. Если информация до слова Добавить определяет форму, где будет расположен новый элемент, то Родитель — место на форме. Функция «Добавить» всегда добавляет элемент в конец Родителя. Примеры:

МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, ЭтаФорма); //добавление в самый конец (низ) формы.
МояКнопка = ЭтаФорма.Элементы.Добавить(Имя, ТипЭлемента, ЭтаФорма.Элементы.МБХ5); //Добавление в конец группы на форме, которая называется «МБХ5».

Важное отступление: Группа может включаться в группу, но все равно останется элементы формы, а не станет элементом группы, в которую включена. И путь у вложенной группы будет: ЭтаФорма.Элементы.ВложеннаяГруппа.

МояКнопка = ЭтаФорма.Элементы.Добавить("Кнопка1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.ВложеннаяГруппа );

Разберем строку: МояКнопка.Вид = ВидКнопкиФормы.ОбычнаяКнопка;

Да у элемента формы есть вид. Только у одних кнопок их 4:

-Гиперссылка

-ГиперссылкаКоманднойПанели

-КнопкаКоманднойПанели

-ОбычнаяКнопка

Из названия понятно, что кнопка может выглядеть как кнопка и как гиперссылка (синенькая надпись). Кроме того, если кнопка находится в Командной панели, то и вид принимает соответствующий.

Разберем строку: МояКнопка.ИмяКоманды = ИмяКоманды;
Здесь очень важное отступление.
Кнопка без команды бесполезна, а потому, по умолчанию, на форме кнопка БЕЗ привязанной к ней КОМАНДЫ НЕ ОТОБРАЖАЕТСЯ.
Убедитесь в этом сами, бросив в конфигураторе на форму кнопку без команды.

Поэтому наш код нужно добавить следующими строками:

МояКнопка.ИмяКоманды = "Команда1";
//использумем переменную МояКнопка уже для добавления команды
МояКнопка = ЭтаФорма.Команды.Добавить("Команда1"); //Имя должно быть уникальным
МояКнопка.Действие = "ДействиеКоманда1";//Имя процедуры, которая будет выполняться при нажатии на добавляемую кнопку, несколько команд могут выполнять одно и тоже действие, а потому не уникально
МояКнопка.Заголовок = "Запуск действия"; //надпись на кнопке. Видна пользователю. Системе безразлична, а потому может не заполняться.  

Перейдем от теоретической к практической части.


Задача, не снимая с поддержки типовую конфигурацию, программно добавить на форму документа свою кнопку, по нажатию которой сообщается «Привет, Мир!».

Важное отступление: Рисование кнопки программно позволит избежать ситуации, когда после обновления кардинально поменялась форма документа, в результате которой расширение не сможет нарисовать необходимый элемент и выпадет в ошибку. При программном добавлении элемента на форму, ошибка может возникнуть только в том случае, когда удалили саму форму (которую, кстати, также можно программно нарисовать и тогда ошибки не будет) . Даже если разработчик оставит форму полностью пустой, все равно добавить новый элемент на нее не составит труда.

Однако!!! Это подходит только для добавления в начало или конец формы. Если требуется элемент запихать внутрь Родителя, то этот метод надежностью ничем не будет отличаться от рисования элементов вручную. Разработчик переименовав или удалив Родителя нарушит логику программы в обоих случаях. И даже , если Родителя указывать по номеру в массиве элементов формы, то это спасет только от переименования, если же разработчик решит удалить некоторые элементы с формы, то нумерация элементов поменяется и в ряде случаев приведет к ошибке.

В любом случае, этот метод чуть более надежный. Хотя и требует больше внимания от программиста, так как система в случае ручного рисования элементов предупредит об изменениях, а в случае программного — нет.

Возьмем документ "ПоступлениеТоваровУслуг" бухгалтерии предприятия 3.0
Дабы не снимать типовую конфигурацию с поддержки воспользуемся расширением конфигурации.
Открываем конфигуратор.
Конфигурация - Расширения конфигурации. Добавить. Обзываем как хотим. Снимаем все галочки, кроме «Активно».
В основной конфигурации ищем документ  поступление товаров и услуг. Раскрываем. Переходим к формам документа. Ищем «ФормаСписка». Через нажатие правой кнопки мыши на ней и выбора «Добавить в расширение» отправляем на доработку в расширение.

Все! Основная конфигурация нам больше не нужна. Далее все действия производим в расширении.

Открываем форму документа  "ПоступлениеТоваровУслуг" (она у нас одна, так как переносили мы только одну - нужную).

Ищем событие формы ПриСозданииНаСервере нажимаем открыть. Так как никаких процедур при создании на сервере у нас еще нет, то система нам предлагает создать такую. Нам следует выбрать когда будет выполняться наш код. До или После кода который уже написан фирмой 1С. Наименее деструктивным методом обычно является После, что система наим и предлагает выбрать. Соглашаемся.

Отступление: вот мы и вернулись к вопросу куда вставлять код. Глупо конечно же жать одну кнопку, чтобы рисовалась другая. Нет, мы хотим чтобы кнопка рисовалась автоматически при открытии формы. А при открытии формы происходит 2 события: это создание формы и непосредственно ее открытие. Так как нам нужна серверная процедура, а серверной является создание, то приоритетным выбором будет событие ПриСозданииНаСервере.

Открывается модуль формы с единственной процедурой, в которой мы и должны прописать код новой кнопки.


Но прежде чем начать писать код, нам надо определиться, куда же будем вставлять кнопку, а также ее вид.


Все случаи рассматривать не будем. Но частные разберем:
1. Обычная кнопка в конце формы.
2. Обычная кнопка в начале формы.
3. Гиперссылка в начале формы.
4. Добавление нескольких кнопок в группу, которая находится в начале формы.
5. Выпадающая кнопка (подменю) в начале формы.
6. Выпадающая кнопка в Родителе.

Случай № 1.

//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Кнопку в конце Родителя (формы)
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВКонце", Тип("КнопкаФормы"), ЭтаФорма);
НоваяКнопка.ИмяКоманды = "Команда1";

Отступление: Выше говорилось, что имена должны быть уникальными и нам очень повезло, что на форме нет имени Команда1. Лучше всего добавлять префиксы к именам, например, Расш1_, но это Вы выполните в качестве домашнего задания.

Случай всем хорош, кроме неудобного расположения кнопки. Поэтому переходим ко второму.

Случай № 2.
Как же нам рисовать кнопку в начале, если функция Добавить, рисует в конце? А никак! Для это существует другая функция: Вставить. Функции полностью идентичные, то есть результат будет одинаков если написать следующее:

//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Кнопку в конце Родителя (формы)
НоваяКнопка = ЭтаФорма.Элементы.Вставить("КнопкаВКонце", Тип("КнопкаФормы"), ЭтаФорма);
НоваяКнопка.ИмяКоманды = "Команда1";


Однако у функции Вставить, есть параметр Элемент — это элемент, который уже существует на форме и который будет якорем для нашего. Но мы не знаем какие элементы уже существуют на форме. Но знаем, что они в массиве, а у каждого элемента массива есть индекс и у первого он равен 0. А потому изменим наш код так:

//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Кнопку перед указанным
НоваяКнопка = ЭтаФорма.Элементы.Вставить("КнопкаВНачале", Тип("КнопкаФормы"), ЭтаФорма, ЭтаФорма.ПодчиненныеЭлементы[0]);
НоваяКнопка.ИмяКоманды = "Команда1";

Случай № 3.
Превратим кнопку в гиперссылку. Для этого нужно добавить всего одну строку — вид кнопки.

//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";//Имя процедуры
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем гиперссылку перед указанным
НоваяКнопка = ЭтаФорма.Элементы.Вставить("КнопкаВНачале", Тип("КнопкаФормы"), ЭтаФорма, ЭтаФорма.ПодчиненныеЭлементы[0]);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка.Вид = ВидКнопкиФормы.Гиперссылка;

Случай № 4.

Без группировки элементы располагаются друг под другом. Если же мы хотим расположить их в ряд, то придется добавить на форму группу.

//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Группу
НоваяГруппа = ЭтаФорма.Элементы.Вставить("Группа1", Тип("ГруппаФормы"), ЭтаФорма, Этаформа.ПодчиненныеЭлементы[0]);
НоваяГруппа.Вид = ВидГруппыФормы.ОбычнаяГруппа;
//Создаем Кнопки
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа1);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа1);
НоваяКнопка.ИмяКоманды = "Команда1";

Заметьте, что хоть кнопки и одинаковы, хоть и выполняют одну и туже команду, но имена у них разные. К тому же, нам опять повезло, что на форме нет группы с именем «Группа1».

Случай № 5.
Все сводится к тому, что требуется создать группу с видом КоманднаяПанель, в нее вставить еще одну группу с видом подменю, у вот в подменю уже пихать кнопки.

//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем Группы
НоваяГруппа = ЭтаФорма.Элементы.Вставить("Группа1", Тип("ГруппаФормы"), ЭтаФорма, Этаформа.ПодчиненныеЭлементы[0]);
НоваяГруппа.Вид = ВидГруппыФормы.КоманднаяПанель;
НоваяГруппа = ЭтаФорма.Элементы.Добавить("Группа2", Тип("ГруппаФормы"), ЭтаФорма.Элементы.Группа1);
НоваяГруппа.Вид = ВидГруппыФормы.Подменю;
НоваяГруппа.Заголовок = "Выпадающая";
//Создаем Кнопки
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа2);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Группа2);
НоваяКнопка.ИмяКоманды = "Команда1";

Случай № 6.
Ищем на форме группу вида КоманднаяПанель. Можно программно через перебор всех элементов. Я же просто знаю, что в типовых формах почти всегда есть группа с названием ГруппаКоманднаяПанель, вид которой КоманднаяПанель. Так как это стандарт, воспользуемся этим.

//Создаем Команду
НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
НоваяКоманда.Действие = "ВыполнитьКоманду";
НоваяКоманда.Заголовок = "Жми сюда";
//Создаем группу, которая будет подменю для типовой
НоваяГруппа = ЭтаФорма.Элементы.Добавить("Подменю1", Тип("ГруппаФормы"), ЭтаФорма.Элементы.ГруппаКоманднаяПанель);
НоваяГруппа.Вид = ВидГруппыФормы.Подменю;
НоваяГруппа.Заголовок = "Выпадающая";
//Создаем Кнопки
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
НоваяКнопка.ИмяКоманды = "Команда1";
НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
НоваяКнопка.ИмяКоманды = "Команда1";

Но тут следует быть осторожным. Фирма 1С всегда может поменять имя группы или вообще удалить ее. Помните об этом.

Ну и самое главное - сама процедура приветствующая мир:

&НаСервере
Процедура Кнопки_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	//Создаем Команду
	НоваяКоманда = ЭтаФорма.Команды.Добавить("Команда1");
	НоваяКоманда.Действие = "ВыполнитьКоманду";
	НоваяКоманда.Заголовок = "Жми сюда";
	//Создаем группу, которая будет подменю для типовой
	НоваяГруппа = ЭтаФорма.Элементы.Добавить("Подменю1", Тип("ГруппаФормы"), ЭтаФорма.Элементы.ГруппаКоманднаяПанель);
	НоваяГруппа.Вид = ВидГруппыФормы.Подменю;
	НоваяГруппа.Заголовок = "Выпадающая";
	//Создаем Кнопки
	НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе1", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
	НоваяКнопка.ИмяКоманды = "Команда1";
	НоваяКнопка = ЭтаФорма.Элементы.Добавить("КнопкаВГруппе2", Тип("КнопкаФормы"), ЭтаФорма.Элементы.Подменю1);
	НоваяКнопка.ИмяКоманды = "Команда1";
КонецПроцедуры

&НаКлиенте
Процедура ВыполнитьКоманду(Команда)
    Сообщить("Привет, Мир!");
КонецПроцедуры

Делал статью как напоминалку для себя и в помощь другим, так что критика принимается, статья редактируется и дополняется.

программно добавить кнопку элемент типовую расширение

См. также

Поинтегрируем: сервисы интеграции – новый стандарт или просто коннектор?

Обмен между базами 1C Администрирование СУБД Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

В платформе 8.3.17 появился замечательный механизм «Сервисы интеграции». Многие считают, что это просто коннектор 1С:Шины. Так ли это?

11.03.2024    4504    dsdred    53    

71

Как готовить и есть массивы

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Все мы используем массивы в своем коде. Это один из первых объектов, который дают ученикам при прохождении обучения программированию. Но умеем ли мы ими пользоваться? В этой статье я хочу показать все методы массива, а также некоторые фишки в работе с массивами.

24.01.2024    5286    YA_418728146    25    

63

Планы обмена VS История данных

Обмен между базами 1C Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Вы все еще регистрируете изменения только на Планах обмена и Регистрах сведений?

11.12.2023    6408    dsdred    36    

111

1С-ная магия

Механизмы платформы 1С Бесплатно (free)

Язык программирования 1С содержит много нюансов и особенностей, которые могут приводить к неожиданным для разработчика результатам. Сталкиваясь с ними, программист начинает лучше понимать логику платформы, а значит, быстрее выявлять ошибки и видеть потенциальные узкие места своего кода там, где позже можно было бы ещё долго медитировать с отладчиком в поисках источника проблемы. Мы рассмотрим разные примеры поведения кода 1С. Разберём результаты выполнения и ответим на вопросы «Почему?», «Как же так?» и «Зачем нам это знать?». 

06.10.2023    18470    SeiOkami    46    

118

Дефрагментация и реиндексация после перехода на платформу 8.3.22

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Начиная с версии платформы 8.3.22 1С снимает стандартные блокировки БД на уровне страниц. Делаем рабочий скрипт, как раньше.

14.09.2023    12086    human_new    27    

74

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8813    YA_418728146    6    

141

Внешние компоненты Native API на языке Rust - Просто!

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Внешние компоненты для 1С можно разработывать очень просто, пользуясь всеми преимуществами языка Rust - от безопасности и кроссплатформенности до удобного менеджера библиотек.

20.08.2023    6275    sebekerga    54    

94

Все скопируем и вставим! (Буфер обмена в 1С 8.3.24)

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрим новую возможность 8.3.24 и как её можно эффективно использовать

27.06.2023    15980    SeiOkami    31    

103
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. vaxhab 16 13.05.21 12:26 Сейчас в теме
Спасибо за напоминалку
Gendelf; Uncore; DrAku1a; +3 Ответить
2. BomjBandit 13.05.21 14:16 Сейчас в теме
Я думаю, что все-таки не хватает картинок, которые показывают результат работы кода.
Если ещё докапываться, то
ЭтаФорма.
лишнее, но мб новичкам нагляднее.
DrAku1a; Sla; +2 Ответить
3. tommadm 15.05.21 08:58 Сейчас в теме
Читайте внимательнее, написано автором: "Отступление: Так как мы будем вставлять новый элемент в туже форму, в которой находится код, то «ЭтаФорма» можно не указывать.".
adhocprog; DrAku1a; +2 Ответить
4. Bassgood 1425 18.05.21 09:52 Сейчас в теме
(2) А еще вместо "ЭтаФорма" (вы его не найдете в СП) требуется использовать более универсальный "ЭтотОбъект"
adhocprog; +1 Ответить
5. Bassgood 1425 18.05.21 10:57 Сейчас в теме
А зачем в принципе что-то добавлять в интерфейс через расширение программным способом, ведь расширения призваны облегчить доработку таких вещей путем интерактивных добавлений на форму новых команд, кнопок и обработчиков к ним?
6. user1312100 197 18.05.21 15:32 Сейчас в теме
(5)В статье написано зачем.
7. SuhoffGV 19.05.21 10:15 Сейчас в теме
(5) Например, если вам нужно добавить одинаковую кнопку в несколько разных форм. В типовых для этого есть спец процедура общего модуля вызываемая в ПриСозданииНаСервере для всех (почти) форм.
Bassgood; +1 Ответить
8. Bassgood 1425 19.05.21 11:06 Сейчас в теме
(7) Если команда добавляется в множество форм - согласен, но в случае добавления ее в пару форм - создавать их программно как-то не очень.
Если нужно добавить одну и ту же команду в несколько форм - можно создать в дереве конфы общую команду (или команду объекта метаданных), указать в ней нужные типы данных объектов (тип параметра команды), в формах которых ее следует отображать, ну и задать ее расположение на формах через группу команд
31. izidakg 170 25.06.23 14:00 Сейчас в теме
(5) если говорить про профессиональную разработку, то новые формы делаете как хотите вы или заказчик
что касается помещенных из основной конфигурации в расширение, то правильным будет программное создание элементов форм, команд, колонок и т.д.
при этом типовая форма НИКОГДА не изменяется
но люди ленивы и не всегда профессиональны, вот и добавляют на формы вручную новые элементы, а потом сложности с обновлением. ведь каждый раз все что руками добавили, нужно перенести снова руками. кодом же все просто, при создании формы в процедуре все уже прописано. максимум возможно придется сделать привязку к другой группе на форме отображение размещаемого элемента.
9. user1312100 197 19.05.21 14:02 Сейчас в теме
Ребят, мне удалить статью?
10. Bassgood 1425 20.05.21 12:02 Сейчас в теме
(9) Зачем, вы будете удалять все публикации, которые обсуждаются или критикуются сообществом? :)
11. user1312100 197 20.05.21 14:12 Сейчас в теме
Дак получается статья ненужная
12. BomjBandit 20.05.21 15:44 Сейчас в теме
(11) Нужная-нужная, никто в здравом уме не будет дорабатывать серьезные базы через расширения. Новые реквизиты создают в дереве метаданных, а их элементы на форму выводят программно. Можешь до кучи сделать статью по программному выводу таблиц, полей и их наглядную иерархию.
28. wertep 23 21.02.23 16:05 Сейчас в теме
(11) Очень даже нужная статья. Особенно сейчас, когда в линейке конфигураций ERP, КА, УТ появились общие модули "МодификацияКонфигурацииПереопределяемый" и через них можно обрабатывать события добавленных элементов. Еще не полностью функционал реализован, но начало положено.

Еще наверное стоит добавить нюанс с подсказкой. У кнопки на форме подсказка отсутствует, просто нет соответствующего свойства. Чтобы у кнопки была подсказка, ее нужно добавлять к команде. Наступил на такую особенность.
user1648665; +1 Ответить
22. пользователь 22.10.21 13:16
Сообщение было скрыто модератором.
...
13. psa247 17 15.10.21 19:49 Сейчас в теме
Такой вопрос. Мне нужно не закрывая документ обновить подменю программно созданных кнопок командной панели.
Уточню свой вопрос. Можно ли динамически пересоздать кнопки помимо процедуры "ПриСозданииНаСервере"
14. user1312100 197 18.10.21 06:33 Сейчас в теме
(13) Я не пробовал, но, думаю, можно. Самое главное определиться с событием: пересоздание кнопок будет при нажатии других кнопок или при изменении реквизита - решайте сами... Попробуйте там вызвать код, а потом обновить форму.
15. psa247 17 18.10.21 06:57 Сейчас в теме
Доброго дня! Респект разработчикам, все получилось и несложно в итоге. Моя задача была - генерировать по событию (считай - в любой момент) заранее неизвестное количество кнопок подменю и чтобы 1С умела конкретно в каждом нажатии сделать что-то уникальное. Само обновление количества кнопок Я сделал процедуру наКлиенте, которая вызывает процедуру НаСервере, которая, соответственно вызывает процедуру создания кнопок подменю аналогично той, что приведена в примере. А уникальность действий обеспечиваю ГУИДами, которые передаю через "Команду". Если кому понадобится - приложу пример
17. user1312100 197 18.10.21 08:08 Сейчас в теме
16. user1312100 197 18.10.21 08:07 Сейчас в теме
Приведите пример процедуры, в которой идет обновление формы... А уж куда ее вставить люди решат сами.
18. psa247 17 18.10.21 08:13 Сейчас в теме
&НаКлиенте
Процедура ПРОФ_ПриОткрытииПосле(Отказ)
	ОбновитьКнопкиМеню();
	ПереключитьДоступностьКнопок(ЛОЖЬ);
КонецПроцедуры

&НаКлиенте
Процедура ПереключитьДоступностьКнопок(ИдетЗапись)
	ЭтаФорма.Элементы.ПРОФ_КнопкаОстановитьЗапись.Доступность = ИдетЗапись;
	ЭтаФорма.Элементы.ПРОФ_ВоспроизвестиЗапись.Доступность = НЕ ИдетЗапись;
	ЭтаФорма.Элементы.ПРОФ_УдалитьЗапись.Доступность = НЕ ИдетЗапись;
	ЭтаФорма.Элементы.ПРОФ_КнопкаНачатьЗапись.Доступность = НЕ ИдетЗапись;
КонецПроцедуры

&НаКлиенте
Процедура ОбновитьКнопкиМеню()
	ОбновитьКнопкиНаСервере();
	ПереключитьДоступностьКнопок(ЛОЖЬ);
КонецПроцедуры

&НаСервере
Процедура ОбновитьКнопкиНаСервере()
	ГУИД = Объект.Ссылка.УникальныйИдентификатор();
	ИмяКаталога = ПолучитьПутьХраненияЗаписей()+ГУИД;
	КаталогНаДиске = Новый Файл(ИмяКаталога);
	Если КаталогНаДиске.Существует() = ЛОЖЬ Тогда Возврат; КонецЕсли;

	Файлы = НайтиФайлы(ИмяКаталога, "*.mp3", ЛОЖЬ);
	// Удаляем все кнопки
	
	Для Каждого Тек ИЗ ЭтаФорма.Элементы.ПРОФ_ВоспроизвестиЗапись.ПодчиненныеЭлементы Цикл
		ЭтаФорма.Элементы.Удалить(Тек);			
	КонецЦикла;
	Для Каждого Тек ИЗ ЭтаФорма.Элементы.ПРОФ_УдалитьЗапись.ПодчиненныеЭлементы Цикл
		ЭтаФорма.Элементы.Удалить(Тек);			
	КонецЦикла;
	
	Для Каждого Тек ИЗ Файлы Цикл
		Струк = ПолучитьСведенияОФайле(Тек.ИмяБезРасширения);
		ИмяКнопки = СтрЗаменить(Тек.ИмяБезРасширения, "~", "_");
		ИмяКнопки = СтрЗаменить(ИмяКнопки, "-", "_");
		ИмяКнопки = Струк.ГУИД;
		
		ЗаголовокКнопки = "Запись от " + Струк.ДатаЗаписи+", время: "+Струк.Продолжительность+" "+Струк.Автор;
		
		НайденныйЭлементФормы = ЭтаФорма.Элементы.Найти("П_" + ИмяКнопки);
		Если НайденныйЭлементФормы <> Неопределено  Тогда
            ЭтаФорма.Элементы.Удалить(НайденныйЭлементФормы);
        КонецЕсли;		
		
		Если ЭтаФорма.Команды.Найти("П_" + ИмяКнопки) = Неопределено Тогда
			НоваяКоманда = ЭтаФорма.Команды.Добавить("П_" + ИмяКнопки);
	        НоваяКоманда.Действие = "ПроигратьЗапись";
			НоваяКоманда.Заголовок = ЗаголовокКнопки;
		КонецЕсли;		
			
		НоваяКнопка = Элементы.Добавить("П_" + ИмяКнопки, Тип("КнопкаФормы"), ЭтаФорма.Элементы.ПРОФ_ВоспроизвестиЗапись);
		НоваяКнопка.Вид = ВидКнопкиФормы.КнопкаКоманднойПанели;
		НоваяКнопка.ИмяКоманды = "П_" + ИмяКнопки;
		НоваяКнопка.Заголовок = ЗаголовокКнопки;
		НоваяКнопка.ТолькоВоВсехДействиях = ЛОЖЬ;  
		НоваяКнопка.Пометка = ЛОЖЬ;
		
		
		ЗаголовокКнопки = "Удалить запись от " + Струк.ДатаЗаписи +", время: "+Струк.Продолжительность+" "+Струк.Автор;
		
		НайденныйЭлементФормы = ЭтаФорма.Элементы.Найти("У_" + ИмяКнопки);
		Если НайденныйЭлементФормы <> Неопределено  Тогда
            ЭтаФорма.Элементы.Удалить(НайденныйЭлементФормы);
        КонецЕсли;		
		
		Если ЭтаФорма.Команды.Найти("У_" + ИмяКнопки) = Неопределено Тогда
			НоваяКоманда = ЭтаФорма.Команды.Добавить("У_" + ИмяКнопки);
	        НоваяКоманда.Действие = "УдалитьЗапись";
			НоваяКоманда.Заголовок = ЗаголовокКнопки;
		КонецЕсли;
		
		НоваяКнопка = Элементы.Добавить("У_" + ИмяКнопки, Тип("КнопкаФормы"), ЭтаФорма.Элементы.ПРОФ_УдалитьЗапись);
		НоваяКнопка.Вид = ВидКнопкиФормы.КнопкаКоманднойПанели;
		НоваяКнопка.ИмяКоманды = "У_" + ИмяКнопки;
		НоваяКнопка.Заголовок = ЗаголовокКнопки;
		НоваяКнопка.ТолькоВоВсехДействиях = ЛОЖЬ;
		НоваяКнопка.Пометка = ЛОЖЬ;
	КонецЦикла;
	
КонецПроцедуры

&НаСервере
Процедура ПРОФ_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	ОбновитьКнопкиНаСервере();
КонецПроцедуры

&НаСервере
Функция ПолучитьСведенияОФайле(Стр)
	Струк = Новый Структура;
	Струк.Вставить("ДатаЗаписи", Неопределено);
	Струк.Вставить("Автор", Неопределено);
	Струк.Вставить("ГУИД", Неопределено);
	Струк.Вставить("Продолжительность", Неопределено);
	
	// Формат имени файла: ДатаЗаписи_Продолжительность_Автор_ГУИД
	Струк.ДатаЗаписи = ПрочитатьДоСледПалки(0, 1, Стр);
	Струк.Продолжительность = ПрочитатьДоСледПалки(1, 2, Стр);
	Струк.Автор = ПрочитатьДоСледПалки(2, 3, Стр);
	Струк.ГУИД = ПрочитатьДоСледПалки(3, 4, Стр);
	
	Если Струк.ГУИД <> Неопределено Тогда
		Струк.ГУИД = СтрЗаменить(Струк.ГУИД, "-", "_");
	КонецЕсли;
	
	Возврат(Струк);
КонецФункции
Показать
19. psa247 17 18.10.21 08:14 Сейчас в теме
Без проблем, кто не разберется - переспросит
20. user1312100 197 18.10.21 08:36 Сейчас в теме
(19)Я правильно понял, что обновлять\перечитывать форму для отображения новых кнопок не нужно?
21. psa247 17 18.10.21 08:46 Сейчас в теме
Да. Я вызываю каждый раз процедуру, которая удаляет все кнопки подменю. Потом заново их пересоздает. Обновление формы не требуется. Открывать/закрывать документ, соответственно, тоже
23. admnnts 01.05.22 08:44 Сейчас в теме
Ожидал от статьи немного большего, т.к. она называется "как добавить программно кнопку на форму путем расширения".
Зачем форму тащить в расширение, если можно добавить через дабавление в расширение процедуры &После("ПриСозданииНаСервере") и тут пиши кнопку программно.
Вот теперь мой искомый вопрос, как заставить эту кнопку выполнять процедуру при нажатии, никак не получается всякими способами, подскажите, пожалуйста, что не так делаю.

При этом кроме самого справочника ничего не добавлялось в расширение. Не формы, не реквизиты. Все описывается в общем модуле - МодификацияКонфигурацииПереопределяемый.
вот код:
&После("ПриСозданииНаСервере")
Процедура ДопЭлементыПрограммно_ПриСозданииНаСервере(Форма, Отказ, СтандартнаяОбработка)
	Если Форма.ИмяФормы = "Справочник.КлючиАналитикиУчетаНоменклатуры.Форма.ФормаЭлемента" Тогда
		
		ПолеНоменклатураКод77 			= Форма.Элементы.Вставить("НоменклатураКод77", Тип("ПолеФормы"));
		ПолеНоменклатураКод77.Заголовок	= "Код 7.7";
		ПолеНоменклатураКод77.Вид		= ВидПоляФормы.ПолеНадписи;
			
		НоменклатураКод77 = Форма.Объект.Номенклатура;
		ПолеНоменклатураКод77.ПутьКДанным	= "Объект.Номенклатура.КодИз77";
			
		//СсылкаНоменклатураКод77				= Форма.Элементы.Вставить("СсылкаКод77", Тип("ДекорацияФормы"));
		//СсылкаНоменклатураКод77.Заголовок 	= "Скопировать код";
		//СсылкаНоменклатураКод77.Гиперссылка	= Истина;
		//СсылкаНоменклатураКод77.УстановитьДействие("Нажатие", "ДопЭлементыПрограммно_ВыполнитьКопированиеКода77");
		
		
		КомандаНоменклатураКод77			= Форма.Команды.Добавить("СкописроватьКод");
		КомандаНоменклатураКод77.Заголовок	= "Скопировать код";
		КомандаНоменклатураКод77.Действие	= "ДопЭлементыПрограммно_ВыполнитьКопированиеКода77";  
		
		СсылкаНоменклатураКод77				= Форма.Элементы.Вставить("СсылкаКод77", Тип("КнопкаФормы"));
		СсылкаНоменклатураКод77.ИмяКоманды	= "СкописроватьКод";
		СсылкаНоменклатураКод77.Вид			= ВидКнопкиФормы.Гиперссылка;
		
	КонецЕсли;

КонецПроцедуры

&НаКлиенте
Процедура ДопЭлементыПрограммно_ВыполнитьКопированиеКода77()

	Сообщить("Должно произойти копирование кода");

КонецПроцедуры // ВыполнитьКопированиеКода77()
Показать
26. wrooom 172 07.09.22 12:43 Сейчас в теме
(23) Нашли решение этой задачи? У меня всегда видна кнопка через "МодификацияКонфигурацииПереопределяемый.ПриСозданииНаСервере", но чтоб кнопка выполняло какое-то действие не получается.
29. wertep 23 21.02.23 16:23 Сейчас в теме
(26) На данный момент через этот механизм можно выполнять действия на клиенте. В действия команды записать вызов "Подключаемый_ВыполнитьПереопределяемуюКоманду".
Команда.Действие = "Подключаемый_ВыполнитьПереопределяемуюКоманду"


И потом перехватить это в модуле "МодификацияКонфигурацииКлиентПереопределяемый".
&После("ВыполнитьПереопределяемуюКоманду")
Процедура Префикс_ВыполнитьПереопределяемуюКоманду(Форма, Команда, ДополнительныеПараметры) Экспорт
	
	// Обработчики команд модифицированных форм
	Если Форма.ИмяФормы = "ПолноеИмяМодифицированнойФормы" Тогда
		
		Если Команда.Имя = "ИмяКоманды" Тогда
			// Обработка команды 
			ОбщегоНазначенияКлиент.СообщитьПользователю("Выполнена команда");
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры
Показать


С выполнением кода на сервере пока все плохо. Только через костыли подключаемых команд.
VyacheslavShilov; +1 Ответить
24. user1312100 197 11.05.22 10:24 Сейчас в теме
Вот реально работающий пример, добавляющий кнопку на стандартную форму движений документа в БП 3.0
&НаСервере
Процедура UK_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	//Создаем Команду
	НоваяКоманда = ЭтаФорма.Команды.Добавить("ДД");
	НоваяКоманда.Действие = "ВыполнитьКоманду_UK";//Имя процедуры
	НоваяКоманда.Заголовок = "ДобавитьДвижение";
	//Создаем Кнопку перед указанным
	НоваяКнопка = ЭтаФорма.Элементы.Вставить("КнопкаВНачале", Тип("КнопкаФормы"), ЭтаФорма, ЭтаФорма.ПодчиненныеЭлементы[0]);
	НоваяКнопка.ИмяКоманды = "ДД";
	//скрываем кнопку и показываем только для реализации и для услуг
	НоваяКнопка.Видимость = Ложь;
	Если  ТипЗнч(ДокументДвижений) = Тип("ДокументСсылка.РеализацияТоваровУслуг") Тогда
		Если ДокументДвижений.ВидОперации = Перечисления.ВидыОперацийРеализацияТоваров.Услуги Тогда
			НоваяКнопка.Видимость = Истина
		КонецЕсли;
	КонецЕсли;	
КонецПроцедуры

&НаКлиенте
Процедура ВыполнитьКоманду_UK(Команда)
	
    РучнаяКорректировка = Истина;
	//Модифицированность = Истина;
	ВыполнитьДействияПриИзмененииРучнойКорректировки();
	Кол = ХозрасчетныйНаборЗаписей.Количество();
	Стр = ХозрасчетныйНаборЗаписей[0];
	Нов = ХозрасчетныйНаборЗаписей.Добавить();
		
	Нов.Активность = Истина;
	Нов.ВалютаДт = Null;
	Нов.ВалютаКт = Null;
	Нов.ВалютнаяСуммаДт = Null;
	Нов.ВалютнаяСуммаКт = Null;
	Нов.ВалютныйДтДоступность = Ложь;
	Нов.ВалютныйКтДоступность = Ложь;
	Нов.КоличественныйДтДоступность = Ложь;
	Нов.КоличественныйКтДоступность = Ложь;
	Нов.КоличествоДт = Null;
	Нов.КоличествоКт = Null;
	Нов.НадписьВР = "ВР:";
	Нов.НадписьКоличествоДт = "";
	Нов.НадписьКоличествоКт = "";
	Нов.НадписьНУ = "НУ:";
	Нов.НадписьПР = "ПР:";
	Нов.НеКорректироватьСтоимостьАвтоматически = Ложь;
	Нов.Организация = Стр.Организация;
	Нов.Период = Стр.Период;
	Нов.ПодразделениеДт = Null;
	Нов.ПодразделениеДтДоступность = Ложь;
	Нов.ПодразделениеКт = Null;
	Нов.ПодразделениеКтДоступность = Ложь;
	Нов.Регистратор = Стр.Регистратор;
	Нов.Содержание = Стр.Содержание;
	Нов.СубконтоДт1 = Стр.СубконтоКт1;
	СубконтоДт1Доступность = Истина;
	Нов.СубконтоДт2 = Стр.СубконтоКт2;
	Нов.СубконтоДт2Доступность = Истина;
	Нов.СубконтоДт3 = Неопределено;
	Нов.СубконтоДт3Доступность = Ложь;
	Нов.СубконтоКт1 = Стр.СубконтоДт1;
	СубконтоКт1Доступность = Истина;
	Нов.СубконтоКт2 = Стр.СубконтоДт2;
	СубконтоКт2Доступность = Истина;
	Нов.СубконтоКт3 = Стр.Регистратор;
	СубконтоКт3Доступность = Истина;
	Нов.Сумма = ?(Кол > 1, Стр.СуммаНУКт, Стр.Сумма);
	Нов.СуммаВРДт = Стр.СуммаВРДт;
	Нов.СуммаВРКт = Стр.СуммаВРКт;
	Нов.СуммаНУДт = ?(Кол > 1, Стр.СуммаНУКт, Стр.СуммаНУДт);
	Нов.СуммаНУКт = Стр.СуммаНУКт;
	Нов.СуммаПРДт = Стр.СуммаПРДт;
	Нов.СуммаПРКт = Стр.СуммаПРКт;
	Нов.УточнениеПериода = Стр.УточнениеПериода;
	
	Нов.СчетДт = ПолучитьПланСчетов_UK("91.02");
	ОбработатьИзменениеСчета_UK("Дт", Нов);
	Нов.СчетКт = ПолучитьПланСчетов_UK("76.06");
	ОбработатьИзменениеСчета_UK("Кт", Нов);
		
КонецПроцедуры

Функция ПолучитьПланСчетов_UK (Стр)
	Возврат ПланыСчетов.Хозрасчетный.НайтиПоКоду(Стр);
КонецФункции

&НаКлиенте
Процедура ОбработатьИзменениеСчета_UK(ДтКт, ТекущиеДанные)

	//ТекущиеДанные = ДтКт;
	
	ПоляФормы = Новый Структура("Субконто1,Субконто2,Субконто3");
	ПоляФормы.Субконто1 = "ХозрасчетныйСубконто" + ДтКт + "1";
	ПоляФормы.Субконто2 = "ХозрасчетныйСубконто" + ДтКт + "2";
	ПоляФормы.Субконто3 = "ХозрасчетныйСубконто" + ДтКт + "3";
	БухгалтерскийУчетКлиентСервер.ПриВыбореСчета(ТекущиеДанные["Счет" + ДтКт], ЭтаФорма, ПоляФормы, Неопределено, Истина, Ложь);
	
	ПоляОбъекта = Новый Структура("Субконто1,Субконто2,Субконто3,Подразделение,Валютный,Количественный,Организация");
	ПоляОбъекта.Субконто1      = "Субконто" + ДтКт + "1";
	ПоляОбъекта.Субконто2      = "Субконто" + ДтКт + "2";
	ПоляОбъекта.Субконто3      = "Субконто" + ДтКт + "3";
	ПоляОбъекта.Подразделение  = "Подразделение" + ДтКт;
	ПоляОбъекта.Валютный       = "Валютный" + ДтКт;
	ПоляОбъекта.Количественный = "Количественный" + ДтКт;
	ПоляОбъекта.Организация    = Объект.Организация;
	БухгалтерскийУчетКлиентСервер.ПриИзмененииСчета(ТекущиеДанные["Счет" + ДтКт], ТекущиеДанные, ПоляОбъекта, Истина,, Ложь);
	
	ИзменитьПараметрыВыбораПолейСубконто(ЭтаФорма, ДтКт);
	
	ЗаполнитьНадписиВПроводке(ТекущиеДанные);
	
КонецПроцедуры
Показать
EvgeniyOlxovskiy; +1 Ответить
25. a-m-gv 36 08.06.22 14:13 Сейчас в теме
Ситуацию 2 стоит дополнить, например:
Элементы.Переместить(Элт,Элементы.ГруппаШапка,Элементы.ГруппаВидаОплаты);

//Элт - вновь созданный элемент,
// переместили в ГруппуШапка, перед Группой Вида оплаты
adhocprog; +1 Ответить
27. 1c-asu 03.12.22 21:23 Сейчас в теме
Спасибо большое. Очень пригодилось для Универсального отчета.
30. MaratM 27.04.23 13:33 Сейчас в теме
Спасибо за статью. Так бы 1с документацию писало, цены бы ей не было.
32. igor447 29.08.23 09:39 Сейчас в теме
Спасибо огромнейшее!!!
33. igor447 29.08.23 10:58 Сейчас в теме
Вопрос: пытаюсь разместить создаваемый элемент в право, пока не получается (ГоризонтальноеПоложение = ГоризонтальноеПоложение.Право). Элемент не в группе. Не подскажите, как это можно осуществить?
34. cdiamond 233 29.11.23 15:42 Сейчас в теме
У вас там в примерах для вставки в начало формы вместо ухищрений с массивом сперва нужно писать простой способ с добавлением, тупо указывая родительский ЭтаФорма.КоманднаяПанель,
А метод Вставить использовать там где реально нужно вставлять между двумя элементами формы.
Оставьте свое сообщение