О цикле обратном замолвите слово...

Публикация № 1723737 08.09.22

Приемы и методы разработки - Механизмы платформы 1С

Однажды, написав статью, расписывающую достоинства 1С, я упомянул среди недостатков - мне не хватает "обратного цикла". При этом, столкнулся с непониманием - "а зачем тебе обратный цикл". Сегодня я отвечу на этот вопрос.
 
 Предисловие

Я обожаю 1С. Программировать в данной среде мне очень комфортно, а главное - разработка занимает относительно немного времени. В своё время, я даже написал статью на Хабре, в которой хвалил 1С и высказывал некоторые претензии.
Данной статьёй я планирую начать цикл "придирок" к языку, платформе, типовым решениям 1С, в целом, высказаться на тему - чего ещё не хватает.

Я искренне верю, что внутри фирмы "1С" наши письма с просьбами читают и анализируют. А также, полагаю, они просматривают публикации на Инфостарте.

 
 Про циклы

 В языке 1С платформы "1С:Предприятие 8" на данный момент существует три вида цикла:

  • Цикл "Для" по счетчику, от меньшего к большему, с неизменным шагом +1;
  • Цикл "Для каждого" для коллекций, поддерживающих перебор (большинство коллекций);
  • Цикл "Пока" по условию (только в начале цикла).

И для решения основных задач этого достаточно. А какие виды циклов существуют ещё?

  • Цикл "Для" по счетчику, с настраиваемым шагом (см. язык BASIC)
  • Цикл "Для" от большего к меньшему (с отрицательным шагом -1, или настраиваемым, см. язык PASCAL)
  • Цикл "Делай ... Пока" по условию (в конце цикла, так что цикл выполнится не менее 1 раза, см. язык PASCAL)
  • Существуют также более сложные варианты циклов (см. язык С и все его "потомки").


Однажды, написав статью, расписывающую достоинства 1С, я упомянул среди недостатков - "мне не хватает обратного цикла". При этом, столкнулся с непониманием - "а зачем вообще нужен обратный цикл?". Сегодня я отвечу на этот вопрос.
Итак...

Рассмотрим задачу: 
Есть таблица значений с колонкой, в которой хранятся числа. Требуется удалить все строки, в которых в указанной колонке хранятся четные значения.
Для моделирования такой таблицы и проверки результата подойдёт следующий код:

ТЗ = новый ТаблицаЗначений;
ТЗ.Колонки.Добавить("Номер", новый ОписаниеТипов("Число"));
Массив = СтрРазделить("1, 1, 2, 1, 4, 6, 1, 1, 1, 8, 10, 1", ", ", Ложь);
Для каждого НомерСтрокой из Массив Цикл
	ТЗ.Добавить().Номер = Число(НомерСтрокой);
КонецЦикла;

Сообщить("Исходник: " + СтрСоединить(ТЗ.ВыгрузитьКолонку("Номер"), ", "));

// место вставки обработчика

Сообщить("Результат: " + СтрСоединить(ТЗ.ВыгрузитьКолонку("Номер"), ", "));

Имя переменной таблицы "ТЗ", имя колонки "Номер";


Попробуем решить данную задачу "в лоб":

Для сч=0 По ТЗ.Количество()-1 Цикл
	Если ТЗ[сч].Номер % 2 = 0 Тогда
		ТЗ.Удалить(сч);
	КонецЕсли;
КонецЦикла;

Попытка выполнить данный код приведет к исключению: "Индекс находится за границами массива" (да, да, именно "массива" - такую ошибку выдаёт платформа).

 
 Причина ошибки

Причина ошибки в том, что выражение "ТЗ.Количество()-1" рассчитывается только один раз до начала выполнения цикла, а не на каждой итерации (это задействует меньше вычислений и оптимально для большинства случаев использования "Для").
А, т.к. внутри цикла мы удаляем элементы коллекции, то размер этой коллекции тоже уменьшается. В итоге, счетчик выходит за пределы нашей коллекции и попытка чтения элемента приводит к ошибке.

 

Попробуем реализовать это через цикл "Пока"

сч = 0;
Пока сч<ТЗ.Количество() Цикл
	Если ТЗ[сч].Номер % 2 = 0 Тогда
		ТЗ.Удалить(сч);
	КонецЕсли;
	сч = сч + 1;
КонецЦикла;

Теперь мы проверяем Количество() при каждой итерации, что неоптимально в плане вычислительных ресурсов, но позволяет избежать выхода за границы. Вместо этого, можно присвоить ТЗ.Количество() некоторой переменной, сверять сч с ней, и уменьшать её когда удаляем строку. Это будет оптимальнее, но на несколько строк кода больше (а чем больше строк, тем сложнее потом будет его читать и разбирать).
Этот код уже выполнится.
Но в результате выдаст:
Исходник: 1, 1, 2, 1, 4, 6, 1, 1, 1, 8, 10, 1
Результат: 1, 1, 1, 6, 1, 1, 1, 10, 1

 
 Почему удалилось не всё?

Почему удалились не все чётные числа? Давайте разберем пошагово:
сч = 0: Массив значений в колонке: [1, 1, 2, 1, 4, 6, 1, 1, 1, 8, 10, 1], значение в ячейке = 1, пропускаем
сч = 1: Массив значений в колонке: [1, 1, 2, 1, 4, 6, 1, 1, 1, 8, 10, 1], значение в ячейке = 1, пропускаем
сч = 2: Массив значений в колонке: [1, 1, 2, 1, 4, 6, 1, 1, 1, 8, 10, 1], значение в ячейке = 2, удаляем, массив сместился на 1 влево
сч = 3: Массив значений в колонке: [1, 1, 1, 4, 6, 1, 1, 1, 8, 10, 1],     значение в ячейке = 4, удаляем, массив сместился на 1 влево
сч = 4: Массив значений в колонке: [1, 1, 1, 6, 1, 1, 1, 8, 10, 1],         значение в ячейке = 1, пропускаем (!)
сч = 5: Массив значений в колонке: [1, 1, 1, 6, 1, 1, 1, 8, 10, 1],         значение в ячейке = 1, пропускаем
сч = 6: Массив значений в колонке: [1, 1, 1, 6, 1, 1, 1, 8, 10, 1],         значение в ячейке = 1, пропускаем
сч = 7: Массив значений в колонке: [1, 1, 1, 6, 1, 1, 1, 8, 10, 1],         значение в ячейке = 8, удаляем, массив сместился на 1 влево
сч = 8: Массив значений в колонке: [1, 1, 1, 6, 1, 1, 1, 10, 1],             значение в ячейке = 1, пропускаем
сч = 9, сч=ТЗ.Количество(), цикл завершен
(красным выделены значения в строке [сч])

Обратите внимание, когда рядом стоят два четных числа, то после удаления строки - второе число смещается на 1 влево, при этом, счетчик увеличивается на 1 и, получается, перескакивает это число.

Такое происходит не только когда два четных числа стоят рядом. Обратите внимание, что когда сч=2 тоже происходит "перескакивание" через 1 значение, но т.к. оно является нечетным и всё равно не должно было быть удалено, то в результате выполнения это незаметно.

 


А как себя поведёт цикл "Для каждого"?

Для Каждого Строка из ТЗ Цикл
	Если Строка.Номер % 2 = 0 Тогда
		ТЗ.Удалить(Строка);
	КонецЕсли;
КонецЦикла;

Этот код уже выполниться без ошибок. Но результат выдаст точно такой-же, как и цикл "Пока"
Исходник: 1, 1, 2, 1, 4, 6, 1, 1, 1, 8, 10, 1
Результат: 1, 1, 1, 6, 1, 1, 1, 10, 1


Как бы решалась эта задача, если бы у нас был обратный цикл?
"Для" со счетчиком -1 решил бы эту проблему:

Для ТЗ.Количество()-1 По сч=0 Цикл //обратный или шаг -1
	Если ТЗ[сч].Номер % 2 = 0 Тогда
		ТЗ.Удалить(сч);
	КонецЕсли;
КонецЦикла;

Т.к. обход коллекции выполняется в обратном порядке, удаление элемента смещает массив относительно счетчика цикла, но и счетчик смещается в том-же направлении.


 

Так как-же быть?
А теперь, варианты костылей, с помощью которых решается эта задача (все они приводят к желаемому результату):

1. Аналог решения, встречаемый в типовых конфигурациях 1С:

МассивНаУдаление = новый Массив;

Для каждого Строка из ТЗ Цикл
	Если Строка.Номер % 2 = 0 Тогда
		МассивНаУдаление.Добавить(Строка);
	КонецЕсли;
КонецЦикла;

Для каждого Строка из МассивНаУдаление Цикл
	ТЗ.Удалить(Строка);
КонецЦикла;

Нужны комментарии?


2. Вариант с циклом "Пока", но со смещением или счетчика или строки

сч = 0;
Пока сч<ТЗ.Количество() Цикл
	Если ТЗ[сч].Номер % 2 = 0 Тогда
		ТЗ.Удалить(сч);
	Иначе
		сч = сч + 1;
	КонецЕсли;
КонецЦикла;


3. Еще один вариант с циклом "Пока"

сч = 0;
Пока сч<ТЗ.Количество() Цикл
	Если ТЗ[сч].Номер %2 = 0 Тогда
		ТЗ.Удалить(сч);
		сч = сч - 1;
	КонецЕсли;
	сч = сч + 1;
КонецЦикла;


4. Эмуляция обратного цикла с помощью цикла "Пока"
(сам я, чаще всего, в коде делаю именно так, т.к. это минимум лишних операций и уменьшение счетчика в первой-же строке внутри цикла гарантирует, что если в теле цикла будет "Продолжить" - не произойдёт зацикливание)

сч = ТЗ.Количество();
Пока сч>0 Цикл
	сч = сч - 1;
	Если ТЗ[сч].Номер % 2 = 0 Тогда
		ТЗ.Удалить(сч);
	КонецЕсли;
КонецЦикла;


5. Эмуляция обратного цикла с помощью цикла "Для"
(а этот метод мне попался недавно, и заинтересовал. Хотя количество операций смены знака здесь немалое, код смотрится весьма лаконично)

Для сч = -ТЗ.Количество() + 1 По 0 Цикл
	Если ТЗ[-сч].Номер % 2 = 0 Тогда
		ТЗ.Удалить(-сч);
	КонецЕсли;
КонецЦикла;

Ну да, цикл "Для" хоть и по счетчику +1, но нормально работает с отрицательными числами.
 

 
Резюмирую

Это упрощенная вариация задач, периодически встречающихся в разработке, к задачам такого-же плана относятся задачи вида "удалить все цифры из строки", "удалить дублирующиеся элементы в коллекции". Даже сама фирма 1С сталкивается с подобными задачами при разработке своих типовых решений. И задача очень лаконично решается через обратный цикл. Вот почему мне бы хотелось видеть его в составе конструкций языка 1С (а заодно, можно бы и "Для каждого" допилить, чтобы не пропускал элементы коллекции).

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. salexdv 2092 08.09.22 08:34 Сейчас в теме
Предлагаю не мелочиться, а сразу попросить у 1С фильтры для коллекций, чтобы делать что-то вроде такого

НоваяТаблица = Таблица.Фильтр((СтрокаТЧ) => СтрокаТЧ.Номер % 2 = 0)


И сортировку туда же

Таблица.Сортировать((Строка0, Строка1) => Строка0.Номер - Строка1.Номер)
CodeNull; LimarenkoA; 7OH; kser87; Бубузяка; VladC#; Altez50; Поручик; Irwin; Sedaiko; kirabr; CyberCerber; cleaner_it; anosin; artbear; Windsor77; Shmell; Артано; SAShikutkin; +19 Ответить
3. SAShikutkin 4 08.09.22 09:00 Сейчас в теме
(1)Аналог LINQ - действительно, было бы интересно)
11. tormozit 6594 08.09.22 09:26 Сейчас в теме
(1) Как их отлаживать? Если выражение достаточно сложное, то захочется пощупать его части для конкретной строки (например на которой возникла ошибка). Как это будет выглядеть?
12. Артано 726 08.09.22 09:29 Сейчас в теме
(11) Я думаю, что в скобках отдельная функция написанная в одну строку. Соответственно отладка будет в той самой функции. По крайней мере в других языках для переопределения условий сортировки/фильтрации пишется отдельная функция.
14. tormozit 6594 08.09.22 09:33 Сейчас в теме
(12) Если будет отдельная функция, то ОК. Технически нам и сейчас мешает ничто сделать такой механизм на прикладном уровне. Только придется делать явный цикл и вызов функции будет компилироваться при каждом его проходе, что несомненно внесет ощутимое замедление.
16. Артано 726 08.09.22 09:35 Сейчас в теме
(14) Поэтому граждане и просят, чтобы работало "искаропки". Тогда будет оптимизировано на уровне платформы. Хотя, полагаю, что сложный алгоритм сравнения не оптимизировать и придется применять функцию к каждому элементу.
58. ubnkfl 14.09.22 18:31 Сейчас в теме
(14)
мешает ничто

"Мешает ничто" - потому что вам не нравится двойное отрицание в русском языке? :)
59. tormozit 6594 14.09.22 22:41 Сейчас в теме
(58) Ты должен последовать моему примеру. Ведь ты и сам об этом задумывался и хотел попробовать. Что тебе мешает?
13. salexdv 2092 08.09.22 09:32 Сейчас в теме
(11) Это просто сокращенная запись такого

Функция ФильтрПоЧетным(СтрокаТЧ)

    Возврат СтрокаТЧ.Номер % 2 = 0;

КонецФункции

Таблица.Фильтр(ФильтрПоЧетным);
21. DrAku1a 1512 08.09.22 09:51 Сейчас в теме
(1) Не в таком виде, а в виде функции, передаваемой как параметр - можно было бы.
Мне нравится рекомендация 1С писать понятный код, даже используя большее количество строк кода.

Т.е. вместо:
СтруктураДанных = новый Структура("Наименование, Представление, Вид, Модифиукатор", "Наименование", "Представление", ...

делать многострочное:
СтруктураДанных = новый Структура;
СтруктураДанных.Вставить("Наименование", "Наименование");
СтруктураДанных.Вставить("Представление", "Представление");
...

второй вариант - нагляднее.
cleaner_it; Артано; +2 Ответить
25. salexdv 2092 08.09.22 09:56 Сейчас в теме
(21) Я с одной стороны согласен, а с другой нет. Конечно, если функция для фильтрации/сортировки сложная, то нет смысла записывать её в одну строку, но вот если она простая, как в моём примере, тогда это проще читается. Просто для нас, как для 1Сников это выглядит непривычно.
33. JohnyDeath 300 09.09.22 09:28 Сейчас в теме
(1) Можно еще вспомнить великолепную 1С++ для 7.7. Там есть очень крутой объект под названием ИндексированнаяТаблица, в которой можно удалять по Индексу с учетом наложенных на него фильтров. А еще у этого объект есть даже Левые и Правые соединения, разности, итоги по узлу и пр..
Вообще мощная вещь, как и весь 1С++
7OH; salexdv; Артано; DrAku1a; +4 Ответить
48. VladC# 65 12.09.22 08:55 Сейчас в теме
(1) Очень напминает лямбды из java, если бы что-то подобное появилось в 1с, то это был бы огромный шаг вперёд, но у 1с своё видение того что нужно, так что даже мечтать не стоит о таком.
2. the1 1118 08.09.22 08:50 Сейчас в теме
Как бы решалась эта задача, если бы у нас был обратный цикл?

Я возможно невнимательно читал, но в чем проблема? Обратный цикл в 1С есть и отлично работает
Для Сч = 1 - ТаблицаЗначений.Количество() По 0 Цикл
	ТаблицаЗначений.Удалить(ТаблицаЗначений.Получить(-Сч));
	// или
	ТаблицаЗначений.Удалить(-Сч);
КонецЦикла;
Revachol; user1792010; Sergey_Borisovi4; akR00b; Lobion; NiGMa; Yashazz; smit1c; Irwin; SerVer1C; insurgut; paybaseme; kuzev; CyberCerber; cleaner_it; mikl79; ixijixi; 7o2uYXg; user1559729; tormozit; +20 Ответить
7. Артано 726 08.09.22 09:12 Сейчас в теме
(2) Если поведение платформы не меняли, то такой цикл не выполнит ни одной итерации.

По сабжу автора - данный вопрос удобно решается обратным циклом, но сам пример может быть решен более оптимально (с точки зрения производительности) без поитерационного удаления строк. Я имею ввиду метод Скопировать().
9. tormozit 6594 08.09.22 09:17 Сейчас в теме
(7) Цикл рабочий. Я тоже его использую. Читай документацию.
Артано; +1 Ответить
10. Артано 726 08.09.22 09:21 Сейчас в теме
(9) Не разглядел два костыля в алгоритме. Согласен, рабочий. Но не очевидный. Документация тут вообще не причем, это просто своеобразный алгоритм, который будет примерно одинаковым на любом языке
8. tormozit 6594 08.09.22 09:15 Сейчас в теме
(2) У меня даже шаблон есть такой
Для Индекс = 1 - <?"Коллекция">.Количество() По 0 Цикл // Обратный обход
	<?"Элемент коллекции"> = <?"Коллекция">[-Индекс];
	Если <?> Тогда
		<?"Коллекция">.Удалить(<?"Элемент коллекции">);
	КонецЕсли;
КонецЦикла;
СергейК; Yashazz; Cmapnep; fancy; simgo83; Windsor77; MVK80; DrAku1a; zqzq; +9 Ответить
35. Cmapnep 16 09.09.22 09:50 Сейчас в теме
(8)
Для Индекс = 1 - .Количество() По 0 Цикл // Обратный обход
= [-Индекс];
Если Тогда
.Удалить();
КонецЕсли;
КонецЦикла;


А можешь поделиться своим файлом шаблонов - уверен там еще много интересного и полезного найдется
15. DrAku1a 1512 08.09.22 09:33 Сейчас в теме
(2) Невнимательно. См. в конце: "5. Эмуляция обратного цикла с помощью цикла "Для""
17. the1 1118 08.09.22 09:36 Сейчас в теме
(15) В чем тогда суть статьи "Не хватает обратного цикла", если обратный цикл есть?
CodeNull; Yashazz; ixijixi; +3 Ответить
20. Артано 726 08.09.22 09:45 Сейчас в теме
(17) Его нет, но его можно эмулировать. Такая эмуляция на мой взгляд есть хардкод. Нативно отрицательный шаг счетчика невозможен
Fox-trot; unknown181538; Windsor77; DrAku1a; +4 Ответить
22. DrAku1a 1512 08.09.22 09:52 Сейчас в теме
(20) Да. Именно про это статья.
49. the1 1118 12.09.22 10:34 Сейчас в теме
(20) Что такое нативно отрицательный шаг счетчика?
50. Артано 726 12.09.22 10:39 Сейчас в теме
(49) Здесь могла быть запятая, но переводится как: "искаропки в 1с нет отрицательного шага счетчика".
51. the1 1118 12.09.22 10:40 Сейчас в теме
(50) Может тогда для примера - где он есть искаропки? Я хоть сравню)
52. Артано 726 12.09.22 10:46 Сейчас в теме
(51) Си и потомки (через декремент) , Паскаль/Делфи, Бейсик и потомки. Множество их.
Питон еще вспомнил. В общем, масса примеров - щупайте =)
53. the1 1118 12.09.22 11:28 Сейчас в теме
(52) Бегло загуглил. Дошло, спасибо)
28. unknown181538 103 08.09.22 18:13 Сейчас в теме
(2) Вариант лаконичны и рабочий, но менее читаемый. Обратный цикл был более прозрачным.
4. quazare 2424 08.09.22 09:08 Сейчас в теме
Используйте функцию "РазложитьСтрокуВМассивПодстрок" - так будет "по-книжному"
18. DrAku1a 1512 08.09.22 09:38 Сейчас в теме
(4) СтрРазделить() - уже полноценная функция платформы (начиная с версии 8.3.6). До этого были только возможности БСП.
Yashazz; paybaseme; quazare; +3 Ответить
29. AntonProgma 37 08.09.22 22:59 Сейчас в теме
(18) главное - помнить о её ковартстве и не рассчитывать на многосимвольный разделитель
DrAku1a; Поручик; +2 Ответить
31. quazare 2424 09.09.22 06:17 Сейчас в теме
(18) вы правы! вообще материал хороший у вас - эдакая гимнастика для извилин.
5. MikhailDr 08.09.22 09:09 Сейчас в теме
Постоянно перебираю таблицы через Сч = Сч - 1; Проблемы не вижу, может я чего-то не понимаю?
19. DrAku1a 1512 08.09.22 09:45 Сейчас в теме
(5) Во-первых, это не так наглядно и интуитивно понятно, как цикл "Для".
Во-вторых, стоит один раз забыть написать эту самую "Сч = Сч - 1" и запустить код на исполнение... и Вы увидите, что проблема имеет место (или, если не делаете "Сч = Сч - 1" в самом начале цикла "Пока" и в цикле по какому-либо условию будет "Продолжить" - можно, также, получить зацикливание).
23. MikhailDr 08.09.22 09:53 Сейчас в теме
(19)
Во-вторых, стоит один раз забыть написать эту самую "Сч = Сч - 1"


Если так рассуждать, то надо от цикла "Пока" отказываться. Ведь там тоже можно вызвать зацикливание, это такой себе довод.

Что до интуитивности то конкретно здесь это вопрос опыта и привычки, для меня это абсолютно интуитивная конструкция.

Я в целом не имею ничего против обратных циклов, это небольшой синтаксический сахар. Но он очень небольшой, есть задачи гораздо более приоритетные в рамках развития платформы.
26. DrAku1a 1512 08.09.22 10:36 Сейчас в теме
(23)
Если так рассуждать, то надо от цикла "Пока" отказываться.
Цикл "Пока" хорошо подходит для обработки выборок (Пока Выборка.Следующий() Цикл).
60. DrAku1a 1512 19.09.22 08:53 Сейчас в теме
(23)
есть задачи гораздо более приоритетные в рамках развития платформы
можете озвучить?
в первую очередь интересует то, что касается языка 1С. Но и платформенные недоработки, и прочее - тоже интересно.
Как сказано в заголовке, я планирую цикл статей таких написать. Но, если это будет нечто большее, чем ИМХО - думаю, будет интереснее.

Например, я хочу разобрать пару типовых конфигураций и посмотреть почему они такие здоровые. Можно ли их сделать "легче" и что это даст.
61. MikhailDr 19.09.22 09:17 Сейчас в теме
(60) Тут конечно надо хорошо подумать, но навскидку я бы назвал пару вещей

1. Доработка механизма расширений. Тут много всего, в идеале расширения должны полностью повторять весь функционал основной конфигурации. Как пример - добавить тип "ЛюбаяСсылка"

2. Доработка контекстной подсказки в конфигураторе. Например создав таблицу в процедуре вам будет доступна контекстная подсказка только в рамках этой процедуры. Но если передать таблицу в другую процедуру, то там уже подсказка недоступна.
62. DrAku1a 1512 19.09.22 10:52 Сейчас в теме
(61) Тип "ЛюбаяСсылка" уже добавлен, но нужен режим совместимости 8.3.20 и выше. Проблема в том, что текущий режим совместимости типовых конфигураций 8.3.17-8.3.18, и с учетом того, как быстро поднимают этот режим - до использования его, например, с УТ 11 или БП 3, ожидать нужно ещё где-то 2 года.

Механизм расширений ещё сырой и активно развивается. Как и всем нововведения 1С, нужно время на адаптацию.

Из моих пожеланий к нему я бы выделил "возможность видеть другие расширения" - т.е. иерархию расширений (механизм "расширение на расширение"), или директиву "использует" с указанием других расширений и их версий и заимствования объектов из других расширений.

По проводу (2), есть мысль что сказать. Тут несколько сложнее ситуация, и связана она с отсутствием типизации параметров (процедур и функций). Это с одной стороны удобно.
6. Evg-Lylyk 3961 08.09.22 09:11 Сейчас в теме
(0) По описанному примеру: ИМХО вариант с массивом простой и понятный. Жаль что Удалить() не работает с массивом.
unknown181538; +1 Ответить
24. SerVer1C 501 08.09.22 09:53 Сейчас в теме
Требуем ООП , LINQ, дженерики и лямбды !!! Ну хотя бы инкремент чтобы завезли (причем в байт-коде он присутствует отдельным оп-кодом).
27. triviumfan 30 08.09.22 12:53 Сейчас в теме
Хоть тема и простая, но было интересно) спасибо
30. Pavel_Vladivostok 58 09.09.22 05:52 Сейчас в теме
Если таблица объемная, я бы предпочел выбрать не удаляемые строки запросом и скопировать исходную таблицу указав массив правильных строк, избегая при этом циклы вообще.
32. Артано 726 09.09.22 08:20 Сейчас в теме
34. JohnyDeath 300 09.09.22 09:45 Сейчас в теме
Еще вариант:
тз = Новый ТаблицаЗначений;
//.... наполнение тз ....
имяСлужебнойКолонки = "_Удалить_";
тз.Колонки.Добавить(имяСлужебнойКолонки, Новый ОписаниеТипов("Булево"));
Для Каждого строкаТЗ Из тз Цикл
	строкаТЗ._Удалить_ = (строкаТЗ.Номер % 2 = 0);	
КонецЦикла;
отбор = Новый Структура(имяСлужебнойКолонки, Ложь);
тз = тз.Скопировать(отбор);
тз.Колонки.Удалить(имяСлужебнойКолонки);
Показать
36. DrAku1a 1512 09.09.22 10:05 Сейчас в теме
(34) А чего мелочиться, давайте сделаем копию таблицы через ТЗ.ВыгрузитьКолонки() и заполним её строками с нечетными числами? (Это, мягко говоря, неоптимально).
38. JohnyDeath 300 09.09.22 10:16 Сейчас в теме
(36) возможно такой вариант будет даже более производительный, чем все вышеперечисленные.
Но надо, конечно же, проверять
39. DrAku1a 1512 09.09.22 10:31 Сейчас в теме
(38) Насколько я понимаю работу менеджеров памяти, выделять память под новые объекты им несколько сложнее и дольше, чем освобождать (по факту, при работе кода память не освобождается, а просто помечается неиспользуемой). При создании новой колонки, новой таблицы, нового массива - нужно ещё найти место где разместить эти объекты. Но, можно проверить, в этом плане 1С может удивить.
37. JohnyDeath 300 09.09.22 10:13 Сейчас в теме
А вообще нет с классическим "GoTo" во втором варианте
сч = 0;
Пока сч<ТЗ.Количество() Цикл
~Перепроверка:
	Если ТЗ[сч].Номер % 2 = 0 Тогда
		ТЗ.Удалить(сч);
		Перейти ~Перепроверка;
	КонецЕсли;
	сч = сч + 1;
КонецЦикла;
Показать
40. DrAku1a 1512 09.09.22 10:35 Сейчас в теме
(37) Оператор goto в языках высокого уровня является объектом критики, поскольку чрезмерное его применение приводит к созданию нечитаемого «спагетти-кода» (источник: статья на Википедии). Поэтому, варианты с безусловным переходом мною даже не рассматривались.
41. JohnyDeath 300 09.09.22 10:40 Сейчас в теме
(40) и что здесь черезмерного? По-моему этот код намного проще читается, чем большинство описанных.
Да, goto нежелателен. Но все-таки действовать надо по ситуациям, а не по рекомендациям википедии и ИТС
Хотя этот вариант будет скорее всего самый долгий
lunjio; Артано; +2 Ответить
42. DrAku1a 1512 09.09.22 11:06 Сейчас в теме
(41) Видимо, неправильно пояснил. Для меня уже за правило стало - не использовать операторы безусловного перехода. Именно из-за критики. Когда-то давно преподаватель информатики озвучил такое мнение: "Квалификация программиста обратно-пропорциональна использованию им оператора безусловного перехода" (это неточная цитата). Написать любой алгоритм возможно без GoTo.
Вот, нашел материал по теме: https://studfile.net/preview/1444532/page:12/
Fox-trot; +1 Ответить
43. JohnyDeath 300 09.09.22 11:09 Сейчас в теме
(42) ровно как и написать любой алгоритм без обратных циклов )
Артано; +1 Ответить
44. DrAku1a 1512 09.09.22 11:11 Сейчас в теме
(43) вот только критики обратных циклов не находил ))
Fox-trot; +1 Ответить
45. Артано 726 09.09.22 11:46 Сейчас в теме
(42) Согласен с Джонни. Если код станет нагляднее и лаконичнее с GOTO, то не вижу оснований фанатично его отрицать. Тот же Дейкстра, считающийся ненавистником безусловных переходов, допускал их ограниченное использование.
47. Art39_ 12.09.22 00:26 Сейчас в теме
5 вариант интересный, возьму на вооружение, жаль раньше не встречал.
46. PerlAmutor 127 09.09.22 17:52 Сейчас в теме
Использую 5-ый вариант цикла наверное уже как год, по поводу и без повода. Однажды увидел в типовой, понравилось.
54. Arxxximed 20 12.09.22 19:17 Сейчас в теме
По моему в 1С ооочень много чего не хватает, и приходится эмулировать. Синтаксический сахар для разработчиков 1С это зло )).
За удобствами вам не в 1С.
За удобствами вам в Python
55. DrAku1a 1512 13.09.22 03:41 Сейчас в теме
(54) В языке программирование - возможно. Хотя, по мне, синтаксис "вот тут отступ - это значит блок ("для", "если")" - ну, такое... Я не хочу сказать, что 1С лучше чем Python, ровно как и обратное. Свои достоинства и недостатки есть в каждом языке и в каждой среде.
Платформа 1С - это не только и не столько язык программирования. Это скорее - конструктор (конфигуратор), внутри которого много конструкторов поменьше (запросов, форматной строки, печатных форм и т.п.). Язык же - инструмент, который помогает работать созданным в конструкторах механизмам.
Прикрепленные файлы:
57. Arxxximed 20 14.09.22 12:07 Сейчас в теме
(55) Да, отступы или скобки - на вкус и цвет, мне отступы вполне зашли. Но по сравнению с Цикл КонецЦикла, Если КонецЕсли, КонецФункции... Уж лучше VBAшное END. Меньше писанины. И один черт отступы то есть во всех языках при форматировании )))))

Но суть не про это, а про синтаксический сахар Ну извините стандартное , идущее с незапамятных времен
переменная += 1;
могли бы уже добавить.

Про платформу - Вы правы, но речь идет именно же про язык. Автору не понравилось что нету обратного Цикла
Мне же не нравится что например питоновское СтрТекст[2:-2] приходится писать в Сред(СтрТекст, 2 , СтрДлина(СтрТекст-4)). Долго писать непонятно читать.
56. Артано 726 14.09.22 05:51 Сейчас в теме
(54) Примерно то же самое говорили разработчики на 7.7 когда появилась восьмёрка. Я например, игнорировал 1с, пока не вышла 8.2. Только после этого пошел в 1с "на полный штат".
Оставьте свое сообщение

См. также

Использование классов .Net в 1С для новичков Промо

Механизмы платформы 1С Платформа 1С v7.7 Платформа 1С v8.3 Бесплатно (free)

Руководство для новичков. Написав статью http://infostart.ru/public/238584/, я понял, что многие не понимают того, что написано. Поэтому в этой статье постараюсь более подробно остановиться на азах и без кода на вражеском языке (C#)

27.01.2016    89624    Serginio    116    

1С и Unicode

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Разбираемся, как 1С работает с текстом и отдельными символами в контексте Unicode.

05.09.2022    1664    Irwin    30    

Почему нельзя использовать ТекущаяДата()

БСП (Библиотека стандартных подсистем) Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

ИТС и ИС не ответили исчерпывающе, поэтому написал данную заметку.

23.08.2022    5897    Патриот    56    

Шпаргалка по функциям АСИНХ

Механизмы платформы 1С Платформа 1С v8.3 Россия Бесплатно (free)

При знакомстве с новой механикой работы с асинхронностью (обещание, ждать и асинх) делал пометки, которыми и хочу поделиться. Ничего сверхъестественного в них нет, просто небольшие примеры и некоторые всплывшие нюансы использования.

29.07.2022    4854    zeltyr    15    

Использование программных перечислений, ч.1: строковые константы Промо

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Часто ли у вас возникает необходимость в коде выполнять сравнение на строку?

10.12.2016    42257    unichkin    74    

Экспертный кейс. История расследования одного небыстрого закрытия месяца в 1C:ERP. Пример неочевидных путей расследования в виде детективной истории

HighLoad оптимизация Механизмы платформы 1С Запросы Платформа 1С v8.3 1С:ERP Управление предприятием 2 Бесплатно (free)

В данной статье хотим рассказать об одном нашем непростом расследовании, в котором удалось собрать сразу несколько проблем на разных уровнях инфраструктуры заказчика и изначальной методологии ведения учета. Само расследование в какой-то момент стало напоминать детективную историю, с роялями в кустах, ошибками платформы, странным поведением пользователей и магическим поведением хорошо знакомых механизмов. Но мы реалисты, поэтому все проблемы были выявлены и устранены ;)

11.07.2022    4262    it-expertise    27    

Состав индексов с дополнительным упорядочиванием на уровне СУБД (MS SQL) при индексации реквизитов

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

В момент обсуждения с коллегами работы индексов в 1С был затронут один из вопросов, который касался темы - каким образом происходит построение индексов при индексации реквизитов у объектов 1С (конкретнее, когда свойство реквизита "Индексировать" устанавливается в "Индексировать с доп. упорядочиванием"). Ранее я всегда опирался на знания, полученные в процессе чтения официальной документации от компании 1С, опубликованной на ITS. Наши мнения в этом вопросе разошлись и, как оказалось позже, мои знания не были актуальными, в итоге было проведено некоторое исследование по данному вопросу, чтобы выяснить истину.

15.06.2022    1628    sinichenko_alex    5    

Динамическое обновление - это зло?

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Копнем глубже в тему "Что же такое динамическое обновление" и почему оно может привести к проблемам. И может ли?

09.05.2022    12155    Infostart    77    

Вспомогательные инструкции в коде 1С Промо

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    38787    tormozit    107    

Об одной неочевидной проблеме перехода на версию платформы 8.3.20

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

При переходе на платформу 8.3.20 мы столкнулись с ошибкой "Повторяющийся псевдоним "Ссылка" Ссылка AS Ссылка,Presentation AS Presentation,Ссылка AS Ссылка" в ряде типовых конфигураций. Причём, эта проблема оказались неизвестна ни Яндексу, ни Гуглу. Путём мучительных экспериментов нам удалось найти решение. Пока я ещё не уверен, действительно это решение или обходной костыль, а настоящая проблема -- в чём-то другом, но это решение работает в ситуации, когда всё сломалось, а проблему надо решать срочно. Предположительная причина: платформа 8.3.20 более строго относится к типизации данных в запросах, чем предыдущие версии, вываливая в случае несоблюдения новшеств малопонятные ошибки.

08.04.2022    4743    Kernelbug    25    

Отборы динамического списка

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Динамический список предоставляет несколько объектов "Отбор". В статье разбирается, какой для чего нужен и как их использовать на форме. Рассматриваются только возможности платформы (без БСП).

28.03.2022    9108    Gladkov_Anton    4    

Фишки платформы 1С 8.3 для начинающего разработчика

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Россия Бесплатно (free)

В данной заметке рассмотрены вспомогательные инструменты платформы, которыми часто пренебрегают начинающие программисты 1С.

11.03.2022    8719    Dimbayyyy    96    

Как прикрутить ГУИД к регистру сведений Промо

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    24355    m-rv    18    

Экспертный кейс. Расследование деградации производительности системы. Проведение документа “Поступление товаров и услуг” (1С:ERP 2)

Механизмы платформы 1С Запросы HighLoad оптимизация Платформа 1С v8.3 1С:ERP Управление предприятием 2 Бесплатно (free)

В ходе проведения нагрузочного тестирования одним из наших клиентов была выявлена сильная деградация производительности системы в целом и, в частности, выполнения ключевой операции “Проведение документа поступление товаров и услуг” в течение выполнения теста. Согласно данным подсистемы БСП “Оценка производительности”, время выполнения ключевой операции “Проведение документа поступление товаров и услуг” возрастало в процессе тестирования с 15-20 секунд в начале тестирования до 150-200 секунд в его финале.

02.03.2022    3350    it-expertise    47    

Модульная архитектура или пара слов о расширениях. Часть I (мысли, рассуждения)

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Статья-размышление о том, какое может быть применение технологии расширений 1С и зачем нам, разработчикам/программистам на 1С, знать общепринятые паттерны проектирования приложений. Итак, а что если я вам скажу, что технология расширений 1С - это одно из прекрасных новшеств компании 1С? Пусть эта статья будет хвалебной одой расширениям 1С.

14.02.2022    5215    amon_ra    67    

Синхронный и асинхронный вызов в новых версиях платформы

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Начиная с платформы 8.3.18.1128 переработана технология работы с асинхронными вызовами. В данной статье хочу описать новые асинхронные вызовы и сравнить их с предыдущими на примере функции - Вопрос на клиенте.

31.01.2022    4570    Shining_ninja    17    

Метод формирования движений в типовых регистрах нетиповыми регистраторами Промо

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    31606    itriot11    34    

Несколько простых приемов для удобной работы в конфигураторе

Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Простая и удобная среда разработки 1С:Предприятия позволяет практически любому человеку начать работать под капотом 1С - в конфигураторе. Время идет, новички становятся программистами, специалистами, а об удобных приемах работы узнают годами, по ходу своего карьерного пути. А здорово было бы, если бы все знали удобные приемы в начале своего пути? Эти несколько приемов будут полезны новичкам, так как они затрагивают ту область работы, с которой приходится сталкиваться в начале карьеры.

12.11.2021    10037    acces969    95    

Как спроектировать структуру регистра сведений

Механизмы платформы 1С Платформа 1С v8.3 Запросы Бесплатно (free)

«Что может быть проще?» — это первое, что приходит в голову. Но что, если это не так? В этой статье мы попробуем затронуть некоторые вопросы, которые могут возникнуть при проектировании больших регистров.

08.11.2021    7375    Neti    60    

О вложенных попытках, исключениях и о представлении ошибок

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данной статье, на небольшом примере, мне бы хотелось показать, как себя ведут вложенные "Попытка-Исключение". А также о том, чем отличаются методы ОписаниеОшибки() и ИнформацияОбОшибке().

07.11.2021    6492    Nicholas    17    

Ускоряем 1С: модули с повторным использованием возвращаемых значений Промо

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

По роду своей деятельности, мне часто приходится обсуждать с программистами детали реализации той или иной функциональности. Очень часто, разговаривая даже с квалифицированными специалистами я сталкиваюсь с незнанием сути платформенной функциональности Повторного использования возвращаемых значений общих модулей. В данной статье я постараюсь дать краткий обзор и основные особенности этой функциональности.

04.09.2017    62149    m-rv    63    

С конфигуратора на EDT. Привычки, которые придется поменять

EDT Языки и среды Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Решил перейти на EDT, чтобы повысить эффективность разработки? А теперь приостановись и выдохни! Я расскажу сейчас о том, из-за чего многие новички в EDT (будучи матёрыми кодерами в конфигураторе) воспринимают встречу с новшествами так, будто их с велосипеда пересадили за штурвал Боинга.

16.09.2021    9134    stas_ganiev    19    

Обработчик ожидания. Нюансы

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

ПодключитьОбработчикОжидания: некоторые подробности и особенности работы

24.08.2021    16605    Yashazz    25    

Прогресс-бар в поле динамического списка

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Изображаем прогресс-бары в колонке динамического списка

23.08.2021    3815    Yashazz    13    

Регулярные выражения без внешних компонент? Легко! Промо

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Сложный способ организовать проверку строки с помощью регулярного выражения в 1С. При этом ни одна внешняя компонента не пострадала. Ну и от платформы (Linux, MustDie) - не зависит.

04.03.2016    76833    starik-2005    111    

ПриПолученииДанныхНаСервере + Контекст формы. Лайфхак

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Передать свои произвольные данные в событие, которое "без контекста"? Легко!

13.08.2021    5515    Yashazz    16    

Новичок новичку: как добавить программно кнопку на форму путем расширения

Механизмы платформы 1С Платформа 1С v8.3 Россия Бесплатно (free)

Рассказываю очень простым языком, как добавить программно кнопку в типовую конфигурацию. Сам новичок в этом деле и рассказываю на "новичковом" языке.

13.05.2021    25601    user1312100    25    

Чем воспользоваться для распознавания котиков в 1С?

Математика и алгоритмы Языки и среды Платформа 1С v8.3 Бесплатно (free)

На митапе по инструментам для расширения возможностей 1С выступил Олег Филиппов. Он сравнил подходы Native API, COM, Docker и Serverless, и рассказал, как упростить использование в 1С алгоритмов, реализованных на других языках, с помощью облачной технологии «Функция как сервис».

12.04.2021    4242    comol    10    

Методика переопределения и вызова обработчиков событий обычной формы Промо

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Россия Бесплатно (free)

Каждый из нас хотя бы раз задумывался над тем, как было бы удобно, если бы мы могли переопределять обработчики событий формы, сохраняя возможность вызова старого обработчика независимо от его имени. В этой статье изложен метод, который позволяет реализовать эту возможность.

24.06.2007    91045    tormozit    31    

Программное создание расширения

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Создание нового расширения "на лету", только штатными средствами 1С.

06.04.2021    5747    Yashazz    14    

Советы из Желтой тетради 📒 #1

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

В этой публикации я собрал в одном месте часть советов и лайфхаков, которые открыл для себя в последнее время. Регулярно я публикую их в своём телеграм-блоге "Жёлтая тетрадь 📒 Блог программиста 1С", здесь же - дайджест этих публикаций.

15.03.2021    5822    builin    120    

Отладка подключаемых обработок Промо

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

На самом деле для этого не нужно ни изменять конфигурацию, ни пользоваться вспомогательной обработкой-отладчиком.. Все просто :)

04.01.2017    84739    unichkin    119    

Флаг "Использовать ПОЧТИ всегда", или Нюанс динамических списков

Механизмы платформы 1С Платформа 1С v8.3 Платформа 1C v8.2 Конфигурации 1cv8 Бесплатно (free)

Небольшая пятничная история по программной работе со строкой динамического списка.

11.02.2021    7790    SeiOkami    36    

Расширенный автоподбор при вводе по строке в поле ввода в управляемых формах

Механизмы платформы 1С Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Бесплатно (free)

Началось все с того, что штатный автоподбор при вводе по строке в поле ввода для некоторых больших справочников устраивать перестал. Вообще, для способа поиска строки "Любая часть" он работает на первый взгляд очень хорошо: работает как полнотекстовый (т.е. по нескольким словам) даже без активации полнотекстового поиска, красиво подсвечивает слова поиска в результатах. Казалось бы, все отлично. Но есть неприятное ограничение - всего лишь 10 значений в результирующем списке (у вас может быть несколько больше, так как платформа неявно добавляет результаты поиска по истории ввода). Для небольших справочников или справочников с разнородным ассортиментом все хорошо. Но не в моей ситуации. А простых путей увеличить количество выдаваемых строк на момент написания статьи мне обнаружить не удалось. Пришлось полностью переопределять автоподбор. Ниже речь пойдет именно об этом. И, к слову, в типовых конфигурациях для некоторых справочников используются похожие приемы для увеличения количества строк результата автоподбора.

21.01.2021    7160    herfis    7    

О формах 1С замолвите слово... Необычное использование знакомого всем объекта

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Неочевидно, но форму 1С можно использовать как универсальный объект, который доступен на клиенте и имеет уникальный набор свойств, методов, событий и конструктор, принимающий параметры. При этом у формы может не быть интерфейса, и ее можно даже не открывать. О реальных примерах применения такого подхода пойдет рассказ.

13.01.2021    9438    CyberCerber    46    

Программные перечисления, ч.2: приемы кэширования при разработке Промо

Универсальные функции Механизмы платформы 1С Запросы Платформа 1С v8.3 Бесплатно (free)

Все знают, что такое кэш, и зачем он нужен. Но в 1С разработчик обычно использует кэширование только на уровне конфигурации, а в какой-нибудь обработке скорее ломает голову над запросом - как получить все данные за один заход... Хочется рассказать о том, как можно добиться хороших результатов с стратегией "разделяй и властвуй".

30.10.2017    29118    unichkin    18    

Наследование свойств элементов, или Как пользователь может сломать вашу форму

Механизмы платформы 1С Платформа 1С v8.3 Платформа 1C v8.2 Конфигурации 1cv8 Бесплатно (free)

В 1С можно установить свойства ТолькоПросмотр, Доступность и Видимость не только на элементы формы, но и на группы элементов. Но стоит ли так делать? Оказывается, пользователь может обойти запреты, которые установлены на папку. Об этом подробнее в видео.

12.01.2021    5378    SeiOkami    27    

Использование JavaScript для обработки данных в 1с

Языки и среды Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В статье мы передадим данные в JavaScript и получим результат обратно в 1С-объекты средствами JSON. Также "поиграем" с переданными данными.

02.01.2021    9806    John_d    21    

Ускоряем медленный/долгий и тормозной стандартный поиск по динамическому списку, настраиваем его под себя

Механизмы платформы 1С Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Бесплатно (free)

Пользователи привыкли искать на форме списка, но, вбивая в поиск некорректные данные, могут завесить всю систему, а если еще искать нужно по НЕ полям списка, то решение только в своём поиске - все это решим в публикации с открытым кодом.

14.12.2020    33663    SizovE    2    

Недокументированное использование стандартных обработок из меню "Все функции". Промо

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрены возможности произвольного использования стандартных функций, вызываемых из меню платформы "Все функции" - "Стандартные" (Активные пользователи, Журнал регистрации, Поиск ссылок на объект, Проведение документов ...).

19.06.2015    126042    ekaruk    142    

Передача параметров по значению в языке 1С

Механизмы платформы 1С Платформа 1С v8.3 ИТ-компания Бесплатно (free)

Все мы знаем, что в 1С можно написать такое: Процедура ОбработатьОбъект(Знач Объект) КонецПроцедуры Т.е. тем самым мы передаем в процедуру параметр по значению Далее в статье будут рассмотрены некоторые особенности передачи по значению объектов НЕпримитивных типов.

26.11.2020    4902    direktorSan    9    

Установка отбора для поля ввода управляемой формы через ПараметрыВыбора (без переопределения событий "НачалоВыбора", "Автоподбор")

Механизмы платформы 1С Платформа 1С v8.3 Управляемые формы Бесплатно (free)

Зачастую возникает необходимость ограничить вывод элементов какого-нибудь справочника или перечисления при редактировании поля ввода (отфильтровать доступные для выбора элементы) эта публикация показывает простой и эффективный способ реализации этого.

15.11.2020    11900    Eugen-S    11    

Групповое изменение реквизитов объектов расширений

Механизмы платформы 1С Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Бесплатно (free)

Доработка встроенной обработки "Групповое изменение реквизитов" для возможности изменения ссылочных реквизитов с ссылками на объекты расширения. Работает в Комплексной конфигурации 2.4.

07.11.2020    2585    Alfn    14    

Простая и быстрая эмуляция операций с битовыми строками Промо

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Битовые строки могли бы упростить реализацию некоторых алгоритмов на языке платформы «1С: Предприятие 8». Но пока в платформе операций с битовыми строками нет. В то же время уже сделанные попытки смоделировать эти операции преобразованиями над числами опираются на циклы обработки отдельных битов, что плохо сказывается на скорости их работы. Предлагается новое простое решение, основанное на представлении битовых строк строками символов «0» и «1». Приводится примеры кода выполнения основных логических операций AND, OR, XOR, NO без использования циклов. В качестве прикладной задачи рассмотрено получение последовательных значений кода Грэя, который можно использовать для ускорения перебора вариантов.

22.06.2016    30901    ildarovich    14    

Лайфхаки для разработчиков 1С. Часть 1

Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Россия Бесплатно (free)

Собрали 20 лайфхаков, которые используют наши программисты при работе с 1С. Формы, контрагенты, СКД, процедуры, глюки платформы и многое другое. В этой статье публикуем первую часть.

30.09.2020    8340    Neti    47    

Контекст любого объекта конструкцией #Если Фамилия Тогда

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Делаем инициализацию переменной в "своей" инструкции препроцессора, для получения контекстной подсказки объекта через точку. В дальнейшем в компилированном коде сама инициализация игнорируется, т.к. "своя" инструкция препроцессора НИКОГДА не выполняется.

17.08.2020    3051    sapervodichka    36    

Новое отображение ошибок в 1С

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрим развитие механизма отображения ошибок в 1С (начиная с 8.3.17)

10.08.2020    30338    SeiOkami    44    

Расширения конфигурации. Полезные советы для разработки Промо

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Полезные советы для разработки и применения расширений. Как подключить отладку, как сохранять данные, последовательность обработчиков, использование модуля менеджера и другое.

12.01.2016    363743    mrXoxot    209    

Динамический список, ключи записей. Нюансы

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Заметки об особенностях динамических списков с произвольным запросом и видом ключа, отличным от "Авто"

07.08.2020    8811    Yashazz    6    

Вы запускаете приложения, но делаете это без уважения

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

О запуске сторонних приложений и скриптов из кода встроенного языка платформы 1С.

21.07.2020    13048    Infostart    32    

Использование Стека вызовов в качестве условия оператора Если [...] Тогда

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Делюсь интересным приёмом, позволяющим использовать данные стека исполнения кода 1С в качестве условия, накладываемого на выполнение кода.

12.07.2020    11210    sapervodichka    63    

Hello, Executor! Познакомимся с языком 1С:Исполнитель и сразу попытаемся его усовершенствовать

Языки и среды Платформа 1С v8.3 Бесплатно (free)

На прошлой неделе произошел долгожданный громкий релиз в мире 1С: вышла бета версия 1С:Исполнителя. И пусть не оправдались все ожидания после анонса, пусть язык еще сырой, что-то сделать на нем очень интересно. Посмотрим, что это такое, и даже произведем небольшую модернизацию языка (Velocity-pad Costilization).

23.06.2020    15040    CyberCerber    294